ghc/compiler/typecheck/TcRnTypes.lhs

   1 %
   2 % (c) The GRASP Project, Glasgow University, 1992-2002
   3 %
   4 \begin{code}
   5 module TcRnTypes(
   6         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   7         TcRef,
   8
   9         -- The environment types
  10         Env(..),
  11         TcGblEnv(..), TcLclEnv(..),
  12         IfGblEnv(..), IfLclEnv(..),
  13
  14         -- Ranamer types
  15         ErrCtxt,
  16         ImportAvails(..), emptyImportAvails, plusImportAvails,
  17         plusAvail, pruneAvails,
  18         AvailEnv, emptyAvailEnv, unitAvailEnv, plusAvailEnv,
  19         mkAvailEnv, lookupAvailEnv, lookupAvailEnv_maybe, availEnvElts, addAvail,
  20         WhereFrom(..), mkModDeps,
  21
  22         -- Typechecker types
  23         TcTyThing(..), GadtRefinement,
  24
  25         -- Template Haskell
  26         ThStage(..), topStage, topSpliceStage,
  27         ThLevel, impLevel, topLevel,
  28
  29         -- Arrows
  30         ArrowCtxt(..), topArrowCtxt, ProcLevel, topProcLevel,
  31
  32         -- Insts
  33         Inst(..), InstOrigin(..), InstLoc(..), pprInstLoc,
  34         instLocSrcLoc, instLocSrcSpan,
  35         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
  36         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  37
  38         -- Misc other types
  39         TcId, TcIdSet, TcDictBinds
  40   ) where
  41
  42 #include "HsVersions.h"
  43
  44 import HsSyn            ( PendingSplice, HsOverLit, LRuleDecl, LForeignDecl,
  45                           ArithSeqInfo, DictBinds, LHsBinds )
  46 import HscTypes         ( FixityEnv,
  47                           HscEnv, TypeEnv, TyThing,
  48                           GenAvailInfo(..), AvailInfo,
  49                           availName, IsBootInterface, Deprecations )
  50 import Packages         ( PackageId )
  51 import Type             ( Type, TvSubstEnv )
  52 import TcType           ( TcTyVarSet, TcType, TcTauType, TcThetaType, SkolemInfo,
  53                           TcPredType, TcKind, tcCmpPred, tcCmpType, tcCmpTypes )
  54 import InstEnv          ( DFunId, InstEnv )
  55 import IOEnv
  56 import RdrName          ( GlobalRdrEnv, LocalRdrEnv )
  57 import Name             ( Name )
  58 import NameEnv
  59 import NameSet          ( NameSet, unionNameSets, DefUses )
  60 import OccName          ( OccEnv )
  61 import Var              ( Id, TyVar )
  62 import VarEnv           ( TidyEnv )
  63 import Module
  64 import SrcLoc           ( SrcSpan, SrcLoc, srcSpanStart )
  65 import VarSet           ( IdSet )
  66 import ErrUtils         ( Messages, Message )
  67 import UniqSupply       ( UniqSupply )
  68 import BasicTypes       ( IPName )
  69 import Util             ( thenCmp )
  70 import Bag
  71 import Outputable
  72 import Maybe            ( mapMaybe )
  73 import ListSetOps       ( unionLists )
  74 \end{code}
  75
  76
  77 %************************************************************************
  78 %*                                                                      *
  79                Standard monad definition for TcRn
  80     All the combinators for the monad can be found in TcRnMonad
  81 %*                                                                      *
  82 %************************************************************************
  83
  84 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  85
  86 \begin{code}
  87 type TcRef a     = IORef a
  88 type TcId        = Id                   -- Type may be a TcType
  89 type TcIdSet     = IdSet
  90 type TcDictBinds = DictBinds TcId       -- Bag of dictionary bindings
  91
  92
  93
  94 type TcRnIf a b c = IOEnv (Env a b) c
  95 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
  96 type IfG a  = IfM () a                          -- Top level
  97 type IfL a  = IfM IfLclEnv a                    -- Nested
  98 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
  99 type RnM  a = TcRn a            -- Historical
 100 type TcM  a = TcRn a            -- Historical
 101 \end{code}
 102
 103
 104 %************************************************************************
 105 %*                                                                      *
 106                 The main environment types
 107 %*                                                                      *
 108 %************************************************************************
 109
 110 \begin{code}
 111 data Env gbl lcl        -- Changes as we move into an expression
 112   = Env {
 113         env_top  :: HscEnv,     -- Top-level stuff that never changes
 114                                 -- Includes all info about imported things
 115
 116         env_us   :: TcRef UniqSupply,   -- Unique supply for local varibles
 117
 118         env_gbl  :: gbl,        -- Info about things defined at the top level
 119                                 -- of the module being compiled
 120
 121         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 122                                 -- an expression
 123     }
 124
 125 -- TcGblEnv describes the top-level of the module at the
 126 -- point at which the typechecker is finished work.
 127 -- It is this structure that is handed on to the desugarer
 128
 129 data TcGblEnv
 130   = TcGblEnv {
 131         tcg_mod     :: Module,          -- Module being compiled
 132         tcg_rdr_env :: GlobalRdrEnv,    -- Top level envt; used during renaming
 133         tcg_default :: Maybe [Type],    -- Types used for defaulting
 134                                         -- Nothing => no 'default' decl
 135
 136         tcg_fix_env  :: FixityEnv,      -- Just for things in this module
 137
 138         tcg_type_env :: TypeEnv,        -- Global type env for the module we are compiling now
 139                 -- All TyCons and Classes (for this module) end up in here right away,
 140                 -- along with their derived constructors, selectors.
 141                 --
 142                 -- (Ids defined in this module start in the local envt,
 143                 --  though they move to the global envt during zonking)
 144
 145         tcg_type_env_var :: TcRef TypeEnv,
 146                 -- Used only to initialise the interface-file
 147                 -- typechecker in initIfaceTcRn, so that it can see stuff
 148                 -- bound in this module when dealing with hi-boot recursions
 149                 -- Updated at intervals (e.g. after dealing with types and classes)
 150
 151         tcg_inst_env :: InstEnv,        -- Instance envt for *home-package* modules
 152                                         -- Includes the dfuns in tcg_insts
 153                 -- Now a bunch of things about this module that are simply
 154                 -- accumulated, but never consulted until the end.
 155                 -- Nevertheless, it's convenient to accumulate them along
 156                 -- with the rest of the info from this module.
 157         tcg_exports :: NameSet,         -- What is exported
 158         tcg_imports :: ImportAvails,    -- Information about what was imported
 159                                         --    from where, including things bound
 160                                         --    in this module
 161
 162         tcg_dus :: DefUses,     -- What is defined in this module and what is used.
 163                                 -- The latter is used to generate
 164                                 --      (a) version tracking; no need to recompile if these
 165                                 --              things have not changed version stamp
 166                                 --      (b) unused-import info
 167
 168         tcg_keep :: TcRef NameSet,      -- Locally-defined top-level names to keep alive
 169                 -- "Keep alive" means give them an Exported flag, so
 170                 -- that the simplifier does not discard them as dead
 171                 -- code, and so that they are exposed in the interface file
 172                 -- (but not to export to the user).
 173                 --
 174                 -- Some things, like dict-fun Ids and default-method Ids are
 175                 -- "born" with the Exported flag on, for exactly the above reason,
 176                 -- but some we only discover as we go.  Specifically:
 177                 --      * The to/from functions for generic data types
 178                 --      * Top-level variables appearing free in the RHS of an orphan rule
 179                 --      * Top-level variables appearing free in a TH bracket
 180
 181         tcg_inst_uses :: TcRef NameSet, -- Home-package Dfuns actually used
 182                 -- Used to generate version dependencies
 183                 -- This records usages, rather like tcg_dus, but it has to
 184                 -- be a mutable variable so it can be augmented
 185                 -- when we look up an instance.  These uses of dfuns are
 186                 -- rather like the free variables of the program, but
 187                 -- are implicit instead of explicit.
 188
 189         tcg_th_used :: TcRef Bool,      -- True <=> Template Haskell syntax used
 190                 -- We need this so that we can generate a dependency on the
 191                 -- Template Haskell package, becuase the desugarer is going to
 192                 -- emit loads of references to TH symbols.  It's rather like
 193                 -- tcg_inst_uses; the reference is implicit rather than explicit,
 194                 -- so we have to zap a mutable variable.
 195
 196                 -- The next fields accumulate the payload of the module
 197                 -- The binds, rules and foreign-decl fiels are collected
 198                 -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 199         tcg_binds   :: LHsBinds Id,             -- Value bindings in this module
 200         tcg_deprecs :: Deprecations,            -- ...Deprecations
 201         tcg_insts   :: [DFunId],                -- ...Instances
 202         tcg_rules   :: [LRuleDecl Id],          -- ...Rules
 203         tcg_fords   :: [LForeignDecl Id]        -- ...Foreign import & exports
 204     }
 205 \end{code}
 206
 207 %************************************************************************
 208 %*                                                                      *
 209                 The interface environments
 210               Used when dealing with IfaceDecls
 211 %*                                                                      *
 212 %************************************************************************
 213
 214 \begin{code}
 215 data IfGblEnv
 216   = IfGblEnv {
 217         -- The type environment for the module being compiled,
 218         -- in case the interface refers back to it via a reference that
 219         -- was originally a hi-boot file.
 220         -- We need the module name so we can test when it's appropriate
 221         -- to look in this env.
 222         if_rec_types :: Maybe (Module, IfG TypeEnv)
 223                 -- Allows a read effect, so it can be in a mutable
 224                 -- variable; c.f. handling the external package type env
 225                 -- Nothing => interactive stuff, no loops possible
 226     }
 227
 228 data IfLclEnv
 229   = IfLclEnv {
 230         -- The module for the current IfaceDecl
 231         -- So if we see   f = \x -> x
 232         -- it means M.f = \x -> x, where M is the if_mod
 233         if_mod :: Module,
 234
 235         if_tv_env  :: OccEnv TyVar,     -- Nested tyvar bindings
 236         if_id_env  :: OccEnv Id         -- Nested id binding
 237     }
 238 \end{code}
 239
 240
 241 %************************************************************************
 242 %*                                                                      *
 243                 The local typechecker environment
 244 %*                                                                      *
 245 %************************************************************************
 246
 247 The Global-Env/Local-Env story
 248 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 249 During type checking, we keep in the tcg_type_env
 250         * All types and classes
 251         * All Ids derived from types and classes (constructors, selectors)
 252
 253 At the end of type checking, we zonk the local bindings,
 254 and as we do so we add to the tcg_type_env
 255         * Locally defined top-level Ids
 256
 257 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 258         a) fed back (via the knot) to typechecking the
 259            unfoldings of interface signatures
 260         b) used in the ModDetails of this module
 261
 262 \begin{code}
 263 data TcLclEnv           -- Changes as we move inside an expression
 264                         -- Discarded after typecheck/rename; not passed on to desugarer
 265   = TcLclEnv {
 266         tcl_loc  :: SrcSpan,            -- Source span
 267         tcl_ctxt :: ErrCtxt,            -- Error context
 268         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 269
 270         tcl_th_ctxt    :: ThStage,      -- Template Haskell context
 271         tcl_arrow_ctxt :: ArrowCtxt,    -- Arrow-notation context
 272
 273         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 274                 -- Maintained during renaming, of course, but also during
 275                 -- type checking, solely so that when renaming a Template-Haskell
 276                 -- splice we have the right environment for the renamer.
 277                 --
 278                 --   Does *not* include global name envt; may shadow it
 279                 --   Includes both ordinary variables and type variables;
 280                 --   they are kept distinct because tyvar have a different
 281                 --   occurrence contructor (Name.TvOcc)
 282                 -- We still need the unsullied global name env so that
 283                 --   we can look up record field names
 284
 285         tcl_env  :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 286                                         -- defined in this module
 287
 288         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 289                         -- Namely, the in-scope TyVars bound in tcl_env,
 290                         -- plus the tyvars mentioned in the types of Ids bound in tcl_lenv
 291                         -- Why mutable? see notes with tcGetGlobalTyVars
 292
 293         tcl_lie   :: TcRef LIE,         -- Place to accumulate type constraints
 294         tcl_gadt  :: GadtRefinement     -- The current type refinement for GADTs
 295
 296 -----------------------------------------------------------
 297 -- Not yet; it's a new complication and I want to see whether it bites
 298 --      tcl_given :: [Inst]             -- Insts available in the current context (see Note [Given Insts])
 299 -----------------------------------------------------------
 300     }
 301
 302 type GadtRefinement = TvSubstEnv        -- Binds rigid type variables to their refinements
 303
 304 {- Note [Given Insts]
 305    ~~~~~~~~~~~~~~~~~~
 306 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 307 and existential contexts. Consider
 308         data T a where { T1 :: b -> b -> T [b] }
 309         f :: Eq a => T a -> Bool
 310         f (T1 x y) = [x]==[y]
 311
 312 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 313 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 314 pass it inwards.
 315
 316 -}
 317
 318 ---------------------------
 319 -- Template Haskell levels
 320 ---------------------------
 321
 322 type ThLevel = Int
 323         -- Indicates how many levels of brackets we are inside
 324         --      (always >= 0)
 325         -- Incremented when going inside a bracket,
 326         -- decremented when going inside a splice
 327
 328 impLevel, topLevel :: ThLevel
 329 topLevel = 1    -- Things defined at top level of this module
 330 impLevel = 0    -- Imported things; they can be used inside a top level splice
 331 --
 332 -- For example:
 333 --      f = ...
 334 --      g1 = $(map ...)         is OK
 335 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 336
 337
 338 data ThStage
 339   = Comp                                -- Ordinary compiling, at level topLevel
 340   | Splice ThLevel                      -- Inside a splice
 341   | Brack  ThLevel                      -- Inside brackets;
 342            (TcRef [PendingSplice])      --   accumulate pending splices here
 343            (TcRef LIE)                  --   and type constraints here
 344 topStage, topSpliceStage :: ThStage
 345 topStage       = Comp
 346 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 347
 348
 349 ---------------------------
 350 -- Arrow-notation stages
 351 ---------------------------
 352
 353 -- In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 354 -- is not in scope to the left of an arrow tail (-<).  For example
 355 --
 356 --      proc x -> (e1 -< e2)
 357 --
 358 -- Here, x is not in scope in e1, but it is in scope in e2.  This can get
 359 -- a bit complicated:
 360 --
 361 --      let x = 3 in
 362 --      prox y -> (proc z -> e1) -< e2
 363 --
 364 -- Here, x and z are in scope in e1, but y is not.  Here's how we track this:
 365 --      a) Assign an "proc level" to each proc, being the number of
 366 --         lexically-enclosing procs + 1.
 367 --      b) Assign to each local variable the proc-level of its lexically
 368 --         enclosing proc.
 369 --      c) Keep a list of out-of-scope procs.  When moving to the left of
 370 --         an arrow-tail, add the proc-level of the immediately enclosing
 371 --         proc to the list.
 372 --      d) When looking up a variable, complain if its proc-level is in
 373 --         the banned list
 374
 375 type ProcLevel = Int    -- Always >= 0
 376 topProcLevel = 0        -- Not inside any proc
 377
 378 data ArrowCtxt = ArrCtxt { proc_level :: ProcLevel,     -- Current level
 379                            proc_banned :: [ProcLevel] } -- Out of scope proc-levels
 380
 381 topArrowCtxt = ArrCtxt { proc_level = topProcLevel, proc_banned = [] }
 382
 383 ---------------------------
 384 -- TcTyThing
 385 ---------------------------
 386
 387 data TcTyThing
 388   = AGlobal TyThing                     -- Used only in the return type of a lookup
 389   | ATcId   TcId ThLevel ProcLevel      -- Ids defined in this module; may not be fully zonked
 390   | ATyVar  TyVar                       -- Type variables
 391   | AThing  TcKind                      -- Used temporarily, during kind checking, for the
 392                                         --      tycons and clases in this recursive group
 393
 394 instance Outputable TcTyThing where     -- Debugging only
 395    ppr (AGlobal g)      = text "AGlobal" <+> ppr g
 396    ppr (ATcId g tl pl)  = text "ATcId" <+> ppr g <+> ppr tl <+> ppr pl
 397    ppr (ATyVar t)       = text "ATyVar" <+> ppr t
 398    ppr (AThing k)       = text "AThing" <+> ppr k
 399 \end{code}
 400
 401 \begin{code}
 402 type ErrCtxt = [TidyEnv -> TcM (TidyEnv, Message)]
 403                         -- Innermost first.  Monadic so that we have a chance
 404                         -- to deal with bound type variables just before error
 405                         -- message construction
 406 \end{code}
 407
 408
 409 %************************************************************************
 410 %*                                                                      *
 411         Operations over ImportAvails
 412 %*                                                                      *
 413 %************************************************************************
 414
 415 ImportAvails summarises what was imported from where, irrespective
 416 of whether the imported things are actually used or not
 417 It is used      * when processing the export list
 418                 * when constructing usage info for the inteface file
 419                 * to identify the list of directly imported modules
 420                         for initialisation purposes
 421                 * when figuring out what things are really unused
 422
 423 \begin{code}
 424 data ImportAvails
 425    = ImportAvails {
 426         imp_env :: ModuleEnv NameSet,
 427                 -- All the things imported, classified by
 428                 -- the *module qualifier* for its import
 429                 --   e.g.        import List as Foo
 430                 -- would add a binding Foo |-> ...stuff from List...
 431                 -- to imp_env.
 432                 --
 433                 -- We need to classify them like this so that we can figure out
 434                 -- "module M" export specifiers in an export list
 435                 -- (see 1.4 Report Section 5.1.1).  Ultimately, we want to find
 436                 -- everything that is unambiguously in scope as 'M.x'
 437                 -- and where plain 'x' is (perhaps ambiguously) in scope.
 438                 -- So the starting point is all things that are in scope as 'M.x',
 439                 -- which is what this field tells us.
 440
 441         imp_mods :: ModuleEnv (Module, Maybe Bool, SrcSpan),
 442                 -- Domain is all directly-imported modules
 443                 -- Maybe value answers the question "is the import restricted?"
 444                 --   Nothing    => unrestricted import (e.g., "import Foo")
 445                 --   Just True  => restricted import, at least one entity (e.g., "import Foo(x)")
 446                 --   Just False => fully restricted import (e.g., "import Foo ()")
 447                 --
 448                 --  A distinction is made between the first and the third in order
 449                 --  to more precisely emit warnings about unused imports.
 450                 --
 451                 -- We need the Module in the range because we can't get
 452                 --      the keys of a ModuleEnv
 453                 -- Used
 454                 --   (a) to help construct the usage information in
 455                 --       the interface file; if we import everything we
 456                 --       need to recompile if the module version changes
 457                 --   (b) to specify what child modules to initialise
 458
 459         imp_dep_mods :: ModuleEnv (Module, IsBootInterface),
 460                 -- Home-package modules needed by the module being compiled
 461                 --
 462                 -- It doesn't matter whether any of these dependencies
 463                 -- are actually *used* when compiling the module; they
 464                 -- are listed if they are below it at all.  For
 465                 -- example, suppose M imports A which imports X.  Then
 466                 -- compiling M might not need to consult X.hi, but X
 467                 -- is still listed in M's dependencies.
 468
 469         imp_dep_pkgs :: [PackageId],
 470                 -- Packages needed by the module being compiled, whether
 471                 -- directly, or via other modules in this package, or via
 472                 -- modules imported from other packages.
 473
 474         imp_orphs :: [Module]
 475                 -- Orphan modules below us in the import tree
 476       }
 477
 478 mkModDeps :: [(Module, IsBootInterface)]
 479           -> ModuleEnv (Module, IsBootInterface)
 480 mkModDeps deps = foldl add emptyModuleEnv deps
 481                where
 482                  add env elt@(m,_) = extendModuleEnv env m elt
 483
 484 emptyImportAvails :: ImportAvails
 485 emptyImportAvails = ImportAvails { imp_env      = emptyModuleEnv,
 486                                    imp_mods     = emptyModuleEnv,
 487                                    imp_dep_mods = emptyModuleEnv,
 488                                    imp_dep_pkgs = [],
 489                                    imp_orphs    = [] }
 490
 491 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 492 plusImportAvails
 493   (ImportAvails { imp_env = env1, imp_mods = mods1,
 494                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1, imp_orphs = orphs1 })
 495   (ImportAvails { imp_env = env2, imp_mods = mods2,
 496                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2, imp_orphs = orphs2 })
 497   = ImportAvails { imp_env      = plusModuleEnv_C unionNameSets env1 env2,
 498                    imp_mods     = mods1  `plusModuleEnv` mods2,
 499                    imp_dep_mods = plusModuleEnv_C plus_mod_dep dmods1 dmods2,
 500                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 501                    imp_orphs    = orphs1 `unionLists` orphs2 }
 502   where
 503     plus_mod_dep (m1, boot1) (m2, boot2)
 504         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 505                 -- Check mod-names match
 506           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 507 \end{code}
 508
 509 %************************************************************************
 510 %*                                                                      *
 511         Avails, AvailEnv, etc
 512 %*                                                                      *
 513 v%************************************************************************
 514
 515 \begin{code}
 516 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 517 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (ns1 `unionLists` ns2)
 518 -- Added SOF 4/97
 519 #ifdef DEBUG
 520 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 521 #endif
 522
 523 -------------------------
 524 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 525             -> [AvailInfo]
 526             -> [AvailInfo]
 527 pruneAvails keep avails
 528   = mapMaybe del avails
 529   where
 530     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 531     del (Avail n) | keep n    = Just (Avail n)
 532                   | otherwise = Nothing
 533     del (AvailTC n ns) | null ns'  = Nothing
 534                        | otherwise = Just (AvailTC n ns')
 535                        where
 536                          ns' = filter keep ns
 537 \end{code}
 538
 539 ---------------------------------------
 540         AvailEnv and friends
 541 ---------------------------------------
 542
 543 \begin{code}
 544 type AvailEnv = NameEnv AvailInfo       -- Maps a Name to the AvailInfo that contains it
 545
 546 emptyAvailEnv :: AvailEnv
 547 emptyAvailEnv = emptyNameEnv
 548
 549 unitAvailEnv :: AvailInfo -> AvailEnv
 550 unitAvailEnv a = unitNameEnv (availName a) a
 551
 552 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 553 plusAvailEnv = plusNameEnv_C plusAvail
 554
 555 lookupAvailEnv_maybe :: AvailEnv -> Name -> Maybe AvailInfo
 556 lookupAvailEnv_maybe = lookupNameEnv
 557
 558 lookupAvailEnv :: AvailEnv -> Name -> AvailInfo
 559 lookupAvailEnv env n = case lookupNameEnv env n of
 560                          Just avail -> avail
 561                          Nothing    -> pprPanic "lookupAvailEnv" (ppr n)
 562
 563 availEnvElts = nameEnvElts
 564
 565 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 566 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 567
 568 mkAvailEnv :: [AvailInfo] -> AvailEnv
 569         -- 'avails' may have several items with the same availName
 570         -- E.g  import Ix( Ix(..), index )
 571         -- will give Ix(Ix,index,range) and Ix(index)
 572         -- We want to combine these; addAvail does that
 573 mkAvailEnv avails = foldl addAvail emptyAvailEnv avails
 574 \end{code}
 575
 576 %************************************************************************
 577 %*                                                                      *
 578 \subsection{Where from}
 579 %*                                                                      *
 580 %************************************************************************
 581
 582 The @WhereFrom@ type controls where the renamer looks for an interface file
 583
 584 \begin{code}
 585 data WhereFrom
 586   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 587   | ImportBySystem                      -- Non user import.
 588
 589 instance Outputable WhereFrom where
 590   ppr (ImportByUser is_boot) | is_boot     = ptext SLIT("{- SOURCE -}")
 591                              | otherwise   = empty
 592   ppr ImportBySystem                       = ptext SLIT("{- SYSTEM -}")
 593 \end{code}
 594
 595
 596 %************************************************************************
 597 %*                                                                      *
 598 \subsection[Inst-types]{@Inst@ types}
 599 %*                                                                      *
 600 v%************************************************************************
 601
 602 An @Inst@ is either a dictionary, an instance of an overloaded
 603 literal, or an instance of an overloaded value.  We call the latter a
 604 ``method'' even though it may not correspond to a class operation.
 605 For example, we might have an instance of the @double@ function at
 606 type Int, represented by
 607
 608         Method 34 doubleId [Int] origin
 609
 610 \begin{code}
 611 data Inst
 612   = Dict
 613         Name
 614         TcPredType
 615         InstLoc
 616
 617   | Method
 618         Id
 619
 620         TcId    -- The overloaded function
 621                         -- This function will be a global, local, or ClassOpId;
 622                         --   inside instance decls (only) it can also be an InstId!
 623                         -- The id needn't be completely polymorphic.
 624                         -- You'll probably find its name (for documentation purposes)
 625                         --        inside the InstOrigin
 626
 627         [TcType]        -- The types to which its polymorphic tyvars
 628                         --      should be instantiated.
 629                         -- These types must saturate the Id's foralls.
 630
 631         TcThetaType     -- The (types of the) dictionaries to which the function
 632                         -- must be applied to get the method
 633
 634         TcTauType       -- The tau-type of the method
 635
 636         InstLoc
 637
 638         -- INVARIANT 1: in (Method u f tys theta tau loc)
 639         --      type of (f tys dicts(from theta)) = tau
 640
 641         -- INVARIANT 2: tau must not be of form (Pred -> Tau)
 642         --   Reason: two methods are considered equal if the
 643         --           base Id matches, and the instantiating types
 644         --           match.  The TcThetaType should then match too.
 645         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 646
 647   | LitInst
 648         Name
 649         HsOverLit       -- The literal from the occurrence site
 650                         --      INVARIANT: never a rebindable-syntax literal
 651                         --      Reason: tcSyntaxName does unification, and we
 652                         --              don't want to deal with that during tcSimplify
 653         TcType          -- The type at which the literal is used
 654         InstLoc
 655 \end{code}
 656
 657 @Insts@ are ordered by their class/type info, rather than by their
 658 unique.  This allows the context-reduction mechanism to use standard finite
 659 maps to do their stuff.
 660
 661 \begin{code}
 662 instance Ord Inst where
 663   compare = cmpInst
 664
 665 instance Eq Inst where
 666   (==) i1 i2 = case i1 `cmpInst` i2 of
 667                  EQ    -> True
 668                  other -> False
 669
 670 cmpInst (Dict _ pred1 _)          (Dict _ pred2 _)          = pred1 `tcCmpPred` pred2
 671 cmpInst (Dict _ _ _)              other                     = LT
 672
 673 cmpInst (Method _ _ _ _ _ _)      (Dict _ _ _)              = GT
 674 cmpInst (Method _ id1 tys1 _ _ _) (Method _ id2 tys2 _ _ _) = (id1 `compare` id2) `thenCmp` (tys1 `tcCmpTypes` tys2)
 675 cmpInst (Method _ _ _ _ _ _)      other                     = LT
 676
 677 cmpInst (LitInst _ _ _ _)         (Dict _ _ _)              = GT
 678 cmpInst (LitInst _ _ _ _)         (Method _ _ _ _ _ _)      = GT
 679 cmpInst (LitInst _ lit1 ty1 _)    (LitInst _ lit2 ty2 _)    = (lit1 `compare` lit2) `thenCmp` (ty1 `tcCmpType` ty2)
 680 \end{code}
 681
 682
 683 %************************************************************************
 684 %*                                                                      *
 685 \subsection[Inst-collections]{LIE: a collection of Insts}
 686 %*                                                                      *
 687 %************************************************************************
 688
 689 \begin{code}
 690 type LIE = Bag Inst
 691
 692 isEmptyLIE        = isEmptyBag
 693 emptyLIE          = emptyBag
 694 unitLIE inst      = unitBag inst
 695 mkLIE insts       = listToBag insts
 696 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 697 consLIE inst lie  = inst `consBag` lie
 698 plusLIEs lies     = unionManyBags lies
 699 lieToList         = bagToList
 700 listToLIE         = listToBag
 701 \end{code}
 702
 703
 704 %************************************************************************
 705 %*                                                                      *
 706 \subsection[Inst-origin]{The @InstOrigin@ type}
 707 %*                                                                      *
 708 %************************************************************************
 709
 710 The @InstOrigin@ type gives information about where a dictionary came from.
 711 This is important for decent error message reporting because dictionaries
 712 don't appear in the original source code.  Doubtless this type will evolve...
 713
 714 It appears in TcMonad because there are a couple of error-message-generation
 715 functions that deal with it.
 716
 717 \begin{code}
 718 data InstLoc = InstLoc InstOrigin SrcSpan ErrCtxt
 719
 720 instLocSrcLoc :: InstLoc -> SrcLoc
 721 instLocSrcLoc (InstLoc _ src_span _) = srcSpanStart src_span
 722
 723 instLocSrcSpan :: InstLoc -> SrcSpan
 724 instLocSrcSpan (InstLoc _ src_span _) = src_span
 725
 726 data InstOrigin
 727   = SigOrigin SkolemInfo        -- Pattern, class decl, inst decl etc;
 728                                 -- Places that bind type variables and introduce
 729                                 -- available constraints
 730
 731   | IPBindOrigin (IPName Name)  -- Binding site of an implicit parameter
 732
 733         -------------------------------------------------------
 734         -- The rest are all occurrences: Insts that are 'wanted'
 735         -------------------------------------------------------
 736   | OccurrenceOf Name           -- Occurrence of an overloaded identifier
 737
 738   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 739
 740   | LiteralOrigin HsOverLit     -- Occurrence of a literal
 741
 742   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 743   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 744
 745   | InstSigOrigin       -- A dict occurrence arising from instantiating
 746                         -- a polymorphic type during a subsumption check
 747
 748   | RecordUpdOrigin
 749   | InstScOrigin        -- Typechecking superclasses of an instance declaration
 750   | DerivOrigin         -- Typechecking deriving
 751   | DefaultOrigin       -- Typechecking a default decl
 752   | DoOrigin            -- Arising from a do expression
 753   | ProcOrigin          -- Arising from a proc expression
 754 \end{code}
 755
 756 \begin{code}
 757 pprInstLoc :: InstLoc -> SDoc
 758 pprInstLoc (InstLoc (SigOrigin info) locn _)
 759   = text "arising from" <+> ppr info    -- I don't think this happens much, if at all
 760 pprInstLoc (InstLoc orig locn _)
 761   = hsep [text "arising from", pp_orig orig, text "at", ppr locn]
 762   where
 763     pp_orig (OccurrenceOf name)  = hsep [ptext SLIT("use of"), quotes (ppr name)]
 764     pp_orig (IPOccOrigin name)   = hsep [ptext SLIT("use of implicit parameter"), quotes (ppr name)]
 765     pp_orig (IPBindOrigin name)  = hsep [ptext SLIT("binding for implicit parameter"), quotes (ppr name)]
 766     pp_orig RecordUpdOrigin      = ptext SLIT("a record update")
 767     pp_orig (LiteralOrigin lit)  = hsep [ptext SLIT("the literal"), quotes (ppr lit)]
 768     pp_orig (ArithSeqOrigin seq) = hsep [ptext SLIT("the arithmetic sequence"), quotes (ppr seq)]
 769     pp_orig (PArrSeqOrigin seq)  = hsep [ptext SLIT("the parallel array sequence"), quotes (ppr seq)]
 770     pp_orig InstSigOrigin        =  ptext SLIT("instantiating a type signature")
 771     pp_orig InstScOrigin         =  ptext SLIT("the superclasses of an instance declaration")
 772     pp_orig DerivOrigin          = ptext SLIT("the 'deriving' clause of a data type declaration")
 773     pp_orig DefaultOrigin        = ptext SLIT("a 'default' declaration")
 774     pp_orig DoOrigin             =  ptext SLIT("a do statement")
 775     pp_orig ProcOrigin           =  ptext SLIT("a proc expression")
 776     pp_orig (SigOrigin info)     = ppr info
 777 \end{code}