ghc/compiler/typecheck/TcRnTypes.lhs

   1 %
   2 % (c) The GRASP Project, Glasgow University, 1992-2002
   3 %
   4 \begin{code}
   5 module TcRnTypes(
   6         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   7         TcRef,
   8
   9         -- The environment types
  10         Env(..),
  11         TcGblEnv(..), TcLclEnv(..),
  12         IfGblEnv(..), IfLclEnv(..),
  13
  14         -- Ranamer types
  15         EntityUsage, emptyUsages, ErrCtxt,
  16         ImportAvails(..), emptyImportAvails, plusImportAvails,
  17         plusAvail, pruneAvails,
  18         AvailEnv, emptyAvailEnv, unitAvailEnv, plusAvailEnv,
  19         mkAvailEnv, lookupAvailEnv, lookupAvailEnv_maybe, availEnvElts, addAvail,
  20         WhereFrom(..), mkModDeps,
  21
  22         -- Typechecker types
  23         TcTyThing(..),
  24
  25         -- Template Haskell
  26         ThStage(..), topStage, topSpliceStage,
  27         ThLevel, impLevel, topLevel,
  28
  29         -- Arrows
  30         ArrowCtxt(..), topArrowCtxt, ProcLevel, topProcLevel,
  31
  32         -- Insts
  33         Inst(..), InstOrigin(..), InstLoc(..), pprInstLoc,
  34         instLocSrcLoc, instLocSrcSpan,
  35         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
  36         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  37
  38         -- Misc other types
  39         TcId, TcIdSet
  40   ) where
  41
  42 #include "HsVersions.h"
  43
  44 import HsSyn            ( PendingSplice, HsOverLit, LHsBind, LRuleDecl, LForeignDecl,
  45                           Pat, ArithSeqInfo )
  46 import HscTypes         ( FixityEnv,
  47                           HscEnv, TypeEnv, TyThing,
  48                           Avails, GenAvailInfo(..), AvailInfo,
  49                           availName, IsBootInterface, Deprecations )
  50 import Packages         ( PackageName )
  51 import TcType           ( TcTyVarSet, TcType, TcTauType, TcThetaType,
  52                           TcPredType, TcKind, tcCmpPred, tcCmpType, tcCmpTypes )
  53 import InstEnv          ( DFunId, InstEnv )
  54 import IOEnv
  55 import RdrName          ( GlobalRdrEnv, LocalRdrEnv )
  56 import Name             ( Name )
  57 import NameEnv
  58 import NameSet          ( NameSet, emptyNameSet, DefUses )
  59 import OccName          ( OccEnv )
  60 import Type             ( Type )
  61 import Class            ( Class )
  62 import Var              ( Id, TyVar )
  63 import VarEnv           ( TidyEnv )
  64 import Module
  65 import SrcLoc           ( SrcSpan, SrcLoc, srcSpanStart )
  66 import VarSet           ( IdSet )
  67 import ErrUtils         ( Messages, Message )
  68 import UniqSupply       ( UniqSupply )
  69 import BasicTypes       ( IPName )
  70 import Util             ( thenCmp )
  71 import Bag
  72 import Outputable
  73 import Maybe            ( mapMaybe )
  74 import ListSetOps       ( unionLists )
  75 \end{code}
  76
  77
  78 %************************************************************************
  79 %*                                                                      *
  80                Standard monad definition for TcRn
  81     All the combinators for the monad can be found in TcRnMonad
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  86
  87 \begin{code}
  88 type TcRef a = IORef a
  89 type TcId    = Id                       -- Type may be a TcType
  90 type TcIdSet = IdSet
  91
  92 type TcRnIf a b c = IOEnv (Env a b) c
  93 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
  94 type IfG a  = IfM () a                          -- Top level
  95 type IfL a  = IfM IfLclEnv a                    -- Nested
  96 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
  97 type RnM  a = TcRn a            -- Historical
  98 type TcM  a = TcRn a            -- Historical
  99 \end{code}
 100
 101
 102 %************************************************************************
 103 %*                                                                      *
 104                 The main environment types
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \begin{code}
 109 data Env gbl lcl        -- Changes as we move into an expression
 110   = Env {
 111         env_top  :: HscEnv,     -- Top-level stuff that never changes
 112                                 --   Includes all info about imported things
 113
 114         env_us   :: TcRef UniqSupply,   -- Unique supply for local varibles
 115
 116         env_gbl  :: gbl,        -- Info about things defined at the top level
 117                                 --   of the module being compiled
 118
 119         env_lcl  :: lcl         -- Nested stuff -- changes as we go into
 120                                 -- an expression
 121     }
 122
 123 -- TcGblEnv describes the top-level of the module at the
 124 -- point at which the typechecker is finished work.
 125 -- It is this structure that is handed on to the desugarer
 126
 127 data TcGblEnv
 128   = TcGblEnv {
 129         tcg_mod     :: Module,          -- Module being compiled
 130         tcg_rdr_env :: GlobalRdrEnv,    -- Top level envt; used during renaming
 131         tcg_default :: Maybe [Type],    -- Types used for defaulting
 132                                         -- Nothing => no 'default' decl
 133
 134         tcg_fix_env  :: FixityEnv,      -- Just for things in this module
 135
 136         tcg_type_env :: TypeEnv,        -- Global type env for the module we are compiling now
 137                 -- All TyCons and Classes (for this module) end up in here right away,
 138                 -- along with their derived constructors, selectors.
 139                 --
 140                 -- (Ids defined in this module start in the local envt,
 141                 --  though they move to the global envt during zonking)
 142
 143         tcg_type_env_var :: TcRef TypeEnv,
 144                 -- Used only to initialise the interface-file
 145                 -- typechecker in initIfaceTcRn, so that it can see stuff
 146                 -- bound in this module when dealing with hi-boot recursions
 147                 -- Updated at intervals (e.g. after dealing with types and classes)
 148
 149         tcg_inst_env :: InstEnv,        -- Instance envt for *home-package* modules
 150                                         -- Includes the dfuns in tcg_insts
 151         tcg_inst_uses :: TcRef NameSet, -- Home-package Dfuns actually used
 152                 -- Used to generate version dependencies
 153                 -- This records usages, rather like tcg_dus, but it has to
 154                 -- be a mutable variable so it can be augmented
 155                 -- when we look up an instance.  These uses of dfuns are
 156                 -- rather like the free variables of the program, but
 157                 -- are implicit instead of explicit.
 158
 159                 -- Now a bunch of things about this module that are simply
 160                 -- accumulated, but never consulted until the end.
 161                 -- Nevertheless, it's convenient to accumulate them along
 162                 -- with the rest of the info from this module.
 163         tcg_exports :: Avails,                  -- What is exported
 164         tcg_imports :: ImportAvails,            -- Information about what was imported
 165                                                 --    from where, including things bound
 166                                                 --    in this module
 167
 168         tcg_dus :: DefUses,     -- What is defined in this module and what is used.
 169                                 -- The latter is used to generate
 170                                 --      (a) version tracking; no need to recompile if these
 171                                 --              things have not changed version stamp
 172                                 --      (b) unused-import info
 173
 174         tcg_keep :: NameSet,    -- Set of names to keep alive, and to expose in the
 175                                 -- interface file (but not to export to the user).
 176                                 -- These are typically extra definitions generated from
 177                                 -- data type declarations which would otherwise be
 178                                 -- dropped as dead code.
 179
 180                 -- The next fields accumulate the payload of the module
 181                 -- The binds, rules and foreign-decl fiels are collected
 182                 -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 183         tcg_binds   :: Bag (LHsBind Id),        -- Value bindings in this module
 184         tcg_deprecs :: Deprecations,            -- ...Deprecations
 185         tcg_insts   :: [DFunId],                -- ...Instances
 186         tcg_rules   :: [LRuleDecl Id],          -- ...Rules
 187         tcg_fords   :: [LForeignDecl Id]        -- ...Foreign import & exports
 188     }
 189 \end{code}
 190
 191 %************************************************************************
 192 %*                                                                      *
 193                 The interface environments
 194               Used when dealing with IfaceDecls
 195 %*                                                                      *
 196 %************************************************************************
 197
 198 \begin{code}
 199 data IfGblEnv
 200   = IfGblEnv {
 201         -- The type environment for the module being compiled,
 202         -- in case the interface refers back to it via a reference that
 203         -- was originally a hi-boot file.
 204         -- We need the module name so we can test when it's appropriate
 205         -- to look in this env.
 206         if_rec_types :: Maybe (Module, IfG TypeEnv),
 207                 -- Allows a read effect, so it can be in a mutable
 208                 -- variable; c.f. handling the external package type env
 209                 -- Nothing => interactive stuff, no loops possible
 210
 211         if_is_boot   :: ModuleEnv (ModuleName, IsBootInterface)
 212         -- Tells what we know about boot interface files
 213         -- When we're importing a module we know absolutely
 214         -- nothing about, so we assume it's from
 215         -- another package, where we aren't doing
 216         -- dependency tracking. So it won't be a hi-boot file.
 217     }
 218
 219 data IfLclEnv
 220   = IfLclEnv {
 221         -- The module for the current IfaceDecl
 222         -- So if we see   f = \x -> x
 223         -- it means M.f = \x -> x, where M is the if_mod
 224         if_mod :: ModuleName,
 225
 226         if_tv_env  :: OccEnv TyVar,     -- Nested tyvar bindings
 227         if_id_env  :: OccEnv Id         -- Nested id binding
 228     }
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234                 The local typechecker environment
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 The Global-Env/Local-Env story
 239 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 240 During type checking, we keep in the tcg_type_env
 241         * All types and classes
 242         * All Ids derived from types and classes (constructors, selectors)
 243
 244 At the end of type checking, we zonk the local bindings,
 245 and as we do so we add to the tcg_type_env
 246         * Locally defined top-level Ids
 247
 248 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 249         a) fed back (via the knot) to typechecking the
 250            unfoldings of interface signatures
 251         b) used in the ModDetails of this module
 252
 253 \begin{code}
 254 data TcLclEnv           -- Changes as we move inside an expression
 255                         -- Discarded after typecheck/rename; not passed on to desugarer
 256   = TcLclEnv {
 257         tcl_loc  :: SrcSpan,            -- Source span
 258         tcl_ctxt :: ErrCtxt,            -- Error context
 259         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 260
 261         tcl_th_ctxt    :: ThStage,      -- Template Haskell context
 262         tcl_arrow_ctxt :: ArrowCtxt,    -- Arrow-notation context
 263
 264         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 265                 -- Maintained during renaming, of course, but also during
 266                 -- type checking, solely so that when renaming a Template-Haskell
 267                 -- splice we have the right environment for the renamer.
 268                 --
 269                 --   Does *not* include global name envt; may shadow it
 270                 --   Includes both ordinary variables and type variables;
 271                 --   they are kept distinct because tyvar have a different
 272                 --   occurrence contructor (Name.TvOcc)
 273                 -- We still need the unsullied global name env so that
 274                 --   we can look up record field names
 275
 276         tcl_env    :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 277                                           -- defined in this module
 278
 279         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 280                         -- Namely, the in-scope TyVars bound in tcl_lenv,
 281                         -- plus the tyvars mentioned in the types of Ids bound in tcl_lenv
 282                         -- Why mutable? see notes with tcGetGlobalTyVars
 283
 284         tcl_lie :: TcRef LIE            -- Place to accumulate type constraints
 285     }
 286
 287 ---------------------------
 288 -- Template Haskell levels
 289 ---------------------------
 290
 291 type ThLevel = Int      -- Always >= 0
 292
 293 data ThStage
 294   = Comp                                -- Ordinary compiling, at level topLevel
 295   | Splice ThLevel                      -- Inside a splice
 296   | Brack  ThLevel                      -- Inside brackets;
 297            (TcRef [PendingSplice])      --   accumulate pending splices here
 298            (TcRef LIE)                  --   and type constraints here
 299 topStage, topSpliceStage :: ThStage
 300 topStage       = Comp
 301 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 302
 303
 304 impLevel, topLevel :: ThLevel
 305 topLevel = 1    -- Things defined at top level of this module
 306 impLevel = 0    -- Imported things; they can be used inside a top level splice
 307 --
 308 -- For example:
 309 --      f = ...
 310 --      g1 = $(map ...)         is OK
 311 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 312
 313
 314 ---------------------------
 315 -- Arrow-notation stages
 316 ---------------------------
 317
 318 -- In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 319 -- is not in scope to the left of an arrow tail (-<).  For example
 320 --
 321 --      proc x -> (e1 -< e2)
 322 --
 323 -- Here, x is not in scope in e1, but it is in scope in e2.  This can get
 324 -- a bit complicated:
 325 --
 326 --      let x = 3 in
 327 --      prox y -> (proc z -> e1) -< e2
 328 --
 329 -- Here, x and z are in scope in e1, but y is not.  Here's how we track this:
 330 --      a) Assign an "proc level" to each proc, being the number of
 331 --         lexically-enclosing procs + 1.
 332 --      b) Assign to each local variable the proc-level of its lexically
 333 --         enclosing proc.
 334 --      c) Keep a list of out-of-scope procs.  When moving to the left of
 335 --         an arrow-tail, add the proc-level of the immediately enclosing
 336 --         proc to the list.
 337 --      d) When looking up a variable, complain if its proc-level is in
 338 --         the banned list
 339
 340 type ProcLevel = Int    -- Always >= 0
 341 topProcLevel = 0        -- Not inside any proc
 342
 343 data ArrowCtxt = ArrCtxt { proc_level :: ProcLevel,     -- Current level
 344                            proc_banned :: [ProcLevel] } -- Out of scope proc-levels
 345
 346 topArrowCtxt = ArrCtxt { proc_level = topProcLevel, proc_banned = [] }
 347
 348 ---------------------------
 349 -- TcTyThing
 350 ---------------------------
 351
 352 data TcTyThing
 353   = AGlobal TyThing                     -- Used only in the return type of a lookup
 354   | ATcId   TcId ThLevel ProcLevel      -- Ids defined in this module; may not be fully zonked
 355   | ATyVar  TyVar                       -- Type variables
 356   | AThing  TcKind                      -- Used temporarily, during kind checking, for the
 357                                         --      tycons and clases in this recursive group
 358
 359 instance Outputable TcTyThing where     -- Debugging only
 360    ppr (AGlobal g)      = text "AGlobal" <+> ppr g
 361    ppr (ATcId g tl pl)  = text "ATcId" <+> ppr g <+> ppr tl <+> ppr pl
 362    ppr (ATyVar t)       = text "ATyVar" <+> ppr t
 363    ppr (AThing k)       = text "AThing" <+> ppr k
 364 \end{code}
 365
 366 \begin{code}
 367 type ErrCtxt = [TidyEnv -> TcM (TidyEnv, Message)]
 368                         -- Innermost first.  Monadic so that we have a chance
 369                         -- to deal with bound type variables just before error
 370                         -- message construction
 371 \end{code}
 372
 373
 374 %************************************************************************
 375 %*                                                                      *
 376                         EntityUsage
 377 %*                                                                      *
 378 %************************************************************************
 379
 380 EntityUsage tells what things are actually need in order to compile this
 381 module.  It is used for generating the usage-version field of the ModIface.
 382
 383 Note that we do not record version info for entities from
 384 other (non-home) packages.  If the package changes, GHC doesn't help.
 385
 386 \begin{code}
 387 type EntityUsage = NameSet
 388         -- The Names are all the (a) home-package
 389         --                       (b) "big" (i.e. no data cons, class ops)
 390         --                       (c) non-locally-defined
 391         --                       (d) non-wired-in
 392         -- names that have been slurped in so far.
 393         -- This is used to generate the "usage" information for this module.
 394
 395 emptyUsages :: EntityUsage
 396 emptyUsages = emptyNameSet
 397 \end{code}
 398
 399
 400 %************************************************************************
 401 %*                                                                      *
 402         Operations over ImportAvails
 403 %*                                                                      *
 404 %************************************************************************
 405
 406 ImportAvails summarises what was imported from where, irrespective
 407 of whether the imported things are actually used or not
 408 It is used      * when processing the export list
 409                 * when constructing usage info for the inteface file
 410                 * to identify the list of directly imported modules
 411                         for initialisation purposes
 412                 * when figuring out what things are really unused
 413
 414 \begin{code}
 415 data ImportAvails
 416    = ImportAvails {
 417         imp_env :: AvailEnv,
 418                 -- All the things that are available from the import
 419                 -- Its domain is all the "main" things;
 420                 -- i.e. *excluding* class ops and constructors
 421                 --      (which appear inside their parent AvailTC)
 422
 423         imp_qual :: ModuleEnv AvailEnv,
 424                 -- Used to figure out "module M" export specifiers
 425                 -- (see 1.4 Report Section 5.1.1).  Ultimately, we want to find
 426                 -- everything that is unambiguously in scope as 'M.x'
 427                 -- and where plain 'x' is (perhaps ambiguously) in scope.
 428                 -- So the starting point is all things that are in scope as 'M.x',
 429                 -- which is what this field tells us.
 430                 --
 431                 -- Domain is the *module qualifier* for imports.
 432                 --   e.g.        import List as Foo
 433                 -- would add a binding Foo |-> ...stuff from List...
 434                 -- to imp_qual.
 435                 -- We keep the stuff as an AvailEnv so that it's easy to
 436                 -- combine stuff coming from different (unqualified)
 437                 -- imports of the same module
 438
 439         imp_mods :: ModuleEnv (Module, Maybe Bool),
 440                 -- Domain is all directly-imported modules
 441                 -- Maybe value answers the question "is the import restricted?"
 442                 --   Nothing    => unrestricted import (e.g., "import Foo")
 443                 --   Just True  => restricted import, at least one entity (e.g., "import Foo(x)")
 444                 --   Just False => fully restricted import (e.g., "import Foo ()")
 445                 --
 446                 --  A distinction is made between the first and the third in order
 447                 --  to more precisely emit warnings about unused imports.
 448                 --
 449                 -- We need the Module in the range because we can't get
 450                 --      the keys of a ModuleEnv
 451                 -- Used
 452                 --   (a) to help construct the usage information in
 453                 --       the interface file; if we import everything we
 454                 --       need to recompile if the module version changes
 455                 --   (b) to specify what child modules to initialise
 456
 457         imp_dep_mods :: ModuleEnv (ModuleName, IsBootInterface),
 458                 -- Home-package modules needed by the module being compiled
 459                 --
 460                 -- It doesn't matter whether any of these dependencies are actually
 461                 -- *used* when compiling the module; they are listed if they are below
 462                 -- it at all.  For example, suppose M imports A which imports X.  Then
 463                 -- compiling M might not need to consult X.hi, but X is still listed
 464                 -- in M's dependencies.
 465
 466         imp_dep_pkgs :: [PackageName],
 467                 -- Packages needed by the module being compiled, whether
 468                 -- directly, or via other modules in this package, or via
 469                 -- modules imported from other packages.
 470
 471         imp_orphs :: [ModuleName]
 472                 -- Orphan modules below us in the import tree
 473       }
 474
 475 mkModDeps :: [(ModuleName, IsBootInterface)]
 476           -> ModuleEnv (ModuleName, IsBootInterface)
 477 mkModDeps deps = foldl add emptyModuleEnv deps
 478                where
 479                  add env elt@(m,_) = extendModuleEnvByName env m elt
 480
 481 emptyImportAvails :: ImportAvails
 482 emptyImportAvails = ImportAvails { imp_env      = emptyAvailEnv,
 483                                    imp_qual     = emptyModuleEnv,
 484                                    imp_mods     = emptyModuleEnv,
 485                                    imp_dep_mods = emptyModuleEnv,
 486                                    imp_dep_pkgs = [],
 487                                    imp_orphs    = [] }
 488
 489 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 490 plusImportAvails
 491   (ImportAvails { imp_env = env1, imp_qual = unqual1, imp_mods = mods1,
 492                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1, imp_orphs = orphs1 })
 493   (ImportAvails { imp_env = env2, imp_qual = unqual2, imp_mods = mods2,
 494                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2, imp_orphs = orphs2 })
 495   = ImportAvails { imp_env      = env1 `plusAvailEnv` env2,
 496                    imp_qual     = plusModuleEnv_C plusAvailEnv unqual1 unqual2,
 497                    imp_mods     = mods1  `plusModuleEnv` mods2,
 498                    imp_dep_mods = plusModuleEnv_C plus_mod_dep dmods1 dmods2,
 499                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 500                    imp_orphs    = orphs1 `unionLists` orphs2 }
 501   where
 502     plus_mod_dep (m1, boot1) (m2, boot2)
 503         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 504                 -- Check mod-names match
 505           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 506 \end{code}
 507
 508 %************************************************************************
 509 %*                                                                      *
 510         Avails, AvailEnv, etc
 511 %*                                                                      *
 512 v%************************************************************************
 513
 514 \begin{code}
 515 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 516 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (ns1 `unionLists` ns2)
 517 -- Added SOF 4/97
 518 #ifdef DEBUG
 519 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 520 #endif
 521
 522 -------------------------
 523 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 524             -> [AvailInfo]
 525             -> [AvailInfo]
 526 pruneAvails keep avails
 527   = mapMaybe del avails
 528   where
 529     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 530     del (Avail n) | keep n    = Just (Avail n)
 531                   | otherwise = Nothing
 532     del (AvailTC n ns) | null ns'  = Nothing
 533                        | otherwise = Just (AvailTC n ns')
 534                        where
 535                          ns' = filter keep ns
 536 \end{code}
 537
 538 ---------------------------------------
 539         AvailEnv and friends
 540 ---------------------------------------
 541
 542 \begin{code}
 543 type AvailEnv = NameEnv AvailInfo       -- Maps a Name to the AvailInfo that contains it
 544
 545 emptyAvailEnv :: AvailEnv
 546 emptyAvailEnv = emptyNameEnv
 547
 548 unitAvailEnv :: AvailInfo -> AvailEnv
 549 unitAvailEnv a = unitNameEnv (availName a) a
 550
 551 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 552 plusAvailEnv = plusNameEnv_C plusAvail
 553
 554 lookupAvailEnv_maybe :: AvailEnv -> Name -> Maybe AvailInfo
 555 lookupAvailEnv_maybe = lookupNameEnv
 556
 557 lookupAvailEnv :: AvailEnv -> Name -> AvailInfo
 558 lookupAvailEnv env n = case lookupNameEnv env n of
 559                          Just avail -> avail
 560                          Nothing    -> pprPanic "lookupAvailEnv" (ppr n)
 561
 562 availEnvElts = nameEnvElts
 563
 564 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 565 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 566
 567 mkAvailEnv :: [AvailInfo] -> AvailEnv
 568         -- 'avails' may have several items with the same availName
 569         -- E.g  import Ix( Ix(..), index )
 570         -- will give Ix(Ix,index,range) and Ix(index)
 571         -- We want to combine these; addAvail does that
 572 mkAvailEnv avails = foldl addAvail emptyAvailEnv avails
 573 \end{code}
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsection{Where from}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 The @WhereFrom@ type controls where the renamer looks for an interface file
 582
 583 \begin{code}
 584 data WhereFrom
 585   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 586   | ImportBySystem                      -- Non user import.
 587
 588 instance Outputable WhereFrom where
 589   ppr (ImportByUser is_boot) | is_boot     = ptext SLIT("{- SOURCE -}")
 590                              | otherwise   = empty
 591   ppr ImportBySystem                       = ptext SLIT("{- SYSTEM -}")
 592 \end{code}
 593
 594
 595 %************************************************************************
 596 %*                                                                      *
 597 \subsection[Inst-types]{@Inst@ types}
 598 %*                                                                      *
 599 v%************************************************************************
 600
 601 An @Inst@ is either a dictionary, an instance of an overloaded
 602 literal, or an instance of an overloaded value.  We call the latter a
 603 ``method'' even though it may not correspond to a class operation.
 604 For example, we might have an instance of the @double@ function at
 605 type Int, represented by
 606
 607         Method 34 doubleId [Int] origin
 608
 609 \begin{code}
 610 data Inst
 611   = Dict
 612         Id
 613         TcPredType
 614         InstLoc
 615
 616   | Method
 617         Id
 618
 619         TcId    -- The overloaded function
 620                         -- This function will be a global, local, or ClassOpId;
 621                         --   inside instance decls (only) it can also be an InstId!
 622                         -- The id needn't be completely polymorphic.
 623                         -- You'll probably find its name (for documentation purposes)
 624                         --        inside the InstOrigin
 625
 626         [TcType]        -- The types to which its polymorphic tyvars
 627                         --      should be instantiated.
 628                         -- These types must saturate the Id's foralls.
 629
 630         TcThetaType     -- The (types of the) dictionaries to which the function
 631                         -- must be applied to get the method
 632
 633         TcTauType       -- The tau-type of the method
 634
 635         InstLoc
 636
 637         -- INVARIANT 1: in (Method u f tys theta tau loc)
 638         --      type of (f tys dicts(from theta)) = tau
 639
 640         -- INVARIANT 2: tau must not be of form (Pred -> Tau)
 641         --   Reason: two methods are considerd equal if the
 642         --           base Id matches, and the instantiating types
 643         --           match.  The TcThetaType should then match too.
 644         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 645
 646   | LitInst
 647         Id
 648         HsOverLit       -- The literal from the occurrence site
 649                         --      INVARIANT: never a rebindable-syntax literal
 650                         --      Reason: tcSyntaxName does unification, and we
 651                         --              don't want to deal with that during tcSimplify
 652         TcType          -- The type at which the literal is used
 653         InstLoc
 654 \end{code}
 655
 656 @Insts@ are ordered by their class/type info, rather than by their
 657 unique.  This allows the context-reduction mechanism to use standard finite
 658 maps to do their stuff.
 659
 660 \begin{code}
 661 instance Ord Inst where
 662   compare = cmpInst
 663
 664 instance Eq Inst where
 665   (==) i1 i2 = case i1 `cmpInst` i2 of
 666                  EQ    -> True
 667                  other -> False
 668
 669 cmpInst (Dict _ pred1 _)          (Dict _ pred2 _)          = pred1 `tcCmpPred` pred2
 670 cmpInst (Dict _ _ _)              other                     = LT
 671
 672 cmpInst (Method _ _ _ _ _ _)      (Dict _ _ _)              = GT
 673 cmpInst (Method _ id1 tys1 _ _ _) (Method _ id2 tys2 _ _ _) = (id1 `compare` id2) `thenCmp` (tys1 `tcCmpTypes` tys2)
 674 cmpInst (Method _ _ _ _ _ _)      other                     = LT
 675
 676 cmpInst (LitInst _ _ _ _)         (Dict _ _ _)              = GT
 677 cmpInst (LitInst _ _ _ _)         (Method _ _ _ _ _ _)      = GT
 678 cmpInst (LitInst _ lit1 ty1 _)    (LitInst _ lit2 ty2 _)    = (lit1 `compare` lit2) `thenCmp` (ty1 `tcCmpType` ty2)
 679 \end{code}
 680
 681
 682 %************************************************************************
 683 %*                                                                      *
 684 \subsection[Inst-collections]{LIE: a collection of Insts}
 685 %*                                                                      *
 686 %************************************************************************
 687
 688 \begin{code}
 689 type LIE = Bag Inst
 690
 691 isEmptyLIE        = isEmptyBag
 692 emptyLIE          = emptyBag
 693 unitLIE inst      = unitBag inst
 694 mkLIE insts       = listToBag insts
 695 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 696 consLIE inst lie  = inst `consBag` lie
 697 plusLIEs lies     = unionManyBags lies
 698 lieToList         = bagToList
 699 listToLIE         = listToBag
 700 \end{code}
 701
 702
 703 %************************************************************************
 704 %*                                                                      *
 705 \subsection[Inst-origin]{The @InstOrigin@ type}
 706 %*                                                                      *
 707 %************************************************************************
 708
 709 The @InstOrigin@ type gives information about where a dictionary came from.
 710 This is important for decent error message reporting because dictionaries
 711 don't appear in the original source code.  Doubtless this type will evolve...
 712
 713 It appears in TcMonad because there are a couple of error-message-generation
 714 functions that deal with it.
 715
 716 \begin{code}
 717 data InstLoc = InstLoc InstOrigin SrcSpan ErrCtxt
 718
 719 instLocSrcLoc :: InstLoc -> SrcLoc
 720 instLocSrcLoc (InstLoc _ src_span _) = srcSpanStart src_span
 721
 722 instLocSrcSpan :: InstLoc -> SrcSpan
 723 instLocSrcSpan (InstLoc _ src_span _) = src_span
 724
 725 data InstOrigin
 726   = OccurrenceOf Name           -- Occurrence of an overloaded identifier
 727
 728   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 729   | IPBindOrigin (IPName Name)  -- Binding site of an implicit parameter
 730
 731   | RecordUpdOrigin
 732
 733   | DataDeclOrigin              -- Typechecking a data declaration
 734
 735   | InstanceDeclOrigin          -- Typechecking an instance decl
 736
 737   | LiteralOrigin HsOverLit     -- Occurrence of a literal
 738
 739   | PatOrigin (Pat Name)
 740
 741   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 742   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 743
 744   | SignatureOrigin             -- A dict created from a type signature
 745   | Rank2Origin                 -- A dict created when typechecking the argument
 746                                 -- of a rank-2 typed function
 747
 748   | DoOrigin                    -- The monad for a do expression
 749   | ProcOrigin                  -- A proc expression
 750
 751   | ClassDeclOrigin             -- Manufactured during a class decl
 752
 753   | InstanceSpecOrigin  Class   -- in a SPECIALIZE instance pragma
 754                         Type
 755
 756         -- When specialising instances the instance info attached to
 757         -- each class is not yet ready, so we record it inside the
 758         -- origin information.  This is a bit of a hack, but it works
 759         -- fine.  (Patrick is to blame [WDP].)
 760
 761   | ValSpecOrigin       Name    -- in a SPECIALIZE pragma for a value
 762
 763         -- Argument or result of a ccall
 764         -- Dictionaries with this origin aren't actually mentioned in the
 765         -- translated term, and so need not be bound.  Nor should they
 766         -- be abstracted over.
 767
 768   | UnknownOrigin       -- Help! I give up...
 769 \end{code}
 770
 771 \begin{code}
 772 pprInstLoc :: InstLoc -> SDoc
 773 pprInstLoc (InstLoc orig locn ctxt)
 774   = hsep [text "arising from", pp_orig orig, text "at", ppr locn]
 775   where
 776     pp_orig (OccurrenceOf name)
 777         = hsep [ptext SLIT("use of"), quotes (ppr name)]
 778     pp_orig (IPOccOrigin name)
 779         = hsep [ptext SLIT("use of implicit parameter"), quotes (ppr name)]
 780     pp_orig (IPBindOrigin name)
 781         = hsep [ptext SLIT("binding for implicit parameter"), quotes (ppr name)]
 782     pp_orig RecordUpdOrigin
 783         = ptext SLIT("a record update")
 784     pp_orig DataDeclOrigin
 785         = ptext SLIT("the data type declaration")
 786     pp_orig InstanceDeclOrigin
 787         = ptext SLIT("the instance declaration")
 788     pp_orig (LiteralOrigin lit)
 789         = hsep [ptext SLIT("the literal"), quotes (ppr lit)]
 790     pp_orig (PatOrigin pat)
 791         = hsep [ptext SLIT("the pattern"), quotes (ppr pat)]
 792     pp_orig (ArithSeqOrigin seq)
 793         = hsep [ptext SLIT("the arithmetic sequence"), quotes (ppr seq)]
 794     pp_orig (PArrSeqOrigin seq)
 795         = hsep [ptext SLIT("the parallel array sequence"), quotes (ppr seq)]
 796     pp_orig (SignatureOrigin)
 797         =  ptext SLIT("a type signature")
 798     pp_orig (Rank2Origin)
 799         =  ptext SLIT("a function with an overloaded argument type")
 800     pp_orig (DoOrigin)
 801         =  ptext SLIT("a do statement")
 802     pp_orig (ProcOrigin)
 803         =  ptext SLIT("a proc expression")
 804     pp_orig (ClassDeclOrigin)
 805         =  ptext SLIT("a class declaration")
 806     pp_orig (InstanceSpecOrigin clas ty)
 807         = hsep [text "a SPECIALIZE instance pragma; class",
 808                 quotes (ppr clas), text "type:", ppr ty]
 809     pp_orig (ValSpecOrigin name)
 810         = hsep [ptext SLIT("a SPECIALIZE user-pragma for"), quotes (ppr name)]
 811     pp_orig (UnknownOrigin)
 812         = ptext SLIT("...oops -- I don't know where the overloading came from!")
 813 \end{code}