ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..), isHsBoot,
  16                           ExternalPackageState(..), HomePackageTable,
  17                           Deprecs(..), FixityEnv, FixItem,
  18                           lookupType, unQualInScope )
  19 import Module           ( Module, unitModuleEnv )
  20 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  21                           LocalRdrEnv, emptyLocalRdrEnv )
  22 import Name             ( Name, isInternalName )
  23 import Type             ( Type )
  24 import NameEnv          ( extendNameEnvList )
  25 import InstEnv          ( emptyInstEnv )
  26
  27 import VarSet           ( emptyVarSet )
  28 import VarEnv           ( TidyEnv, emptyTidyEnv, emptyVarEnv )
  29 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  30                           mkWarnMsg, printErrorsAndWarnings,
  31                           mkLocMessage, mkLongErrMsg )
  32 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  33 import NameEnv          ( emptyNameEnv )
  34 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  35 import OccName          ( emptyOccEnv )
  36 import Bag              ( emptyBag )
  37 import Outputable
  38 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  39 import Unique           ( Unique )
  40 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  41 import StaticFlags      ( opt_PprStyle_Debug )
  42 import Bag              ( snocBag, unionBags )
  43 import Panic            ( showException )
  44
  45 import Maybe            ( isJust )
  46 import IO               ( stderr )
  47 import DATA_IOREF       ( newIORef, readIORef )
  48 import EXCEPTION        ( Exception )
  49 \end{code}
  50
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55                         initTc
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 \begin{code}
  60 ioToTcRn :: IO r -> TcRn r
  61 ioToTcRn = ioToIOEnv
  62 \end{code}
  63
  64 \begin{code}
  65 initTc :: HscEnv
  66        -> HscSource
  67        -> Module
  68        -> TcM r
  69        -> IO (Messages, Maybe r)
  70                 -- Nothing => error thrown by the thing inside
  71                 -- (error messages should have been printed already)
  72
  73 initTc hsc_env hsc_src mod do_this
  74  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  75         tvs_var      <- newIORef emptyVarSet ;
  76         type_env_var <- newIORef emptyNameEnv ;
  77         dfuns_var    <- newIORef emptyNameSet ;
  78         keep_var     <- newIORef emptyNameSet ;
  79         th_var       <- newIORef False ;
  80
  81         let {
  82              gbl_env = TcGblEnv {
  83                 tcg_mod      = mod,
  84                 tcg_src      = hsc_src,
  85                 tcg_rdr_env  = emptyGlobalRdrEnv,
  86                 tcg_fix_env  = emptyNameEnv,
  87                 tcg_default  = Nothing,
  88                 tcg_type_env = emptyNameEnv,
  89                 tcg_type_env_var = type_env_var,
  90                 tcg_inst_env  = emptyInstEnv,
  91                 tcg_inst_uses = dfuns_var,
  92                 tcg_th_used   = th_var,
  93                 tcg_exports  = emptyNameSet,
  94                 tcg_imports  = init_imports,
  95                 tcg_dus      = emptyDUs,
  96                 tcg_binds    = emptyLHsBinds,
  97                 tcg_deprecs  = NoDeprecs,
  98                 tcg_insts    = [],
  99                 tcg_rules    = [],
 100                 tcg_fords    = [],
 101                 tcg_keep     = keep_var
 102              } ;
 103              lcl_env = TcLclEnv {
 104                 tcl_errs       = errs_var,
 105                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 106                 tcl_ctxt       = [],
 107                 tcl_rdr        = emptyLocalRdrEnv,
 108                 tcl_th_ctxt    = topStage,
 109                 tcl_arrow_ctxt = topArrowCtxt,
 110                 tcl_env        = emptyNameEnv,
 111                 tcl_tyvars     = tvs_var,
 112                 tcl_lie        = panic "initTc:LIE",    -- LIE only valid inside a getLIE
 113                 tcl_gadt       = emptyVarEnv
 114              } ;
 115         } ;
 116
 117         -- OK, here's the business end!
 118         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 119                              do { r <- tryM do_this
 120                                 ; case r of
 121                                     Right res -> return (Just res)
 122                                     Left _    -> return Nothing } ;
 123
 124         -- Collect any error messages
 125         msgs <- readIORef errs_var ;
 126
 127         let { dflags = hsc_dflags hsc_env
 128             ; final_res | errorsFound dflags msgs = Nothing
 129                         | otherwise               = maybe_res } ;
 130
 131         return (msgs, final_res)
 132     }
 133   where
 134     init_imports = emptyImportAvails { imp_env = unitModuleEnv mod emptyNameSet }
 135         -- Initialise tcg_imports with an empty set of bindings for
 136         -- this module, so that if we see 'module M' in the export
 137         -- list, and there are no bindings in M, we don't bleat
 138         -- "unknown module M".
 139
 140 initTcPrintErrors       -- Used from the interactive loop only
 141        :: HscEnv
 142        -> Module
 143        -> TcM r
 144        -> IO (Maybe r)
 145 initTcPrintErrors env mod todo = do
 146   (msgs, res) <- initTc env HsSrcFile mod todo
 147   printErrorsAndWarnings msgs
 148   return res
 149
 150 -- mkImpTypeEnv makes the imported symbol table
 151 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 152              -> Name -> Maybe TyThing
 153 mkImpTypeEnv pcs hpt = lookup
 154   where
 155     pte = eps_PTE pcs
 156     lookup name | isInternalName name = Nothing
 157                 | otherwise           = lookupType hpt pte name
 158 \end{code}
 159
 160
 161 %************************************************************************
 162 %*                                                                      *
 163                 Initialisation
 164 %*                                                                      *
 165 %************************************************************************
 166
 167
 168 \begin{code}
 169 initTcRnIf :: Char              -- Tag for unique supply
 170            -> HscEnv
 171            -> gbl -> lcl
 172            -> TcRnIf gbl lcl a
 173            -> IO a
 174 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 175    = do { us     <- mkSplitUniqSupply uniq_tag ;
 176         ; us_var <- newIORef us ;
 177
 178         ; let { env = Env { env_top = hsc_env,
 179                             env_us  = us_var,
 180                             env_gbl = gbl_env,
 181                             env_lcl = lcl_env } }
 182
 183         ; runIOEnv env thing_inside
 184         }
 185 \end{code}
 186
 187 %************************************************************************
 188 %*                                                                      *
 189                 Simple accessors
 190 %*                                                                      *
 191 %************************************************************************
 192
 193 \begin{code}
 194 getTopEnv :: TcRnIf gbl lcl HscEnv
 195 getTopEnv = do { env <- getEnv; return (env_top env) }
 196
 197 getGblEnv :: TcRnIf gbl lcl gbl
 198 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 199
 200 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 201 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 202                           env { env_gbl = upd gbl })
 203
 204 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 205 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 206
 207 getLclEnv :: TcRnIf gbl lcl lcl
 208 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 209
 210 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 211 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 212                           env { env_lcl = upd lcl })
 213
 214 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 215 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 216
 217 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 218 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 219
 220 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 221 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 222 \end{code}
 223
 224
 225 Command-line flags
 226
 227 \begin{code}
 228 getDOpts :: TcRnIf gbl lcl DynFlags
 229 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 230
 231 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 232 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 233
 234 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 235 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 236                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 237
 238 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 239 ifOptM flag thing_inside = do { b <- doptM flag;
 240                                 if b then thing_inside else return () }
 241
 242 getGhciMode :: TcRnIf gbl lcl GhcMode
 243 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 244 \end{code}
 245
 246 \begin{code}
 247 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 248 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 249
 250 getEps :: TcRnIf gbl lcl ExternalPackageState
 251 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 252
 253 -- Updating the EPS.  This should be an atomic operation.
 254 -- Note the delicate 'seq' which forces the EPS before putting it in the
 255 -- variable.  Otherwise what happens is that we get
 256 --      write eps_var (....(unsafeRead eps_var)....)
 257 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 258 -- we make the unsafeRead happen before we update the variable.
 259
 260 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 261           -> TcRnIf gbl lcl a
 262 updateEps upd_fn = do   { traceIf (text "updating EPS")
 263                         ; eps_var <- getEpsVar
 264                         ; eps <- readMutVar eps_var
 265                         ; let { (eps', val) = upd_fn eps }
 266                         ; seq eps' (writeMutVar eps_var eps')
 267                         ; return val }
 268
 269 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 270            -> TcRnIf gbl lcl ()
 271 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 272                         ; eps_var <- getEpsVar
 273                         ; eps <- readMutVar eps_var
 274                         ; let { eps' = upd_fn eps }
 275                         ; seq eps' (writeMutVar eps_var eps') }
 276
 277 getHpt :: TcRnIf gbl lcl HomePackageTable
 278 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 279
 280 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 281 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 282                   ; return (eps, hsc_HPT env) }
 283 \end{code}
 284
 285 %************************************************************************
 286 %*                                                                      *
 287                 Unique supply
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 \begin{code}
 292 newUnique :: TcRnIf gbl lcl Unique
 293 newUnique = do { us <- newUniqueSupply ;
 294                  return (uniqFromSupply us) }
 295
 296 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 297 newUniqueSupply
 298  = do { env <- getEnv ;
 299         let { u_var = env_us env } ;
 300         us <- readMutVar u_var ;
 301         let { (us1, us2) = splitUniqSupply us } ;
 302         writeMutVar u_var us1 ;
 303         return us2 }
 304 \end{code}
 305
 306
 307 %************************************************************************
 308 %*                                                                      *
 309                 Debugging
 310 %*                                                                      *
 311 %************************************************************************
 312
 313 \begin{code}
 314 traceTc, traceRn :: SDoc -> TcRn ()
 315 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 316 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 317 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 318
 319
 320 traceIf :: SDoc -> TcRnIf m n ()
 321 traceIf      = dumpOptIf Opt_D_dump_if_trace
 322 traceHiDiffs = dumpOptIf Opt_D_dump_hi_diffs
 323
 324
 325 dumpOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 326 dumpOptIf flag doc = ifOptM flag $
 327                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 328
 329 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 330 dumpOptTcRn flag doc = ifOptM flag $ do
 331                         { ctxt <- getErrCtxt
 332                         ; loc  <- getSrcSpanM
 333                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 334                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 335                         ; dumpTcRn real_doc }
 336
 337 dumpTcRn :: SDoc -> TcRn ()
 338 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 339                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345                 Typechecker global environment
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 \begin{code}
 350 getModule :: TcRn Module
 351 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 352
 353 tcIsHsBoot :: TcRn Bool
 354 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 355
 356 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 357 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 358
 359 getImports :: TcRn ImportAvails
 360 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 361
 362 getFixityEnv :: TcRn FixityEnv
 363 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 364
 365 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 366 extendFixityEnv new_bit
 367   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 368                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 369
 370 getDefaultTys :: TcRn (Maybe [Type])
 371 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 372 \end{code}
 373
 374 %************************************************************************
 375 %*                                                                      *
 376                 Error management
 377 %*                                                                      *
 378 %************************************************************************
 379
 380 \begin{code}
 381 getSrcSpanM :: TcRn SrcSpan
 382         -- Avoid clash with Name.getSrcLoc
 383 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 384
 385 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 386 setSrcSpan loc thing_inside
 387   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 388   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 389
 390 addLocM :: (a -> TcM b) -> Located a -> TcM b
 391 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 392
 393 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 394 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 395
 396 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 397 wrapLocFstM fn (L loc a) =
 398   setSrcSpan loc $ do
 399     (b,c) <- fn a
 400     return (L loc b, c)
 401
 402 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 403 wrapLocSndM fn (L loc a) =
 404   setSrcSpan loc $ do
 405     (b,c) <- fn a
 406     return (b, L loc c)
 407 \end{code}
 408
 409
 410 \begin{code}
 411 getErrsVar :: TcRn (TcRef Messages)
 412 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 413
 414 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 415 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 416
 417 addErr :: Message -> TcRn ()
 418 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 419
 420 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 421 addLocErr (L loc e) fn = addErrAt loc (fn e)
 422
 423 addErrAt :: SrcSpan -> Message -> TcRn ()
 424 addErrAt loc msg = addLongErrAt loc msg empty
 425
 426 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 427 addLongErrAt loc msg extra
 428  = do {  errs_var <- getErrsVar ;
 429          rdr_env <- getGlobalRdrEnv ;
 430          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 431          (warns, errs) <- readMutVar errs_var ;
 432          writeMutVar errs_var (warns, errs `snocBag` err) }
 433
 434 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 435 addErrs msgs = mappM_ add msgs
 436              where
 437                add (loc,msg) = addErrAt loc msg
 438
 439 addReport :: Message -> TcRn ()
 440 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 441
 442 addReportAt :: SrcSpan -> Message -> TcRn ()
 443 addReportAt loc msg
 444   = do { errs_var <- getErrsVar ;
 445          rdr_env <- getGlobalRdrEnv ;
 446          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 447          (warns, errs) <- readMutVar errs_var ;
 448          writeMutVar errs_var (warns `snocBag` warn, errs) }
 449
 450 addWarn :: Message -> TcRn ()
 451 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 452
 453 addWarnAt :: SrcSpan -> Message -> TcRn ()
 454 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 455
 456 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 457 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 458
 459 checkErr :: Bool -> Message -> TcRn ()
 460 -- Add the error if the bool is False
 461 checkErr ok msg = checkM ok (addErr msg)
 462
 463 warnIf :: Bool -> Message -> TcRn ()
 464 warnIf True  msg = addWarn msg
 465 warnIf False msg = return ()
 466
 467 addMessages :: Messages -> TcRn ()
 468 addMessages (m_warns, m_errs)
 469   = do { errs_var <- getErrsVar ;
 470          (warns, errs) <- readMutVar errs_var ;
 471          writeMutVar errs_var (warns `unionBags` m_warns,
 472                                errs  `unionBags` m_errs) }
 473
 474 discardWarnings :: TcRn a -> TcRn a
 475 -- Ignore warnings inside the thing inside;
 476 -- used to ignore-unused-variable warnings inside derived code
 477 -- With -dppr-debug, the effects is switched off, so you can still see
 478 -- what warnings derived code would give
 479 discardWarnings thing_inside
 480   | opt_PprStyle_Debug = thing_inside
 481   | otherwise
 482   = do  { errs_var <- newMutVar emptyMessages
 483         ; result <- setErrsVar errs_var thing_inside
 484         ; (_warns, errs) <- readMutVar errs_var
 485         ; addMessages (emptyBag, errs)
 486         ; return result }
 487 \end{code}
 488
 489
 490 \begin{code}
 491 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 492          -> TcRn r      -- Main action: do this first
 493          -> TcRn r
 494 recoverM recover thing
 495   = do { mb_res <- try_m thing ;
 496          case mb_res of
 497            Left exn  -> recover
 498            Right res -> returnM res }
 499
 500 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 501     -- (tryTc m) executes m, and returns
 502     --  Just r,  if m succeeds (returning r) and caused no errors
 503     --  Nothing, if m fails, or caused errors
 504     -- It also returns all the errors accumulated by m
 505     --  (even in the Just case, there might be warnings)
 506     --
 507     -- It always succeeds (never raises an exception)
 508 tryTc m
 509  = do { errs_var <- newMutVar emptyMessages ;
 510
 511         mb_r <- try_m (setErrsVar errs_var m) ;
 512
 513         new_errs <- readMutVar errs_var ;
 514
 515         dflags <- getDOpts ;
 516
 517         return (new_errs,
 518                 case mb_r of
 519                   Left exn -> Nothing
 520                   Right r | errorsFound dflags new_errs -> Nothing
 521                           | otherwise                   -> Just r)
 522    }
 523
 524 try_m :: TcRn r -> TcRn (Either Exception r)
 525 -- Does try_m, with a debug-trace on failure
 526 try_m thing
 527   = do { mb_r <- tryM thing ;
 528          case mb_r of
 529              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 530              Right r  -> return mb_r }
 531   where
 532     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 533
 534 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 535 -- Just like tryTc, except that it ensures that the LIE
 536 -- for the thing is propagated only if there are no errors
 537 -- Hence it's restricted to the type-check monad
 538 tryTcLIE thing_inside
 539   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 540          ifM (isJust mb_r) (extendLIEs lie) ;
 541          return (errs, mb_r) }
 542
 543 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 544 -- (tryTcLIE_ r m) tries m; if it succeeds it returns it,
 545 -- otherwise it returns r.  Any error messages added by m are discarded,
 546 -- whether or not m succeeds.
 547 tryTcLIE_ recover main
 548   = do { (_msgs, mb_res) <- tryTcLIE main ;
 549          case mb_res of
 550            Just res -> return res
 551            Nothing  -> recover }
 552
 553 checkNoErrs :: TcM r -> TcM r
 554 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 555 -- If m fails then (checkNoErrsTc m) fails.
 556 -- If m succeeds, it checks whether m generated any errors messages
 557 --      (it might have recovered internally)
 558 --      If so, it fails too.
 559 -- Regardless, any errors generated by m are propagated to the enclosing context.
 560 checkNoErrs main
 561   = do { (msgs, mb_res) <- tryTcLIE main ;
 562          addMessages msgs ;
 563          case mb_res of
 564            Just r  -> return r
 565            Nothing -> failM
 566    }
 567
 568 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 569 --      ifErrsM bale_out main
 570 -- does 'bale_out' if there are errors in errors collection
 571 -- otherwise does 'main'
 572 ifErrsM bale_out normal
 573  = do { errs_var <- getErrsVar ;
 574         msgs <- readMutVar errs_var ;
 575         dflags <- getDOpts ;
 576         if errorsFound dflags msgs then
 577            bale_out
 578         else
 579            normal }
 580
 581 failIfErrsM :: TcRn ()
 582 -- Useful to avoid error cascades
 583 failIfErrsM = ifErrsM failM (return ())
 584 \end{code}
 585
 586
 587 %************************************************************************
 588 %*                                                                      *
 589         Context management and error message generation
 590                     for the type checker
 591 %*                                                                      *
 592 %************************************************************************
 593
 594 \begin{code}
 595 getErrCtxt :: TcM ErrCtxt
 596 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 597
 598 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 599 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 600
 601 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 602 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 603
 604 addErrCtxt :: Message -> TcM a -> TcM a
 605 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 606
 607 -- Helper function for the above
 608 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 609 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 610                            env { tcl_ctxt = upd ctxt })
 611
 612 -- Conditionally add an error context
 613 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 614 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 615 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 616
 617 popErrCtxt :: TcM a -> TcM a
 618 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 619
 620 getInstLoc :: InstOrigin -> TcM InstLoc
 621 getInstLoc origin
 622   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 623          return (InstLoc origin loc (tcl_ctxt env)) }
 624
 625 addInstCtxt :: InstLoc -> TcM a -> TcM a
 626 -- Add the SrcSpan and context from the first Inst in the list
 627 --      (they all have similar locations)
 628 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 629   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 630 \end{code}
 631
 632     The addErrTc functions add an error message, but do not cause failure.
 633     The 'M' variants pass a TidyEnv that has already been used to
 634     tidy up the message; we then use it to tidy the context messages
 635
 636 \begin{code}
 637 addErrTc :: Message -> TcM ()
 638 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 639
 640 addErrsTc :: [Message] -> TcM ()
 641 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 642
 643 addErrTcM :: (TidyEnv, Message) -> TcM ()
 644 addErrTcM (tidy_env, err_msg)
 645   = do { ctxt <- getErrCtxt ;
 646          loc  <- getSrcSpanM ;
 647          add_err_tcm tidy_env err_msg loc ctxt }
 648 \end{code}
 649
 650 The failWith functions add an error message and cause failure
 651
 652 \begin{code}
 653 failWithTc :: Message -> TcM a               -- Add an error message and fail
 654 failWithTc err_msg
 655   = addErrTc err_msg >> failM
 656
 657 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 658 failWithTcM local_and_msg
 659   = addErrTcM local_and_msg >> failM
 660
 661 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 662 checkTc True  err = returnM ()
 663 checkTc False err = failWithTc err
 664 \end{code}
 665
 666         Warnings have no 'M' variant, nor failure
 667
 668 \begin{code}
 669 addWarnTc :: Message -> TcM ()
 670 addWarnTc msg
 671  = do { ctxt <- getErrCtxt ;
 672         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 673         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 674
 675 warnTc :: Bool -> Message -> TcM ()
 676 warnTc warn_if_true warn_msg
 677   | warn_if_true = addWarnTc warn_msg
 678   | otherwise    = return ()
 679 \end{code}
 680
 681         Helper functions
 682
 683 \begin{code}
 684 add_err_tcm tidy_env err_msg loc ctxt
 685  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 686         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 687
 688 do_ctxt tidy_env []
 689  = return []
 690 do_ctxt tidy_env (c:cs)
 691  = do { (tidy_env', m) <- c tidy_env  ;
 692         ms             <- do_ctxt tidy_env' cs  ;
 693         return (m:ms) }
 694
 695 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 696                  | otherwise          = take 3 ctxt
 697 \end{code}
 698
 699 debugTc is useful for monadi debugging code
 700
 701 \begin{code}
 702 debugTc :: TcM () -> TcM ()
 703 #ifdef DEBUG
 704 debugTc thing = thing
 705 #else
 706 debugTc thing = return ()
 707 #endif
 708 \end{code}
 709
 710  %************************************************************************
 711 %*                                                                      *
 712              Type constraints (the so-called LIE)
 713 %*                                                                      *
 714 %************************************************************************
 715
 716 \begin{code}
 717 getLIEVar :: TcM (TcRef LIE)
 718 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 719
 720 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 721 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 722
 723 getLIE :: TcM a -> TcM (a, [Inst])
 724 -- (getLIE m) runs m, and returns the type constraints it generates
 725 getLIE thing_inside
 726   = do { lie_var <- newMutVar emptyLIE ;
 727          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 728                           thing_inside ;
 729          lie <- readMutVar lie_var ;
 730          return (res, lieToList lie) }
 731
 732 extendLIE :: Inst -> TcM ()
 733 extendLIE inst
 734   = do { lie_var <- getLIEVar ;
 735          lie <- readMutVar lie_var ;
 736          writeMutVar lie_var (inst `consLIE` lie) }
 737
 738 extendLIEs :: [Inst] -> TcM ()
 739 extendLIEs []
 740   = returnM ()
 741 extendLIEs insts
 742   = do { lie_var <- getLIEVar ;
 743          lie <- readMutVar lie_var ;
 744          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 745 \end{code}
 746
 747 \begin{code}
 748 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 749 -- Set the local type envt, but do *not* disturb other fields,
 750 -- notably the lie_var
 751 setLclTypeEnv lcl_env thing_inside
 752   = updLclEnv upd thing_inside
 753   where
 754     upd env = env { tcl_env = tcl_env lcl_env,
 755                     tcl_tyvars = tcl_tyvars lcl_env }
 756 \end{code}
 757
 758
 759 %************************************************************************
 760 %*                                                                      *
 761              Template Haskell context
 762 %*                                                                      *
 763 %************************************************************************
 764
 765 \begin{code}
 766 recordThUse :: TcM ()
 767 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 768
 769 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 770 keepAliveTc n = do { env <- getGblEnv;
 771                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 772
 773 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 774 keepAliveSetTc ns = do { env <- getGblEnv;
 775                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 776
 777 getStage :: TcM ThStage
 778 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 779
 780 setStage :: ThStage -> TcM a -> TcM a
 781 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 782 \end{code}
 783
 784
 785 %************************************************************************
 786 %*                                                                      *
 787              Arrow context
 788 %*                                                                      *
 789 %************************************************************************
 790
 791 \begin{code}
 792 popArrowBinders :: TcM a -> TcM a       -- Move to the left of a (-<); see comments in TcRnTypes
 793 popArrowBinders
 794   = updLclEnv (\ env -> env { tcl_arrow_ctxt = pop (tcl_arrow_ctxt env)  })
 795   where
 796     pop (ArrCtxt {proc_level = curr_lvl, proc_banned = banned})
 797         = ASSERT( not (curr_lvl `elem` banned) )
 798           ArrCtxt {proc_level = curr_lvl + 1, proc_banned = curr_lvl : banned}
 799
 800 getBannedProcLevels :: TcM [ProcLevel]
 801 getBannedProcLevels
 802   = do { env <- getLclEnv; return (proc_banned (tcl_arrow_ctxt env)) }
 803
 804 incProcLevel :: TcM a -> TcM a
 805 incProcLevel
 806   = updLclEnv (\ env -> env { tcl_arrow_ctxt = inc (tcl_arrow_ctxt env) })
 807   where
 808     inc ctxt = ctxt { proc_level = proc_level ctxt + 1 }
 809 \end{code}
 810
 811
 812 %************************************************************************
 813 %*                                                                      *
 814              Stuff for the renamer's local env
 815 %*                                                                      *
 816 %************************************************************************
 817
 818 \begin{code}
 819 getLocalRdrEnv :: RnM LocalRdrEnv
 820 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 821
 822 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 823 setLocalRdrEnv rdr_env thing_inside
 824   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 825 \end{code}
 826
 827
 828 %************************************************************************
 829 %*                                                                      *
 830              Stuff for interface decls
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 \begin{code}
 835 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 836 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 837                                 if_loc     = loc,
 838                                 if_tv_env  = emptyOccEnv,
 839                                 if_id_env  = emptyOccEnv }
 840
 841 initIfaceTcRn :: IfG a -> TcRn a
 842 initIfaceTcRn thing_inside
 843   = do  { tcg_env <- getGblEnv
 844         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 845               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 846         ; setEnvs (if_env, ()) thing_inside }
 847
 848 initIfaceExtCore :: IfL a -> TcRn a
 849 initIfaceExtCore thing_inside
 850   = do  { tcg_env <- getGblEnv
 851         ; let { mod = tcg_mod tcg_env
 852               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 853               ; if_env = IfGblEnv {
 854                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 855               ; if_lenv = mkIfLclEnv mod doc
 856           }
 857         ; setEnvs (if_env, if_lenv) thing_inside }
 858
 859 initIfaceCheck :: HscEnv -> IfG a -> IO a
 860 -- Used when checking the up-to-date-ness of the old Iface
 861 -- Initialise the environment with no useful info at all
 862 initIfaceCheck hsc_env do_this
 863  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 864         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 865     }
 866
 867 initIfaceTc :: HscEnv -> ModIface
 868             -> (TcRef TypeEnv -> IfL a) -> IO a
 869 -- Used when type-checking checking an up-to-date interface file
 870 -- No type envt from the current module, but we do know the module dependencies
 871 initIfaceTc hsc_env iface do_this
 872  = do   { tc_env_var <- newIORef emptyTypeEnv
 873         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 874               ; if_lenv = mkIfLclEnv mod doc
 875            }
 876         ; initTcRnIf 'i' hsc_env gbl_env if_lenv (do_this tc_env_var)
 877     }
 878   where
 879     mod = mi_module iface
 880     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 881
 882 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 883 -- Used when sucking in new Rules in SimplCore
 884 -- We have available the type envt of the module being compiled, and we must use it
 885 initIfaceRules hsc_env guts do_this
 886  = do   { let {
 887              type_info = (mg_module guts, return (mg_types guts))
 888            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 889            }
 890
 891         -- Run the thing; any exceptions just bubble out from here
 892         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 893     }
 894
 895 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 896 initIfaceLcl mod loc_doc thing_inside
 897   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 898
 899 getIfModule :: IfL Module
 900 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 901
 902 --------------------
 903 failIfM :: Message -> IfL a
 904 -- The Iface monad doesn't have a place to accumulate errors, so we
 905 -- just fall over fast if one happens; it "shouldnt happen".
 906 -- We use IfL here so that we can get context info out of the local env
 907 failIfM msg
 908   = do  { env <- getLclEnv
 909         ; let full_msg = if_loc env $$ nest 2 msg
 910         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 911         ; failM }
 912
 913 --------------------
 914 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 915 -- Run thing_inside in an interleaved thread.
 916 -- It shares everything with the parent thread, so this is DANGEROUS.
 917 --
 918 -- It returns Nothing if the computation fails
 919 --
 920 -- It's used for lazily type-checking interface
 921 -- signatures, which is pretty benign
 922
 923 forkM_maybe doc thing_inside
 924  = do { unsafeInterleaveM $
 925         do { traceIf (text "Starting fork {" <+> doc)
 926            ; mb_res <- tryM thing_inside ;
 927              case mb_res of
 928                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 929                                 ; return (Just r) }
 930                 Left exn -> do {
 931
 932                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 933                     -- Otherwise we silently discard errors. Errors can legitimately
 934                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 935                       ifOptM Opt_D_dump_if_trace
 936                              (print_errs (hang (text "forkM failed:" <+> doc)
 937                                              4 (text (show exn))))
 938
 939                     ; traceIf (text "} ending fork (badly)" <+> doc)
 940                     ; return Nothing }
 941         }}
 942   where
 943     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 944
 945 forkM :: SDoc -> IfL a -> IfL a
 946 forkM doc thing_inside
 947  = do   { mb_res <- forkM_maybe doc thing_inside
 948         ; return (case mb_res of
 949                         Nothing -> pprPanic "forkM" doc
 950                         Just r  -> r) }
 951 \end{code}
 952
 953 %************************************************************************
 954 %*                                                                      *
 955              Stuff for GADTs
 956 %*                                                                      *
 957 %************************************************************************
 958
 959 \begin{code}
 960 getTypeRefinement :: TcM GadtRefinement
 961 getTypeRefinement = do { lcl_env <- getLclEnv; return (tcl_gadt lcl_env) }
 962
 963 setTypeRefinement :: GadtRefinement -> TcM a -> TcM a
 964 setTypeRefinement gadt = updLclEnv (\env -> env { tcl_gadt = gadt })
 965 \end{code}