ghc/compiler/typecheck/TcRnTypes.lhs

   1 %
   2 % (c) The GRASP Project, Glasgow University, 1992-2002
   3 %
   4 \begin{code}
   5 module TcRnTypes(
   6         TcRn, TcM, RnM, -- The monad is opaque outside this module
   7
   8         -- Standard monadic operations
   9         thenM, thenM_, returnM, failM,
  10
  11         -- Non-standard operations
  12         runTcRn, fixM, tryM, ioToTcRn,
  13         newMutVar, readMutVar, writeMutVar,
  14         getEnv, setEnv, updEnv, unsafeInterleaveM,
  15
  16         -- The environment types
  17         Env(..), TopEnv(..), TcGblEnv(..),
  18         TcLclEnv(..), RnLclEnv(..),
  19
  20         -- Ranamer types
  21         RnMode(..), isInterfaceMode, isCmdLineMode,
  22         EntityUsage, emptyUsages, ErrCtxt,
  23         ImportAvails(..), emptyImportAvails, plusImportAvails,
  24         plusAvail, pruneAvails,
  25         AvailEnv, emptyAvailEnv, unitAvailEnv, plusAvailEnv,
  26         mkAvailEnv, lookupAvailEnv, availEnvElts, addAvail,
  27         WhereFrom(..),
  28
  29         -- Typechecker types
  30         TcTyThing(..),
  31
  32         -- Template Haskell
  33         Stage(..), topStage, topSpliceStage,
  34         Level, impLevel, topLevel,
  35
  36         -- Insts
  37         Inst(..), InstOrigin(..), InstLoc(..), pprInstLoc, instLocSrcLoc,
  38         LIE, emptyLIE, unitLIE, plusLIE, consLIE,
  39         plusLIEs, mkLIE, isEmptyLIE, lieToList, listToLIE,
  40
  41         -- Misc other types
  42         TcRef, TcId, TcIdSet
  43   ) where
  44
  45 #include "HsVersions.h"
  46
  47 import HsSyn            ( PendingSplice, HsOverLit, MonoBinds, RuleDecl, ForeignDecl )
  48 import RnHsSyn          ( RenamedHsExpr, RenamedPat, RenamedArithSeqInfo )
  49 import HscTypes         ( GhciMode, ExternalPackageState, HomePackageTable, NameCache,
  50                           GlobalRdrEnv, LocalRdrEnv, FixityEnv, TypeEnv, TyThing,
  51                           Avails, GenAvailInfo(..), AvailInfo, availName,
  52                           IsBootInterface, Deprecations )
  53 import Packages         ( PackageName )
  54 import TcType           ( TcTyVarSet, TcType, TcTauType, TcThetaType, TcPredType, TcKind,
  55                           tcCmpPred, tcCmpType, tcCmpTypes )
  56 import InstEnv          ( DFunId, InstEnv )
  57 import Name             ( Name )
  58 import NameEnv
  59 import NameSet          ( NameSet, emptyNameSet )
  60 import Type             ( Type )
  61 import Class            ( Class )
  62 import Var              ( Id, TyVar )
  63 import VarEnv           ( TidyEnv )
  64 import Module
  65 import SrcLoc           ( SrcLoc )
  66 import VarSet           ( IdSet )
  67 import ErrUtils         ( Messages, Message )
  68 import CmdLineOpts      ( DynFlags )
  69 import UniqSupply       ( UniqSupply )
  70 import BasicTypes       ( IPName )
  71 import Util             ( thenCmp )
  72 import Bag
  73 import Outputable
  74 import DATA_IOREF       ( IORef, newIORef, readIORef, writeIORef )
  75 import UNSAFE_IO        ( unsafeInterleaveIO )
  76 import FIX_IO           ( fixIO )
  77 import EXCEPTION        ( Exception )
  78 import Maybe            ( mapMaybe )
  79 import ListSetOps       ( unionLists )
  80 import Panic            ( tryMost )
  81 \end{code}
  82
  83
  84 \begin{code}
  85 type TcRef a = IORef a
  86 type TcId    = Id                       -- Type may be a TcType
  87 type TcIdSet = IdSet
  88 \end{code}
  89
  90 %************************************************************************
  91 %*                                                                      *
  92                Standard monad definition for TcRn
  93     All the combinators for the monad can be found in TcRnMonad
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 The monad itself has to be defined here,
  98 because it is mentioned by ErrCtxt
  99
 100 \begin{code}
 101 newtype TcRn m a = TcRn (Env m -> IO a)
 102 unTcRn (TcRn f) = f
 103
 104 type TcM a = TcRn TcLclEnv a
 105 type RnM a = TcRn RnLclEnv a
 106
 107 returnM :: a -> TcRn m a
 108 returnM a = TcRn (\ env -> return a)
 109
 110 thenM :: TcRn m a -> (a -> TcRn m b) -> TcRn m b
 111 thenM (TcRn m) f = TcRn (\ env -> do { r <- m env ;
 112                                        unTcRn (f r) env })
 113
 114 thenM_ :: TcRn m a -> TcRn m b -> TcRn m b
 115 thenM_ (TcRn m) f = TcRn (\ env -> do { m env ; unTcRn f env })
 116
 117 failM :: TcRn m a
 118 failM = TcRn (\ env -> ioError (userError "TcRn failure"))
 119
 120 instance Monad (TcRn m) where
 121   (>>=)  = thenM
 122   (>>)   = thenM_
 123   return = returnM
 124   fail s = failM        -- Ignore the string
 125 \end{code}
 126
 127
 128 %************************************************************************
 129 %*                                                                      *
 130         Fundmantal combinators specific to the monad
 131 %*                                                                      *
 132 %************************************************************************
 133
 134 Running it
 135
 136 \begin{code}
 137 runTcRn :: Env m -> TcRn m a -> IO a
 138 runTcRn env (TcRn m) = m env
 139 \end{code}
 140
 141 The fixpoint combinator
 142
 143 \begin{code}
 144 {-# NOINLINE fixM #-}
 145   -- Aargh!  Not inlining fixTc alleviates a space leak problem.
 146   -- Normally fixTc is used with a lazy tuple match: if the optimiser is
 147   -- shown the definition of fixTc, it occasionally transforms the code
 148   -- in such a way that the code generator doesn't spot the selector
 149   -- thunks.  Sigh.
 150
 151 fixM :: (a -> TcRn m a) -> TcRn m a
 152 fixM f = TcRn (\ env -> fixIO (\ r -> unTcRn (f r) env))
 153 \end{code}
 154
 155 Error recovery
 156
 157 \begin{code}
 158 tryM :: TcRn m r -> TcRn m (Either Exception r)
 159 -- Reflect exception into TcRn monad
 160 tryM (TcRn thing) = TcRn (\ env -> tryMost (thing env))
 161 \end{code}
 162
 163 Lazy interleave
 164
 165 \begin{code}
 166 unsafeInterleaveM :: TcRn m a -> TcRn m a
 167 unsafeInterleaveM (TcRn m) = TcRn (\ env -> unsafeInterleaveIO (m env))
 168 \end{code}
 169
 170 \end{code}
 171
 172 Performing arbitrary I/O, plus the read/write var (for efficiency)
 173
 174 \begin{code}
 175 ioToTcRn :: IO a -> TcRn m a
 176 ioToTcRn io = TcRn (\ env -> io)
 177
 178 newMutVar :: a -> TcRn m (TcRef a)
 179 newMutVar val = TcRn (\ env -> newIORef val)
 180
 181 writeMutVar :: TcRef a -> a -> TcRn m ()
 182 writeMutVar var val = TcRn (\ env -> writeIORef var val)
 183
 184 readMutVar :: TcRef a -> TcRn m a
 185 readMutVar var = TcRn (\ env -> readIORef var)
 186 \end{code}
 187
 188 Getting the environment
 189
 190 \begin{code}
 191 getEnv :: TcRn m (Env m)
 192 {-# INLINE getEnv #-}
 193 getEnv = TcRn (\ env -> return env)
 194
 195 setEnv :: Env n -> TcRn n a -> TcRn m a
 196 {-# INLINE setEnv #-}
 197 setEnv new_env (TcRn m) = TcRn (\ env -> m new_env)
 198
 199 updEnv :: (Env m -> Env n) -> TcRn n a -> TcRn m a
 200 {-# INLINE updEnv #-}
 201 updEnv upd (TcRn m) = TcRn (\ env -> m (upd env))
 202 \end{code}
 203
 204
 205 %************************************************************************
 206 %*                                                                      *
 207                 The main environment types
 208 %*                                                                      *
 209 %************************************************************************
 210
 211 \begin{code}
 212 data Env a      -- Changes as we move into an expression
 213   = Env {
 214         env_top  :: TopEnv,     -- Top-level stuff that never changes
 215                                 --   Mainly a bunch of updatable refs
 216                                 --   Includes all info about imported things
 217         env_gbl  :: TcGblEnv,   -- Info about things defined at the top leve
 218                                 --   of the module being compiled
 219
 220         env_lcl  :: a,          -- Different for the type checker
 221                                 -- and the renamer
 222
 223         env_loc  :: SrcLoc      -- Source location
 224     }
 225
 226 data TopEnv     -- Built once at top level then does not change
 227                 -- Concerns imported stuff
 228                 -- Exceptions: error recovery points, meta computation points
 229    = TopEnv {
 230         top_mode    :: GhciMode,
 231         top_dflags  :: DynFlags,
 232
 233         -- Stuff about imports
 234         top_eps    :: TcRef ExternalPackageState,
 235                 -- PIT, ImportedModuleInfo
 236                 -- DeclsMap, IfaceRules, IfaceInsts, InstGates
 237                 -- TypeEnv, InstEnv, RuleBase
 238                 -- Mutable, because we demand-load declarations that extend the state
 239
 240         top_hpt  :: HomePackageTable,
 241                 -- The home package table that we've accumulated while
 242                 -- compiling the home package,
 243                 -- *excluding* the module we are compiling right now.
 244                 -- (In one-shot mode the current module is the only
 245                 --  home-package module, so tc_hpt is empty.  All other
 246                 --  modules count as "external-package" modules.)
 247                 -- tc_hpt is not mutable because we only demand-load
 248                 -- external packages; the home package is eagerly
 249                 -- loaded by the compilation manager.
 250
 251         -- The global name supply
 252         top_nc     :: TcRef NameCache,          -- Maps original names to Names
 253         top_us     :: TcRef UniqSupply,         -- Unique supply for this module
 254         top_errs   :: TcRef Messages
 255    }
 256
 257 -- TcGblEnv describes the top-level of the module at the
 258 -- point at which the typechecker is finished work.
 259 -- It is this structure that is handed on to the desugarer
 260
 261 data TcGblEnv
 262   = TcGblEnv {
 263         tcg_mod    :: Module,           -- Module being compiled
 264         tcg_usages :: TcRef EntityUsage,  -- What version of what entities
 265                                           -- have been used from other home-pkg modules
 266         tcg_rdr_env :: GlobalRdrEnv,    -- Top level envt; used during renaming
 267         tcg_fix_env :: FixityEnv,       -- Ditto
 268         tcg_default :: [Type],          -- Types used for defaulting
 269
 270         tcg_type_env :: TypeEnv,        -- Global type env for the module we are compiling now
 271                 -- All TyCons and Classes (for this module) end up in here right away,
 272                 -- along with their derived constructors, selectors.
 273                 --
 274                 -- (Ids defined in this module start in the local envt,
 275                 --  though they move to the global envt during zonking)
 276
 277         tcg_inst_env :: TcRef InstEnv,  -- Global instance env: a combination of
 278                                         --      tc_pcs, tc_hpt, *and* tc_insts
 279                 -- This field is mutable so that it can be updated inside a
 280                 -- Template Haskell splice, which might suck in some new
 281                 -- instance declarations.  This is a slightly differen strategy
 282                 -- than for the type envt, where we look up first in tcg_type_env
 283                 -- and then in the mutable EPS, because the InstEnv for this module
 284                 -- is constructed (in principle at least) only from the modules
 285                 -- 'below' this one, so it's this-module-specific
 286
 287                 -- Now a bunch of things about this module that are simply
 288                 -- accumulated, but never consulted until the end.
 289                 -- Nevertheless, it's convenient to accumulate them along
 290                 -- with the rest of the info from this module.
 291         tcg_exports :: Avails,                  -- What is exported
 292         tcg_imports :: ImportAvails,            -- Information about what was imported
 293                                                 --    from where, including things bound
 294                                                 --    in this module
 295                 -- The next fields are always fully zonked
 296         tcg_binds   :: MonoBinds Id,            -- Value bindings in this module
 297         tcg_deprecs :: Deprecations,            -- ...Deprecations
 298         tcg_insts   :: [DFunId],                -- ...Instances
 299         tcg_rules   :: [RuleDecl Id],           -- ...Rules
 300         tcg_fords   :: [ForeignDecl Id]         -- ...Foreign import & exports
 301     }
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307                 The local typechecker environment
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 The Global-Env/Local-Env story
 312 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 313 During type checking, we keep in the tcg_type_env
 314         * All types and classes
 315         * All Ids derived from types and classes (constructors, selectors)
 316
 317 At the end of type checking, we zonk the local bindings,
 318 and as we do so we add to the tcg_type_env
 319         * Locally defined top-level Ids
 320
 321 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 322         a) fed back (via the knot) to typechecking the
 323            unfoldings of interface signatures
 324         b) used in the ModDetails of this module
 325
 326 \begin{code}
 327 data TcLclEnv
 328   = TcLclEnv {
 329         tcl_ctxt :: ErrCtxt,    -- Error context
 330
 331         tcl_level  :: Stage,            -- Template Haskell context
 332
 333         tcl_env    :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 334                                           -- defined in this module
 335
 336         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 337                                         -- Namely, the in-scope TyVars bound in tcl_lenv,
 338                                         -- plus the tyvars mentioned in the types of
 339                                         -- Ids bound in tcl_lenv
 340                                         -- Why mutable? see notes with tcGetGlobalTyVars
 341
 342         tcl_lie :: TcRef LIE            -- Place to accumulate type constraints
 343     }
 344
 345 type Level = Int
 346
 347 data Stage
 348   = Comp                                -- Ordinary compiling, at level topLevel
 349   | Splice Level                        -- Inside a splice
 350   | Brack  Level                        -- Inside brackets;
 351            (TcRef [PendingSplice])      --   accumulate pending splices here
 352            (TcRef LIE)                  --   and type constraints here
 353 topStage, topSpliceStage :: Stage
 354 topStage       = Comp
 355 topSpliceStage = Splice (topLevel - 1)  -- Stage for the body of a top-level splice
 356
 357
 358 impLevel, topLevel :: Level
 359 topLevel = 1    -- Things defined at top level of this module
 360 impLevel = 0    -- Imported things; they can be used inside a top level splice
 361 --
 362 -- For example:
 363 --      f = ...
 364 --      g1 = $(map ...)         is OK
 365 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 366
 367 data TcTyThing
 368   = AGlobal TyThing             -- Used only in the return type of a lookup
 369   | ATcId   TcId Level          -- Ids defined in this module; may not be fully zonked
 370   | ATyVar  TyVar               -- Type variables
 371   | AThing  TcKind              -- Used temporarily, during kind checking
 372 -- Here's an example of how the AThing guy is used
 373 -- Suppose we are checking (forall a. T a Int):
 374 --      1. We first bind (a -> AThink kv), where kv is a kind variable.
 375 --      2. Then we kind-check the (T a Int) part.
 376 --      3. Then we zonk the kind variable.
 377 --      4. Now we know the kind for 'a', and we add (a -> ATyVar a::K) to the environment
 378
 379 instance Outputable TcTyThing where     -- Debugging only
 380    ppr (AGlobal g) = text "AGlobal" <+> ppr g
 381    ppr (ATcId g l) = text "ATcId" <+> ppr g <+> ppr l
 382    ppr (ATyVar t)  = text "ATyVar" <+> ppr t
 383    ppr (AThing k)  = text "AThing" <+> ppr k
 384 \end{code}
 385
 386 \begin{code}
 387 type ErrCtxt = [TidyEnv -> TcM (TidyEnv, Message)]
 388                         -- Innermost first.  Monadic so that we have a chance
 389                         -- to deal with bound type variables just before error
 390                         -- message construction
 391 \end{code}
 392
 393
 394 %************************************************************************
 395 %*                                                                      *
 396                 The local renamer environment
 397 %*                                                                      *
 398 %************************************************************************
 399
 400 \begin{code}
 401 data RnLclEnv
 402   = RnLclEnv {
 403         rn_mode :: RnMode,
 404         rn_lenv :: LocalRdrEnv          -- Local name envt
 405                 --   Does *not* include global name envt; may shadow it
 406                 --   Includes both ordinary variables and type variables;
 407                 --   they are kept distinct because tyvar have a different
 408                 --   occurrence contructor (Name.TvOcc)
 409                 -- We still need the unsullied global name env so that
 410                 --   we can look up record field names
 411      }
 412
 413 data RnMode = SourceMode                -- Renaming source code
 414             | InterfaceMode Module      -- Renaming interface declarations from M
 415             | CmdLineMode               -- Renaming a command-line expression
 416
 417 isInterfaceMode (InterfaceMode _) = True
 418 isInterfaceMode _                 = False
 419
 420 isCmdLineMode CmdLineMode = True
 421 isCmdLineMode _ = False
 422 \end{code}
 423
 424
 425 %************************************************************************
 426 %*                                                                      *
 427                         EntityUsage
 428 %*                                                                      *
 429 %************************************************************************
 430
 431 EntityUsage tells what things are actually need in order to compile this
 432 module.  It is used for generating the usage-version field of the ModIface.
 433
 434 Note that we do not record version info for entities from
 435 other (non-home) packages.  If the package changes, GHC doesn't help.
 436
 437 \begin{code}
 438 type EntityUsage = NameSet
 439         -- The Names are all the (a) home-package
 440         --                       (b) "big" (i.e. no data cons, class ops)
 441         --                       (c) non-locally-defined
 442         --                       (d) non-wired-in
 443         -- names that have been slurped in so far.
 444         -- This is used to generate the "usage" information for this module.
 445
 446 emptyUsages :: EntityUsage
 447 emptyUsages = emptyNameSet
 448 \end{code}
 449
 450
 451 %************************************************************************
 452 %*                                                                      *
 453         Operations over ImportAvails
 454 %*                                                                      *
 455 %************************************************************************
 456
 457 ImportAvails summarises what was imported from where, irrespective
 458 of whether the imported htings are actually used or not
 459 It is used      * when porcessing the export list
 460                 * when constructing usage info for the inteface file
 461                 * to identify the list of directly imported modules
 462                         for initialisation purposes
 463
 464 \begin{code}
 465 data ImportAvails
 466    = ImportAvails {
 467         imp_env :: AvailEnv,
 468                 -- All the things that are available from the import
 469                 -- Its domain is all the "main" things;
 470                 -- i.e. *excluding* class ops and constructors
 471                 --      (which appear inside their parent AvailTC)
 472
 473         imp_qual :: ModuleEnv AvailEnv,
 474                 -- Used to figure out "module M" export specifiers
 475                 -- (see 1.4 Report Section 5.1.1).  Ultimately, we want to find
 476                 -- everything that is unambiguously in scope as 'M.x'
 477                 -- and where plain 'x' is (perhaps ambiguously) in scope.
 478                 -- So the starting point is all things that are in scope as 'M.x',
 479                 -- which is what this field tells us.
 480                 --
 481                 -- Domain is the *module qualifier* for imports.
 482                 --   e.g.        import List as Foo
 483                 -- would add a binding Foo |-> ...stuff from List...
 484                 -- to imp_qual.
 485                 -- We keep the stuff as an AvailEnv so that it's easy to
 486                 -- combine stuff coming from different (unqualified)
 487                 -- imports of the same module
 488
 489         imp_mods :: ModuleEnv (Module, Bool),
 490                 -- Domain is all directly-imported modules
 491                 -- Bool is True if there was an unrestricted import
 492                 --      (i.e. not a selective list)
 493                 -- We need the Module in the range because we can't get
 494                 --      the keys of a ModuleEnv
 495                 -- Used
 496                 --   (a) to help construct the usage information in
 497                 --       the interface file; if we import everything we
 498                 --       need to recompile if the module version changes
 499                 --   (b) to specify what child modules to initialise
 500
 501         imp_dep_mods :: ModuleEnv (ModuleName, IsBootInterface),
 502                 -- Home-package modules needed by the module being compiled
 503                 --
 504                 -- It doesn't matter whether any of these dependencies are actually
 505                 -- *used* when compiling the module; they are listed if they are below
 506                 -- it at all.  For example, suppose M imports A which imports X.  Then
 507                 -- compiling M might not need to consult X.hi, but X is still listed
 508                 -- in M's dependencies.
 509
 510         imp_dep_pkgs :: [PackageName],
 511                 -- Packages needed by the module being compiled, whether
 512                 -- directly, or via other modules in this package, or via
 513                 -- modules imported from other packages.
 514
 515         imp_orphs :: [ModuleName]
 516                 -- Orphan modules below us in the import tree
 517       }
 518
 519 emptyImportAvails :: ImportAvails
 520 emptyImportAvails = ImportAvails { imp_env      = emptyAvailEnv,
 521                                    imp_qual     = emptyModuleEnv,
 522                                    imp_mods     = emptyModuleEnv,
 523                                    imp_dep_mods = emptyModuleEnv,
 524                                    imp_dep_pkgs = [],
 525                                    imp_orphs    = [] }
 526
 527 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 528 plusImportAvails
 529   (ImportAvails { imp_env = env1, imp_qual = unqual1, imp_mods = mods1,
 530                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1, imp_orphs = orphs1 })
 531   (ImportAvails { imp_env = env2, imp_qual = unqual2, imp_mods = mods2,
 532                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2, imp_orphs = orphs2 })
 533   = ImportAvails { imp_env      = env1 `plusAvailEnv` env2,
 534                    imp_qual     = plusModuleEnv_C plusAvailEnv unqual1 unqual2,
 535                    imp_mods     = mods1  `plusModuleEnv` mods2,
 536                    imp_dep_mods = plusModuleEnv_C plus_mod_dep dmods1 dmods2,
 537                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 538                    imp_orphs    = orphs1 `unionLists` orphs2 }
 539   where
 540     plus_mod_dep (m1, boot1) (m2, boot2)
 541         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 542                 -- Check mod-names match
 543           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 544 \end{code}
 545
 546 %************************************************************************
 547 %*                                                                      *
 548         Avails, AvailEnv, etc
 549 %*                                                                      *
 550 v%************************************************************************
 551
 552 \begin{code}
 553 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 554 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (ns1 `unionLists` ns2)
 555 -- Added SOF 4/97
 556 #ifdef DEBUG
 557 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 558 #endif
 559
 560 -------------------------
 561 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 562             -> [AvailInfo]
 563             -> [AvailInfo]
 564 pruneAvails keep avails
 565   = mapMaybe del avails
 566   where
 567     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 568     del (Avail n) | keep n    = Just (Avail n)
 569                   | otherwise = Nothing
 570     del (AvailTC n ns) | null ns'  = Nothing
 571                        | otherwise = Just (AvailTC n ns')
 572                        where
 573                          ns' = filter keep ns
 574 \end{code}
 575
 576 ---------------------------------------
 577         AvailEnv and friends
 578 ---------------------------------------
 579
 580 \begin{code}
 581 type AvailEnv = NameEnv AvailInfo       -- Maps a Name to the AvailInfo that contains it
 582
 583 emptyAvailEnv :: AvailEnv
 584 emptyAvailEnv = emptyNameEnv
 585
 586 unitAvailEnv :: AvailInfo -> AvailEnv
 587 unitAvailEnv a = unitNameEnv (availName a) a
 588
 589 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 590 plusAvailEnv = plusNameEnv_C plusAvail
 591
 592 lookupAvailEnv = lookupNameEnv
 593
 594 availEnvElts = nameEnvElts
 595
 596 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 597 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 598
 599 mkAvailEnv :: [AvailInfo] -> AvailEnv
 600         -- 'avails' may have several items with the same availName
 601         -- E.g  import Ix( Ix(..), index )
 602         -- will give Ix(Ix,index,range) and Ix(index)
 603         -- We want to combine these; addAvail does that
 604 mkAvailEnv avails = foldl addAvail emptyAvailEnv avails
 605 \end{code}
 606
 607 %************************************************************************
 608 %*                                                                      *
 609 \subsection{Where from}
 610 %*                                                                      *
 611 %************************************************************************
 612
 613 The @WhereFrom@ type controls where the renamer looks for an interface file
 614
 615 \begin{code}
 616 data WhereFrom
 617   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 618
 619   | ImportForUsage IsBootInterface      -- Import when chasing usage info from an interaface file
 620                                         --      Failure in this case is not an error
 621
 622   | ImportBySystem                      -- Non user import.
 623
 624 instance Outputable WhereFrom where
 625   ppr (ImportByUser is_boot) | is_boot     = ptext SLIT("{- SOURCE -}")
 626                              | otherwise   = empty
 627   ppr (ImportForUsage is_boot) | is_boot   = ptext SLIT("{- USAGE SOURCE -}")
 628                                | otherwise = ptext SLIT("{- USAGE -}")
 629   ppr ImportBySystem                       = ptext SLIT("{- SYSTEM -}")
 630 \end{code}
 631
 632
 633 %************************************************************************
 634 %*                                                                      *
 635 \subsection[Inst-types]{@Inst@ types}
 636 %*                                                                      *
 637 v%************************************************************************
 638
 639 An @Inst@ is either a dictionary, an instance of an overloaded
 640 literal, or an instance of an overloaded value.  We call the latter a
 641 ``method'' even though it may not correspond to a class operation.
 642 For example, we might have an instance of the @double@ function at
 643 type Int, represented by
 644
 645         Method 34 doubleId [Int] origin
 646
 647 \begin{code}
 648 data Inst
 649   = Dict
 650         Id
 651         TcPredType
 652         InstLoc
 653
 654   | Method
 655         Id
 656
 657         TcId    -- The overloaded function
 658                         -- This function will be a global, local, or ClassOpId;
 659                         --   inside instance decls (only) it can also be an InstId!
 660                         -- The id needn't be completely polymorphic.
 661                         -- You'll probably find its name (for documentation purposes)
 662                         --        inside the InstOrigin
 663
 664         [TcType]        -- The types to which its polymorphic tyvars
 665                         --      should be instantiated.
 666                         -- These types must saturate the Id's foralls.
 667
 668         TcThetaType     -- The (types of the) dictionaries to which the function
 669                         -- must be applied to get the method
 670
 671         TcTauType       -- The tau-type of the method
 672
 673         InstLoc
 674
 675         -- INVARIANT 1: in (Method u f tys theta tau loc)
 676         --      type of (f tys dicts(from theta)) = tau
 677
 678         -- INVARIANT 2: tau must not be of form (Pred -> Tau)
 679         --   Reason: two methods are considerd equal if the
 680         --           base Id matches, and the instantiating types
 681         --           match.  The TcThetaType should then match too.
 682         --   This only bites in the call to tcInstClassOp in TcClassDcl.mkMethodBind
 683
 684   | LitInst
 685         Id
 686         HsOverLit       -- The literal from the occurrence site
 687                         --      INVARIANT: never a rebindable-syntax literal
 688                         --      Reason: tcSyntaxName does unification, and we
 689                         --              don't want to deal with that during tcSimplify
 690         TcType          -- The type at which the literal is used
 691         InstLoc
 692 \end{code}
 693
 694 @Insts@ are ordered by their class/type info, rather than by their
 695 unique.  This allows the context-reduction mechanism to use standard finite
 696 maps to do their stuff.
 697
 698 \begin{code}
 699 instance Ord Inst where
 700   compare = cmpInst
 701
 702 instance Eq Inst where
 703   (==) i1 i2 = case i1 `cmpInst` i2 of
 704                  EQ    -> True
 705                  other -> False
 706
 707 cmpInst (Dict _ pred1 _)          (Dict _ pred2 _)          = pred1 `tcCmpPred` pred2
 708 cmpInst (Dict _ _ _)              other                     = LT
 709
 710 cmpInst (Method _ _ _ _ _ _)      (Dict _ _ _)              = GT
 711 cmpInst (Method _ id1 tys1 _ _ _) (Method _ id2 tys2 _ _ _) = (id1 `compare` id2) `thenCmp` (tys1 `tcCmpTypes` tys2)
 712 cmpInst (Method _ _ _ _ _ _)      other                     = LT
 713
 714 cmpInst (LitInst _ _ _ _)         (Dict _ _ _)              = GT
 715 cmpInst (LitInst _ _ _ _)         (Method _ _ _ _ _ _)      = GT
 716 cmpInst (LitInst _ lit1 ty1 _)    (LitInst _ lit2 ty2 _)    = (lit1 `compare` lit2) `thenCmp` (ty1 `tcCmpType` ty2)
 717 \end{code}
 718
 719
 720 %************************************************************************
 721 %*                                                                      *
 722 \subsection[Inst-collections]{LIE: a collection of Insts}
 723 %*                                                                      *
 724 %************************************************************************
 725
 726 \begin{code}
 727 type LIE = Bag Inst
 728
 729 isEmptyLIE        = isEmptyBag
 730 emptyLIE          = emptyBag
 731 unitLIE inst      = unitBag inst
 732 mkLIE insts       = listToBag insts
 733 plusLIE lie1 lie2 = lie1 `unionBags` lie2
 734 consLIE inst lie  = inst `consBag` lie
 735 plusLIEs lies     = unionManyBags lies
 736 lieToList         = bagToList
 737 listToLIE         = listToBag
 738 \end{code}
 739
 740
 741 %************************************************************************
 742 %*                                                                      *
 743 \subsection[Inst-origin]{The @InstOrigin@ type}
 744 %*                                                                      *
 745 %************************************************************************
 746
 747 The @InstOrigin@ type gives information about where a dictionary came from.
 748 This is important for decent error message reporting because dictionaries
 749 don't appear in the original source code.  Doubtless this type will evolve...
 750
 751 It appears in TcMonad because there are a couple of error-message-generation
 752 functions that deal with it.
 753
 754 \begin{code}
 755 data InstLoc = InstLoc InstOrigin SrcLoc ErrCtxt
 756
 757 instLocSrcLoc :: InstLoc -> SrcLoc
 758 instLocSrcLoc (InstLoc _ src_loc _) = src_loc
 759
 760 data InstOrigin
 761   = OccurrenceOf Name           -- Occurrence of an overloaded identifier
 762
 763   | IPOcc (IPName Name)         -- Occurrence of an implicit parameter
 764   | IPBind (IPName Name)        -- Binding site of an implicit parameter
 765
 766   | RecordUpdOrigin
 767
 768   | DataDeclOrigin              -- Typechecking a data declaration
 769
 770   | InstanceDeclOrigin          -- Typechecking an instance decl
 771
 772   | LiteralOrigin HsOverLit     -- Occurrence of a literal
 773
 774   | PatOrigin RenamedPat
 775
 776   | ArithSeqOrigin RenamedArithSeqInfo -- [x..], [x..y] etc
 777   | PArrSeqOrigin  RenamedArithSeqInfo -- [:x..y:] and [:x,y..z:]
 778
 779   | SignatureOrigin             -- A dict created from a type signature
 780   | Rank2Origin                 -- A dict created when typechecking the argument
 781                                 -- of a rank-2 typed function
 782
 783   | DoOrigin                    -- The monad for a do expression
 784
 785   | ClassDeclOrigin             -- Manufactured during a class decl
 786
 787   | InstanceSpecOrigin  Class   -- in a SPECIALIZE instance pragma
 788                         Type
 789
 790         -- When specialising instances the instance info attached to
 791         -- each class is not yet ready, so we record it inside the
 792         -- origin information.  This is a bit of a hack, but it works
 793         -- fine.  (Patrick is to blame [WDP].)
 794
 795   | ValSpecOrigin       Name    -- in a SPECIALIZE pragma for a value
 796
 797         -- Argument or result of a ccall
 798         -- Dictionaries with this origin aren't actually mentioned in the
 799         -- translated term, and so need not be bound.  Nor should they
 800         -- be abstracted over.
 801
 802   | CCallOrigin         String                  -- CCall label
 803                         (Maybe RenamedHsExpr)   -- Nothing if it's the result
 804                                                 -- Just arg, for an argument
 805
 806   | LitLitOrigin        String  -- the litlit
 807
 808   | UnknownOrigin       -- Help! I give up...
 809 \end{code}
 810
 811 \begin{code}
 812 pprInstLoc :: InstLoc -> SDoc
 813 pprInstLoc (InstLoc orig locn ctxt)
 814   = hsep [text "arising from", pp_orig orig, text "at", ppr locn]
 815   where
 816     pp_orig (OccurrenceOf name)
 817         = hsep [ptext SLIT("use of"), quotes (ppr name)]
 818     pp_orig (IPOcc name)
 819         = hsep [ptext SLIT("use of implicit parameter"), quotes (ppr name)]
 820     pp_orig (IPBind name)
 821         = hsep [ptext SLIT("binding for implicit parameter"), quotes (ppr name)]
 822     pp_orig RecordUpdOrigin
 823         = ptext SLIT("a record update")
 824     pp_orig DataDeclOrigin
 825         = ptext SLIT("the data type declaration")
 826     pp_orig InstanceDeclOrigin
 827         = ptext SLIT("the instance declaration")
 828     pp_orig (LiteralOrigin lit)
 829         = hsep [ptext SLIT("the literal"), quotes (ppr lit)]
 830     pp_orig (PatOrigin pat)
 831         = hsep [ptext SLIT("the pattern"), quotes (ppr pat)]
 832     pp_orig (ArithSeqOrigin seq)
 833         = hsep [ptext SLIT("the arithmetic sequence"), quotes (ppr seq)]
 834     pp_orig (PArrSeqOrigin seq)
 835         = hsep [ptext SLIT("the parallel array sequence"), quotes (ppr seq)]
 836     pp_orig (SignatureOrigin)
 837         =  ptext SLIT("a type signature")
 838     pp_orig (Rank2Origin)
 839         =  ptext SLIT("a function with an overloaded argument type")
 840     pp_orig (DoOrigin)
 841         =  ptext SLIT("a do statement")
 842     pp_orig (ClassDeclOrigin)
 843         =  ptext SLIT("a class declaration")
 844     pp_orig (InstanceSpecOrigin clas ty)
 845         = hsep [text "a SPECIALIZE instance pragma; class",
 846                 quotes (ppr clas), text "type:", ppr ty]
 847     pp_orig (ValSpecOrigin name)
 848         = hsep [ptext SLIT("a SPECIALIZE user-pragma for"), quotes (ppr name)]
 849     pp_orig (CCallOrigin clabel Nothing{-ccall result-})
 850         = hsep [ptext SLIT("the result of the _ccall_ to"), quotes (text clabel)]
 851     pp_orig (CCallOrigin clabel (Just arg_expr))
 852         = hsep [ptext SLIT("an argument in the _ccall_ to"), quotes (text clabel) <> comma,
 853                 text "namely", quotes (ppr arg_expr)]
 854     pp_orig (LitLitOrigin s)
 855         = hsep [ptext SLIT("the ``literal-literal''"), quotes (text s)]
 856     pp_orig (UnknownOrigin)
 857         = ptext SLIT("...oops -- I don't know where the overloading came from!")
 858 \end{code}