ghc/compiler/typecheck/TcSplice.lhs

   1 2%
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcSplice]{Template Haskell splices}
   5
   6 \begin{code}
   7 module TcSplice( tcSpliceExpr, tcSpliceDecls, tcBracket ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HscMain          ( compileExpr )
  12 import TcRnDriver       ( importSupportingDecls, tcTopSrcDecls )
  13         -- These imports are the reason that TcSplice
  14         -- is very high up the module hierarchy
  15
  16 import qualified Language.Haskell.THSyntax as Meta
  17
  18 import HscTypes         ( HscEnv(..), GhciMode(..), PersistentCompilerState(..), unQualInScope )
  19 import HsSyn            ( HsBracket(..) )
  20 import Convert          ( convertToHsExpr, convertToHsDecls )
  21 import RnExpr           ( rnExpr )
  22 import RdrHsSyn         ( RdrNameHsExpr, RdrNameHsDecl )
  23 import RnHsSyn          ( RenamedHsExpr )
  24 import TcExpr           ( tcMonoExpr )
  25 import TcHsSyn          ( TcExpr, TypecheckedHsExpr, mkHsLet, zonkTopExpr )
  26 import TcSimplify       ( tcSimplifyTop )
  27 import TcType           ( TcType, openTypeKind, mkAppTy )
  28 import TcEnv            ( spliceOK, tcMetaTy )
  29 import TcRnTypes        ( TopEnv(..) )
  30 import TcMType          ( newTyVarTy, zapToType )
  31 import Name             ( Name )
  32 import TcRnMonad
  33
  34 import TysWiredIn       ( mkListTy )
  35 import DsMeta           ( exprTyConName, declTyConName, decTyConName, qTyConName )
  36 import ErrUtils (Message)
  37 import Outputable
  38 import Panic            ( showException )
  39 import GHC.Base         ( unsafeCoerce# )       -- Should have a better home in the module hierarchy
  40 import Monad (liftM)
  41 \end{code}
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 \subsection{Main interface + stubs for the non-GHCI case
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 \begin{code}
  51 tcSpliceDecls :: RenamedHsExpr -> TcM [RdrNameHsDecl]
  52
  53 tcSpliceExpr :: Name
  54              -> RenamedHsExpr
  55              -> TcType
  56              -> TcM TcExpr
  57
  58 #ifndef GHCI
  59 tcSpliceExpr n e ty = pprPanic "Cant do tcSpliceExpr without GHCi" (ppr e)
  60 tcSpliceDecls e     = pprPanic "Cant do tcSpliceDecls without GHCi" (ppr e)
  61 #else
  62 \end{code}
  63
  64 %************************************************************************
  65 %*                                                                      *
  66 \subsection{Splicing an expression}
  67 %*                                                                      *
  68 %************************************************************************
  69
  70 \begin{code}
  71 tcBracket :: HsBracket Name -> TcM TcType
  72 tcBracket (ExpBr expr)
  73   = newTyVarTy openTypeKind             `thenM` \ any_ty ->
  74     tcMonoExpr expr any_ty              `thenM_`
  75     tcMetaTy exprTyConName
  76         -- Result type is Expr (= Q Exp)
  77
  78 tcBracket (DecBr decls)
  79   = tcTopSrcDecls decls                 `thenM_`
  80     tcMetaTy decTyConName               `thenM` \ decl_ty ->
  81     tcMetaTy qTyConName                 `thenM` \ q_ty ->
  82     returnM (mkAppTy q_ty (mkListTy decl_ty))
  83         -- Result type is Q [Dec]
  84 \end{code}
  85
  86
  87 %************************************************************************
  88 %*                                                                      *
  89 \subsection{Splicing an expression}
  90 %*                                                                      *
  91 %************************************************************************
  92
  93 \begin{code}
  94 tcSpliceExpr name expr res_ty
  95   = getStage            `thenM` \ level ->
  96     case spliceOK level of {
  97         Nothing         -> failWithTc (illegalSplice level) ;
  98         Just next_level ->
  99
 100     case level of {
 101         Comp                   -> tcTopSplice expr res_ty ;
 102         Brack _ ps_var lie_var ->
 103
 104         -- A splice inside brackets
 105         -- NB: ignore res_ty, apart from zapping it to a mono-type
 106         -- e.g.   [| reverse $(h 4) |]
 107         -- Here (h 4) :: Q Exp
 108         -- but $(h 4) :: forall a.a     i.e. anything!
 109
 110     zapToType res_ty                            `thenM_`
 111     tcMetaTy exprTyConName                      `thenM` \ meta_exp_ty ->
 112     setStage (Splice next_level) (
 113         setLIEVar lie_var          $
 114         tcMonoExpr expr meta_exp_ty
 115     )                                           `thenM` \ expr' ->
 116
 117         -- Write the pending splice into the bucket
 118     readMutVar ps_var                           `thenM` \ ps ->
 119     writeMutVar ps_var ((name,expr') : ps)      `thenM_`
 120
 121     returnM (panic "tcSpliceExpr")      -- The returned expression is ignored
 122     }}
 123
 124 -- tcTopSplice used to have this:
 125 -- Note that we do not decrement the level (to -1) before
 126 -- typechecking the expression.  For example:
 127 --      f x = $( ...$(g 3) ... )
 128 -- The recursive call to tcMonoExpr will simply expand the
 129 -- inner escape before dealing with the outer one
 130
 131 tcTopSplice expr res_ty
 132   = tcMetaTy exprTyConName              `thenM` \ meta_exp_ty ->
 133
 134         -- Typecheck the expression
 135     tcTopSpliceExpr expr meta_exp_ty    `thenM` \ zonked_q_expr ->
 136
 137         -- Run the expression
 138     traceTc (text "About to run" <+> ppr zonked_q_expr)         `thenM_`
 139     runMetaE zonked_q_expr              `thenM` \ simple_expr ->
 140
 141     let
 142         -- simple_expr :: Meta.Exp
 143
 144         expr2 :: RdrNameHsExpr
 145         expr2 = convertToHsExpr simple_expr
 146     in
 147     traceTc (text "Got result" <+> ppr expr2)   `thenM_`
 148
 149     showSplice "expression"
 150                zonked_q_expr (ppr expr2)        `thenM_`
 151     initRn SourceMode (rnExpr expr2)            `thenM` \ (exp3, fvs) ->
 152     importSupportingDecls fvs                   `thenM` \ env ->
 153
 154     setGblEnv env (tcMonoExpr exp3 res_ty)
 155
 156
 157 tcTopSpliceExpr :: RenamedHsExpr -> TcType -> TcM TypecheckedHsExpr
 158 tcTopSpliceExpr expr meta_ty
 159   = checkNoErrs $       -- checkNoErrs: must not try to run the thing
 160                         --              if the type checker fails!
 161
 162     setStage topSpliceStage $
 163
 164         -- Typecheck the expression
 165     getLIE (tcMonoExpr expr meta_ty)    `thenM` \ (expr', lie) ->
 166
 167         -- Solve the constraints
 168     tcSimplifyTop lie                   `thenM` \ const_binds ->
 169
 170         -- And zonk it
 171     zonkTopExpr (mkHsLet const_binds expr')
 172 \end{code}
 173
 174
 175 %************************************************************************
 176 %*                                                                      *
 177 \subsection{Splicing an expression}
 178 %*                                                                      *
 179 %************************************************************************
 180
 181 \begin{code}
 182 -- Always at top level
 183 tcSpliceDecls expr
 184   = tcMetaTy decTyConName               `thenM` \ meta_dec_ty ->
 185     tcMetaTy qTyConName                 `thenM` \ meta_q_ty ->
 186     let
 187         list_q = mkAppTy meta_q_ty (mkListTy meta_dec_ty)
 188     in
 189     tcTopSpliceExpr expr list_q         `thenM` \ zonked_q_expr ->
 190
 191         -- Run the expression
 192     traceTc (text "About to run" <+> ppr zonked_q_expr)         `thenM_`
 193     runMetaD zonked_q_expr              `thenM` \ simple_expr ->
 194     -- simple_expr :: [Meta.Dec]
 195     -- decls :: [RdrNameHsDecl]
 196     handleErrors (convertToHsDecls simple_expr) `thenM` \ decls ->
 197     traceTc (text "Got result" <+> vcat (map ppr decls))        `thenM_`
 198     showSplice "declarations"
 199                zonked_q_expr (vcat (map ppr decls))             `thenM_`
 200     returnM decls
 201
 202   where handleErrors :: [Either a Message] -> TcM [a]
 203         handleErrors [] = return []
 204         handleErrors (Left x:xs) = liftM (x:) (handleErrors xs)
 205         handleErrors (Right m:xs) = do addErrTc m
 206                                        handleErrors xs
 207 \end{code}
 208
 209
 210 %************************************************************************
 211 %*                                                                      *
 212 \subsection{Running an expression}
 213 %*                                                                      *
 214 %************************************************************************
 215
 216 \begin{code}
 217 runMetaE :: TypecheckedHsExpr   -- Of type (Q Exp)
 218          -> TcM Meta.Exp        -- Of type Exp
 219 runMetaE e = runMeta e
 220
 221 runMetaD :: TypecheckedHsExpr   -- Of type Q [Dec]
 222          -> TcM [Meta.Dec]      -- Of type [Dec]
 223 runMetaD e = runMeta e
 224
 225 runMeta :: TypecheckedHsExpr    -- Of type X
 226         -> TcM t                -- Of type t
 227 runMeta expr
 228   = getTopEnv           `thenM` \ top_env ->
 229     getGblEnv           `thenM` \ tcg_env ->
 230     getEps              `thenM` \ eps ->
 231     getNameCache        `thenM` \ name_cache ->
 232     getModule           `thenM` \ this_mod ->
 233     let
 234         ghci_mode = top_mode top_env
 235
 236         hsc_env = HscEnv { hsc_mode = ghci_mode, hsc_HPT = top_hpt top_env,
 237                            hsc_dflags = top_dflags top_env }
 238
 239         pcs = PCS { pcs_nc = name_cache, pcs_EPS = eps }
 240
 241         type_env = tcg_type_env tcg_env
 242         rdr_env  = tcg_rdr_env tcg_env
 243     in
 244         -- Wrap the compile-and-run in an exception-catcher
 245         -- Compiling might fail if linking fails
 246         -- Running might fail if it throws an exception
 247     tryM (ioToTcRn (do
 248         hval <- HscMain.compileExpr
 249                       hsc_env pcs this_mod
 250                       rdr_env type_env expr
 251         Meta.runQ (unsafeCoerce# hval)          -- Coerce it to Q t, and run it
 252     ))                                  `thenM` \ either_tval ->
 253
 254     case either_tval of
 255           Left exn -> failWithTc (vcat [text "Exception when trying to run compile-time code:",
 256                                         nest 4 (vcat [text "Code:" <+> ppr expr,
 257                                                       text ("Exn: " ++ Panic.showException exn)])])
 258           Right v  -> returnM v
 259 \end{code}
 260
 261
 262
 263 -----------------------------------
 264         Random comments
 265
 266
 267       module Foo where
 268         import Lib( g :: Int -> M Exp )
 269         h x = not x
 270         f x y = [| \z -> (x, $(g y), z, map, h) |]
 271
 272         h p = $( (\q r -> if q then [| \s -> (p,r,s) |]
 273                                else ... ) True 3)   )
 274
 275 ==> core
 276
 277         f :: Liftable a => a -> Int -> M Exp
 278         f = /\a -> \d::Liftable a ->
 279             \ x y -> genSym "z"         `bindM` \ z::String ->
 280                      g y                `bindM` \ vv::Exp ->
 281                      Lam z (Tup [lift d x, v, Var z,
 282                                  Glob "Prelude" "map",
 283                                  Glob "Foo" "h"])
 284
 285
 286         h :: Tree Int -> M Exp
 287         h = \p -> \s' -> (p,3,s')
 288
 289
 290                 Bound   Used
 291
 292         map:    C0      C1      (top-level/imp)
 293         x:      C0      C1      (lam/case)
 294         y:      C0      C0
 295         z:      C1      C1
 296
 297         p:      C0      S1
 298         r:      S0      S1
 299         q:      S0      S0
 300         s:      S1      S1
 301
 302 -------
 303
 304         f x y = lam "z" (tup [lift x, g y, var "z",
 305                               [| map |], [| h |] ])
 306 ==> core
 307
 308         f = \x y -> lam "z" (tup [lift d x, g y, var "z",
 309                                   return (Glob "Prelude" "map"),
 310                                   return (Glob "Foo" "h")])
 311
 312
 313
 314
 315
 316
 317
 318         h :: M Exp -> M Exp
 319         h v = [| \x -> map $v x |]
 320
 321         g :: Tree Int -> M Exp
 322         g x = $(h [| x |])
 323 ==>
 324         g x = \x' -> map x x'
 325
 326 *** Simon claims x does not have to be liftable! **
 327
 328 Level 0 compile time
 329 Level 1 run time
 330 Level 2 code returned by run time (generation time)
 331
 332 Non-top-level variables
 333         x occurs at level 1
 334           inside brackets
 335             bound at level 0    --> x
 336             bound at level 1    --> var "x"
 337
 338           not inside brackets   --> x
 339
 340         x at level 2
 341           inside brackets
 342             bound at level 0    --> x
 343             bound at level 1    --> var "x"
 344
 345         f x = x
 346
 347 Two successive brackets aren't allowed
 348
 349
 350 %************************************************************************
 351 %*                                                                      *
 352 \subsection{Errors and contexts}
 353 %*                                                                      *
 354 %************************************************************************
 355
 356 \begin{code}
 357 showSplice :: String -> TypecheckedHsExpr -> SDoc -> TcM ()
 358 showSplice what before after
 359   = getSrcLocM          `thenM` \ loc ->
 360     traceSplice (vcat [ppr loc <> colon <+> text "Splicing" <+> text what,
 361                        nest 2 (sep [nest 2 (ppr before),
 362                                     text "======>",
 363                                     nest 2 after])])
 364
 365 illegalSplice level
 366   = ptext SLIT("Illegal splice at level") <+> ppr level
 367
 368 #endif  /* GHCI */
 369 \end{code}