ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..),
  16                           isHsBoot, ModSummary(..),
  17                           ExternalPackageState(..), HomePackageTable,
  18                           Deprecs(..), FixityEnv, FixItem,
  19                           lookupType, unQualInScope )
  20 import Module           ( Module, unitModuleEnv )
  21 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  22                           LocalRdrEnv, emptyLocalRdrEnv )
  23 import Name             ( Name, isInternalName, mkInternalName, getOccName, getSrcLoc )
  24 import Type             ( Type )
  25 import NameEnv          ( extendNameEnvList )
  26 import InstEnv          ( emptyInstEnv )
  27
  28 import VarSet           ( emptyVarSet )
  29 import VarEnv           ( TidyEnv, emptyTidyEnv, emptyVarEnv )
  30 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  31                           mkWarnMsg, printErrorsAndWarnings, pprBagOfErrors,
  32                           mkLocMessage, mkLongErrMsg )
  33 import Packages         ( mkHomeModules )
  34 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  35 import NameEnv          ( emptyNameEnv )
  36 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  37 import OccName          ( emptyOccEnv )
  38 import Bag              ( emptyBag )
  39 import Outputable
  40 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  41 import Unique           ( Unique )
  42 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  43 import StaticFlags      ( opt_PprStyle_Debug )
  44 import Bag              ( snocBag, unionBags, unitBag )
  45 import Panic            ( showException )
  46
  47 import IO               ( stderr )
  48 import DATA_IOREF       ( newIORef, readIORef )
  49 import EXCEPTION        ( Exception )
  50 \end{code}
  51
  52
  53
  54 %************************************************************************
  55 %*                                                                      *
  56                         initTc
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 ioToTcRn :: IO r -> TcRn r
  62 ioToTcRn = ioToIOEnv
  63 \end{code}
  64
  65 \begin{code}
  66 initTc :: HscEnv
  67        -> HscSource
  68        -> Module
  69        -> TcM r
  70        -> IO (Messages, Maybe r)
  71                 -- Nothing => error thrown by the thing inside
  72                 -- (error messages should have been printed already)
  73
  74 initTc hsc_env hsc_src mod do_this
  75  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  76         tvs_var      <- newIORef emptyVarSet ;
  77         type_env_var <- newIORef emptyNameEnv ;
  78         dfuns_var    <- newIORef emptyNameSet ;
  79         keep_var     <- newIORef emptyNameSet ;
  80         th_var       <- newIORef False ;
  81         dfun_n_var   <- newIORef 1 ;
  82
  83         let {
  84              gbl_env = TcGblEnv {
  85                 tcg_mod      = mod,
  86                 tcg_src      = hsc_src,
  87                 tcg_rdr_env  = emptyGlobalRdrEnv,
  88                 tcg_fix_env  = emptyNameEnv,
  89                 tcg_default  = Nothing,
  90                 tcg_type_env = emptyNameEnv,
  91                 tcg_type_env_var = type_env_var,
  92                 tcg_inst_env  = emptyInstEnv,
  93                 tcg_inst_uses = dfuns_var,
  94                 tcg_th_used   = th_var,
  95                 tcg_exports  = emptyNameSet,
  96                 tcg_imports  = init_imports,
  97                 tcg_home_mods = home_mods,
  98                 tcg_dus      = emptyDUs,
  99                 tcg_rn_decls = Nothing,
 100                 tcg_binds    = emptyLHsBinds,
 101                 tcg_deprecs  = NoDeprecs,
 102                 tcg_insts    = [],
 103                 tcg_rules    = [],
 104                 tcg_fords    = [],
 105                 tcg_dfun_n   = dfun_n_var,
 106                 tcg_keep     = keep_var
 107              } ;
 108              lcl_env = TcLclEnv {
 109                 tcl_errs       = errs_var,
 110                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 111                 tcl_ctxt       = [],
 112                 tcl_rdr        = emptyLocalRdrEnv,
 113                 tcl_th_ctxt    = topStage,
 114                 tcl_arrow_ctxt = NoArrowCtxt,
 115                 tcl_env        = emptyNameEnv,
 116                 tcl_tyvars     = tvs_var,
 117                 tcl_lie        = panic "initTc:LIE",    -- LIE only valid inside a getLIE
 118                 tcl_gadt       = emptyVarEnv
 119              } ;
 120         } ;
 121
 122         -- OK, here's the business end!
 123         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 124                              do { r <- tryM do_this
 125                                 ; case r of
 126                                     Right res -> return (Just res)
 127                                     Left _    -> return Nothing } ;
 128
 129         -- Collect any error messages
 130         msgs <- readIORef errs_var ;
 131
 132         let { dflags = hsc_dflags hsc_env
 133             ; final_res | errorsFound dflags msgs = Nothing
 134                         | otherwise               = maybe_res } ;
 135
 136         return (msgs, final_res)
 137     }
 138   where
 139     home_mods = mkHomeModules (map ms_mod (hsc_mod_graph hsc_env))
 140         -- A guess at the home modules.  This will be correct in
 141         -- --make and GHCi modes, but in one-shot mode we need to
 142         -- fix it up after we know the real dependencies of the current
 143         -- module (see tcRnModule).
 144         -- Setting it here is necessary for the typechecker entry points
 145         -- other than tcRnModule: tcRnGetInfo, for example.  These are
 146         -- all called via the GHC module, so hsc_mod_graph will contain
 147         -- something sensible.
 148
 149     init_imports = emptyImportAvails {imp_env = unitModuleEnv mod emptyNameSet}
 150         -- Initialise tcg_imports with an empty set of bindings for
 151         -- this module, so that if we see 'module M' in the export
 152         -- list, and there are no bindings in M, we don't bleat
 153         -- "unknown module M".
 154
 155 initTcPrintErrors       -- Used from the interactive loop only
 156        :: HscEnv
 157        -> Module
 158        -> TcM r
 159        -> IO (Maybe r)
 160 initTcPrintErrors env mod todo = do
 161   (msgs, res) <- initTc env HsSrcFile mod todo
 162   printErrorsAndWarnings msgs
 163   return res
 164
 165 -- mkImpTypeEnv makes the imported symbol table
 166 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 167              -> Name -> Maybe TyThing
 168 mkImpTypeEnv pcs hpt = lookup
 169   where
 170     pte = eps_PTE pcs
 171     lookup name | isInternalName name = Nothing
 172                 | otherwise           = lookupType hpt pte name
 173 \end{code}
 174
 175
 176 %************************************************************************
 177 %*                                                                      *
 178                 Initialisation
 179 %*                                                                      *
 180 %************************************************************************
 181
 182
 183 \begin{code}
 184 initTcRnIf :: Char              -- Tag for unique supply
 185            -> HscEnv
 186            -> gbl -> lcl
 187            -> TcRnIf gbl lcl a
 188            -> IO a
 189 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 190    = do { us     <- mkSplitUniqSupply uniq_tag ;
 191         ; us_var <- newIORef us ;
 192
 193         ; let { env = Env { env_top = hsc_env,
 194                             env_us  = us_var,
 195                             env_gbl = gbl_env,
 196                             env_lcl = lcl_env } }
 197
 198         ; runIOEnv env thing_inside
 199         }
 200 \end{code}
 201
 202 %************************************************************************
 203 %*                                                                      *
 204                 Simple accessors
 205 %*                                                                      *
 206 %************************************************************************
 207
 208 \begin{code}
 209 getTopEnv :: TcRnIf gbl lcl HscEnv
 210 getTopEnv = do { env <- getEnv; return (env_top env) }
 211
 212 getGblEnv :: TcRnIf gbl lcl gbl
 213 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 214
 215 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 216 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 217                           env { env_gbl = upd gbl })
 218
 219 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 220 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 221
 222 getLclEnv :: TcRnIf gbl lcl lcl
 223 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 224
 225 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 226 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 227                           env { env_lcl = upd lcl })
 228
 229 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 230 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 231
 232 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 233 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 234
 235 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 236 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 237 \end{code}
 238
 239
 240 Command-line flags
 241
 242 \begin{code}
 243 getDOpts :: TcRnIf gbl lcl DynFlags
 244 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 245
 246 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 247 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 248
 249 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 250 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 251                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 252
 253 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 254 ifOptM flag thing_inside = do { b <- doptM flag;
 255                                 if b then thing_inside else return () }
 256
 257 getGhciMode :: TcRnIf gbl lcl GhcMode
 258 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 259 \end{code}
 260
 261 \begin{code}
 262 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 263 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 264
 265 getEps :: TcRnIf gbl lcl ExternalPackageState
 266 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 267
 268 -- Updating the EPS.  This should be an atomic operation.
 269 -- Note the delicate 'seq' which forces the EPS before putting it in the
 270 -- variable.  Otherwise what happens is that we get
 271 --      write eps_var (....(unsafeRead eps_var)....)
 272 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 273 -- we make the unsafeRead happen before we update the variable.
 274
 275 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 276           -> TcRnIf gbl lcl a
 277 updateEps upd_fn = do   { traceIf (text "updating EPS")
 278                         ; eps_var <- getEpsVar
 279                         ; eps <- readMutVar eps_var
 280                         ; let { (eps', val) = upd_fn eps }
 281                         ; seq eps' (writeMutVar eps_var eps')
 282                         ; return val }
 283
 284 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 285            -> TcRnIf gbl lcl ()
 286 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 287                         ; eps_var <- getEpsVar
 288                         ; eps <- readMutVar eps_var
 289                         ; let { eps' = upd_fn eps }
 290                         ; seq eps' (writeMutVar eps_var eps') }
 291
 292 getHpt :: TcRnIf gbl lcl HomePackageTable
 293 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 294
 295 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 296 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 297                   ; return (eps, hsc_HPT env) }
 298 \end{code}
 299
 300 %************************************************************************
 301 %*                                                                      *
 302                 Unique supply
 303 %*                                                                      *
 304 %************************************************************************
 305
 306 \begin{code}
 307 newUnique :: TcRnIf gbl lcl Unique
 308 newUnique = do { us <- newUniqueSupply ;
 309                  return (uniqFromSupply us) }
 310
 311 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 312 newUniqueSupply
 313  = do { env <- getEnv ;
 314         let { u_var = env_us env } ;
 315         us <- readMutVar u_var ;
 316         let { (us1, us2) = splitUniqSupply us } ;
 317         writeMutVar u_var us1 ;
 318         return us2 }
 319
 320 newLocalName :: Name -> TcRnIf gbl lcl Name
 321 newLocalName name       -- Make a clone
 322   = newUnique           `thenM` \ uniq ->
 323     returnM (mkInternalName uniq (getOccName name) (getSrcLoc name))
 324 \end{code}
 325
 326
 327 %************************************************************************
 328 %*                                                                      *
 329                 Debugging
 330 %*                                                                      *
 331 %************************************************************************
 332
 333 \begin{code}
 334 traceTc, traceRn :: SDoc -> TcRn ()
 335 traceRn      = traceOptTcRn Opt_D_dump_rn_trace
 336 traceTc      = traceOptTcRn Opt_D_dump_tc_trace
 337 traceSplice  = traceOptTcRn Opt_D_dump_splices
 338
 339
 340 traceIf :: SDoc -> TcRnIf m n ()
 341 traceIf      = traceOptIf Opt_D_dump_if_trace
 342 traceHiDiffs = traceOptIf Opt_D_dump_hi_diffs
 343
 344
 345 traceOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 346 traceOptIf flag doc = ifOptM flag $
 347                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 348
 349 traceOptTcRn :: DynFlag -> SDoc -> TcRn ()
 350 traceOptTcRn flag doc = ifOptM flag $ do
 351                         { ctxt <- getErrCtxt
 352                         ; loc  <- getSrcSpanM
 353                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 354                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 355                         ; dumpTcRn real_doc }
 356
 357 dumpTcRn :: SDoc -> TcRn ()
 358 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 359                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 360
 361 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 362 dumpOptTcRn flag doc = ifOptM flag (dumpTcRn doc)
 363 \end{code}
 364
 365
 366 %************************************************************************
 367 %*                                                                      *
 368                 Typechecker global environment
 369 %*                                                                      *
 370 %************************************************************************
 371
 372 \begin{code}
 373 getModule :: TcRn Module
 374 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 375
 376 tcIsHsBoot :: TcRn Bool
 377 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 378
 379 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 380 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 381
 382 getImports :: TcRn ImportAvails
 383 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 384
 385 getFixityEnv :: TcRn FixityEnv
 386 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 387
 388 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 389 extendFixityEnv new_bit
 390   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 391                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 392
 393 getDefaultTys :: TcRn (Maybe [Type])
 394 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 395 \end{code}
 396
 397 %************************************************************************
 398 %*                                                                      *
 399                 Error management
 400 %*                                                                      *
 401 %************************************************************************
 402
 403 \begin{code}
 404 getSrcSpanM :: TcRn SrcSpan
 405         -- Avoid clash with Name.getSrcLoc
 406 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 407
 408 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 409 setSrcSpan loc thing_inside
 410   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 411   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 412
 413 addLocM :: (a -> TcM b) -> Located a -> TcM b
 414 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 415
 416 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 417 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 418
 419 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 420 wrapLocFstM fn (L loc a) =
 421   setSrcSpan loc $ do
 422     (b,c) <- fn a
 423     return (L loc b, c)
 424
 425 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 426 wrapLocSndM fn (L loc a) =
 427   setSrcSpan loc $ do
 428     (b,c) <- fn a
 429     return (b, L loc c)
 430 \end{code}
 431
 432
 433 \begin{code}
 434 getErrsVar :: TcRn (TcRef Messages)
 435 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 436
 437 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 438 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 439
 440 addErr :: Message -> TcRn ()
 441 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 442
 443 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 444 addLocErr (L loc e) fn = addErrAt loc (fn e)
 445
 446 addErrAt :: SrcSpan -> Message -> TcRn ()
 447 addErrAt loc msg = addLongErrAt loc msg empty
 448
 449 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 450 addLongErrAt loc msg extra
 451  = do {  errs_var <- getErrsVar ;
 452          rdr_env <- getGlobalRdrEnv ;
 453          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 454          (warns, errs) <- readMutVar errs_var ;
 455          traceTc (ptext SLIT("Adding error:") <+> \ _ -> pprBagOfErrors (unitBag err)) ;
 456                 -- Ugh!  traceTc is too specific; unitBag is horrible
 457          writeMutVar errs_var (warns, errs `snocBag` err) }
 458
 459 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 460 addErrs msgs = mappM_ add msgs
 461              where
 462                add (loc,msg) = addErrAt loc msg
 463
 464 addReport :: Message -> TcRn ()
 465 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 466
 467 addReportAt :: SrcSpan -> Message -> TcRn ()
 468 addReportAt loc msg
 469   = do { errs_var <- getErrsVar ;
 470          rdr_env <- getGlobalRdrEnv ;
 471          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 472          (warns, errs) <- readMutVar errs_var ;
 473          writeMutVar errs_var (warns `snocBag` warn, errs) }
 474
 475 addWarn :: Message -> TcRn ()
 476 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 477
 478 addWarnAt :: SrcSpan -> Message -> TcRn ()
 479 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 480
 481 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 482 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 483
 484 checkErr :: Bool -> Message -> TcRn ()
 485 -- Add the error if the bool is False
 486 checkErr ok msg = checkM ok (addErr msg)
 487
 488 warnIf :: Bool -> Message -> TcRn ()
 489 warnIf True  msg = addWarn msg
 490 warnIf False msg = return ()
 491
 492 addMessages :: Messages -> TcRn ()
 493 addMessages (m_warns, m_errs)
 494   = do { errs_var <- getErrsVar ;
 495          (warns, errs) <- readMutVar errs_var ;
 496          writeMutVar errs_var (warns `unionBags` m_warns,
 497                                errs  `unionBags` m_errs) }
 498
 499 discardWarnings :: TcRn a -> TcRn a
 500 -- Ignore warnings inside the thing inside;
 501 -- used to ignore-unused-variable warnings inside derived code
 502 -- With -dppr-debug, the effects is switched off, so you can still see
 503 -- what warnings derived code would give
 504 discardWarnings thing_inside
 505   | opt_PprStyle_Debug = thing_inside
 506   | otherwise
 507   = do  { errs_var <- newMutVar emptyMessages
 508         ; result <- setErrsVar errs_var thing_inside
 509         ; (_warns, errs) <- readMutVar errs_var
 510         ; addMessages (emptyBag, errs)
 511         ; return result }
 512 \end{code}
 513
 514
 515 \begin{code}
 516 try_m :: TcRn r -> TcRn (Either Exception r)
 517 -- Does try_m, with a debug-trace on failure
 518 try_m thing
 519   = do { mb_r <- tryM thing ;
 520          case mb_r of
 521              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 522              Right r  -> return mb_r }
 523   where
 524     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 525
 526 -----------------------
 527 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 528          -> TcRn r      -- Main action: do this first
 529          -> TcRn r
 530 -- Errors in 'thing' are retained
 531 recoverM recover thing
 532   = do { mb_res <- try_m thing ;
 533          case mb_res of
 534            Left exn  -> recover
 535            Right res -> returnM res }
 536
 537 -----------------------
 538 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 539 -- (tryTc m) executes m, and returns
 540 --      Just r,  if m succeeds (returning r)
 541 --      Nothing, if m fails
 542 -- It also returns all the errors and warnings accumulated by m
 543 -- It always succeeds (never raises an exception)
 544 tryTc m
 545  = do { errs_var <- newMutVar emptyMessages ;
 546         res  <- try_m (setErrsVar errs_var m) ;
 547         msgs <- readMutVar errs_var ;
 548         return (msgs, case res of
 549                             Left exn  -> Nothing
 550                             Right val -> Just val)
 551         -- The exception is always the IOEnv built-in
 552         -- in exception; see IOEnv.failM
 553    }
 554
 555 -----------------------
 556 tryTcErrs :: TcRn a -> TcRn (Messages, Maybe a)
 557 -- Run the thing, returning
 558 --      Just r,  if m succceeds with no error messages
 559 --      Nothing, if m fails, or if it succeeds but has error messages
 560 -- Either way, the messages are returned; even in the Just case
 561 -- there might be warnings
 562 tryTcErrs thing
 563   = do  { (msgs, res) <- tryTc thing
 564         ; dflags <- getDOpts
 565         ; let errs_found = errorsFound dflags msgs
 566         ; return (msgs, case res of
 567                           Nothing -> Nothing
 568                           Just val | errs_found -> Nothing
 569                                    | otherwise  -> Just val)
 570         }
 571
 572 -----------------------
 573 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 574 -- Just like tryTcErrs, except that it ensures that the LIE
 575 -- for the thing is propagated only if there are no errors
 576 -- Hence it's restricted to the type-check monad
 577 tryTcLIE thing_inside
 578   = do  { ((msgs, mb_res), lie) <- getLIE (tryTcErrs thing_inside) ;
 579         ; case mb_res of
 580             Nothing  -> return (msgs, Nothing)
 581             Just val -> do { extendLIEs lie; return (msgs, Just val) }
 582         }
 583
 584 -----------------------
 585 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 586 -- (tryTcLIE_ r m) tries m;
 587 --      if m succeeds with no error messages, it's the answer
 588 --      otherwise tryTcLIE_ drops everything from m and tries r instead.
 589 tryTcLIE_ recover main
 590   = do  { (msgs, mb_res) <- tryTcLIE main
 591         ; case mb_res of
 592              Just val -> do { addMessages msgs  -- There might be warnings
 593                              ; return val }
 594              Nothing  -> recover                -- Discard all msgs
 595         }
 596
 597 -----------------------
 598 checkNoErrs :: TcM r -> TcM r
 599 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 600 -- If m fails then (checkNoErrsTc m) fails.
 601 -- If m succeeds, it checks whether m generated any errors messages
 602 --      (it might have recovered internally)
 603 --      If so, it fails too.
 604 -- Regardless, any errors generated by m are propagated to the enclosing context.
 605 checkNoErrs main
 606   = do  { (msgs, mb_res) <- tryTcLIE main
 607         ; addMessages msgs
 608         ; case mb_res of
 609             Nothing   -> failM
 610             Just val -> return val
 611         }
 612
 613 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 614 --      ifErrsM bale_out main
 615 -- does 'bale_out' if there are errors in errors collection
 616 -- otherwise does 'main'
 617 ifErrsM bale_out normal
 618  = do { errs_var <- getErrsVar ;
 619         msgs <- readMutVar errs_var ;
 620         dflags <- getDOpts ;
 621         if errorsFound dflags msgs then
 622            bale_out
 623         else
 624            normal }
 625
 626 failIfErrsM :: TcRn ()
 627 -- Useful to avoid error cascades
 628 failIfErrsM = ifErrsM failM (return ())
 629 \end{code}
 630
 631
 632 %************************************************************************
 633 %*                                                                      *
 634         Context management and error message generation
 635                     for the type checker
 636 %*                                                                      *
 637 %************************************************************************
 638
 639 \begin{code}
 640 getErrCtxt :: TcM ErrCtxt
 641 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 642
 643 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 644 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 645
 646 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 647 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 648
 649 addErrCtxt :: Message -> TcM a -> TcM a
 650 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 651
 652 -- Helper function for the above
 653 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 654 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 655                            env { tcl_ctxt = upd ctxt })
 656
 657 -- Conditionally add an error context
 658 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 659 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 660 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 661
 662 popErrCtxt :: TcM a -> TcM a
 663 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 664
 665 getInstLoc :: InstOrigin -> TcM InstLoc
 666 getInstLoc origin
 667   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 668          return (InstLoc origin loc (tcl_ctxt env)) }
 669
 670 addInstCtxt :: InstLoc -> TcM a -> TcM a
 671 -- Add the SrcSpan and context from the first Inst in the list
 672 --      (they all have similar locations)
 673 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 674   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 675 \end{code}
 676
 677     The addErrTc functions add an error message, but do not cause failure.
 678     The 'M' variants pass a TidyEnv that has already been used to
 679     tidy up the message; we then use it to tidy the context messages
 680
 681 \begin{code}
 682 addErrTc :: Message -> TcM ()
 683 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 684
 685 addErrsTc :: [Message] -> TcM ()
 686 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 687
 688 addErrTcM :: (TidyEnv, Message) -> TcM ()
 689 addErrTcM (tidy_env, err_msg)
 690   = do { ctxt <- getErrCtxt ;
 691          loc  <- getSrcSpanM ;
 692          add_err_tcm tidy_env err_msg loc ctxt }
 693 \end{code}
 694
 695 The failWith functions add an error message and cause failure
 696
 697 \begin{code}
 698 failWithTc :: Message -> TcM a               -- Add an error message and fail
 699 failWithTc err_msg
 700   = addErrTc err_msg >> failM
 701
 702 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 703 failWithTcM local_and_msg
 704   = addErrTcM local_and_msg >> failM
 705
 706 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 707 checkTc True  err = returnM ()
 708 checkTc False err = failWithTc err
 709 \end{code}
 710
 711         Warnings have no 'M' variant, nor failure
 712
 713 \begin{code}
 714 addWarnTc :: Message -> TcM ()
 715 addWarnTc msg
 716  = do { ctxt <- getErrCtxt ;
 717         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 718         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 719
 720 warnTc :: Bool -> Message -> TcM ()
 721 warnTc warn_if_true warn_msg
 722   | warn_if_true = addWarnTc warn_msg
 723   | otherwise    = return ()
 724 \end{code}
 725
 726         Helper functions
 727
 728 \begin{code}
 729 add_err_tcm tidy_env err_msg loc ctxt
 730  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 731         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 732
 733 do_ctxt tidy_env []
 734  = return []
 735 do_ctxt tidy_env (c:cs)
 736  = do { (tidy_env', m) <- c tidy_env  ;
 737         ms             <- do_ctxt tidy_env' cs  ;
 738         return (m:ms) }
 739
 740 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 741                  | otherwise          = take 3 ctxt
 742 \end{code}
 743
 744 debugTc is useful for monadi debugging code
 745
 746 \begin{code}
 747 debugTc :: TcM () -> TcM ()
 748 #ifdef DEBUG
 749 debugTc thing = thing
 750 #else
 751 debugTc thing = return ()
 752 #endif
 753 \end{code}
 754
 755  %************************************************************************
 756 %*                                                                      *
 757              Type constraints (the so-called LIE)
 758 %*                                                                      *
 759 %************************************************************************
 760
 761 \begin{code}
 762 nextDFunIndex :: TcM Int        -- Get the next dfun index
 763 nextDFunIndex = do { env <- getGblEnv
 764                    ; let dfun_n_var = tcg_dfun_n env
 765                    ; n <- readMutVar dfun_n_var
 766                    ; writeMutVar dfun_n_var (n+1)
 767                    ; return n }
 768
 769 getLIEVar :: TcM (TcRef LIE)
 770 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 771
 772 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 773 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 774
 775 getLIE :: TcM a -> TcM (a, [Inst])
 776 -- (getLIE m) runs m, and returns the type constraints it generates
 777 getLIE thing_inside
 778   = do { lie_var <- newMutVar emptyLIE ;
 779          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 780                           thing_inside ;
 781          lie <- readMutVar lie_var ;
 782          return (res, lieToList lie) }
 783
 784 extendLIE :: Inst -> TcM ()
 785 extendLIE inst
 786   = do { lie_var <- getLIEVar ;
 787          lie <- readMutVar lie_var ;
 788          writeMutVar lie_var (inst `consLIE` lie) }
 789
 790 extendLIEs :: [Inst] -> TcM ()
 791 extendLIEs []
 792   = returnM ()
 793 extendLIEs insts
 794   = do { lie_var <- getLIEVar ;
 795          lie <- readMutVar lie_var ;
 796          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 797 \end{code}
 798
 799 \begin{code}
 800 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 801 -- Set the local type envt, but do *not* disturb other fields,
 802 -- notably the lie_var
 803 setLclTypeEnv lcl_env thing_inside
 804   = updLclEnv upd thing_inside
 805   where
 806     upd env = env { tcl_env = tcl_env lcl_env,
 807                     tcl_tyvars = tcl_tyvars lcl_env }
 808 \end{code}
 809
 810
 811 %************************************************************************
 812 %*                                                                      *
 813              Template Haskell context
 814 %*                                                                      *
 815 %************************************************************************
 816
 817 \begin{code}
 818 recordThUse :: TcM ()
 819 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 820
 821 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 822 keepAliveTc n = do { env <- getGblEnv;
 823                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 824
 825 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 826 keepAliveSetTc ns = do { env <- getGblEnv;
 827                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 828
 829 getStage :: TcM ThStage
 830 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 831
 832 setStage :: ThStage -> TcM a -> TcM a
 833 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 834 \end{code}
 835
 836
 837 %************************************************************************
 838 %*                                                                      *
 839              Stuff for the renamer's local env
 840 %*                                                                      *
 841 %************************************************************************
 842
 843 \begin{code}
 844 getLocalRdrEnv :: RnM LocalRdrEnv
 845 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 846
 847 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 848 setLocalRdrEnv rdr_env thing_inside
 849   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 850 \end{code}
 851
 852
 853 %************************************************************************
 854 %*                                                                      *
 855              Stuff for interface decls
 856 %*                                                                      *
 857 %************************************************************************
 858
 859 \begin{code}
 860 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 861 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 862                                 if_loc     = loc,
 863                                 if_tv_env  = emptyOccEnv,
 864                                 if_id_env  = emptyOccEnv }
 865
 866 initIfaceTcRn :: IfG a -> TcRn a
 867 initIfaceTcRn thing_inside
 868   = do  { tcg_env <- getGblEnv
 869         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 870               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 871         ; setEnvs (if_env, ()) thing_inside }
 872
 873 initIfaceExtCore :: IfL a -> TcRn a
 874 initIfaceExtCore thing_inside
 875   = do  { tcg_env <- getGblEnv
 876         ; let { mod = tcg_mod tcg_env
 877               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 878               ; if_env = IfGblEnv {
 879                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 880               ; if_lenv = mkIfLclEnv mod doc
 881           }
 882         ; setEnvs (if_env, if_lenv) thing_inside }
 883
 884 initIfaceCheck :: HscEnv -> IfG a -> IO a
 885 -- Used when checking the up-to-date-ness of the old Iface
 886 -- Initialise the environment with no useful info at all
 887 initIfaceCheck hsc_env do_this
 888  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 889         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 890     }
 891
 892 initIfaceTc :: ModIface
 893             -> (TcRef TypeEnv -> IfL a) -> TcRnIf gbl lcl a
 894 -- Used when type-checking checking an up-to-date interface file
 895 -- No type envt from the current module, but we do know the module dependencies
 896 initIfaceTc iface do_this
 897  = do   { tc_env_var <- newMutVar emptyTypeEnv
 898         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 899               ; if_lenv = mkIfLclEnv mod doc
 900            }
 901         ; setEnvs (gbl_env, if_lenv) (do_this tc_env_var)
 902     }
 903   where
 904     mod = mi_module iface
 905     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 906
 907 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 908 -- Used when sucking in new Rules in SimplCore
 909 -- We have available the type envt of the module being compiled, and we must use it
 910 initIfaceRules hsc_env guts do_this
 911  = do   { let {
 912              type_info = (mg_module guts, return (mg_types guts))
 913            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 914            }
 915
 916         -- Run the thing; any exceptions just bubble out from here
 917         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 918     }
 919
 920 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 921 initIfaceLcl mod loc_doc thing_inside
 922   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 923
 924 getIfModule :: IfL Module
 925 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 926
 927 --------------------
 928 failIfM :: Message -> IfL a
 929 -- The Iface monad doesn't have a place to accumulate errors, so we
 930 -- just fall over fast if one happens; it "shouldnt happen".
 931 -- We use IfL here so that we can get context info out of the local env
 932 failIfM msg
 933   = do  { env <- getLclEnv
 934         ; let full_msg = (if_loc env <> colon) $$ nest 2 msg
 935         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 936         ; failM }
 937
 938 --------------------
 939 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 940 -- Run thing_inside in an interleaved thread.
 941 -- It shares everything with the parent thread, so this is DANGEROUS.
 942 --
 943 -- It returns Nothing if the computation fails
 944 --
 945 -- It's used for lazily type-checking interface
 946 -- signatures, which is pretty benign
 947
 948 forkM_maybe doc thing_inside
 949  = do { unsafeInterleaveM $
 950         do { traceIf (text "Starting fork {" <+> doc)
 951            ; mb_res <- tryM thing_inside ;
 952              case mb_res of
 953                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 954                                 ; return (Just r) }
 955                 Left exn -> do {
 956
 957                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 958                     -- Otherwise we silently discard errors. Errors can legitimately
 959                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 960                       ifOptM Opt_D_dump_if_trace
 961                              (print_errs (hang (text "forkM failed:" <+> doc)
 962                                              4 (text (show exn))))
 963
 964                     ; traceIf (text "} ending fork (badly)" <+> doc)
 965                     ; return Nothing }
 966         }}
 967   where
 968     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 969
 970 forkM :: SDoc -> IfL a -> IfL a
 971 forkM doc thing_inside
 972  = do   { mb_res <- forkM_maybe doc thing_inside
 973         ; return (case mb_res of
 974                         Nothing -> pgmError "Cannot continue after interface file error"
 975                                    -- pprPanic "forkM" doc
 976                         Just r  -> r) }
 977 \end{code}
 978
 979 %************************************************************************
 980 %*                                                                      *
 981              Stuff for GADTs
 982 %*                                                                      *
 983 %************************************************************************
 984
 985 \begin{code}
 986 getTypeRefinement :: TcM GadtRefinement
 987 getTypeRefinement = do { lcl_env <- getLclEnv; return (tcl_gadt lcl_env) }
 988
 989 setTypeRefinement :: GadtRefinement -> TcM a -> TcM a
 990 setTypeRefinement gadt = updLclEnv (\env -> env { tcl_gadt = gadt })
 991 \end{code}