ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..), isHsBoot,
  16                           ExternalPackageState(..), HomePackageTable,
  17                           Deprecs(..), FixityEnv, FixItem,
  18                           lookupType, unQualInScope )
  19 import Module           ( Module, unitModuleEnv )
  20 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  21                           LocalRdrEnv, emptyLocalRdrEnv )
  22 import Name             ( Name, isInternalName )
  23 import Type             ( Type )
  24 import NameEnv          ( extendNameEnvList )
  25 import InstEnv          ( emptyInstEnv )
  26
  27 import VarSet           ( emptyVarSet )
  28 import VarEnv           ( TidyEnv, emptyTidyEnv, emptyVarEnv )
  29 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  30                           mkWarnMsg, printErrorsAndWarnings,
  31                           mkLocMessage, mkLongErrMsg )
  32 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  33 import NameEnv          ( emptyNameEnv )
  34 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  35 import OccName          ( emptyOccEnv )
  36 import Bag              ( emptyBag )
  37 import Outputable
  38 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  39 import Unique           ( Unique )
  40 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  41 import StaticFlags      ( opt_PprStyle_Debug )
  42 import Bag              ( snocBag, unionBags )
  43 import Panic            ( showException )
  44
  45 import Maybe            ( isJust )
  46 import IO               ( stderr )
  47 import DATA_IOREF       ( newIORef, readIORef )
  48 import EXCEPTION        ( Exception )
  49 \end{code}
  50
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55                         initTc
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 \begin{code}
  60 ioToTcRn :: IO r -> TcRn r
  61 ioToTcRn = ioToIOEnv
  62 \end{code}
  63
  64 \begin{code}
  65 initTc :: HscEnv
  66        -> HscSource
  67        -> Module
  68        -> TcM r
  69        -> IO (Messages, Maybe r)
  70                 -- Nothing => error thrown by the thing inside
  71                 -- (error messages should have been printed already)
  72
  73 initTc hsc_env hsc_src mod do_this
  74  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  75         tvs_var      <- newIORef emptyVarSet ;
  76         type_env_var <- newIORef emptyNameEnv ;
  77         dfuns_var    <- newIORef emptyNameSet ;
  78         keep_var     <- newIORef emptyNameSet ;
  79         th_var       <- newIORef False ;
  80         dfun_n_var   <- newIORef 1 ;
  81
  82         let {
  83              gbl_env = TcGblEnv {
  84                 tcg_mod      = mod,
  85                 tcg_src      = hsc_src,
  86                 tcg_rdr_env  = emptyGlobalRdrEnv,
  87                 tcg_fix_env  = emptyNameEnv,
  88                 tcg_default  = Nothing,
  89                 tcg_type_env = emptyNameEnv,
  90                 tcg_type_env_var = type_env_var,
  91                 tcg_inst_env  = emptyInstEnv,
  92                 tcg_inst_uses = dfuns_var,
  93                 tcg_th_used   = th_var,
  94                 tcg_exports  = emptyNameSet,
  95                 tcg_imports  = init_imports,
  96                 tcg_dus      = emptyDUs,
  97                 tcg_rn_decls = Nothing,
  98                 tcg_binds    = emptyLHsBinds,
  99                 tcg_deprecs  = NoDeprecs,
 100                 tcg_insts    = [],
 101                 tcg_rules    = [],
 102                 tcg_fords    = [],
 103                 tcg_dfun_n   = dfun_n_var,
 104                 tcg_keep     = keep_var
 105              } ;
 106              lcl_env = TcLclEnv {
 107                 tcl_errs       = errs_var,
 108                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 109                 tcl_ctxt       = [],
 110                 tcl_rdr        = emptyLocalRdrEnv,
 111                 tcl_th_ctxt    = topStage,
 112                 tcl_arrow_ctxt = panic "initTc:arrow",  -- only used inside proc
 113                 tcl_env        = emptyNameEnv,
 114                 tcl_tyvars     = tvs_var,
 115                 tcl_lie        = panic "initTc:LIE",    -- LIE only valid inside a getLIE
 116                 tcl_gadt       = emptyVarEnv
 117              } ;
 118         } ;
 119
 120         -- OK, here's the business end!
 121         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 122                              do { r <- tryM do_this
 123                                 ; case r of
 124                                     Right res -> return (Just res)
 125                                     Left _    -> return Nothing } ;
 126
 127         -- Collect any error messages
 128         msgs <- readIORef errs_var ;
 129
 130         let { dflags = hsc_dflags hsc_env
 131             ; final_res | errorsFound dflags msgs = Nothing
 132                         | otherwise               = maybe_res } ;
 133
 134         return (msgs, final_res)
 135     }
 136   where
 137     init_imports = emptyImportAvails { imp_env = unitModuleEnv mod emptyNameSet }
 138         -- Initialise tcg_imports with an empty set of bindings for
 139         -- this module, so that if we see 'module M' in the export
 140         -- list, and there are no bindings in M, we don't bleat
 141         -- "unknown module M".
 142
 143 initTcPrintErrors       -- Used from the interactive loop only
 144        :: HscEnv
 145        -> Module
 146        -> TcM r
 147        -> IO (Maybe r)
 148 initTcPrintErrors env mod todo = do
 149   (msgs, res) <- initTc env HsSrcFile mod todo
 150   printErrorsAndWarnings msgs
 151   return res
 152
 153 -- mkImpTypeEnv makes the imported symbol table
 154 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 155              -> Name -> Maybe TyThing
 156 mkImpTypeEnv pcs hpt = lookup
 157   where
 158     pte = eps_PTE pcs
 159     lookup name | isInternalName name = Nothing
 160                 | otherwise           = lookupType hpt pte name
 161 \end{code}
 162
 163
 164 %************************************************************************
 165 %*                                                                      *
 166                 Initialisation
 167 %*                                                                      *
 168 %************************************************************************
 169
 170
 171 \begin{code}
 172 initTcRnIf :: Char              -- Tag for unique supply
 173            -> HscEnv
 174            -> gbl -> lcl
 175            -> TcRnIf gbl lcl a
 176            -> IO a
 177 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 178    = do { us     <- mkSplitUniqSupply uniq_tag ;
 179         ; us_var <- newIORef us ;
 180
 181         ; let { env = Env { env_top = hsc_env,
 182                             env_us  = us_var,
 183                             env_gbl = gbl_env,
 184                             env_lcl = lcl_env } }
 185
 186         ; runIOEnv env thing_inside
 187         }
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192                 Simple accessors
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 getTopEnv :: TcRnIf gbl lcl HscEnv
 198 getTopEnv = do { env <- getEnv; return (env_top env) }
 199
 200 getGblEnv :: TcRnIf gbl lcl gbl
 201 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 202
 203 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 204 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 205                           env { env_gbl = upd gbl })
 206
 207 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 208 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 209
 210 getLclEnv :: TcRnIf gbl lcl lcl
 211 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 212
 213 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 214 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 215                           env { env_lcl = upd lcl })
 216
 217 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 218 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 219
 220 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 221 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 222
 223 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 224 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 225 \end{code}
 226
 227
 228 Command-line flags
 229
 230 \begin{code}
 231 getDOpts :: TcRnIf gbl lcl DynFlags
 232 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 233
 234 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 235 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 236
 237 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 238 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 239                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 240
 241 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 242 ifOptM flag thing_inside = do { b <- doptM flag;
 243                                 if b then thing_inside else return () }
 244
 245 getGhciMode :: TcRnIf gbl lcl GhcMode
 246 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 247 \end{code}
 248
 249 \begin{code}
 250 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 251 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 252
 253 getEps :: TcRnIf gbl lcl ExternalPackageState
 254 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 255
 256 -- Updating the EPS.  This should be an atomic operation.
 257 -- Note the delicate 'seq' which forces the EPS before putting it in the
 258 -- variable.  Otherwise what happens is that we get
 259 --      write eps_var (....(unsafeRead eps_var)....)
 260 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 261 -- we make the unsafeRead happen before we update the variable.
 262
 263 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 264           -> TcRnIf gbl lcl a
 265 updateEps upd_fn = do   { traceIf (text "updating EPS")
 266                         ; eps_var <- getEpsVar
 267                         ; eps <- readMutVar eps_var
 268                         ; let { (eps', val) = upd_fn eps }
 269                         ; seq eps' (writeMutVar eps_var eps')
 270                         ; return val }
 271
 272 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 273            -> TcRnIf gbl lcl ()
 274 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 275                         ; eps_var <- getEpsVar
 276                         ; eps <- readMutVar eps_var
 277                         ; let { eps' = upd_fn eps }
 278                         ; seq eps' (writeMutVar eps_var eps') }
 279
 280 getHpt :: TcRnIf gbl lcl HomePackageTable
 281 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 282
 283 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 284 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 285                   ; return (eps, hsc_HPT env) }
 286 \end{code}
 287
 288 %************************************************************************
 289 %*                                                                      *
 290                 Unique supply
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 \begin{code}
 295 newUnique :: TcRnIf gbl lcl Unique
 296 newUnique = do { us <- newUniqueSupply ;
 297                  return (uniqFromSupply us) }
 298
 299 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 300 newUniqueSupply
 301  = do { env <- getEnv ;
 302         let { u_var = env_us env } ;
 303         us <- readMutVar u_var ;
 304         let { (us1, us2) = splitUniqSupply us } ;
 305         writeMutVar u_var us1 ;
 306         return us2 }
 307 \end{code}
 308
 309
 310 %************************************************************************
 311 %*                                                                      *
 312                 Debugging
 313 %*                                                                      *
 314 %************************************************************************
 315
 316 \begin{code}
 317 traceTc, traceRn :: SDoc -> TcRn ()
 318 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 319 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 320 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 321
 322
 323 traceIf :: SDoc -> TcRnIf m n ()
 324 traceIf      = dumpOptIf Opt_D_dump_if_trace
 325 traceHiDiffs = dumpOptIf Opt_D_dump_hi_diffs
 326
 327
 328 dumpOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 329 dumpOptIf flag doc = ifOptM flag $
 330                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 331
 332 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 333 dumpOptTcRn flag doc = ifOptM flag $ do
 334                         { ctxt <- getErrCtxt
 335                         ; loc  <- getSrcSpanM
 336                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 337                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 338                         ; dumpTcRn real_doc }
 339
 340 dumpTcRn :: SDoc -> TcRn ()
 341 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 342                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 343 \end{code}
 344
 345
 346 %************************************************************************
 347 %*                                                                      *
 348                 Typechecker global environment
 349 %*                                                                      *
 350 %************************************************************************
 351
 352 \begin{code}
 353 getModule :: TcRn Module
 354 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 355
 356 tcIsHsBoot :: TcRn Bool
 357 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 358
 359 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 360 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 361
 362 getImports :: TcRn ImportAvails
 363 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 364
 365 getFixityEnv :: TcRn FixityEnv
 366 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 367
 368 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 369 extendFixityEnv new_bit
 370   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 371                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 372
 373 getDefaultTys :: TcRn (Maybe [Type])
 374 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 375 \end{code}
 376
 377 %************************************************************************
 378 %*                                                                      *
 379                 Error management
 380 %*                                                                      *
 381 %************************************************************************
 382
 383 \begin{code}
 384 getSrcSpanM :: TcRn SrcSpan
 385         -- Avoid clash with Name.getSrcLoc
 386 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 387
 388 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 389 setSrcSpan loc thing_inside
 390   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 391   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 392
 393 addLocM :: (a -> TcM b) -> Located a -> TcM b
 394 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 395
 396 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 397 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 398
 399 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 400 wrapLocFstM fn (L loc a) =
 401   setSrcSpan loc $ do
 402     (b,c) <- fn a
 403     return (L loc b, c)
 404
 405 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 406 wrapLocSndM fn (L loc a) =
 407   setSrcSpan loc $ do
 408     (b,c) <- fn a
 409     return (b, L loc c)
 410 \end{code}
 411
 412
 413 \begin{code}
 414 getErrsVar :: TcRn (TcRef Messages)
 415 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 416
 417 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 418 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 419
 420 addErr :: Message -> TcRn ()
 421 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 422
 423 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 424 addLocErr (L loc e) fn = addErrAt loc (fn e)
 425
 426 addErrAt :: SrcSpan -> Message -> TcRn ()
 427 addErrAt loc msg = addLongErrAt loc msg empty
 428
 429 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 430 addLongErrAt loc msg extra
 431  = do {  errs_var <- getErrsVar ;
 432          rdr_env <- getGlobalRdrEnv ;
 433          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 434          (warns, errs) <- readMutVar errs_var ;
 435          writeMutVar errs_var (warns, errs `snocBag` err) }
 436
 437 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 438 addErrs msgs = mappM_ add msgs
 439              where
 440                add (loc,msg) = addErrAt loc msg
 441
 442 addReport :: Message -> TcRn ()
 443 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 444
 445 addReportAt :: SrcSpan -> Message -> TcRn ()
 446 addReportAt loc msg
 447   = do { errs_var <- getErrsVar ;
 448          rdr_env <- getGlobalRdrEnv ;
 449          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 450          (warns, errs) <- readMutVar errs_var ;
 451          writeMutVar errs_var (warns `snocBag` warn, errs) }
 452
 453 addWarn :: Message -> TcRn ()
 454 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 455
 456 addWarnAt :: SrcSpan -> Message -> TcRn ()
 457 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 458
 459 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 460 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 461
 462 checkErr :: Bool -> Message -> TcRn ()
 463 -- Add the error if the bool is False
 464 checkErr ok msg = checkM ok (addErr msg)
 465
 466 warnIf :: Bool -> Message -> TcRn ()
 467 warnIf True  msg = addWarn msg
 468 warnIf False msg = return ()
 469
 470 addMessages :: Messages -> TcRn ()
 471 addMessages (m_warns, m_errs)
 472   = do { errs_var <- getErrsVar ;
 473          (warns, errs) <- readMutVar errs_var ;
 474          writeMutVar errs_var (warns `unionBags` m_warns,
 475                                errs  `unionBags` m_errs) }
 476
 477 discardWarnings :: TcRn a -> TcRn a
 478 -- Ignore warnings inside the thing inside;
 479 -- used to ignore-unused-variable warnings inside derived code
 480 -- With -dppr-debug, the effects is switched off, so you can still see
 481 -- what warnings derived code would give
 482 discardWarnings thing_inside
 483   | opt_PprStyle_Debug = thing_inside
 484   | otherwise
 485   = do  { errs_var <- newMutVar emptyMessages
 486         ; result <- setErrsVar errs_var thing_inside
 487         ; (_warns, errs) <- readMutVar errs_var
 488         ; addMessages (emptyBag, errs)
 489         ; return result }
 490 \end{code}
 491
 492
 493 \begin{code}
 494 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 495          -> TcRn r      -- Main action: do this first
 496          -> TcRn r
 497 recoverM recover thing
 498   = do { mb_res <- try_m thing ;
 499          case mb_res of
 500            Left exn  -> recover
 501            Right res -> returnM res }
 502
 503 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 504     -- (tryTc m) executes m, and returns
 505     --  Just r,  if m succeeds (returning r) and caused no errors
 506     --  Nothing, if m fails, or caused errors
 507     -- It also returns all the errors accumulated by m
 508     --  (even in the Just case, there might be warnings)
 509     --
 510     -- It always succeeds (never raises an exception)
 511 tryTc m
 512  = do { errs_var <- newMutVar emptyMessages ;
 513
 514         mb_r <- try_m (setErrsVar errs_var m) ;
 515
 516         new_errs <- readMutVar errs_var ;
 517
 518         dflags <- getDOpts ;
 519
 520         return (new_errs,
 521                 case mb_r of
 522                   Left exn -> Nothing
 523                   Right r | errorsFound dflags new_errs -> Nothing
 524                           | otherwise                   -> Just r)
 525    }
 526
 527 try_m :: TcRn r -> TcRn (Either Exception r)
 528 -- Does try_m, with a debug-trace on failure
 529 try_m thing
 530   = do { mb_r <- tryM thing ;
 531          case mb_r of
 532              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 533              Right r  -> return mb_r }
 534   where
 535     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 536
 537 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 538 -- Just like tryTc, except that it ensures that the LIE
 539 -- for the thing is propagated only if there are no errors
 540 -- Hence it's restricted to the type-check monad
 541 tryTcLIE thing_inside
 542   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 543          ifM (isJust mb_r) (extendLIEs lie) ;
 544          return (errs, mb_r) }
 545
 546 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 547 -- (tryTcLIE_ r m) tries m; if it succeeds it returns it,
 548 -- otherwise it returns r.  Any error messages added by m are discarded,
 549 -- whether or not m succeeds.
 550 tryTcLIE_ recover main
 551   = do { (_msgs, mb_res) <- tryTcLIE main ;
 552          case mb_res of
 553            Just res -> return res
 554            Nothing  -> recover }
 555
 556 checkNoErrs :: TcM r -> TcM r
 557 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 558 -- If m fails then (checkNoErrsTc m) fails.
 559 -- If m succeeds, it checks whether m generated any errors messages
 560 --      (it might have recovered internally)
 561 --      If so, it fails too.
 562 -- Regardless, any errors generated by m are propagated to the enclosing context.
 563 checkNoErrs main
 564   = do { (msgs, mb_res) <- tryTcLIE main ;
 565          addMessages msgs ;
 566          case mb_res of
 567            Just r  -> return r
 568            Nothing -> failM
 569    }
 570
 571 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 572 --      ifErrsM bale_out main
 573 -- does 'bale_out' if there are errors in errors collection
 574 -- otherwise does 'main'
 575 ifErrsM bale_out normal
 576  = do { errs_var <- getErrsVar ;
 577         msgs <- readMutVar errs_var ;
 578         dflags <- getDOpts ;
 579         if errorsFound dflags msgs then
 580            bale_out
 581         else
 582            normal }
 583
 584 failIfErrsM :: TcRn ()
 585 -- Useful to avoid error cascades
 586 failIfErrsM = ifErrsM failM (return ())
 587 \end{code}
 588
 589
 590 %************************************************************************
 591 %*                                                                      *
 592         Context management and error message generation
 593                     for the type checker
 594 %*                                                                      *
 595 %************************************************************************
 596
 597 \begin{code}
 598 getErrCtxt :: TcM ErrCtxt
 599 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 600
 601 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 602 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 603
 604 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 605 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 606
 607 addErrCtxt :: Message -> TcM a -> TcM a
 608 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 609
 610 -- Helper function for the above
 611 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 612 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 613                            env { tcl_ctxt = upd ctxt })
 614
 615 -- Conditionally add an error context
 616 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 617 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 618 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 619
 620 popErrCtxt :: TcM a -> TcM a
 621 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 622
 623 getInstLoc :: InstOrigin -> TcM InstLoc
 624 getInstLoc origin
 625   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 626          return (InstLoc origin loc (tcl_ctxt env)) }
 627
 628 addInstCtxt :: InstLoc -> TcM a -> TcM a
 629 -- Add the SrcSpan and context from the first Inst in the list
 630 --      (they all have similar locations)
 631 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 632   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 633 \end{code}
 634
 635     The addErrTc functions add an error message, but do not cause failure.
 636     The 'M' variants pass a TidyEnv that has already been used to
 637     tidy up the message; we then use it to tidy the context messages
 638
 639 \begin{code}
 640 addErrTc :: Message -> TcM ()
 641 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 642
 643 addErrsTc :: [Message] -> TcM ()
 644 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 645
 646 addErrTcM :: (TidyEnv, Message) -> TcM ()
 647 addErrTcM (tidy_env, err_msg)
 648   = do { ctxt <- getErrCtxt ;
 649          loc  <- getSrcSpanM ;
 650          add_err_tcm tidy_env err_msg loc ctxt }
 651 \end{code}
 652
 653 The failWith functions add an error message and cause failure
 654
 655 \begin{code}
 656 failWithTc :: Message -> TcM a               -- Add an error message and fail
 657 failWithTc err_msg
 658   = addErrTc err_msg >> failM
 659
 660 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 661 failWithTcM local_and_msg
 662   = addErrTcM local_and_msg >> failM
 663
 664 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 665 checkTc True  err = returnM ()
 666 checkTc False err = failWithTc err
 667 \end{code}
 668
 669         Warnings have no 'M' variant, nor failure
 670
 671 \begin{code}
 672 addWarnTc :: Message -> TcM ()
 673 addWarnTc msg
 674  = do { ctxt <- getErrCtxt ;
 675         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 676         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 677
 678 warnTc :: Bool -> Message -> TcM ()
 679 warnTc warn_if_true warn_msg
 680   | warn_if_true = addWarnTc warn_msg
 681   | otherwise    = return ()
 682 \end{code}
 683
 684         Helper functions
 685
 686 \begin{code}
 687 add_err_tcm tidy_env err_msg loc ctxt
 688  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 689         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 690
 691 do_ctxt tidy_env []
 692  = return []
 693 do_ctxt tidy_env (c:cs)
 694  = do { (tidy_env', m) <- c tidy_env  ;
 695         ms             <- do_ctxt tidy_env' cs  ;
 696         return (m:ms) }
 697
 698 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 699                  | otherwise          = take 3 ctxt
 700 \end{code}
 701
 702 debugTc is useful for monadi debugging code
 703
 704 \begin{code}
 705 debugTc :: TcM () -> TcM ()
 706 #ifdef DEBUG
 707 debugTc thing = thing
 708 #else
 709 debugTc thing = return ()
 710 #endif
 711 \end{code}
 712
 713  %************************************************************************
 714 %*                                                                      *
 715              Type constraints (the so-called LIE)
 716 %*                                                                      *
 717 %************************************************************************
 718
 719 \begin{code}
 720 nextDFunIndex :: TcM Int        -- Get the next dfun index
 721 nextDFunIndex = do { env <- getGblEnv
 722                    ; let dfun_n_var = tcg_dfun_n env
 723                    ; n <- readMutVar dfun_n_var
 724                    ; writeMutVar dfun_n_var (n+1)
 725                    ; return n }
 726
 727 getLIEVar :: TcM (TcRef LIE)
 728 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 729
 730 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 731 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 732
 733 getLIE :: TcM a -> TcM (a, [Inst])
 734 -- (getLIE m) runs m, and returns the type constraints it generates
 735 getLIE thing_inside
 736   = do { lie_var <- newMutVar emptyLIE ;
 737          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 738                           thing_inside ;
 739          lie <- readMutVar lie_var ;
 740          return (res, lieToList lie) }
 741
 742 extendLIE :: Inst -> TcM ()
 743 extendLIE inst
 744   = do { lie_var <- getLIEVar ;
 745          lie <- readMutVar lie_var ;
 746          writeMutVar lie_var (inst `consLIE` lie) }
 747
 748 extendLIEs :: [Inst] -> TcM ()
 749 extendLIEs []
 750   = returnM ()
 751 extendLIEs insts
 752   = do { lie_var <- getLIEVar ;
 753          lie <- readMutVar lie_var ;
 754          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 755 \end{code}
 756
 757 \begin{code}
 758 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 759 -- Set the local type envt, but do *not* disturb other fields,
 760 -- notably the lie_var
 761 setLclTypeEnv lcl_env thing_inside
 762   = updLclEnv upd thing_inside
 763   where
 764     upd env = env { tcl_env = tcl_env lcl_env,
 765                     tcl_tyvars = tcl_tyvars lcl_env }
 766 \end{code}
 767
 768
 769 %************************************************************************
 770 %*                                                                      *
 771              Template Haskell context
 772 %*                                                                      *
 773 %************************************************************************
 774
 775 \begin{code}
 776 recordThUse :: TcM ()
 777 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 778
 779 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 780 keepAliveTc n = do { env <- getGblEnv;
 781                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 782
 783 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 784 keepAliveSetTc ns = do { env <- getGblEnv;
 785                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 786
 787 getStage :: TcM ThStage
 788 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 789
 790 setStage :: ThStage -> TcM a -> TcM a
 791 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 792 \end{code}
 793
 794
 795 %************************************************************************
 796 %*                                                                      *
 797              Stuff for the renamer's local env
 798 %*                                                                      *
 799 %************************************************************************
 800
 801 \begin{code}
 802 getLocalRdrEnv :: RnM LocalRdrEnv
 803 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 804
 805 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 806 setLocalRdrEnv rdr_env thing_inside
 807   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 808 \end{code}
 809
 810
 811 %************************************************************************
 812 %*                                                                      *
 813              Stuff for interface decls
 814 %*                                                                      *
 815 %************************************************************************
 816
 817 \begin{code}
 818 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 819 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 820                                 if_loc     = loc,
 821                                 if_tv_env  = emptyOccEnv,
 822                                 if_id_env  = emptyOccEnv }
 823
 824 initIfaceTcRn :: IfG a -> TcRn a
 825 initIfaceTcRn thing_inside
 826   = do  { tcg_env <- getGblEnv
 827         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 828               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 829         ; setEnvs (if_env, ()) thing_inside }
 830
 831 initIfaceExtCore :: IfL a -> TcRn a
 832 initIfaceExtCore thing_inside
 833   = do  { tcg_env <- getGblEnv
 834         ; let { mod = tcg_mod tcg_env
 835               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 836               ; if_env = IfGblEnv {
 837                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 838               ; if_lenv = mkIfLclEnv mod doc
 839           }
 840         ; setEnvs (if_env, if_lenv) thing_inside }
 841
 842 initIfaceCheck :: HscEnv -> IfG a -> IO a
 843 -- Used when checking the up-to-date-ness of the old Iface
 844 -- Initialise the environment with no useful info at all
 845 initIfaceCheck hsc_env do_this
 846  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 847         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 848     }
 849
 850 initIfaceTc :: ModIface
 851             -> (TcRef TypeEnv -> IfL a) -> TcRnIf gbl lcl a
 852 -- Used when type-checking checking an up-to-date interface file
 853 -- No type envt from the current module, but we do know the module dependencies
 854 initIfaceTc iface do_this
 855  = do   { tc_env_var <- newMutVar emptyTypeEnv
 856         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 857               ; if_lenv = mkIfLclEnv mod doc
 858            }
 859         ; setEnvs (gbl_env, if_lenv) (do_this tc_env_var)
 860     }
 861   where
 862     mod = mi_module iface
 863     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 864
 865 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 866 -- Used when sucking in new Rules in SimplCore
 867 -- We have available the type envt of the module being compiled, and we must use it
 868 initIfaceRules hsc_env guts do_this
 869  = do   { let {
 870              type_info = (mg_module guts, return (mg_types guts))
 871            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 872            }
 873
 874         -- Run the thing; any exceptions just bubble out from here
 875         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 876     }
 877
 878 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 879 initIfaceLcl mod loc_doc thing_inside
 880   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 881
 882 getIfModule :: IfL Module
 883 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 884
 885 --------------------
 886 failIfM :: Message -> IfL a
 887 -- The Iface monad doesn't have a place to accumulate errors, so we
 888 -- just fall over fast if one happens; it "shouldnt happen".
 889 -- We use IfL here so that we can get context info out of the local env
 890 failIfM msg
 891   = do  { env <- getLclEnv
 892         ; let full_msg = if_loc env $$ nest 2 msg
 893         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 894         ; failM }
 895
 896 --------------------
 897 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 898 -- Run thing_inside in an interleaved thread.
 899 -- It shares everything with the parent thread, so this is DANGEROUS.
 900 --
 901 -- It returns Nothing if the computation fails
 902 --
 903 -- It's used for lazily type-checking interface
 904 -- signatures, which is pretty benign
 905
 906 forkM_maybe doc thing_inside
 907  = do { unsafeInterleaveM $
 908         do { traceIf (text "Starting fork {" <+> doc)
 909            ; mb_res <- tryM thing_inside ;
 910              case mb_res of
 911                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 912                                 ; return (Just r) }
 913                 Left exn -> do {
 914
 915                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 916                     -- Otherwise we silently discard errors. Errors can legitimately
 917                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 918                       ifOptM Opt_D_dump_if_trace
 919                              (print_errs (hang (text "forkM failed:" <+> doc)
 920                                              4 (text (show exn))))
 921
 922                     ; traceIf (text "} ending fork (badly)" <+> doc)
 923                     ; return Nothing }
 924         }}
 925   where
 926     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 927
 928 forkM :: SDoc -> IfL a -> IfL a
 929 forkM doc thing_inside
 930  = do   { mb_res <- forkM_maybe doc thing_inside
 931         ; return (case mb_res of
 932                         Nothing -> pprPanic "forkM" doc
 933                         Just r  -> r) }
 934 \end{code}
 935
 936 %************************************************************************
 937 %*                                                                      *
 938              Stuff for GADTs
 939 %*                                                                      *
 940 %************************************************************************
 941
 942 \begin{code}
 943 getTypeRefinement :: TcM GadtRefinement
 944 getTypeRefinement = do { lcl_env <- getLclEnv; return (tcl_gadt lcl_env) }
 945
 946 setTypeRefinement :: GadtRefinement -> TcM a -> TcM a
 947 setTypeRefinement gadt = updLclEnv (\env -> env { tcl_gadt = gadt })
 948 \end{code}