ghc/compiler/typecheck/TcRnMonad.lhs

   1 \begin{code}
   2 module TcRnMonad(
   3         module TcRnMonad,
   4         module TcRnTypes,
   5         module IOEnv
   6   ) where
   7
   8 #include "HsVersions.h"
   9
  10 import TcRnTypes        -- Re-export all
  11 import IOEnv            -- Re-export all
  12
  13 import HsSyn            ( emptyLHsBinds )
  14 import HscTypes         ( HscEnv(..), ModGuts(..), ModIface(..),
  15                           TyThing, TypeEnv, emptyTypeEnv, HscSource(..), isHsBoot,
  16                           ExternalPackageState(..), HomePackageTable,
  17                           Deprecs(..), FixityEnv, FixItem,
  18                           lookupType, unQualInScope )
  19 import Module           ( Module, unitModuleEnv )
  20 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  21                           LocalRdrEnv, emptyLocalRdrEnv )
  22 import Name             ( Name, isInternalName )
  23 import Type             ( Type )
  24 import NameEnv          ( extendNameEnvList )
  25 import InstEnv          ( emptyInstEnv )
  26
  27 import VarSet           ( emptyVarSet )
  28 import VarEnv           ( TidyEnv, emptyTidyEnv, emptyVarEnv )
  29 import ErrUtils         ( Message, Messages, emptyMessages, errorsFound,
  30                           mkWarnMsg, printErrorsAndWarnings,
  31                           mkLocMessage, mkLongErrMsg )
  32 import SrcLoc           ( mkGeneralSrcSpan, isGoodSrcSpan, SrcSpan, Located(..) )
  33 import NameEnv          ( emptyNameEnv )
  34 import NameSet          ( NameSet, emptyDUs, emptyNameSet, unionNameSets, addOneToNameSet )
  35 import OccName          ( emptyOccEnv )
  36 import Bag              ( emptyBag )
  37 import Outputable
  38 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, uniqFromSupply, splitUniqSupply )
  39 import Unique           ( Unique )
  40 import DynFlags         ( DynFlags(..), DynFlag(..), dopt, dopt_set, GhcMode )
  41 import StaticFlags      ( opt_PprStyle_Debug )
  42 import Bag              ( snocBag, unionBags )
  43 import Panic            ( showException )
  44
  45 import Maybe            ( isJust )
  46 import IO               ( stderr )
  47 import DATA_IOREF       ( newIORef, readIORef )
  48 import EXCEPTION        ( Exception )
  49 \end{code}
  50
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55                         initTc
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 \begin{code}
  60 ioToTcRn :: IO r -> TcRn r
  61 ioToTcRn = ioToIOEnv
  62 \end{code}
  63
  64 \begin{code}
  65 initTc :: HscEnv
  66        -> HscSource
  67        -> Module
  68        -> TcM r
  69        -> IO (Messages, Maybe r)
  70                 -- Nothing => error thrown by the thing inside
  71                 -- (error messages should have been printed already)
  72
  73 initTc hsc_env hsc_src mod do_this
  74  = do { errs_var     <- newIORef (emptyBag, emptyBag) ;
  75         tvs_var      <- newIORef emptyVarSet ;
  76         type_env_var <- newIORef emptyNameEnv ;
  77         dfuns_var    <- newIORef emptyNameSet ;
  78         keep_var     <- newIORef emptyNameSet ;
  79         th_var       <- newIORef False ;
  80
  81         let {
  82              gbl_env = TcGblEnv {
  83                 tcg_mod      = mod,
  84                 tcg_src      = hsc_src,
  85                 tcg_rdr_env  = emptyGlobalRdrEnv,
  86                 tcg_fix_env  = emptyNameEnv,
  87                 tcg_default  = Nothing,
  88                 tcg_type_env = emptyNameEnv,
  89                 tcg_type_env_var = type_env_var,
  90                 tcg_inst_env  = emptyInstEnv,
  91                 tcg_inst_uses = dfuns_var,
  92                 tcg_th_used   = th_var,
  93                 tcg_exports  = emptyNameSet,
  94                 tcg_imports  = init_imports,
  95                 tcg_dus      = emptyDUs,
  96                 tcg_binds    = emptyLHsBinds,
  97                 tcg_deprecs  = NoDeprecs,
  98                 tcg_insts    = [],
  99                 tcg_rules    = [],
 100                 tcg_fords    = [],
 101                 tcg_keep     = keep_var
 102              } ;
 103              lcl_env = TcLclEnv {
 104                 tcl_errs       = errs_var,
 105                 tcl_loc        = mkGeneralSrcSpan FSLIT("Top level"),
 106                 tcl_ctxt       = [],
 107                 tcl_rdr        = emptyLocalRdrEnv,
 108                 tcl_th_ctxt    = topStage,
 109                 tcl_env        = emptyNameEnv,
 110                 tcl_tyvars     = tvs_var,
 111                 tcl_lie        = panic "initTc:LIE",    -- LIE only valid inside a getLIE
 112                 tcl_gadt       = emptyVarEnv
 113              } ;
 114         } ;
 115
 116         -- OK, here's the business end!
 117         maybe_res <- initTcRnIf 'a' hsc_env gbl_env lcl_env $
 118                              do { r <- tryM do_this
 119                                 ; case r of
 120                                     Right res -> return (Just res)
 121                                     Left _    -> return Nothing } ;
 122
 123         -- Collect any error messages
 124         msgs <- readIORef errs_var ;
 125
 126         let { dflags = hsc_dflags hsc_env
 127             ; final_res | errorsFound dflags msgs = Nothing
 128                         | otherwise               = maybe_res } ;
 129
 130         return (msgs, final_res)
 131     }
 132   where
 133     init_imports = emptyImportAvails { imp_env = unitModuleEnv mod emptyNameSet }
 134         -- Initialise tcg_imports with an empty set of bindings for
 135         -- this module, so that if we see 'module M' in the export
 136         -- list, and there are no bindings in M, we don't bleat
 137         -- "unknown module M".
 138
 139 initTcPrintErrors       -- Used from the interactive loop only
 140        :: HscEnv
 141        -> Module
 142        -> TcM r
 143        -> IO (Maybe r)
 144 initTcPrintErrors env mod todo = do
 145   (msgs, res) <- initTc env HsSrcFile mod todo
 146   printErrorsAndWarnings msgs
 147   return res
 148
 149 -- mkImpTypeEnv makes the imported symbol table
 150 mkImpTypeEnv :: ExternalPackageState -> HomePackageTable
 151              -> Name -> Maybe TyThing
 152 mkImpTypeEnv pcs hpt = lookup
 153   where
 154     pte = eps_PTE pcs
 155     lookup name | isInternalName name = Nothing
 156                 | otherwise           = lookupType hpt pte name
 157 \end{code}
 158
 159
 160 %************************************************************************
 161 %*                                                                      *
 162                 Initialisation
 163 %*                                                                      *
 164 %************************************************************************
 165
 166
 167 \begin{code}
 168 initTcRnIf :: Char              -- Tag for unique supply
 169            -> HscEnv
 170            -> gbl -> lcl
 171            -> TcRnIf gbl lcl a
 172            -> IO a
 173 initTcRnIf uniq_tag hsc_env gbl_env lcl_env thing_inside
 174    = do { us     <- mkSplitUniqSupply uniq_tag ;
 175         ; us_var <- newIORef us ;
 176
 177         ; let { env = Env { env_top = hsc_env,
 178                             env_us  = us_var,
 179                             env_gbl = gbl_env,
 180                             env_lcl = lcl_env } }
 181
 182         ; runIOEnv env thing_inside
 183         }
 184 \end{code}
 185
 186 %************************************************************************
 187 %*                                                                      *
 188                 Simple accessors
 189 %*                                                                      *
 190 %************************************************************************
 191
 192 \begin{code}
 193 getTopEnv :: TcRnIf gbl lcl HscEnv
 194 getTopEnv = do { env <- getEnv; return (env_top env) }
 195
 196 getGblEnv :: TcRnIf gbl lcl gbl
 197 getGblEnv = do { env <- getEnv; return (env_gbl env) }
 198
 199 updGblEnv :: (gbl -> gbl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 200 updGblEnv upd = updEnv (\ env@(Env { env_gbl = gbl }) ->
 201                           env { env_gbl = upd gbl })
 202
 203 setGblEnv :: gbl -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 204 setGblEnv gbl_env = updEnv (\ env -> env { env_gbl = gbl_env })
 205
 206 getLclEnv :: TcRnIf gbl lcl lcl
 207 getLclEnv = do { env <- getEnv; return (env_lcl env) }
 208
 209 updLclEnv :: (lcl -> lcl) -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 210 updLclEnv upd = updEnv (\ env@(Env { env_lcl = lcl }) ->
 211                           env { env_lcl = upd lcl })
 212
 213 setLclEnv :: lcl' -> TcRnIf gbl lcl' a -> TcRnIf gbl lcl a
 214 setLclEnv lcl_env = updEnv (\ env -> env { env_lcl = lcl_env })
 215
 216 getEnvs :: TcRnIf gbl lcl (gbl, lcl)
 217 getEnvs = do { env <- getEnv; return (env_gbl env, env_lcl env) }
 218
 219 setEnvs :: (gbl', lcl') -> TcRnIf gbl' lcl' a -> TcRnIf gbl lcl a
 220 setEnvs (gbl_env, lcl_env) = updEnv (\ env -> env { env_gbl = gbl_env, env_lcl = lcl_env })
 221 \end{code}
 222
 223
 224 Command-line flags
 225
 226 \begin{code}
 227 getDOpts :: TcRnIf gbl lcl DynFlags
 228 getDOpts = do { env <- getTopEnv; return (hsc_dflags env) }
 229
 230 doptM :: DynFlag -> TcRnIf gbl lcl Bool
 231 doptM flag = do { dflags <- getDOpts; return (dopt flag dflags) }
 232
 233 setOptM :: DynFlag -> TcRnIf gbl lcl a -> TcRnIf gbl lcl a
 234 setOptM flag = updEnv (\ env@(Env { env_top = top }) ->
 235                          env { env_top = top { hsc_dflags = dopt_set (hsc_dflags top) flag}} )
 236
 237 ifOptM :: DynFlag -> TcRnIf gbl lcl () -> TcRnIf gbl lcl ()     -- Do it flag is true
 238 ifOptM flag thing_inside = do { b <- doptM flag;
 239                                 if b then thing_inside else return () }
 240
 241 getGhciMode :: TcRnIf gbl lcl GhcMode
 242 getGhciMode = do { env <- getTopEnv; return (ghcMode (hsc_dflags env)) }
 243 \end{code}
 244
 245 \begin{code}
 246 getEpsVar :: TcRnIf gbl lcl (TcRef ExternalPackageState)
 247 getEpsVar = do { env <- getTopEnv; return (hsc_EPS env) }
 248
 249 getEps :: TcRnIf gbl lcl ExternalPackageState
 250 getEps = do { env <- getTopEnv; readMutVar (hsc_EPS env) }
 251
 252 -- Updating the EPS.  This should be an atomic operation.
 253 -- Note the delicate 'seq' which forces the EPS before putting it in the
 254 -- variable.  Otherwise what happens is that we get
 255 --      write eps_var (....(unsafeRead eps_var)....)
 256 -- and if the .... is strict, that's obviously bottom.  By forcing it beforehand
 257 -- we make the unsafeRead happen before we update the variable.
 258
 259 updateEps :: (ExternalPackageState -> (ExternalPackageState, a))
 260           -> TcRnIf gbl lcl a
 261 updateEps upd_fn = do   { traceIf (text "updating EPS")
 262                         ; eps_var <- getEpsVar
 263                         ; eps <- readMutVar eps_var
 264                         ; let { (eps', val) = upd_fn eps }
 265                         ; seq eps' (writeMutVar eps_var eps')
 266                         ; return val }
 267
 268 updateEps_ :: (ExternalPackageState -> ExternalPackageState)
 269            -> TcRnIf gbl lcl ()
 270 updateEps_ upd_fn = do  { traceIf (text "updating EPS_")
 271                         ; eps_var <- getEpsVar
 272                         ; eps <- readMutVar eps_var
 273                         ; let { eps' = upd_fn eps }
 274                         ; seq eps' (writeMutVar eps_var eps') }
 275
 276 getHpt :: TcRnIf gbl lcl HomePackageTable
 277 getHpt = do { env <- getTopEnv; return (hsc_HPT env) }
 278
 279 getEpsAndHpt :: TcRnIf gbl lcl (ExternalPackageState, HomePackageTable)
 280 getEpsAndHpt = do { env <- getTopEnv; eps <- readMutVar (hsc_EPS env)
 281                   ; return (eps, hsc_HPT env) }
 282 \end{code}
 283
 284 %************************************************************************
 285 %*                                                                      *
 286                 Unique supply
 287 %*                                                                      *
 288 %************************************************************************
 289
 290 \begin{code}
 291 newUnique :: TcRnIf gbl lcl Unique
 292 newUnique = do { us <- newUniqueSupply ;
 293                  return (uniqFromSupply us) }
 294
 295 newUniqueSupply :: TcRnIf gbl lcl UniqSupply
 296 newUniqueSupply
 297  = do { env <- getEnv ;
 298         let { u_var = env_us env } ;
 299         us <- readMutVar u_var ;
 300         let { (us1, us2) = splitUniqSupply us } ;
 301         writeMutVar u_var us1 ;
 302         return us2 }
 303 \end{code}
 304
 305
 306 %************************************************************************
 307 %*                                                                      *
 308                 Debugging
 309 %*                                                                      *
 310 %************************************************************************
 311
 312 \begin{code}
 313 traceTc, traceRn :: SDoc -> TcRn ()
 314 traceRn      = dumpOptTcRn Opt_D_dump_rn_trace
 315 traceTc      = dumpOptTcRn Opt_D_dump_tc_trace
 316 traceSplice  = dumpOptTcRn Opt_D_dump_splices
 317
 318
 319 traceIf :: SDoc -> TcRnIf m n ()
 320 traceIf      = dumpOptIf Opt_D_dump_if_trace
 321 traceHiDiffs = dumpOptIf Opt_D_dump_hi_diffs
 322
 323
 324 dumpOptIf :: DynFlag -> SDoc -> TcRnIf m n ()  -- No RdrEnv available, so qualify everything
 325 dumpOptIf flag doc = ifOptM flag $
 326                      ioToIOEnv (printForUser stderr alwaysQualify doc)
 327
 328 dumpOptTcRn :: DynFlag -> SDoc -> TcRn ()
 329 dumpOptTcRn flag doc = ifOptM flag $ do
 330                         { ctxt <- getErrCtxt
 331                         ; loc  <- getSrcSpanM
 332                         ; ctxt_msgs <- do_ctxt emptyTidyEnv ctxt
 333                         ; let real_doc = mkLocMessage loc (vcat (doc : ctxt_to_use ctxt_msgs))
 334                         ; dumpTcRn real_doc }
 335
 336 dumpTcRn :: SDoc -> TcRn ()
 337 dumpTcRn doc = do { rdr_env <- getGlobalRdrEnv ;
 338                     ioToTcRn (printForUser stderr (unQualInScope rdr_env) doc) }
 339 \end{code}
 340
 341
 342 %************************************************************************
 343 %*                                                                      *
 344                 Typechecker global environment
 345 %*                                                                      *
 346 %************************************************************************
 347
 348 \begin{code}
 349 getModule :: TcRn Module
 350 getModule = do { env <- getGblEnv; return (tcg_mod env) }
 351
 352 tcIsHsBoot :: TcRn Bool
 353 tcIsHsBoot = do { env <- getGblEnv; return (isHsBoot (tcg_src env)) }
 354
 355 getGlobalRdrEnv :: TcRn GlobalRdrEnv
 356 getGlobalRdrEnv = do { env <- getGblEnv; return (tcg_rdr_env env) }
 357
 358 getImports :: TcRn ImportAvails
 359 getImports = do { env <- getGblEnv; return (tcg_imports env) }
 360
 361 getFixityEnv :: TcRn FixityEnv
 362 getFixityEnv = do { env <- getGblEnv; return (tcg_fix_env env) }
 363
 364 extendFixityEnv :: [(Name,FixItem)] -> RnM a -> RnM a
 365 extendFixityEnv new_bit
 366   = updGblEnv (\env@(TcGblEnv { tcg_fix_env = old_fix_env }) ->
 367                 env {tcg_fix_env = extendNameEnvList old_fix_env new_bit})
 368
 369 getDefaultTys :: TcRn (Maybe [Type])
 370 getDefaultTys = do { env <- getGblEnv; return (tcg_default env) }
 371 \end{code}
 372
 373 %************************************************************************
 374 %*                                                                      *
 375                 Error management
 376 %*                                                                      *
 377 %************************************************************************
 378
 379 \begin{code}
 380 getSrcSpanM :: TcRn SrcSpan
 381         -- Avoid clash with Name.getSrcLoc
 382 getSrcSpanM = do { env <- getLclEnv; return (tcl_loc env) }
 383
 384 setSrcSpan :: SrcSpan -> TcRn a -> TcRn a
 385 setSrcSpan loc thing_inside
 386   | isGoodSrcSpan loc = updLclEnv (\env -> env { tcl_loc = loc }) thing_inside
 387   | otherwise         = thing_inside    -- Don't overwrite useful info with useless
 388
 389 addLocM :: (a -> TcM b) -> Located a -> TcM b
 390 addLocM fn (L loc a) = setSrcSpan loc $ fn a
 391
 392 wrapLocM :: (a -> TcM b) -> Located a -> TcM (Located b)
 393 wrapLocM fn (L loc a) = setSrcSpan loc $ do b <- fn a; return (L loc b)
 394
 395 wrapLocFstM :: (a -> TcM (b,c)) -> Located a -> TcM (Located b, c)
 396 wrapLocFstM fn (L loc a) =
 397   setSrcSpan loc $ do
 398     (b,c) <- fn a
 399     return (L loc b, c)
 400
 401 wrapLocSndM :: (a -> TcM (b,c)) -> Located a -> TcM (b, Located c)
 402 wrapLocSndM fn (L loc a) =
 403   setSrcSpan loc $ do
 404     (b,c) <- fn a
 405     return (b, L loc c)
 406 \end{code}
 407
 408
 409 \begin{code}
 410 getErrsVar :: TcRn (TcRef Messages)
 411 getErrsVar = do { env <- getLclEnv; return (tcl_errs env) }
 412
 413 setErrsVar :: TcRef Messages -> TcRn a -> TcRn a
 414 setErrsVar v = updLclEnv (\ env -> env { tcl_errs =  v })
 415
 416 addErr :: Message -> TcRn ()
 417 addErr msg = do { loc <- getSrcSpanM ; addErrAt loc msg }
 418
 419 addLocErr :: Located e -> (e -> Message) -> TcRn ()
 420 addLocErr (L loc e) fn = addErrAt loc (fn e)
 421
 422 addErrAt :: SrcSpan -> Message -> TcRn ()
 423 addErrAt loc msg = addLongErrAt loc msg empty
 424
 425 addLongErrAt :: SrcSpan -> Message -> Message -> TcRn ()
 426 addLongErrAt loc msg extra
 427  = do {  errs_var <- getErrsVar ;
 428          rdr_env <- getGlobalRdrEnv ;
 429          let { err = mkLongErrMsg loc (unQualInScope rdr_env) msg extra } ;
 430          (warns, errs) <- readMutVar errs_var ;
 431          writeMutVar errs_var (warns, errs `snocBag` err) }
 432
 433 addErrs :: [(SrcSpan,Message)] -> TcRn ()
 434 addErrs msgs = mappM_ add msgs
 435              where
 436                add (loc,msg) = addErrAt loc msg
 437
 438 addReport :: Message -> TcRn ()
 439 addReport msg = do loc <- getSrcSpanM; addReportAt loc msg
 440
 441 addReportAt :: SrcSpan -> Message -> TcRn ()
 442 addReportAt loc msg
 443   = do { errs_var <- getErrsVar ;
 444          rdr_env <- getGlobalRdrEnv ;
 445          let { warn = mkWarnMsg loc (unQualInScope rdr_env) msg } ;
 446          (warns, errs) <- readMutVar errs_var ;
 447          writeMutVar errs_var (warns `snocBag` warn, errs) }
 448
 449 addWarn :: Message -> TcRn ()
 450 addWarn msg = addReport (ptext SLIT("Warning:") <+> msg)
 451
 452 addWarnAt :: SrcSpan -> Message -> TcRn ()
 453 addWarnAt loc msg = addReportAt loc (ptext SLIT("Warning:") <+> msg)
 454
 455 addLocWarn :: Located e -> (e -> Message) -> TcRn ()
 456 addLocWarn (L loc e) fn = addReportAt loc (fn e)
 457
 458 checkErr :: Bool -> Message -> TcRn ()
 459 -- Add the error if the bool is False
 460 checkErr ok msg = checkM ok (addErr msg)
 461
 462 warnIf :: Bool -> Message -> TcRn ()
 463 warnIf True  msg = addWarn msg
 464 warnIf False msg = return ()
 465
 466 addMessages :: Messages -> TcRn ()
 467 addMessages (m_warns, m_errs)
 468   = do { errs_var <- getErrsVar ;
 469          (warns, errs) <- readMutVar errs_var ;
 470          writeMutVar errs_var (warns `unionBags` m_warns,
 471                                errs  `unionBags` m_errs) }
 472
 473 discardWarnings :: TcRn a -> TcRn a
 474 -- Ignore warnings inside the thing inside;
 475 -- used to ignore-unused-variable warnings inside derived code
 476 -- With -dppr-debug, the effects is switched off, so you can still see
 477 -- what warnings derived code would give
 478 discardWarnings thing_inside
 479   | opt_PprStyle_Debug = thing_inside
 480   | otherwise
 481   = do  { errs_var <- newMutVar emptyMessages
 482         ; result <- setErrsVar errs_var thing_inside
 483         ; (_warns, errs) <- readMutVar errs_var
 484         ; addMessages (emptyBag, errs)
 485         ; return result }
 486 \end{code}
 487
 488
 489 \begin{code}
 490 recoverM :: TcRn r      -- Recovery action; do this if the main one fails
 491          -> TcRn r      -- Main action: do this first
 492          -> TcRn r
 493 recoverM recover thing
 494   = do { mb_res <- try_m thing ;
 495          case mb_res of
 496            Left exn  -> recover
 497            Right res -> returnM res }
 498
 499 tryTc :: TcRn a -> TcRn (Messages, Maybe a)
 500     -- (tryTc m) executes m, and returns
 501     --  Just r,  if m succeeds (returning r) and caused no errors
 502     --  Nothing, if m fails, or caused errors
 503     -- It also returns all the errors accumulated by m
 504     --  (even in the Just case, there might be warnings)
 505     --
 506     -- It always succeeds (never raises an exception)
 507 tryTc m
 508  = do { errs_var <- newMutVar emptyMessages ;
 509
 510         mb_r <- try_m (setErrsVar errs_var m) ;
 511
 512         new_errs <- readMutVar errs_var ;
 513
 514         dflags <- getDOpts ;
 515
 516         return (new_errs,
 517                 case mb_r of
 518                   Left exn -> Nothing
 519                   Right r | errorsFound dflags new_errs -> Nothing
 520                           | otherwise                   -> Just r)
 521    }
 522
 523 try_m :: TcRn r -> TcRn (Either Exception r)
 524 -- Does try_m, with a debug-trace on failure
 525 try_m thing
 526   = do { mb_r <- tryM thing ;
 527          case mb_r of
 528              Left exn -> do { traceTc (exn_msg exn); return mb_r }
 529              Right r  -> return mb_r }
 530   where
 531     exn_msg exn = text "tryTc/recoverM recovering from" <+> text (showException exn)
 532
 533 tryTcLIE :: TcM a -> TcM (Messages, Maybe a)
 534 -- Just like tryTc, except that it ensures that the LIE
 535 -- for the thing is propagated only if there are no errors
 536 -- Hence it's restricted to the type-check monad
 537 tryTcLIE thing_inside
 538   = do { ((errs, mb_r), lie) <- getLIE (tryTc thing_inside) ;
 539          ifM (isJust mb_r) (extendLIEs lie) ;
 540          return (errs, mb_r) }
 541
 542 tryTcLIE_ :: TcM r -> TcM r -> TcM r
 543 -- (tryTcLIE_ r m) tries m; if it succeeds it returns it,
 544 -- otherwise it returns r.  Any error messages added by m are discarded,
 545 -- whether or not m succeeds.
 546 tryTcLIE_ recover main
 547   = do { (_msgs, mb_res) <- tryTcLIE main ;
 548          case mb_res of
 549            Just res -> return res
 550            Nothing  -> recover }
 551
 552 checkNoErrs :: TcM r -> TcM r
 553 -- (checkNoErrs m) succeeds iff m succeeds and generates no errors
 554 -- If m fails then (checkNoErrsTc m) fails.
 555 -- If m succeeds, it checks whether m generated any errors messages
 556 --      (it might have recovered internally)
 557 --      If so, it fails too.
 558 -- Regardless, any errors generated by m are propagated to the enclosing context.
 559 checkNoErrs main
 560   = do { (msgs, mb_res) <- tryTcLIE main ;
 561          addMessages msgs ;
 562          case mb_res of
 563            Just r  -> return r
 564            Nothing -> failM
 565    }
 566
 567 ifErrsM :: TcRn r -> TcRn r -> TcRn r
 568 --      ifErrsM bale_out main
 569 -- does 'bale_out' if there are errors in errors collection
 570 -- otherwise does 'main'
 571 ifErrsM bale_out normal
 572  = do { errs_var <- getErrsVar ;
 573         msgs <- readMutVar errs_var ;
 574         dflags <- getDOpts ;
 575         if errorsFound dflags msgs then
 576            bale_out
 577         else
 578            normal }
 579
 580 failIfErrsM :: TcRn ()
 581 -- Useful to avoid error cascades
 582 failIfErrsM = ifErrsM failM (return ())
 583 \end{code}
 584
 585
 586 %************************************************************************
 587 %*                                                                      *
 588         Context management and error message generation
 589                     for the type checker
 590 %*                                                                      *
 591 %************************************************************************
 592
 593 \begin{code}
 594 getErrCtxt :: TcM ErrCtxt
 595 getErrCtxt = do { env <- getLclEnv; return (tcl_ctxt env) }
 596
 597 setErrCtxt :: ErrCtxt -> TcM a -> TcM a
 598 setErrCtxt ctxt = updLclEnv (\ env -> env { tcl_ctxt = ctxt })
 599
 600 addErrCtxtM :: (TidyEnv -> TcM (TidyEnv, Message)) -> TcM a -> TcM a
 601 addErrCtxtM msg = updCtxt (\ msgs -> msg : msgs)
 602
 603 addErrCtxt :: Message -> TcM a -> TcM a
 604 addErrCtxt msg = addErrCtxtM (\env -> returnM (env, msg))
 605
 606 -- Helper function for the above
 607 updCtxt :: (ErrCtxt -> ErrCtxt) -> TcM a -> TcM a
 608 updCtxt upd = updLclEnv (\ env@(TcLclEnv { tcl_ctxt = ctxt }) ->
 609                            env { tcl_ctxt = upd ctxt })
 610
 611 -- Conditionally add an error context
 612 maybeAddErrCtxt :: Maybe Message -> TcM a -> TcM a
 613 maybeAddErrCtxt (Just msg) thing_inside = addErrCtxt msg thing_inside
 614 maybeAddErrCtxt Nothing    thing_inside = thing_inside
 615
 616 popErrCtxt :: TcM a -> TcM a
 617 popErrCtxt = updCtxt (\ msgs -> case msgs of { [] -> []; (m:ms) -> ms })
 618
 619 getInstLoc :: InstOrigin -> TcM InstLoc
 620 getInstLoc origin
 621   = do { loc <- getSrcSpanM ; env <- getLclEnv ;
 622          return (InstLoc origin loc (tcl_ctxt env)) }
 623
 624 addInstCtxt :: InstLoc -> TcM a -> TcM a
 625 -- Add the SrcSpan and context from the first Inst in the list
 626 --      (they all have similar locations)
 627 addInstCtxt (InstLoc _ src_loc ctxt) thing_inside
 628   = setSrcSpan src_loc (updCtxt (\ old_ctxt -> ctxt) thing_inside)
 629 \end{code}
 630
 631     The addErrTc functions add an error message, but do not cause failure.
 632     The 'M' variants pass a TidyEnv that has already been used to
 633     tidy up the message; we then use it to tidy the context messages
 634
 635 \begin{code}
 636 addErrTc :: Message -> TcM ()
 637 addErrTc err_msg = addErrTcM (emptyTidyEnv, err_msg)
 638
 639 addErrsTc :: [Message] -> TcM ()
 640 addErrsTc err_msgs = mappM_ addErrTc err_msgs
 641
 642 addErrTcM :: (TidyEnv, Message) -> TcM ()
 643 addErrTcM (tidy_env, err_msg)
 644   = do { ctxt <- getErrCtxt ;
 645          loc  <- getSrcSpanM ;
 646          add_err_tcm tidy_env err_msg loc ctxt }
 647 \end{code}
 648
 649 The failWith functions add an error message and cause failure
 650
 651 \begin{code}
 652 failWithTc :: Message -> TcM a               -- Add an error message and fail
 653 failWithTc err_msg
 654   = addErrTc err_msg >> failM
 655
 656 failWithTcM :: (TidyEnv, Message) -> TcM a   -- Add an error message and fail
 657 failWithTcM local_and_msg
 658   = addErrTcM local_and_msg >> failM
 659
 660 checkTc :: Bool -> Message -> TcM ()         -- Check that the boolean is true
 661 checkTc True  err = returnM ()
 662 checkTc False err = failWithTc err
 663 \end{code}
 664
 665         Warnings have no 'M' variant, nor failure
 666
 667 \begin{code}
 668 addWarnTc :: Message -> TcM ()
 669 addWarnTc msg
 670  = do { ctxt <- getErrCtxt ;
 671         ctxt_msgs <- do_ctxt emptyTidyEnv ctxt ;
 672         addWarn (vcat (msg : ctxt_to_use ctxt_msgs)) }
 673
 674 warnTc :: Bool -> Message -> TcM ()
 675 warnTc warn_if_true warn_msg
 676   | warn_if_true = addWarnTc warn_msg
 677   | otherwise    = return ()
 678 \end{code}
 679
 680         Helper functions
 681
 682 \begin{code}
 683 add_err_tcm tidy_env err_msg loc ctxt
 684  = do { ctxt_msgs <- do_ctxt tidy_env ctxt ;
 685         addLongErrAt loc err_msg (vcat (ctxt_to_use ctxt_msgs)) }
 686
 687 do_ctxt tidy_env []
 688  = return []
 689 do_ctxt tidy_env (c:cs)
 690  = do { (tidy_env', m) <- c tidy_env  ;
 691         ms             <- do_ctxt tidy_env' cs  ;
 692         return (m:ms) }
 693
 694 ctxt_to_use ctxt | opt_PprStyle_Debug = ctxt
 695                  | otherwise          = take 3 ctxt
 696 \end{code}
 697
 698 debugTc is useful for monadi debugging code
 699
 700 \begin{code}
 701 debugTc :: TcM () -> TcM ()
 702 #ifdef DEBUG
 703 debugTc thing = thing
 704 #else
 705 debugTc thing = return ()
 706 #endif
 707 \end{code}
 708
 709  %************************************************************************
 710 %*                                                                      *
 711              Type constraints (the so-called LIE)
 712 %*                                                                      *
 713 %************************************************************************
 714
 715 \begin{code}
 716 getLIEVar :: TcM (TcRef LIE)
 717 getLIEVar = do { env <- getLclEnv; return (tcl_lie env) }
 718
 719 setLIEVar :: TcRef LIE -> TcM a -> TcM a
 720 setLIEVar lie_var = updLclEnv (\ env -> env { tcl_lie = lie_var })
 721
 722 getLIE :: TcM a -> TcM (a, [Inst])
 723 -- (getLIE m) runs m, and returns the type constraints it generates
 724 getLIE thing_inside
 725   = do { lie_var <- newMutVar emptyLIE ;
 726          res <- updLclEnv (\ env -> env { tcl_lie = lie_var })
 727                           thing_inside ;
 728          lie <- readMutVar lie_var ;
 729          return (res, lieToList lie) }
 730
 731 extendLIE :: Inst -> TcM ()
 732 extendLIE inst
 733   = do { lie_var <- getLIEVar ;
 734          lie <- readMutVar lie_var ;
 735          writeMutVar lie_var (inst `consLIE` lie) }
 736
 737 extendLIEs :: [Inst] -> TcM ()
 738 extendLIEs []
 739   = returnM ()
 740 extendLIEs insts
 741   = do { lie_var <- getLIEVar ;
 742          lie <- readMutVar lie_var ;
 743          writeMutVar lie_var (mkLIE insts `plusLIE` lie) }
 744 \end{code}
 745
 746 \begin{code}
 747 setLclTypeEnv :: TcLclEnv -> TcM a -> TcM a
 748 -- Set the local type envt, but do *not* disturb other fields,
 749 -- notably the lie_var
 750 setLclTypeEnv lcl_env thing_inside
 751   = updLclEnv upd thing_inside
 752   where
 753     upd env = env { tcl_env = tcl_env lcl_env,
 754                     tcl_tyvars = tcl_tyvars lcl_env }
 755 \end{code}
 756
 757
 758 %************************************************************************
 759 %*                                                                      *
 760              Template Haskell context
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 \begin{code}
 765 recordThUse :: TcM ()
 766 recordThUse = do { env <- getGblEnv; writeMutVar (tcg_th_used env) True }
 767
 768 keepAliveTc :: Name -> TcM ()   -- Record the name in the keep-alive set
 769 keepAliveTc n = do { env <- getGblEnv;
 770                    ; updMutVar (tcg_keep env) (`addOneToNameSet` n) }
 771
 772 keepAliveSetTc :: NameSet -> TcM ()     -- Record the name in the keep-alive set
 773 keepAliveSetTc ns = do { env <- getGblEnv;
 774                        ; updMutVar (tcg_keep env) (`unionNameSets` ns) }
 775
 776 getStage :: TcM ThStage
 777 getStage = do { env <- getLclEnv; return (tcl_th_ctxt env) }
 778
 779 setStage :: ThStage -> TcM a -> TcM a
 780 setStage s = updLclEnv (\ env -> env { tcl_th_ctxt = s })
 781 \end{code}
 782
 783
 784 %************************************************************************
 785 %*                                                                      *
 786              Stuff for the renamer's local env
 787 %*                                                                      *
 788 %************************************************************************
 789
 790 \begin{code}
 791 getLocalRdrEnv :: RnM LocalRdrEnv
 792 getLocalRdrEnv = do { env <- getLclEnv; return (tcl_rdr env) }
 793
 794 setLocalRdrEnv :: LocalRdrEnv -> RnM a -> RnM a
 795 setLocalRdrEnv rdr_env thing_inside
 796   = updLclEnv (\env -> env {tcl_rdr = rdr_env}) thing_inside
 797 \end{code}
 798
 799
 800 %************************************************************************
 801 %*                                                                      *
 802              Stuff for interface decls
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 mkIfLclEnv :: Module -> SDoc -> IfLclEnv
 808 mkIfLclEnv mod loc = IfLclEnv { if_mod     = mod,
 809                                 if_loc     = loc,
 810                                 if_tv_env  = emptyOccEnv,
 811                                 if_id_env  = emptyOccEnv }
 812
 813 initIfaceTcRn :: IfG a -> TcRn a
 814 initIfaceTcRn thing_inside
 815   = do  { tcg_env <- getGblEnv
 816         ; let { if_env = IfGblEnv { if_rec_types = Just (tcg_mod tcg_env, get_type_env) }
 817               ; get_type_env = readMutVar (tcg_type_env_var tcg_env) }
 818         ; setEnvs (if_env, ()) thing_inside }
 819
 820 initIfaceExtCore :: IfL a -> TcRn a
 821 initIfaceExtCore thing_inside
 822   = do  { tcg_env <- getGblEnv
 823         ; let { mod = tcg_mod tcg_env
 824               ; doc = ptext SLIT("External Core file for") <+> quotes (ppr mod)
 825               ; if_env = IfGblEnv {
 826                         if_rec_types = Just (mod, return (tcg_type_env tcg_env)) }
 827               ; if_lenv = mkIfLclEnv mod doc
 828           }
 829         ; setEnvs (if_env, if_lenv) thing_inside }
 830
 831 initIfaceCheck :: HscEnv -> IfG a -> IO a
 832 -- Used when checking the up-to-date-ness of the old Iface
 833 -- Initialise the environment with no useful info at all
 834 initIfaceCheck hsc_env do_this
 835  = do   { let gbl_env = IfGblEnv { if_rec_types = Nothing }
 836         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 837     }
 838
 839 initIfaceTc :: ModIface
 840             -> (TcRef TypeEnv -> IfL a) -> TcRnIf gbl lcl a
 841 -- Used when type-checking checking an up-to-date interface file
 842 -- No type envt from the current module, but we do know the module dependencies
 843 initIfaceTc iface do_this
 844  = do   { tc_env_var <- newMutVar emptyTypeEnv
 845         ; let { gbl_env = IfGblEnv { if_rec_types = Just (mod, readMutVar tc_env_var) } ;
 846               ; if_lenv = mkIfLclEnv mod doc
 847            }
 848         ; setEnvs (gbl_env, if_lenv) (do_this tc_env_var)
 849     }
 850   where
 851     mod = mi_module iface
 852     doc = ptext SLIT("The interface for") <+> quotes (ppr mod)
 853
 854 initIfaceRules :: HscEnv -> ModGuts -> IfG a -> IO a
 855 -- Used when sucking in new Rules in SimplCore
 856 -- We have available the type envt of the module being compiled, and we must use it
 857 initIfaceRules hsc_env guts do_this
 858  = do   { let {
 859              type_info = (mg_module guts, return (mg_types guts))
 860            ; gbl_env = IfGblEnv { if_rec_types = Just type_info } ;
 861            }
 862
 863         -- Run the thing; any exceptions just bubble out from here
 864         ; initTcRnIf 'i' hsc_env gbl_env () do_this
 865     }
 866
 867 initIfaceLcl :: Module -> SDoc -> IfL a -> IfM lcl a
 868 initIfaceLcl mod loc_doc thing_inside
 869   = setLclEnv (mkIfLclEnv mod loc_doc) thing_inside
 870
 871 getIfModule :: IfL Module
 872 getIfModule = do { env <- getLclEnv; return (if_mod env) }
 873
 874 --------------------
 875 failIfM :: Message -> IfL a
 876 -- The Iface monad doesn't have a place to accumulate errors, so we
 877 -- just fall over fast if one happens; it "shouldnt happen".
 878 -- We use IfL here so that we can get context info out of the local env
 879 failIfM msg
 880   = do  { env <- getLclEnv
 881         ; let full_msg = if_loc env $$ nest 2 msg
 882         ; ioToIOEnv (printErrs (full_msg defaultErrStyle))
 883         ; failM }
 884
 885 --------------------
 886 forkM_maybe :: SDoc -> IfL a -> IfL (Maybe a)
 887 -- Run thing_inside in an interleaved thread.
 888 -- It shares everything with the parent thread, so this is DANGEROUS.
 889 --
 890 -- It returns Nothing if the computation fails
 891 --
 892 -- It's used for lazily type-checking interface
 893 -- signatures, which is pretty benign
 894
 895 forkM_maybe doc thing_inside
 896  = do { unsafeInterleaveM $
 897         do { traceIf (text "Starting fork {" <+> doc)
 898            ; mb_res <- tryM thing_inside ;
 899              case mb_res of
 900                 Right r  -> do  { traceIf (text "} ending fork" <+> doc)
 901                                 ; return (Just r) }
 902                 Left exn -> do {
 903
 904                     -- Bleat about errors in the forked thread, if -ddump-if-trace is on
 905                     -- Otherwise we silently discard errors. Errors can legitimately
 906                     -- happen when compiling interface signatures (see tcInterfaceSigs)
 907                       ifOptM Opt_D_dump_if_trace
 908                              (print_errs (hang (text "forkM failed:" <+> doc)
 909                                              4 (text (show exn))))
 910
 911                     ; traceIf (text "} ending fork (badly)" <+> doc)
 912                     ; return Nothing }
 913         }}
 914   where
 915     print_errs sdoc = ioToIOEnv (printErrs (sdoc defaultErrStyle))
 916
 917 forkM :: SDoc -> IfL a -> IfL a
 918 forkM doc thing_inside
 919  = do   { mb_res <- forkM_maybe doc thing_inside
 920         ; return (case mb_res of
 921                         Nothing -> pprPanic "forkM" doc
 922                         Just r  -> r) }
 923 \end{code}
 924
 925 %************************************************************************
 926 %*                                                                      *
 927              Stuff for GADTs
 928 %*                                                                      *
 929 %************************************************************************
 930
 931 \begin{code}
 932 getTypeRefinement :: TcM GadtRefinement
 933 getTypeRefinement = do { lcl_env <- getLclEnv; return (tcl_gadt lcl_env) }
 934
 935 setTypeRefinement :: GadtRefinement -> TcM a -> TcM a
 936 setTypeRefinement gadt = updLclEnv (\env -> env { tcl_gadt = gadt })
 937 \end{code}