ghc/compiler/typecheck/TcRnTypes.lhs

   1 %
   2 % (c) The GRASP Project, Glasgow University, 1992-2002
   3 %
   4 \begin{code}
   5 module TcRnTypes(
   6         TcRn, TcM, RnM, -- The monad is opaque outside this module
   7
   8         -- Standard monadic operations
   9         thenM, thenM_, returnM, failM,
  10
  11         -- Non-standard operations
  12         runTcRn, fixM, tryM, ioToTcRn,
  13         newMutVar, readMutVar, writeMutVar,
  14         getEnv, setEnv, updEnv, unsafeInterleaveM,
  15
  16         -- The environment types
  17         Env(..), TopEnv(..), TcGblEnv(..),
  18         TcLclEnv(..), RnLclEnv(..),
  19
  20         -- Ranamer types
  21         RnMode(..), isInterfaceMode, isCmdLineMode,
  22         EntityUsage, emptyUsages, ErrCtxt,
  23         ImportAvails(..), emptyImportAvails, plusImportAvails,
  24         plusAvail, pruneAvails,
  25         AvailEnv, emptyAvailEnv, unitAvailEnv, plusAvailEnv,
  26         mkAvailEnv, lookupAvailEnv, availEnvElts, addAvail,
  27         WhereFrom(..),
  28
  29         -- Typechecker types
  30         TcTyThing(..),
  31
  32         -- Template Haskell
  33         Stage(..), topStage, topSpliceStage,
  34         Level, impLevel, topLevel,
  35
  36         -- Insts
  37         Inst(..), InstOrigin(..), InstLoc, pprInstLoc,
  38         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
  39         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  40
  41         -- Misc other types
  42         TcRef, TcId, TcIdSet
  43   ) where
  44
  45 #include "HsVersions.h"
  46
  47 import HsSyn            ( PendingSplice, HsOverLit, MonoBinds, RuleDecl, ForeignDecl )
  48 import RnHsSyn          ( RenamedHsExpr, RenamedPat, RenamedArithSeqInfo )
  49 import HscTypes         ( GhciMode, ExternalPackageState, HomePackageTable, NameCache,
  50                           GlobalRdrEnv, LocalRdrEnv, FixityEnv, TypeEnv, TyThing,
  51                           Avails, GenAvailInfo(..), AvailInfo, availName,
  52                           IsBootInterface, Deprecations, WhetherHasOrphans )
  53 import Packages         ( PackageName )
  54 import TcType           ( TcTyVarSet, TcType, TcTauType, TcThetaType, TcPredType, TcKind,
  55                           tcCmpPred, tcCmpType, tcCmpTypes )
  56 import InstEnv          ( DFunId, InstEnv )
  57 import Name             ( Name )
  58 import NameEnv
  59 import NameSet          ( NameSet, emptyNameSet )
  60 import Type             ( Type )
  61 import Class            ( Class )
  62 import Var              ( Id, TyVar )
  63 import VarEnv           ( TidyEnv )
  64 import Module
  65 import SrcLoc           ( SrcLoc )
  66 import VarSet           ( IdSet )
  67 import ErrUtils         ( Messages, Message )
  68 import CmdLineOpts      ( DynFlags )
  69 import UniqSupply       ( UniqSupply )
  70 import BasicTypes       ( IPName )
  71 import Util             ( thenCmp )
  72 import Bag
  73 import Outputable
  74 import DATA_IOREF       ( IORef, newIORef, readIORef, writeIORef )
  75 import UNSAFE_IO        ( unsafeInterleaveIO )
  76 import FIX_IO           ( fixIO )
  77 import EXCEPTION        ( Exception )
  78 import Maybe            ( mapMaybe )
  79 import List             ( nub )
  80 import Panic            ( tryMost )
  81 \end{code}
  82
  83
  84 \begin{code}
  85 type TcRef a = IORef a
  86 type TcId    = Id                       -- Type may be a TcType
  87 type TcIdSet = IdSet
  88 \end{code}
  89
  90 %************************************************************************
  91 %*                                                                      *
  92                Standard monad definition for TcRn
  93     All the combinators for the monad can be found in TcRnMonad
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 The monad itself has to be defined here,
  98 because it is mentioned by ErrCtxt
  99
 100 \begin{code}
 101 newtype TcRn m a = TcRn (Env m -> IO a)
 102 unTcRn (TcRn f) = f
 103
 104 type TcM a = TcRn TcLclEnv a
 105 type RnM a = TcRn RnLclEnv a
 106
 107 returnM :: a -> TcRn m a
 108 returnM a = TcRn (\ env -> return a)
 109
 110 thenM :: TcRn m a -> (a -> TcRn m b) -> TcRn m b
 111 thenM (TcRn m) f = TcRn (\ env -> do { r <- m env ;
 112                                        unTcRn (f r) env })
 113
 114 thenM_ :: TcRn m a -> TcRn m b -> TcRn m b
 115 thenM_ (TcRn m) f = TcRn (\ env -> do { m env ; unTcRn f env })
 116
 117 failM :: TcRn m a
 118 failM = TcRn (\ env -> ioError (userError "TcRn failure"))
 119
 120 instance Monad (TcRn m) where
 121   (>>=)  = thenM
 122   (>>)   = thenM_
 123   return = returnM
 124   fail s = failM        -- Ignore the string
 125 \end{code}
 126
 127
 128 %************************************************************************
 129 %*                                                                      *
 130         Fundmantal combinators specific to the monad
 131 %*                                                                      *
 132 %************************************************************************
 133
 134 Running it
 135
 136 \begin{code}
 137 runTcRn :: Env m -> TcRn m a -> IO a
 138 runTcRn env (TcRn m) = m env
 139 \end{code}
 140
 141 The fixpoint combinator
 142
 143 \begin{code}
 144 {-# NOINLINE fixM #-}
 145   -- Aargh!  Not inlining fixTc alleviates a space leak problem.
 146   -- Normally fixTc is used with a lazy tuple match: if the optimiser is
 147   -- shown the definition of fixTc, it occasionally transforms the code
 148   -- in such a way that the code generator doesn't spot the selector
 149   -- thunks.  Sigh.
 150
 151 fixM :: (a -> TcRn m a) -> TcRn m a
 152 fixM f = TcRn (\ env -> fixIO (\ r -> unTcRn (f r) env))
 153 \end{code}
 154
 155 Error recovery
 156
 157 \begin{code}
 158 tryM :: TcRn m r -> TcRn m (Either Exception r)
 159 -- Reflect exception into TcRn monad
 160 tryM (TcRn thing) = TcRn (\ env -> tryMost (thing env))
 161 \end{code}
 162
 163 Lazy interleave
 164
 165 \begin{code}
 166 unsafeInterleaveM :: TcRn m a -> TcRn m a
 167 unsafeInterleaveM (TcRn m) = TcRn (\ env -> unsafeInterleaveIO (m env))
 168 \end{code}
 169
 170 \end{code}
 171
 172 Performing arbitrary I/O, plus the read/write var (for efficiency)
 173
 174 \begin{code}
 175 ioToTcRn :: IO a -> TcRn m a
 176 ioToTcRn io = TcRn (\ env -> io)
 177
 178 newMutVar :: a -> TcRn m (TcRef a)
 179 newMutVar val = TcRn (\ env -> newIORef val)
 180
 181 writeMutVar :: TcRef a -> a -> TcRn m ()
 182 writeMutVar var val = TcRn (\ env -> writeIORef var val)
 183
 184 readMutVar :: TcRef a -> TcRn m a
 185 readMutVar var = TcRn (\ env -> readIORef var)
 186 \end{code}
 187
 188 Getting the environment
 189
 190 \begin{code}
 191 getEnv :: TcRn m (Env m)
 192 {-# INLINE getEnv #-}
 193 getEnv = TcRn (\ env -> return env)
 194
 195 setEnv :: Env n -> TcRn n a -> TcRn m a
 196 {-# INLINE setEnv #-}
 197 setEnv new_env (TcRn m) = TcRn (\ env -> m new_env)
 198
 199 updEnv :: (Env m -> Env n) -> TcRn n a -> TcRn m a
 200 {-# INLINE updEnv #-}
 201 updEnv upd (TcRn m) = TcRn (\ env -> m (upd env))
 202 \end{code}
 203
 204
 205 %************************************************************************
 206 %*                                                                      *
 207                 The main environment types
 208 %*                                                                      *
 209 %************************************************************************
 210
 211 \begin{code}
 212 data Env a      -- Changes as we move into an expression
 213   = Env {
 214         env_top  :: TopEnv,     -- Top-level stuff that never changes
 215                                 --   Mainly a bunch of updatable refs
 216                                 --   Includes all info about imported things
 217         env_gbl  :: TcGblEnv,   -- Info about things defined at the top leve
 218                                 --   of the module being compiled
 219
 220         env_lcl  :: a,          -- Different for the type checker
 221                                 -- and the renamer
 222
 223         env_loc  :: SrcLoc      -- Source location
 224     }
 225
 226 data TopEnv     -- Built once at top level then does not change
 227                 -- Concerns imported stuff
 228                 -- Exceptions: error recovery points, meta computation points
 229    = TopEnv {
 230         top_mode    :: GhciMode,
 231         top_dflags  :: DynFlags,
 232
 233         -- Stuff about imports
 234         top_eps    :: TcRef ExternalPackageState,
 235                 -- PIT, ImportedModuleInfo
 236                 -- DeclsMap, IfaceRules, IfaceInsts, InstGates
 237                 -- TypeEnv, InstEnv, RuleBase
 238
 239         top_hpt  :: HomePackageTable,
 240                 -- The home package table that we've accumulated while
 241                 -- compiling the home package,
 242                 -- *excluding* the module we are compiling right now.
 243                 -- (In one-shot mode the current module is the only
 244                 --  home-package module, so tc_hpt is empty.  All other
 245                 --  modules count as "external-package" modules.)
 246                 -- tc_hpt is not mutable because we only demand-load
 247                 -- external packages; the home package is eagerly
 248                 -- loaded by the compilation manager.
 249
 250         -- The global name supply
 251         top_nc     :: TcRef NameCache,          -- Maps original names to Names
 252         top_us     :: TcRef UniqSupply,         -- Unique supply for this module
 253         top_errs   :: TcRef Messages
 254    }
 255
 256 -- TcGblEnv describes the top-level of the module at the
 257 -- point at which the typechecker is finished work.
 258 -- It is this structure that is handed on to the desugarer
 259
 260 data TcGblEnv
 261   = TcGblEnv {
 262         tcg_mod    :: Module,           -- Module being compiled
 263         tcg_usages :: TcRef EntityUsage,  -- What version of what entities
 264                                           -- have been used from other home-pkg modules
 265         tcg_rdr_env :: GlobalRdrEnv,    -- Top level envt; used during renaming
 266         tcg_fix_env :: FixityEnv,       -- Ditto
 267         tcg_default :: [Type],          -- Types used for defaulting
 268
 269         tcg_type_env :: TypeEnv,        -- Global type env for the module we are compiling now
 270                 -- All TyCons and Classes (for this module) end up in here right away,
 271                 -- along with their derived constructors, selectors.
 272                 --
 273                 -- (Ids defined in this module start in the local envt,
 274                 --  though they move to the global envt during zonking)
 275
 276                 -- Cached things
 277         tcg_ist :: Name -> Maybe TyThing,       -- Imported symbol table
 278                 -- Global type env: a combination of tcg_eps, tcg_hpt
 279                 --      (but *not* tcg_type_env; no deep reason)
 280                 -- When the PCS changes this must be refreshed,
 281                 -- notably after running some compile-time code
 282
 283         tcg_inst_env :: InstEnv,        -- Global instance env: a combination of
 284                                         --      tc_pcs, tc_hpt, *and* tc_insts
 285
 286                 -- Now a bunch of things about this module that are simply
 287                 -- accumulated, but never consulted until the end.
 288                 -- Nevertheless, it's convenient to accumulate them along
 289                 -- with the rest of the info from this module.
 290         tcg_exports :: Avails,                  -- What is exported
 291         tcg_imports :: ImportAvails,            -- Information about what was imported
 292                                                 --    from where, including things bound
 293                                                 --    in this module
 294                 -- The next fields are always fully zonked
 295         tcg_binds   :: MonoBinds Id,            -- Value bindings in this module
 296         tcg_deprecs :: Deprecations,            -- ...Deprecations
 297         tcg_insts   :: [DFunId],                -- ...Instances
 298         tcg_rules   :: [RuleDecl Id],           -- ...Rules
 299         tcg_fords   :: [ForeignDecl Id]         -- ...Foreign import & exports
 300     }
 301 \end{code}
 302
 303
 304 %************************************************************************
 305 %*                                                                      *
 306                 The local typechecker environment
 307 %*                                                                      *
 308 %************************************************************************
 309
 310 The Global-Env/Local-Env story
 311 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 312 During type checking, we keep in the tcg_type_env
 313         * All types and classes
 314         * All Ids derived from types and classes (constructors, selectors)
 315
 316 At the end of type checking, we zonk the local bindings,
 317 and as we do so we add to the tcg_type_env
 318         * Locally defined top-level Ids
 319
 320 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 321         a) fed back (via the knot) to typechecking the
 322            unfoldings of interface signatures
 323         b) used in the ModDetails of this module
 324
 325 \begin{code}
 326 data TcLclEnv
 327   = TcLclEnv {
 328         tcl_ctxt :: ErrCtxt,    -- Error context
 329
 330         tcl_level  :: Stage,            -- Template Haskell context
 331
 332         tcl_env    :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 333                                           -- defined in this module
 334
 335         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 336                                         -- Namely, the in-scope TyVars bound in tcl_lenv,
 337                                         -- plus the tyvars mentioned in the types of
 338                                         -- Ids bound in tcl_lenv
 339                                         -- Why mutable? see notes with tcGetGlobalTyVars
 340
 341         tcl_lie :: TcRef LIE            -- Place to accumulate type constraints
 342     }
 343
 344 type Level = Int
 345
 346 data Stage
 347   = Comp                                -- Ordinary compiling, at level topLevel
 348   | Splice Level                        -- Inside a splice
 349   | Brack  Level                        -- Inside brackets;
 350            (TcRef [PendingSplice])      --   accumulate pending splices here
 351            (TcRef LIE)                  --   and type constraints here
 352 topStage, topSpliceStage :: Stage
 353 topStage       = Comp
 354 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 355
 356
 357 impLevel, topLevel :: Level
 358 topLevel = 1    -- Things dedined at top level of this module
 359 impLevel = 0    -- Imported things; they can be used inside a top level splice
 360 --
 361 -- For example:
 362 --      f = ...
 363 --      g1 = $(map ...)         is OK
 364 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 365
 366 data TcTyThing
 367   = AGlobal TyThing             -- Used only in the return type of a lookup
 368   | ATcId   TcId Level          -- Ids defined in this module; may not be fully zonked
 369   | ATyVar  TyVar               -- Type variables
 370   | AThing  TcKind              -- Used temporarily, during kind checking
 371 -- Here's an example of how the AThing guy is used
 372 -- Suppose we are checking (forall a. T a Int):
 373 --      1. We first bind (a -> AThink kv), where kv is a kind variable.
 374 --      2. Then we kind-check the (T a Int) part.
 375 --      3. Then we zonk the kind variable.
 376 --      4. Now we know the kind for 'a', and we add (a -> ATyVar a::K) to the environment
 377 \end{code}
 378
 379 \begin{code}
 380 type ErrCtxt = [TidyEnv -> TcM (TidyEnv, Message)]
 381                         -- Innermost first.  Monadic so that we have a chance
 382                         -- to deal with bound type variables just before error
 383                         -- message construction
 384 \end{code}
 385
 386
 387 %************************************************************************
 388 %*                                                                      *
 389                 The local renamer environment
 390 %*                                                                      *
 391 %************************************************************************
 392
 393 \begin{code}
 394 data RnLclEnv
 395   = RnLclEnv {
 396         rn_mode :: RnMode,
 397         rn_lenv :: LocalRdrEnv          -- Local name envt
 398                 --   Does *not* include global name envt; may shadow it
 399                 --   Includes both ordinary variables and type variables;
 400                 --   they are kept distinct because tyvar have a different
 401                 --   occurrence contructor (Name.TvOcc)
 402                 -- We still need the unsullied global name env so that
 403                 --   we can look up record field names
 404      }
 405
 406 data RnMode = SourceMode                -- Renaming source code
 407             | InterfaceMode Module      -- Renaming interface declarations from M
 408             | CmdLineMode               -- Renaming a command-line expression
 409
 410 isInterfaceMode (InterfaceMode _) = True
 411 isInterfaceMode _                 = False
 412
 413 isCmdLineMode CmdLineMode = True
 414 isCmdLineMode _ = False
 415 \end{code}
 416
 417
 418 %************************************************************************
 419 %*                                                                      *
 420                         EntityUsage
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 EntityUsage tells what things are actually need in order to compile this
 425 module.  It is used for generating the usage-version field of the ModIface.
 426
 427 Note that we do not record version info for entities from
 428 other (non-home) packages.  If the package changes, GHC doesn't help.
 429
 430 \begin{code}
 431 type EntityUsage = NameSet
 432         -- The Names are all the (a) home-package
 433         --                       (b) "big" (i.e. no data cons, class ops)
 434         --                       (c) non-locally-defined
 435         --                       (d) non-wired-in
 436         -- names that have been slurped in so far.
 437         -- This is used to generate the "usage" information for this module.
 438
 439 emptyUsages :: EntityUsage
 440 emptyUsages = emptyNameSet
 441 \end{code}
 442
 443
 444 %************************************************************************
 445 %*                                                                      *
 446         Operations over ImportAvails
 447 %*                                                                      *
 448 %************************************************************************
 449
 450 ImportAvails summarises what was imported from where, irrespective
 451 of whether the imported htings are actually used or not
 452 It is used      * when porcessing the export list
 453                 * when constructing usage info for the inteface file
 454                 * to identify the list of directly imported modules
 455                         for initialisation purposes
 456
 457 \begin{code}
 458 data ImportAvails
 459    = ImportAvails {
 460         imp_env :: AvailEnv,
 461                 -- All the things that are available from the import
 462                 -- Its domain is all the "main" things;
 463                 -- i.e. *excluding* class ops and constructors
 464                 --      (which appear inside their parent AvailTC)
 465
 466         imp_unqual :: ModuleEnv AvailEnv,
 467                 -- Used to figure out "module M" export specifiers
 468                 -- Domain is only modules with *unqualified* imports
 469                 -- (see 1.4 Report Section 5.1.1)
 470                 -- We keep the stuff as an AvailEnv so that it's easy to
 471                 -- combine stuff coming from different (unqualified)
 472                 -- imports of the same module
 473
 474         imp_mods :: ModuleEnv (Module, Bool),
 475                 -- Domain is all directly-imported modules
 476                 -- Bool is True if there was an unrestricted import
 477                 --      (i.e. not a selective list)
 478                 -- We need the Module in the range because we can't get
 479                 --      the keys of a ModuleEnv
 480                 -- Used
 481                 --   (a) to help construct the usage information in
 482                 --       the interface file; if we import everything we
 483                 --       need to recompile if the module version changes
 484                 --   (b) to specify what child modules to initialise
 485
 486         dep_mods :: ModuleEnv (ModuleName, WhetherHasOrphans, IsBootInterface),
 487                 -- For a given import or set of imports,
 488                 -- there's an entry here for
 489                 -- (a) modules below the one being compiled, in the current package
 490                 -- (b) orphan modules below the one being compiled, regardless of package
 491                 --
 492                 -- It doesn't matter whether any of these dependencies are actually
 493                 -- *used* when compiling the module; they are listed if they are below
 494                 -- it at all.  For example, suppose M imports A which imports X.  Then
 495                 -- compiling M might not need to consult X.hi, but X is still listed
 496                 -- in M's dependencies.
 497
 498         dep_pkgs :: [PackageName]
 499                 -- Packages needed by the module being compiled, whether
 500                 -- directly, or via other modules in this package, or via
 501                 -- modules imported from other packages.
 502       }
 503
 504 emptyImportAvails :: ImportAvails
 505 emptyImportAvails = ImportAvails { imp_env    = emptyAvailEnv,
 506                                    imp_unqual = emptyModuleEnv,
 507                                    imp_mods   = emptyModuleEnv,
 508                                    dep_mods   = emptyModuleEnv,
 509                                    dep_pkgs   = [] }
 510
 511 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 512 plusImportAvails
 513   (ImportAvails { imp_env = env1, imp_unqual = unqual1, imp_mods = mods1,
 514                   dep_mods = dmods1, dep_pkgs = dpkgs1 })
 515   (ImportAvails { imp_env = env2, imp_unqual = unqual2, imp_mods = mods2,
 516                   dep_mods = dmods2, dep_pkgs = dpkgs2 })
 517   = ImportAvails { imp_env    = env1 `plusAvailEnv` env2,
 518                    imp_unqual = plusModuleEnv_C plusAvailEnv unqual1 unqual2,
 519                    imp_mods   = mods1  `plusModuleEnv` mods2,
 520                    dep_mods   = plusModuleEnv_C plus_mod_dep dmods1 dmods2,
 521                    dep_pkgs   = nub (dpkgs1 ++ dpkgs2)   }
 522   where
 523     plus_mod_dep (m1, orphan1, boot1) (m2, orphan2, boot2)
 524         = WARN( not (m1 == m2 && (boot1 || boot2 || orphan1 == orphan2)),
 525                 (ppr m1 <+> ppr m2) $$ (ppr orphan1 <+> ppr orphan2) $$ (ppr boot1 <+> ppr boot2) )
 526                 -- Check mod-names match, and orphan-hood matches; but a boot interface
 527                 -- might not know about orphan hood, so only check the orphan match
 528                 -- if both are non-boot interfaces
 529           (m1, orphan1 || orphan2, boot1 && boot2)
 530         -- If either side can "see" a non-hi-boot interface, use that
 531         -- Similarly orphan-hood (see note about about why orphan1 and 2 might differ)
 532 \end{code}
 533
 534 %************************************************************************
 535 %*                                                                      *
 536         Avails, AvailEnv, etc
 537 %*                                                                      *
 538 v%************************************************************************
 539
 540 \begin{code}
 541 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 542 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (nub (ns1 ++ ns2))
 543 -- Added SOF 4/97
 544 #ifdef DEBUG
 545 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 546 #endif
 547
 548 -------------------------
 549 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 550             -> [AvailInfo]
 551             -> [AvailInfo]
 552 pruneAvails keep avails
 553   = mapMaybe del avails
 554   where
 555     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 556     del (Avail n) | keep n    = Just (Avail n)
 557                   | otherwise = Nothing
 558     del (AvailTC n ns) | null ns'  = Nothing
 559                        | otherwise = Just (AvailTC n ns')
 560                        where
 561                          ns' = filter keep ns
 562 \end{code}
 563
 564 ---------------------------------------
 565         AvailEnv and friends
 566 ---------------------------------------
 567
 568 \begin{code}
 569 type AvailEnv = NameEnv AvailInfo       -- Maps a Name to the AvailInfo that contains it
 570
 571 emptyAvailEnv :: AvailEnv
 572 emptyAvailEnv = emptyNameEnv
 573
 574 unitAvailEnv :: AvailInfo -> AvailEnv
 575 unitAvailEnv a = unitNameEnv (availName a) a
 576
 577 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 578 plusAvailEnv = plusNameEnv_C plusAvail
 579
 580 lookupAvailEnv = lookupNameEnv
 581
 582 availEnvElts = nameEnvElts
 583
 584 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 585 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 586
 587 mkAvailEnv :: [AvailInfo] -> AvailEnv
 588         -- 'avails' may have several items with the same availName
 589         -- E.g  import Ix( Ix(..), index )
 590         -- will give Ix(Ix,index,range) and Ix(index)
 591         -- We want to combine these; addAvail does that
 592 mkAvailEnv avails = foldl addAvail emptyAvailEnv avails
 593 \end{code}
 594
 595 %************************************************************************
 596 %*                                                                      *
 597 \subsection{Where from}
 598 %*                                                                      *
 599 %************************************************************************
 600
 601 The @WhereFrom@ type controls where the renamer looks for an interface file
 602
 603 \begin{code}
 604 data WhereFrom
 605   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 606
 607   | ImportForUsage IsBootInterface      -- Import when chasing usage info from an interaface file
 608                                         --      Failure in this case is not an error
 609
 610   | ImportBySystem                      -- Non user import.
 611
 612 instance Outputable WhereFrom where
 613   ppr (ImportByUser is_boot) | is_boot     = ptext SLIT("{- SOURCE -}")
 614                              | otherwise   = empty
 615   ppr (ImportForUsage is_boot) | is_boot   = ptext SLIT("{- USAGE SOURCE -}")
 616                                | otherwise = ptext SLIT("{- USAGE -}")
 617   ppr ImportBySystem                       = ptext SLIT("{- SYSTEM -}")
 618 \end{code}
 619
 620
 621 %************************************************************************
 622 %*                                                                      *
 623 \subsection[Inst-types]{@Inst@ types}
 624 %*                                                                      *
 625 v%************************************************************************
 626
 627 An @Inst@ is either a dictionary, an instance of an overloaded
 628 literal, or an instance of an overloaded value.  We call the latter a
 629 ``method'' even though it may not correspond to a class operation.
 630 For example, we might have an instance of the @double@ function at
 631 type Int, represented by
 632
 633         Method 34 doubleId [Int] origin
 634
 635 \begin{code}
 636 data Inst
 637   = Dict
 638         Id
 639         TcPredType
 640         InstLoc
 641
 642   | Method
 643         Id
 644
 645         TcId    -- The overloaded function
 646                         -- This function will be a global, local, or ClassOpId;
 647                         --   inside instance decls (only) it can also be an InstId!
 648                         -- The id needn't be completely polymorphic.
 649                         -- You'll probably find its name (for documentation purposes)
 650                         --        inside the InstOrigin
 651
 652         [TcType]        -- The types to which its polymorphic tyvars
 653                         --      should be instantiated.
 654                         -- These types must saturate the Id's foralls.
 655
 656         TcThetaType     -- The (types of the) dictionaries to which the function
 657                         -- must be applied to get the method
 658
 659         TcTauType       -- The type of the method
 660
 661         InstLoc
 662
 663         -- INVARIANT: in (Method u f tys theta tau loc)
 664         --      type of (f tys dicts(from theta)) = tau
 665
 666   | LitInst
 667         Id
 668         HsOverLit       -- The literal from the occurrence site
 669                         --      INVARIANT: never a rebindable-syntax literal
 670                         --      Reason: tcSyntaxName does unification, and we
 671                         --              don't want to deal with that during tcSimplify
 672         TcType          -- The type at which the literal is used
 673         InstLoc
 674 \end{code}
 675
 676 @Insts@ are ordered by their class/type info, rather than by their
 677 unique.  This allows the context-reduction mechanism to use standard finite
 678 maps to do their stuff.
 679
 680 \begin{code}
 681 instance Ord Inst where
 682   compare = cmpInst
 683
 684 instance Eq Inst where
 685   (==) i1 i2 = case i1 `cmpInst` i2 of
 686                  EQ    -> True
 687                  other -> False
 688
 689 cmpInst (Dict _ pred1 _)          (Dict _ pred2 _)          = pred1 `tcCmpPred` pred2
 690 cmpInst (Dict _ _ _)              other                     = LT
 691
 692 cmpInst (Method _ _ _ _ _ _)      (Dict _ _ _)              = GT
 693 cmpInst (Method _ id1 tys1 _ _ _) (Method _ id2 tys2 _ _ _) = (id1 `compare` id2) `thenCmp` (tys1 `tcCmpTypes` tys2)
 694 cmpInst (Method _ _ _ _ _ _)      other                     = LT
 695
 696 cmpInst (LitInst _ _ _ _)         (Dict _ _ _)              = GT
 697 cmpInst (LitInst _ _ _ _)         (Method _ _ _ _ _ _)      = GT
 698 cmpInst (LitInst _ lit1 ty1 _)    (LitInst _ lit2 ty2 _)    = (lit1 `compare` lit2) `thenCmp` (ty1 `tcCmpType` ty2)
 699 \end{code}
 700
 701
 702 %************************************************************************
 703 %*                                                                      *
 704 \subsection[Inst-collections]{LIE: a collection of Insts}
 705 %*                                                                      *
 706 %************************************************************************
 707
 708 \begin{code}
 709 type LIE = Bag Inst
 710
 711 isEmptyLIE        = isEmptyBag
 712 emptyLIE          = emptyBag
 713 unitLIE inst      = unitBag inst
 714 mkLIE insts       = listToBag insts
 715 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 716 consLIE inst lie  = inst `consBag` lie
 717 plusLIEs lies     = unionManyBags lies
 718 lieToList         = bagToList
 719 listToLIE         = listToBag
 720 \end{code}
 721
 722
 723 %************************************************************************
 724 %*                                                                      *
 725 \subsection[Inst-origin]{The @InstOrigin@ type}
 726 %*                                                                      *
 727 %************************************************************************
 728
 729 The @InstOrigin@ type gives information about where a dictionary came from.
 730 This is important for decent error message reporting because dictionaries
 731 don't appear in the original source code.  Doubtless this type will evolve...
 732
 733 It appears in TcMonad because there are a couple of error-message-generation
 734 functions that deal with it.
 735
 736 \begin{code}
 737 type InstLoc = (InstOrigin, SrcLoc, ErrCtxt)
 738
 739 data InstOrigin
 740   = OccurrenceOf Name           -- Occurrence of an overloaded identifier
 741
 742   | IPOcc (IPName Name)         -- Occurrence of an implicit parameter
 743   | IPBind (IPName Name)        -- Binding site of an implicit parameter
 744
 745   | RecordUpdOrigin
 746
 747   | DataDeclOrigin              -- Typechecking a data declaration
 748
 749   | InstanceDeclOrigin          -- Typechecking an instance decl
 750
 751   | LiteralOrigin HsOverLit     -- Occurrence of a literal
 752
 753   | PatOrigin RenamedPat
 754
 755   | ArithSeqOrigin RenamedArithSeqInfo -- [x..], [x..y] etc
 756   | PArrSeqOrigin  RenamedArithSeqInfo -- [:x..y:] and [:x,y..z:]
 757
 758   | SignatureOrigin             -- A dict created from a type signature
 759   | Rank2Origin                 -- A dict created when typechecking the argument
 760                                 -- of a rank-2 typed function
 761
 762   | DoOrigin                    -- The monad for a do expression
 763
 764   | ClassDeclOrigin             -- Manufactured during a class decl
 765
 766   | InstanceSpecOrigin  Class   -- in a SPECIALIZE instance pragma
 767                         Type
 768
 769         -- When specialising instances the instance info attached to
 770         -- each class is not yet ready, so we record it inside the
 771         -- origin information.  This is a bit of a hack, but it works
 772         -- fine.  (Patrick is to blame [WDP].)
 773
 774   | ValSpecOrigin       Name    -- in a SPECIALIZE pragma for a value
 775
 776         -- Argument or result of a ccall
 777         -- Dictionaries with this origin aren't actually mentioned in the
 778         -- translated term, and so need not be bound.  Nor should they
 779         -- be abstracted over.
 780
 781   | CCallOrigin         String                  -- CCall label
 782                         (Maybe RenamedHsExpr)   -- Nothing if it's the result
 783                                                 -- Just arg, for an argument
 784
 785   | LitLitOrigin        String  -- the litlit
 786
 787   | UnknownOrigin       -- Help! I give up...
 788 \end{code}
 789
 790 \begin{code}
 791 pprInstLoc :: InstLoc -> SDoc
 792 pprInstLoc (orig, locn, ctxt)
 793   = hsep [text "arising from", pp_orig orig, text "at", ppr locn]
 794   where
 795     pp_orig (OccurrenceOf name)
 796         = hsep [ptext SLIT("use of"), quotes (ppr name)]
 797     pp_orig (IPOcc name)
 798         = hsep [ptext SLIT("use of implicit parameter"), quotes (ppr name)]
 799     pp_orig (IPBind name)
 800         = hsep [ptext SLIT("binding for implicit parameter"), quotes (ppr name)]
 801     pp_orig RecordUpdOrigin
 802         = ptext SLIT("a record update")
 803     pp_orig DataDeclOrigin
 804         = ptext SLIT("the data type declaration")
 805     pp_orig InstanceDeclOrigin
 806         = ptext SLIT("the instance declaration")
 807     pp_orig (LiteralOrigin lit)
 808         = hsep [ptext SLIT("the literal"), quotes (ppr lit)]
 809     pp_orig (PatOrigin pat)
 810         = hsep [ptext SLIT("the pattern"), quotes (ppr pat)]
 811     pp_orig (ArithSeqOrigin seq)
 812         = hsep [ptext SLIT("the arithmetic sequence"), quotes (ppr seq)]
 813     pp_orig (PArrSeqOrigin seq)
 814         = hsep [ptext SLIT("the parallel array sequence"), quotes (ppr seq)]
 815     pp_orig (SignatureOrigin)
 816         =  ptext SLIT("a type signature")
 817     pp_orig (Rank2Origin)
 818         =  ptext SLIT("a function with an overloaded argument type")
 819     pp_orig (DoOrigin)
 820         =  ptext SLIT("a do statement")
 821     pp_orig (ClassDeclOrigin)
 822         =  ptext SLIT("a class declaration")
 823     pp_orig (InstanceSpecOrigin clas ty)
 824         = hsep [text "a SPECIALIZE instance pragma; class",
 825                 quotes (ppr clas), text "type:", ppr ty]
 826     pp_orig (ValSpecOrigin name)
 827         = hsep [ptext SLIT("a SPECIALIZE user-pragma for"), quotes (ppr name)]
 828     pp_orig (CCallOrigin clabel Nothing{-ccall result-})
 829         = hsep [ptext SLIT("the result of the _ccall_ to"), quotes (text clabel)]
 830     pp_orig (CCallOrigin clabel (Just arg_expr))
 831         = hsep [ptext SLIT("an argument in the _ccall_ to"), quotes (text clabel) <> comma,
 832                 text "namely", quotes (ppr arg_expr)]
 833     pp_orig (LitLitOrigin s)
 834         = hsep [ptext SLIT("the ``literal-literal''"), quotes (text s)]
 835     pp_orig (UnknownOrigin)
 836         = ptext SLIT("...oops -- I don't know where the overloading came from!")
 837 \end{code}