ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  14                           TyThing, Dependencies(..), TypeEnv, emptyTypeEnv,
  15                           ExternalPackageState(..), HomePackageTable,
  16                           ModDetails(..), HomeModInfo(..),
  17                           Deprecs(..), FixityEnv, FixItem,
  18                           GhciMode, lookupType, unQualInScope )
  19 import Module           ( Module, ModuleName, unitModuleEnv, foldModuleEnv, emptyModuleEnv )
  20 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  21                           LocalRdrEnv, emptyLocalRdrEnv )
  22 import Name             ( Name, isInternalName )
  23 import Type             ( Type )
  24 import NameEnv          ( extendNameEnvList )
  25 import InstEnv          ( InstEnv, emptyInstEnv, extendInstEnv )
  26
  27 import VarSet           ( emptyVarSet )
  28 import VarEnv           ( TidyEnv, emptyTidyEnv )
  29 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  30                           mkErrMsg, mkWarnMsg, printErrorsAndWarnings,
  31                           mkLocMessage, mkLongErrMsg )
  32 import SrcLoc           ( mkGeneralSrcSpan, SrcSpan, Located(..) )
  33 import NameEnv          ( emptyNameEnv )
  34 import NameSet          ( emptyDUs, emptyNameSet )
  35 import OccName          ( emptyOccEnv )
  36 import Module           ( moduleName )
  37 import Bag              ( emptyBag )
  38 import Outputable
  39 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  40 import Unique           ( Unique )
  41 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt, opt_PprStyle_Debug, dopt_set )
  42 import Bag              ( snocBag, unionBags )
  43 import Panic            ( showException )
  44
  45 import Maybe            ( isJust )
  46 import IO               ( stderr )
  47 import DATA_IOREF       ( newIORef, readIORef )
  48 import EXCEPTION        ( Exception )
  49 \end{code}
  50
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55                         initTc
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 \begin{code}
  60 ioToTcRn :: IO r -> TcRn r
  61 ioToTcRn = ioToIOEnv
  62 \end{code}
  63
  64 \begin{code}
  65 initTc :: HscEnv
  66        -> Module
  67        -> TcM r
  68        -> IO (Messages, Maybe r)
  69                 -- Nothing => error thrown by the thing inside
  70                 -- (error messages should have been printed already)
  71
  72 initTc hsc_env mod do_this
  73  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  74         tvs_var      <- newIORef emptyVarSet ;
  75         type_env_var <- newIORef emptyNameEnv ;
  76         dfuns_var    <- newIORef emptyNameSet ;
  77         th_var       <- newIORef False ;
  78
  79         let {
  80              gbl_env = TcGblEnv {
  81                 tcg_mod      = mod,
  82                 tcg_rdr_env  = emptyGlobalRdrEnv,
  83                 tcg_fix_env  = emptyNameEnv,
  84                 tcg_default  = Nothing,
  85                 tcg_type_env = emptyNameEnv,
  86                 tcg_type_env_var = type_env_var,
  87                 tcg_inst_env  = mkImpInstEnv hsc_env,
  88                 tcg_inst_uses = dfuns_var,
  89                 tcg_th_used   = th_var,
  90                 tcg_exports  = emptyNameSet,
  91                 tcg_imports  = init_imports,
  92                 tcg_dus      = emptyDUs,
  93                 tcg_binds    = emptyBag,
  94                 tcg_deprecs  = NoDeprecs,
  95                 tcg_insts    = [],
  96                 tcg_rules    = [],
  97                 tcg_fords    = [],
  98                 tcg_keep     = emptyNameSet
  99              } ;
 100              lcl_env = TcLclEnv {
 101                 tcl_errs       = errs_var,
 102                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level of module"),
 103                 tcl_ctxt       = [],
 104                 tcl_rdr        = emptyLocalRdrEnv,
 105                 tcl_th_ctxt    = topStage,
 106                 tcl_arrow_ctxt = topArrowCtxt,
 107                 tcl_env        = emptyNameEnv,
 108                 tcl_tyvars     = tvs_var,
 109                 tcl_lie        = panic "initTc:LIE"     -- LIE only valid inside a getLIE
 110              } ;
 111         } ;
 112
 113         -- OK, here's the business end!
 114         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 115                              do { r <- tryM do_this
 116                                 ; case r of
 117                                     Right res -> return (Just res)
 118                                     Left _    -> return Nothing } ;
 119
 120         -- Collect any error messages
 121         msgs <- readIORef errs_var ;
 122
 123         let { dflags = hsc_dflags hsc_env
 124             ; final_res | errorsFound dflags msgs = Nothing
 125                         | otherwise               = maybe_res } ;
 126
 127         return (msgs, final_res)
 128     }
 129   where
 130     init_imports = emptyImportAvails { imp_qual = unitModuleEnv mod emptyAvailEnv }
 131         -- Initialise tcg_imports with an empty set of bindings for
 132         -- this module, so that if we see 'module M' in the export
 133         -- list, and there are no bindings in M, we don't bleat
 134         -- "unknown module M".
 135
 136 initTcPrintErrors
 137        :: HscEnv
 138        -> Module
 139        -> TcM r
 140        -> IO (Maybe r)
 141 initTcPrintErrors env mod todo = do
 142   (msgs, res) <- initTc env mod todo
 143   printErrorsAndWarnings msgs
 144   return res
 145
 146 mkImpInstEnv :: HscEnv -> InstEnv
 147 -- At the moment we (wrongly) build an instance environment from all the
 148 -- home-package modules we have already compiled.
 149 -- We should really only get instances from modules below us in the
 150 -- module import tree.
 151 mkImpInstEnv (HscEnv {hsc_dflags = dflags, hsc_HPT = hpt})
 152   = foldModuleEnv (add . md_insts . hm_details) emptyInstEnv hpt
 153   where
 154     add dfuns inst_env = foldl extendInstEnv inst_env dfuns
 155
 156 -- mkImpTypeEnv makes the imported symbol table
 157 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 158              -> Name -> Maybe TyThing
 159 mkImpTypeEnv pcs hpt = lookup
 160   where
 161     pte = eps_PTE pcs
 162     lookup name | isInternalName name = Nothing
 163                 | otherwise           = lookupType hpt pte name
 164 \end{code}
 165
 166
 167 %************************************************************************
 168 %*                                                                      *
 169                 Initialisation
 170 %*                                                                      *
 171 %************************************************************************
 172
 173
 174 \begin{code}
 175 initTcRnIf :: Char              -- Tag for unique supply
 176            -> HscEnv
 177            -> gbl -> lcl
 178            -> TcRnIf gbl lcl a
 179            -> IO a
 180 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 181    = do { us     <- mkSplitUniqSupply uniq_tag ;
 182         ; us_var <- newIORef us ;
 183
 184         ; let { env = Env { env_top = hsc_env,
 185                             env_us  = us_var,
 186                             env_gbl = gbl_env,
 187                             env_lcl = lcl_env } }
 188
 189         ; runIOEnv env thing_inside
 190         }
 191 \end{code}
 192
 193 %************************************************************************
 194 %*                                                                      *
 195                 Simple accessors
 196 %*                                                                      *
 197 %************************************************************************
 198
 199 \begin{code}
 200 getTopEnv :: TcRnIf gbl lcl HscEnv
 201 getTopEnv = do { env <- getEnv; return (env_top env) }
 202
 203 getGblEnv :: TcRnIf gbl lcl gbl
 204 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 205
 206 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 207 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 208                           env { env_gbl = upd gbl })
 209
 210 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 211 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 212
 213 getLclEnv :: TcRnIf gbl lcl lcl
 214 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 215
 216 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 217 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 218                           env { env_lcl = upd lcl })
 219
 220 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 221 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 222
 223 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 224 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 225
 226 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 227 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 228 \end{code}
 229
 230
 231 Command-line flags
 232
 233 \begin{code}
 234 getDOpts :: TcRnIf gbl lcl DynFlags
 235 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 236
 237 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 238 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 239
 240 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 241 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 242                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 243
 244 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 245 ifOptM flag thing_inside = do { b <- doptM flag;
 246                                 if b then thing_inside else return () }
 247
 248 getGhciMode :: TcRnIf gbl lcl GhciMode
 249 getGhciMode = do { env <- getTopEnv; return (hsc_mode env) }
 250 \end{code}
 251
 252 \begin{code}
 253 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 254 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 255
 256 getEps :: TcRnIf gbl lcl ExternalPackageState
 257 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 258
 259 setEps :: ExternalPackageState -> TcRnIf gbl lcl ()
 260 setEps eps = do { env <- getTopEnv; writeMutVar (hsc_EPS env) eps }
 261
 262 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 263           -> TcRnIf gbl lcl a
 264 updateEps upd_fn = do   { eps_var <- getEpsVar
 265                         ; eps <- readMutVar eps_var
 266                         ; let { (eps', val) = upd_fn eps }
 267                         ; writeMutVar eps_var eps'
 268                         ; return val }
 269
 270 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 271            -> TcRnIf gbl lcl ()
 272 updateEps_ upd_fn = do  { eps_var <- getEpsVar
 273                         ; updMutVar eps_var upd_fn }
 274
 275 getHpt :: TcRnIf gbl lcl HomePackageTable
 276 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 277 \end{code}
 278
 279 %************************************************************************
 280 %*                                                                      *
 281                 Unique supply
 282 %*                                                                      *
 283 %************************************************************************
 284
 285 \begin{code}
 286 newUnique :: TcRnIf gbl lcl Unique
 287 newUnique = do { us <- newUniqueSupply ;
 288                  return (uniqFromSupply us) }
 289
 290 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 291 newUniqueSupply
 292  = do { env <- getEnv ;
 293         let { u_var = env_us env } ;
 294         us <- readMutVar u_var ;
 295         let { (us1, us2) = splitUniqSupply us } ;
 296         writeMutVar u_var us1 ;
 297         return us2 }
 298 \end{code}
 299
 300
 301 %************************************************************************
 302 %*                                                                      *
 303                 Debugging
 304 %*                                                                      *
 305 %************************************************************************
 306
 307 \begin{code}
 308 traceTc, traceRn :: SDoc -> TcRn ()
 309 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 310 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 311 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 312
 313
 314 traceIf :: SDoc -> TcRnIf m n ()
 315 traceIf      = dumpOptIf Opt_D_dump_if_trace
 316 traceHiDiffs = dumpOptIf Opt_D_dump_hi_diffs
 317
 318
 319 dumpOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 320 dumpOptIf flag doc = ifOptM flag $
 321                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 322
 323 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 324 dumpOptTcRn flag doc = ifOptM flag $ do
 325                         { ctxt <- getErrCtxt
 326                         ; loc  <- getSrcSpanM
 327                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 328                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 329                         ; dumpTcRn real_doc }
 330
 331 dumpTcRn :: SDoc -> TcRn ()
 332 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 333                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 334 \end{code}
 335
 336
 337 %************************************************************************
 338 %*                                                                      *
 339                 Typechecker global environment
 340 %*                                                                      *
 341 %************************************************************************
 342
 343 \begin{code}
 344 getModule :: TcRn Module
 345 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 346
 347 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 348 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 349
 350 getImports :: TcRn ImportAvails
 351 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 352
 353 getFixityEnv :: TcRn FixityEnv
 354 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 355
 356 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 357 extendFixityEnv new_bit
 358   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 359                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 360
 361 getDefaultTys :: TcRn (Maybe [Type])
 362 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 363 \end{code}
 364
 365 %************************************************************************
 366 %*                                                                      *
 367                 Error management
 368 %*                                                                      *
 369 %************************************************************************
 370
 371 \begin{code}
 372 getSrcSpanM :: TcRn SrcSpan
 373         -- Avoid clash with Name.getSrcLoc
 374 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 375
 376 addSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 377 addSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc })
 378
 379 addLocM :: (a -> TcM b) -> Located a -> TcM b
 380 addLocM fn (L loc a) = addSrcSpan loc $ fn a
 381
 382 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 383 wrapLocM fn (L loc a) = addSrcSpan loc $ do b <- fn a; return (L loc b)
 384
 385 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 386 wrapLocFstM fn (L loc a) =
 387   addSrcSpan loc $ do
 388     (b,c) <- fn a
 389     return (L loc b, c)
 390
 391 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 392 wrapLocSndM fn (L loc a) =
 393   addSrcSpan loc $ do
 394     (b,c) <- fn a
 395     return (b, L loc c)
 396 \end{code}
 397
 398
 399 \begin{code}
 400 getErrsVar :: TcRn (TcRef Messages)
 401 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 402
 403 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 404 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 405
 406 addErr :: Message -> TcRn ()
 407 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 408
 409 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 410 addLocErr (L loc e) fn = addErrAt loc (fn e)
 411
 412 addErrAt :: SrcSpan -> Message -> TcRn ()
 413 addErrAt loc msg = addLongErrAt loc msg empty
 414
 415 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 416 addLongErrAt loc msg extra
 417  = do {  errs_var <- getErrsVar ;
 418          rdr_env <- getGlobalRdrEnv ;
 419          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 420          (warns, errs) <- readMutVar errs_var ;
 421          writeMutVar errs_var (warns, errs `snocBag` err) }
 422
 423 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 424 addErrs msgs = mappM_ add msgs
 425              where
 426                add (loc,msg) = addErrAt loc msg
 427
 428 addReport :: Message -> TcRn ()
 429 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 430
 431 addReportAt :: SrcSpan -> Message -> TcRn ()
 432 addReportAt loc msg
 433   = do { errs_var <- getErrsVar ;
 434          rdr_env <- getGlobalRdrEnv ;
 435          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 436          (warns, errs) <- readMutVar errs_var ;
 437          writeMutVar errs_var (warns `snocBag` warn, errs) }
 438
 439 addWarn :: Message -> TcRn ()
 440 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 441
 442 addWarnAt :: SrcSpan -> Message -> TcRn ()
 443 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 444
 445 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 446 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 447
 448 checkErr :: Bool -> Message -> TcRn ()
 449 -- Add the error if the bool is False
 450 checkErr ok msg = checkM ok (addErr msg)
 451
 452 warnIf :: Bool -> Message -> TcRn ()
 453 warnIf True  msg = addWarn msg
 454 warnIf False msg = return ()
 455
 456 addMessages :: Messages -> TcRn ()
 457 addMessages (m_warns, m_errs)
 458   = do { errs_var <- getErrsVar ;
 459          (warns, errs) <- readMutVar errs_var ;
 460          writeMutVar errs_var (warns `unionBags` m_warns,
 461                                errs  `unionBags` m_errs) }
 462
 463 discardWarnings :: TcRn a -> TcRn a
 464 -- Ignore warnings inside the thing inside;
 465 -- used to ignore-unused-variable warnings inside derived code
 466 -- With -dppr-debug, the effects is switched off, so you can still see
 467 -- what warnings derived code would give
 468 discardWarnings thing_inside
 469   | opt_PprStyle_Debug = thing_inside
 470   | otherwise
 471   = do  { errs_var <- newMutVar emptyMessages
 472         ; result <- setErrsVar errs_var thing_inside
 473         ; (_warns, errs) <- readMutVar errs_var
 474         ; addMessages (emptyBag, errs)
 475         ; return result }
 476 \end{code}
 477
 478
 479 \begin{code}
 480 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 481          -> TcRn r      -- Main action: do this first
 482          -> TcRn r
 483 recoverM recover thing
 484   = do { mb_res <- try_m thing ;
 485          case mb_res of
 486            Left exn  -> recover
 487            Right res -> returnM res }
 488
 489 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 490     -- (tryTc m) executes m, and returns
 491     --  Just r,  if m succeeds (returning r) and caused no errors
 492     --  Nothing, if m fails, or caused errors
 493     -- It also returns all the errors accumulated by m
 494     --  (even in the Just case, there might be warnings)
 495     --
 496     -- It always succeeds (never raises an exception)
 497 tryTc m
 498  = do { errs_var <- newMutVar emptyMessages ;
 499
 500         mb_r <- try_m (setErrsVar errs_var m) ;
 501
 502         new_errs <- readMutVar errs_var ;
 503
 504         dflags <- getDOpts ;
 505
 506         return (new_errs,
 507                 case mb_r of
 508                   Left exn -> Nothing
 509                   Right r | errorsFound dflags new_errs -> Nothing
 510                           | otherwise                   -> Just r)
 511    }
 512
 513 try_m :: TcRn r -> TcRn (Either Exception r)
 514 -- Does try_m, with a debug-trace on failure
 515 try_m thing
 516   = do { mb_r <- tryM thing ;
 517          case mb_r of
 518              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 519              Right r  -> return mb_r }
 520   where
 521     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 522
 523 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 524 -- Just like tryTc, except that it ensures that the LIE
 525 -- for the thing is propagated only if there are no errors
 526 -- Hence it's restricted to the type-check monad
 527 tryTcLIE thing_inside
 528   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 529          ifM (isJust mb_r) (extendLIEs lie) ;
 530          return (errs, mb_r) }
 531
 532 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 533 -- (tryTcLIE_ r m) tries m; if it succeeds it returns it,
 534 -- otherwise it returns r.  Any error messages added by m are discarded,
 535 -- whether or not m succeeds.
 536 tryTcLIE_ recover main
 537   = do { (_msgs, mb_res) <- tryTcLIE main ;
 538          case mb_res of
 539            Just res -> return res
 540            Nothing  -> recover }
 541
 542 checkNoErrs :: TcM r -> TcM r
 543 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 544 -- If m fails then (checkNoErrsTc m) fails.
 545 -- If m succeeds, it checks whether m generated any errors messages
 546 --      (it might have recovered internally)
 547 --      If so, it fails too.
 548 -- Regardless, any errors generated by m are propagated to the enclosing context.
 549 checkNoErrs main
 550   = do { (msgs, mb_res) <- tryTcLIE main ;
 551          addMessages msgs ;
 552          case mb_res of
 553            Just r  -> return r
 554            Nothing -> failM
 555    }
 556
 557 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 558 --      ifErrsM bale_out main
 559 -- does 'bale_out' if there are errors in errors collection
 560 -- otherwise does 'main'
 561 ifErrsM bale_out normal
 562  = do { errs_var <- getErrsVar ;
 563         msgs <- readMutVar errs_var ;
 564         dflags <- getDOpts ;
 565         if errorsFound dflags msgs then
 566            bale_out
 567         else
 568            normal }
 569
 570 failIfErrsM :: TcRn ()
 571 -- Useful to avoid error cascades
 572 failIfErrsM = ifErrsM failM (return ())
 573 \end{code}
 574
 575
 576 %************************************************************************
 577 %*                                                                      *
 578         Context management and error message generation
 579                     for the type checker
 580 %*                                                                      *
 581 %************************************************************************
 582
 583 \begin{code}
 584 setErrCtxtM, addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 585 setErrCtxtM msg = updCtxt (\ msgs -> [msg])
 586 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 587
 588 setErrCtxt, addErrCtxt :: Message -> TcM a -> TcM a
 589 setErrCtxt msg = setErrCtxtM (\env -> returnM (env, msg))
 590 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 591
 592 popErrCtxt :: TcM a -> TcM a
 593 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 594
 595 getErrCtxt :: TcM ErrCtxt
 596 getErrCtxt = do { env <- getLclEnv ; return (tcl_ctxt env) }
 597
 598 -- Helper function for the above
 599 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 600 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 601                            env { tcl_ctxt = upd ctxt })
 602
 603 getInstLoc :: InstOrigin -> TcM InstLoc
 604 getInstLoc origin
 605   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 606          return (InstLoc origin loc (tcl_ctxt env)) }
 607
 608 addInstCtxt :: InstLoc -> TcM a -> TcM a
 609 -- Add the SrcSpan and context from the first Inst in the list
 610 --      (they all have similar locations)
 611 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 612   = addSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 613 \end{code}
 614
 615     The addErrTc functions add an error message, but do not cause failure.
 616     The 'M' variants pass a TidyEnv that has already been used to
 617     tidy up the message; we then use it to tidy the context messages
 618
 619 \begin{code}
 620 addErrTc :: Message -> TcM ()
 621 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 622
 623 addErrsTc :: [Message] -> TcM ()
 624 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 625
 626 addErrTcM :: (TidyEnv, Message) -> TcM ()
 627 addErrTcM (tidy_env, err_msg)
 628   = do { ctxt <- getErrCtxt ;
 629          loc  <- getSrcSpanM ;
 630          add_err_tcm tidy_env err_msg loc ctxt }
 631 \end{code}
 632
 633 The failWith functions add an error message and cause failure
 634
 635 \begin{code}
 636 failWithTc :: Message -> TcM a               -- Add an error message and fail
 637 failWithTc err_msg
 638   = addErrTc err_msg >> failM
 639
 640 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 641 failWithTcM local_and_msg
 642   = addErrTcM local_and_msg >> failM
 643
 644 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 645 checkTc True  err = returnM ()
 646 checkTc False err = failWithTc err
 647 \end{code}
 648
 649         Warnings have no 'M' variant, nor failure
 650
 651 \begin{code}
 652 addWarnTc :: Message -> TcM ()
 653 addWarnTc msg
 654  = do { ctxt <- getErrCtxt ;
 655         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 656         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 657
 658 warnTc :: Bool -> Message -> TcM ()
 659 warnTc warn_if_true warn_msg
 660   | warn_if_true = addWarnTc warn_msg
 661   | otherwise    = return ()
 662 \end{code}
 663
 664         Helper functions
 665
 666 \begin{code}
 667 add_err_tcm tidy_env err_msg loc ctxt
 668  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 669         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 670
 671 do_ctxt tidy_env []
 672  = return []
 673 do_ctxt tidy_env (c:cs)
 674  = do { (tidy_env', m) <- c tidy_env  ;
 675         ms             <- do_ctxt tidy_env' cs  ;
 676         return (m:ms) }
 677
 678 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 679                  | otherwise          = take 3 ctxt
 680 \end{code}
 681
 682 %************************************************************************
 683 %*                                                                      *
 684              Type constraints (the so-called LIE)
 685 %*                                                                      *
 686 %************************************************************************
 687
 688 \begin{code}
 689 getLIEVar :: TcM (TcRef LIE)
 690 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 691
 692 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 693 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 694
 695 getLIE :: TcM a -> TcM (a, [Inst])
 696 -- (getLIE m) runs m, and returns the type constraints it generates
 697 getLIE thing_inside
 698   = do { lie_var <- newMutVar emptyLIE ;
 699          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 700                           thing_inside ;
 701          lie <- readMutVar lie_var ;
 702          return (res, lieToList lie) }
 703
 704 extendLIE :: Inst -> TcM ()
 705 extendLIE inst
 706   = do { lie_var <- getLIEVar ;
 707          lie <- readMutVar lie_var ;
 708          writeMutVar lie_var (inst `consLIE` lie) }
 709
 710 extendLIEs :: [Inst] -> TcM ()
 711 extendLIEs []
 712   = returnM ()
 713 extendLIEs insts
 714   = do { lie_var <- getLIEVar ;
 715          lie <- readMutVar lie_var ;
 716          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 717 \end{code}
 718
 719 \begin{code}
 720 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 721 -- Set the local type envt, but do *not* disturb other fields,
 722 -- notably the lie_var
 723 setLclTypeEnv lcl_env thing_inside
 724   = updLclEnv upd thing_inside
 725   where
 726     upd env = env { tcl_env = tcl_env lcl_env,
 727                     tcl_tyvars = tcl_tyvars lcl_env }
 728 \end{code}
 729
 730
 731 %************************************************************************
 732 %*                                                                      *
 733              Template Haskell context
 734 %*                                                                      *
 735 %************************************************************************
 736
 737 \begin{code}
 738 recordThUse :: TcM ()
 739 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 740
 741 getStage :: TcM ThStage
 742 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 743
 744 setStage :: ThStage -> TcM a -> TcM a
 745 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 746 \end{code}
 747
 748
 749 %************************************************************************
 750 %*                                                                      *
 751              Arrow context
 752 %*                                                                      *
 753 %************************************************************************
 754
 755 \begin{code}
 756 popArrowBinders :: TcM a -> TcM a       -- Move to the left of a (-<); see comments in TcRnTypes
 757 popArrowBinders
 758   = updLclEnv (\ env -> env { tcl_arrow_ctxt = pop (tcl_arrow_ctxt env)  })
 759   where
 760     pop (ArrCtxt {proc_level = curr_lvl, proc_banned = banned})
 761         = ASSERT( not (curr_lvl `elem` banned) )
 762           ArrCtxt {proc_level = curr_lvl, proc_banned = curr_lvl : banned}
 763
 764 getBannedProcLevels :: TcM [ProcLevel]
 765   = do { env <- getLclEnv; return (proc_banned (tcl_arrow_ctxt env)) }
 766
 767 incProcLevel :: TcM a -> TcM a
 768 incProcLevel
 769   = updLclEnv (\ env -> env { tcl_arrow_ctxt = inc (tcl_arrow_ctxt env) })
 770   where
 771     inc ctxt = ctxt { proc_level = proc_level ctxt + 1 }
 772 \end{code}
 773
 774
 775 %************************************************************************
 776 %*                                                                      *
 777              Stuff for the renamer's local env
 778 %*                                                                      *
 779 %************************************************************************
 780
 781 \begin{code}
 782 getLocalRdrEnv :: RnM LocalRdrEnv
 783 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 784
 785 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 786 setLocalRdrEnv rdr_env thing_inside
 787   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 788 \end{code}
 789
 790
 791 %************************************************************************
 792 %*                                                                      *
 793              Stuff for interface decls
 794 %*                                                                      *
 795 %************************************************************************
 796
 797 \begin{code}
 798 initIfaceTcRn :: IfG a -> TcRn a
 799 initIfaceTcRn thing_inside
 800   = do  { tcg_env <- getGblEnv
 801         ; let { if_env = IfGblEnv {
 802                         if_rec_types = Just (tcg_mod tcg_env, get_type_env),
 803                         if_is_boot   = imp_dep_mods (tcg_imports tcg_env) }
 804               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 805         ; setEnvs (if_env, ()) thing_inside }
 806
 807 initIfaceExtCore :: IfL a -> TcRn a
 808 initIfaceExtCore thing_inside
 809   = do  { tcg_env <- getGblEnv
 810         ; let { mod = tcg_mod tcg_env
 811               ; if_env = IfGblEnv {
 812                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)),
 813                         if_is_boot   = imp_dep_mods (tcg_imports tcg_env) }
 814               ; if_lenv = IfLclEnv { if_mod     = moduleName mod,
 815                                      if_tv_env  = emptyOccEnv,
 816                                      if_id_env  = emptyOccEnv }
 817           }
 818         ; setEnvs (if_env, if_lenv) thing_inside }
 819
 820 initIfaceCheck :: HscEnv -> IfG a -> IO a
 821 -- Used when checking the up-to-date-ness of the old Iface
 822 -- Initialise the environment with no useful info at all
 823 initIfaceCheck hsc_env do_this
 824  = do   { let { gbl_env = IfGblEnv { if_is_boot   = emptyModuleEnv,
 825                                      if_rec_types = Nothing } ;
 826            }
 827         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 828     }
 829
 830 initIfaceTc :: HscEnv -> ModIface
 831             -> (TcRef TypeEnv -> IfL a) -> IO a
 832 -- Used when type-checking checking an up-to-date interface file
 833 -- No type envt from the current module, but we do know the module dependencies
 834 initIfaceTc hsc_env iface do_this
 835  = do   { tc_env_var <- newIORef emptyTypeEnv
 836         ; let { gbl_env = IfGblEnv { if_is_boot   = mkModDeps (dep_mods (mi_deps iface)),
 837                                      if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 838               ; if_lenv = IfLclEnv { if_mod     = moduleName mod,
 839                                      if_tv_env  = emptyOccEnv,
 840                                      if_id_env  = emptyOccEnv }
 841            }
 842         ; initTcRnIf 'i' hsc_env gbl_env if_lenv (do_this tc_env_var)
 843     }
 844   where
 845     mod = mi_module iface
 846
 847 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 848 -- Used when sucking in new Rules in SimplCore
 849 -- We have available the type envt of the module being compiled, and we must use it
 850 initIfaceRules hsc_env guts do_this
 851  = do   { let {
 852              is_boot = mkModDeps (dep_mods (mg_deps guts))
 853                         -- Urgh!  But we do somehow need to get the info
 854                         -- on whether (for this particular compilation) we should
 855                         -- import a hi-boot file or not.
 856            ; type_info = (mg_module guts, return (mg_types guts))
 857            ; gbl_env = IfGblEnv { if_is_boot   = is_boot,
 858                                   if_rec_types = Just type_info } ;
 859            }
 860
 861         -- Run the thing; any exceptions just bubble out from here
 862         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 863     }
 864
 865 initIfaceLcl :: ModuleName -> IfL a -> IfM lcl a
 866 initIfaceLcl mod thing_inside
 867   = setLclEnv (IfLclEnv { if_mod      = mod,
 868                            if_tv_env  = emptyOccEnv,
 869                            if_id_env  = emptyOccEnv })
 870               thing_inside
 871
 872
 873 --------------------
 874 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 875 -- Run thing_inside in an interleaved thread.
 876 -- It shares everything with the parent thread, so this is DANGEROUS.
 877 --
 878 -- It returns Nothing if the computation fails
 879 --
 880 -- It's used for lazily type-checking interface
 881 -- signatures, which is pretty benign
 882
 883 forkM_maybe doc thing_inside
 884  = do { unsafeInterleaveM $
 885         do { traceIf (text "Starting fork {" <+> doc)
 886            ; mb_res <- tryM thing_inside ;
 887              case mb_res of
 888                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 889                                 ; return (Just r) }
 890                 Left exn -> do {
 891
 892                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 893                     -- Otherwise we silently discard errors. Errors can legitimately
 894                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 895                       ifOptM Opt_D_dump_if_trace
 896                              (print_errs (hang (text "forkM failed:" <+> doc)
 897                                              4 (text (show exn))))
 898
 899                     ; traceIf (text "} ending fork (badly)" <+> doc)
 900                     ; return Nothing }
 901         }}
 902   where
 903     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 904
 905 forkM :: SDoc -> IfL a -> IfL a
 906 forkM doc thing_inside
 907  = do   { mb_res <- forkM_maybe doc thing_inside
 908         ; return (case mb_res of
 909                         Nothing -> pprPanic "forkM" doc
 910                         Just r  -> r) }
 911 \end{code}