ghc/compiler/typecheck/TcSplice.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcSplice]{Template Haskell splices}
   5
   6 \begin{code}
   7 module TcSplice( tcSpliceExpr, tcSpliceDecls, tcBracket ) where
   8
   9 #include "HsVersions.h"
  10
  11 import HscMain          ( compileExpr )
  12 import TcRnDriver       ( tcTopSrcDecls )
  13         -- These imports are the reason that TcSplice
  14         -- is very high up the module hierarchy
  15
  16 import qualified Language.Haskell.TH as TH
  17 -- THSyntax gives access to internal functions and data types
  18 import qualified Language.Haskell.TH.Syntax as TH
  19
  20 import HsSyn            ( HsBracket(..), HsExpr(..), HsSplice(..), LHsExpr, LHsDecl,
  21                           HsType, LHsType )
  22 import Convert          ( convertToHsExpr, convertToHsDecls, convertToHsType )
  23 import RnExpr           ( rnLExpr )
  24 import RnEnv            ( lookupFixityRn, lookupSrcOcc_maybe )
  25 import RdrName          ( RdrName, mkRdrQual, mkRdrUnqual, lookupLocalRdrEnv )
  26 import RnTypes          ( rnLHsType )
  27 import TcExpr           ( tcCheckRho, tcMonoExpr )
  28 import TcHsSyn          ( mkHsLet, zonkTopLExpr )
  29 import TcSimplify       ( tcSimplifyTop, tcSimplifyBracket )
  30 import TcUnify          ( Expected, zapExpectedTo, zapExpectedType )
  31 import TcType           ( TcType, TcKind, liftedTypeKind, mkAppTy, tcSplitSigmaTy )
  32 import TcEnv            ( spliceOK, tcMetaTy, bracketOK )
  33 import TcMType          ( newTyFlexiVarTy, newKindVar, UserTypeCtxt(ExprSigCtxt), zonkTcType, zonkTcTyVar )
  34 import TcHsType         ( tcHsSigType, kcHsType )
  35 import TcIface          ( tcImportDecl )
  36 import TypeRep          ( Type(..), PredType(..), TyThing(..) ) -- For reification
  37 import Name             ( Name, NamedThing(..), nameOccName, nameModule, isExternalName,
  38                           mkInternalName, nameIsLocalOrFrom )
  39 import NameEnv          ( lookupNameEnv )
  40 import HscTypes         ( lookupType, ExternalPackageState(..) )
  41 import OccName
  42 import Var              ( Id, TyVar, idType )
  43 import Module           ( moduleUserString, mkModule )
  44 import TcRnMonad
  45 import IfaceEnv         ( lookupOrig )
  46 import Class            ( Class, classExtraBigSig )
  47 import TyCon            ( TyCon, AlgTyConRhs(..), tyConTyVars, getSynTyConDefn,
  48                           isSynTyCon, isNewTyCon, tyConDataCons, algTyConRhs, isPrimTyCon, isFunTyCon,
  49                           tyConArity, isUnLiftedTyCon )
  50 import DataCon          ( DataCon, dataConTyCon, dataConOrigArgTys, dataConStrictMarks,
  51                           dataConName, dataConFieldLabels, dataConWrapId, dataConIsInfix,
  52                           isVanillaDataCon )
  53 import Id               ( idName, globalIdDetails )
  54 import IdInfo           ( GlobalIdDetails(..) )
  55 import TysWiredIn       ( mkListTy )
  56 import DsMeta           ( expQTyConName, typeQTyConName, decTyConName, qTyConName, nameTyConName )
  57 import ErrUtils         ( Message )
  58 import SrcLoc           ( noLoc, unLoc, getLoc, noSrcLoc )
  59 import Outputable
  60 import Unique           ( Unique, Uniquable(..), getKey, mkUniqueGrimily )
  61
  62 import BasicTypes       ( StrictnessMark(..), Fixity(..), FixityDirection(..) )
  63 import Panic            ( showException )
  64 import FastString       ( LitString )
  65
  66 import GHC.Base         ( unsafeCoerce#, Int#, Int(..) )        -- Should have a better home in the module hierarchy
  67 import Monad            ( liftM )
  68 import Maybes           ( orElse )
  69
  70 #ifdef GHCI
  71 import FastString       ( mkFastString )
  72 #endif
  73 \end{code}
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 \subsection{Main interface + stubs for the non-GHCI case
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \begin{code}
  83 tcSpliceDecls :: LHsExpr Name -> TcM [LHsDecl RdrName]
  84 tcSpliceExpr  :: HsSplice Name -> Expected TcType -> TcM (HsExpr TcId)
  85 kcSpliceType  :: HsSplice Name -> TcM (HsType Name, TcKind)
  86
  87 #ifndef GHCI
  88 tcSpliceExpr n e ty = pprPanic "Cant do tcSpliceExpr without GHCi" (ppr e)
  89 tcSpliceDecls e     = pprPanic "Cant do tcSpliceDecls without GHCi" (ppr e)
  90 #else
  91 \end{code}
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{Quoting an expression}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 \begin{code}
 100 tcBracket :: HsBracket Name -> Expected TcType -> TcM (LHsExpr Id)
 101 tcBracket brack res_ty
 102   = getStage                            `thenM` \ level ->
 103     case bracketOK level of {
 104         Nothing         -> failWithTc (illegalBracket level) ;
 105         Just next_level ->
 106
 107         -- Typecheck expr to make sure it is valid,
 108         -- but throw away the results.  We'll type check
 109         -- it again when we actually use it.
 110     recordThUse                         `thenM_`
 111     newMutVar []                        `thenM` \ pending_splices ->
 112     getLIEVar                           `thenM` \ lie_var ->
 113
 114     setStage (Brack next_level pending_splices lie_var) (
 115         getLIE (tc_bracket brack)
 116     )                                   `thenM` \ (meta_ty, lie) ->
 117     tcSimplifyBracket lie               `thenM_`
 118
 119         -- Make the expected type have the right shape
 120     zapExpectedTo res_ty meta_ty        `thenM_`
 121
 122         -- Return the original expression, not the type-decorated one
 123     readMutVar pending_splices          `thenM` \ pendings ->
 124     returnM (noLoc (HsBracketOut brack pendings))
 125     }
 126
 127 tc_bracket :: HsBracket Name -> TcM TcType
 128 tc_bracket (VarBr v)
 129   = tcMetaTy nameTyConName
 130         -- Result type is Var (not Q-monadic)
 131
 132 tc_bracket (ExpBr expr)
 133   = newTyFlexiVarTy liftedTypeKind      `thenM` \ any_ty ->
 134     tcCheckRho expr any_ty              `thenM_`
 135     tcMetaTy expQTyConName
 136         -- Result type is Expr (= Q Exp)
 137
 138 tc_bracket (TypBr typ)
 139   = tcHsSigType ExprSigCtxt typ         `thenM_`
 140     tcMetaTy typeQTyConName
 141         -- Result type is Type (= Q Typ)
 142
 143 tc_bracket (DecBr decls)
 144   = tcTopSrcDecls [{- no boot-names -}] decls           `thenM_`
 145         -- Typecheck the declarations, dicarding the result
 146         -- We'll get all that stuff later, when we splice it in
 147
 148     tcMetaTy decTyConName       `thenM` \ decl_ty ->
 149     tcMetaTy qTyConName         `thenM` \ q_ty ->
 150     returnM (mkAppTy q_ty (mkListTy decl_ty))
 151         -- Result type is Q [Dec]
 152 \end{code}
 153
 154
 155 %************************************************************************
 156 %*                                                                      *
 157 \subsection{Splicing an expression}
 158 %*                                                                      *
 159 %************************************************************************
 160
 161 \begin{code}
 162 tcSpliceExpr (HsSplice name expr) res_ty
 163   = setSrcSpan (getLoc expr)    $
 164     getStage            `thenM` \ level ->
 165     case spliceOK level of {
 166         Nothing         -> failWithTc (illegalSplice level) ;
 167         Just next_level ->
 168
 169     case level of {
 170         Comp                   -> do { e <- tcTopSplice expr res_ty
 171                                      ; returnM (unLoc e) } ;
 172         Brack _ ps_var lie_var ->
 173
 174         -- A splice inside brackets
 175         -- NB: ignore res_ty, apart from zapping it to a mono-type
 176         -- e.g.   [| reverse $(h 4) |]
 177         -- Here (h 4) :: Q Exp
 178         -- but $(h 4) :: forall a.a     i.e. anything!
 179
 180     zapExpectedType res_ty liftedTypeKind       `thenM_`
 181     tcMetaTy expQTyConName                      `thenM` \ meta_exp_ty ->
 182     setStage (Splice next_level) (
 183         setLIEVar lie_var          $
 184         tcCheckRho expr meta_exp_ty
 185     )                                           `thenM` \ expr' ->
 186
 187         -- Write the pending splice into the bucket
 188     readMutVar ps_var                           `thenM` \ ps ->
 189     writeMutVar ps_var ((name,expr') : ps)      `thenM_`
 190
 191     returnM (panic "tcSpliceExpr")      -- The returned expression is ignored
 192     }}
 193
 194 -- tcTopSplice used to have this:
 195 -- Note that we do not decrement the level (to -1) before
 196 -- typechecking the expression.  For example:
 197 --      f x = $( ...$(g 3) ... )
 198 -- The recursive call to tcMonoExpr will simply expand the
 199 -- inner escape before dealing with the outer one
 200
 201 tcTopSplice :: LHsExpr Name -> Expected TcType -> TcM (LHsExpr Id)
 202 tcTopSplice expr res_ty
 203   = tcMetaTy expQTyConName              `thenM` \ meta_exp_ty ->
 204
 205         -- Typecheck the expression
 206     tcTopSpliceExpr expr meta_exp_ty    `thenM` \ zonked_q_expr ->
 207
 208         -- Run the expression
 209     traceTc (text "About to run" <+> ppr zonked_q_expr)         `thenM_`
 210     runMetaE zonked_q_expr              `thenM` \ simple_expr ->
 211
 212     let
 213         -- simple_expr :: TH.Exp
 214
 215         expr2 :: LHsExpr RdrName
 216         expr2 = convertToHsExpr simple_expr
 217     in
 218     traceTc (text "Got result" <+> ppr expr2)   `thenM_`
 219
 220     showSplice "expression"
 221                zonked_q_expr (ppr expr2)        `thenM_`
 222
 223         -- Rename it, but bale out if there are errors
 224         -- otherwise the type checker just gives more spurious errors
 225     checkNoErrs (rnLExpr expr2)                 `thenM` \ (exp3, fvs) ->
 226
 227     tcMonoExpr exp3 res_ty
 228
 229
 230 tcTopSpliceExpr :: LHsExpr Name -> TcType -> TcM (LHsExpr Id)
 231 -- Type check an expression that is the body of a top-level splice
 232 --   (the caller will compile and run it)
 233 tcTopSpliceExpr expr meta_ty
 234   = checkNoErrs $       -- checkNoErrs: must not try to run the thing
 235                         --              if the type checker fails!
 236
 237     setStage topSpliceStage $ do
 238
 239
 240     do  { recordThUse   -- Record that TH is used (for pkg depdendency)
 241
 242         -- Typecheck the expression
 243         ; (expr', lie) <- getLIE (tcCheckRho expr meta_ty)
 244
 245         -- Solve the constraints
 246         ; const_binds <- tcSimplifyTop lie
 247
 248         -- And zonk it
 249         ; zonkTopLExpr (mkHsLet const_binds expr') }
 250 \end{code}
 251
 252
 253 %************************************************************************
 254 %*                                                                      *
 255                 Splicing a type
 256 %*                                                                      *
 257 %************************************************************************
 258
 259 Very like splicing an expression, but we don't yet share code.
 260
 261 \begin{code}
 262 kcSpliceType (HsSplice name hs_expr)
 263   = setSrcSpan (getLoc hs_expr) $ do
 264         { level <- getStage
 265         ; case spliceOK level of {
 266                 Nothing         -> failWithTc (illegalSplice level) ;
 267                 Just next_level -> do
 268
 269         { case level of {
 270                 Comp                   -> do { (t,k) <- kcTopSpliceType hs_expr
 271                                              ; return (unLoc t, k) } ;
 272                 Brack _ ps_var lie_var -> do
 273
 274         {       -- A splice inside brackets
 275         ; meta_ty <- tcMetaTy typeQTyConName
 276         ; expr' <- setStage (Splice next_level) $
 277                    setLIEVar lie_var            $
 278                    tcCheckRho hs_expr meta_ty
 279
 280                 -- Write the pending splice into the bucket
 281         ; ps <- readMutVar ps_var
 282         ; writeMutVar ps_var ((name,expr') : ps)
 283
 284         -- e.g.   [| Int -> $(h 4) |]
 285         -- Here (h 4) :: Q Type
 286         -- but $(h 4) :: forall a.a     i.e. any kind
 287         ; kind <- newKindVar
 288         ; returnM (panic "kcSpliceType", kind)  -- The returned type is ignored
 289     }}}}}
 290
 291 kcTopSpliceType :: LHsExpr Name -> TcM (LHsType Name, TcKind)
 292 kcTopSpliceType expr
 293   = do  { meta_ty <- tcMetaTy typeQTyConName
 294
 295         -- Typecheck the expression
 296         ; zonked_q_expr <- tcTopSpliceExpr expr meta_ty
 297
 298         -- Run the expression
 299         ; traceTc (text "About to run" <+> ppr zonked_q_expr)
 300         ; simple_ty <- runMetaT zonked_q_expr
 301
 302         ; let   -- simple_ty :: TH.Type
 303                 hs_ty2 :: LHsType RdrName
 304                 hs_ty2 = convertToHsType simple_ty
 305
 306         ; traceTc (text "Got result" <+> ppr hs_ty2)
 307
 308         ; showSplice "type" zonked_q_expr (ppr hs_ty2)
 309
 310         -- Rename it, but bale out if there are errors
 311         -- otherwise the type checker just gives more spurious errors
 312         ; let doc = ptext SLIT("In the spliced type") <+> ppr hs_ty2
 313         ; hs_ty3 <- checkNoErrs (rnLHsType doc hs_ty2)
 314
 315         ; kcHsType hs_ty3 }
 316 \end{code}
 317
 318 %************************************************************************
 319 %*                                                                      *
 320 \subsection{Splicing an expression}
 321 %*                                                                      *
 322 %************************************************************************
 323
 324 \begin{code}
 325 -- Always at top level
 326 tcSpliceDecls expr
 327   = do  { meta_dec_ty <- tcMetaTy decTyConName
 328         ; meta_q_ty <- tcMetaTy qTyConName
 329         ; let list_q = mkAppTy meta_q_ty (mkListTy meta_dec_ty)
 330         ; zonked_q_expr <- tcTopSpliceExpr expr list_q
 331
 332                 -- Run the expression
 333         ; traceTc (text "About to run" <+> ppr zonked_q_expr)
 334         ; simple_expr <- runMetaD zonked_q_expr
 335
 336             -- simple_expr :: [TH.Dec]
 337             -- decls :: [RdrNameHsDecl]
 338         ; decls <- handleErrors (convertToHsDecls simple_expr)
 339         ; traceTc (text "Got result" <+> vcat (map ppr decls))
 340         ; showSplice "declarations"
 341                      zonked_q_expr (vcat (map ppr decls))
 342         ; returnM decls }
 343
 344   where handleErrors :: [Either a Message] -> TcM [a]
 345         handleErrors [] = return []
 346         handleErrors (Left x:xs) = liftM (x:) (handleErrors xs)
 347         handleErrors (Right m:xs) = do addErrTc m
 348                                        handleErrors xs
 349 \end{code}
 350
 351
 352 %************************************************************************
 353 %*                                                                      *
 354 \subsection{Running an expression}
 355 %*                                                                      *
 356 %************************************************************************
 357
 358 \begin{code}
 359 runMetaE :: LHsExpr Id  -- Of type (Q Exp)
 360          -> TcM TH.Exp  -- Of type Exp
 361 runMetaE e = runMeta e
 362
 363 runMetaT :: LHsExpr Id          -- Of type (Q Type)
 364          -> TcM TH.Type         -- Of type Type
 365 runMetaT e = runMeta e
 366
 367 runMetaD :: LHsExpr Id          -- Of type Q [Dec]
 368          -> TcM [TH.Dec]        -- Of type [Dec]
 369 runMetaD e = runMeta e
 370
 371 runMeta :: LHsExpr Id           -- Of type X
 372         -> TcM t                -- Of type t
 373 runMeta expr
 374   = do  { hsc_env <- getTopEnv
 375         ; tcg_env <- getGblEnv
 376         ; this_mod <- getModule
 377         ; let type_env = tcg_type_env tcg_env
 378               rdr_env  = tcg_rdr_env tcg_env
 379         -- Wrap the compile-and-run in an exception-catcher
 380         -- Compiling might fail if linking fails
 381         -- Running might fail if it throws an exception
 382         ; either_tval <- tryM $ do
 383                 {       -- Compile it
 384                   hval <- ioToTcRn (HscMain.compileExpr
 385                                       hsc_env this_mod
 386                                       rdr_env type_env expr)
 387                         -- Coerce it to Q t, and run it
 388                 ; TH.runQ (unsafeCoerce# hval) }
 389
 390         ; case either_tval of
 391               Left exn -> failWithTc (vcat [text "Exception when trying to run compile-time code:",
 392                                             nest 4 (vcat [text "Code:" <+> ppr expr,
 393                                                       text ("Exn: " ++ Panic.showException exn)])])
 394               Right v  -> returnM v }
 395 \end{code}
 396
 397 To call runQ in the Tc monad, we need to make TcM an instance of Quasi:
 398
 399 \begin{code}
 400 instance TH.Quasi (IOEnv (Env TcGblEnv TcLclEnv)) where
 401   qNewName s = do { u <- newUnique
 402                   ; let i = getKey u
 403                   ; return (TH.mkNameU s i) }
 404
 405   qReport True msg  = addErr (text msg)
 406   qReport False msg = addReport (text msg)
 407
 408   qCurrentModule = do { m <- getModule; return (moduleUserString m) }
 409   qReify v = reify v
 410   qRecover = recoverM
 411
 412   qRunIO io = ioToTcRn io
 413 \end{code}
 414
 415
 416 %************************************************************************
 417 %*                                                                      *
 418 \subsection{Errors and contexts}
 419 %*                                                                      *
 420 %************************************************************************
 421
 422 \begin{code}
 423 showSplice :: String -> LHsExpr Id -> SDoc -> TcM ()
 424 showSplice what before after
 425   = getSrcSpanM         `thenM` \ loc ->
 426     traceSplice (vcat [ppr loc <> colon <+> text "Splicing" <+> text what,
 427                        nest 2 (sep [nest 2 (ppr before),
 428                                     text "======>",
 429                                     nest 2 after])])
 430
 431 illegalBracket level
 432   = ptext SLIT("Illegal bracket at level") <+> ppr level
 433
 434 illegalSplice level
 435   = ptext SLIT("Illegal splice at level") <+> ppr level
 436
 437 #endif  /* GHCI */
 438 \end{code}
 439
 440
 441 %************************************************************************
 442 %*                                                                      *
 443                         Reification
 444 %*                                                                      *
 445 %************************************************************************
 446
 447
 448 \begin{code}
 449 reify :: TH.Name -> TcM TH.Info
 450 reify th_name
 451   = do  { name <- lookupThName th_name
 452         ; thing <- tcLookupTh name
 453                 -- ToDo: this tcLookup could fail, which would give a
 454                 --       rather unhelpful error message
 455         ; reifyThing thing
 456     }
 457
 458 lookupThName :: TH.Name -> TcM Name
 459 lookupThName (TH.Name occ (TH.NameG th_ns mod))
 460   = lookupOrig (mkModule (TH.modString mod))
 461                (OccName.mkOccName ghc_ns (TH.occString occ))
 462   where
 463     ghc_ns = case th_ns of
 464                 TH.DataName  -> dataName
 465                 TH.TcClsName -> tcClsName
 466                 TH.VarName   -> varName
 467
 468 lookupThName (TH.Name occ (TH.NameU uniq))
 469   = return (mkInternalName (mk_uniq uniq) (OccName.mkOccFS bogus_ns occ_fs) noSrcLoc)
 470   where
 471     occ_fs = mkFastString (TH.occString occ)
 472     bogus_ns = OccName.varName  -- Not yet recorded in the TH name
 473                                 -- but only the unique matters
 474
 475 lookupThName th_name@(TH.Name occ flavour)      -- NameS or NameQ
 476   =  do { let occ = OccName.mkOccFS ns occ_fs
 477               rdr_name = case flavour of
 478                             TH.NameS   -> mkRdrUnqual occ
 479                             TH.NameQ m -> mkRdrQual (mkModule (TH.modString m)) occ
 480         ; rdr_env <- getLocalRdrEnv
 481         ; case lookupLocalRdrEnv rdr_env rdr_name of
 482                 Just name -> return name
 483                 Nothing   -> do
 484         { mb_name <- lookupSrcOcc_maybe rdr_name
 485         ; case mb_name of
 486             Just name -> return name ;
 487             Nothing   -> failWithTc (notInScope th_name)
 488         }}
 489   where
 490     ns | isLexCon occ_fs = OccName.dataName
 491        | otherwise       = OccName.varName
 492     occ_fs = mkFastString (TH.occString occ)
 493
 494 tcLookupTh :: Name -> TcM TcTyThing
 495 -- This is a specialised version of TcEnv.tcLookup; specialised mainly in that
 496 -- it gives a reify-related error message on failure, whereas in the normal
 497 -- tcLookup, failure is a bug.
 498 tcLookupTh name
 499   = do  { (gbl_env, lcl_env) <- getEnvs
 500         ; case lookupNameEnv (tcl_env lcl_env) name of
 501                 Just thing -> returnM thing
 502                 Nothing    -> do
 503         { if nameIsLocalOrFrom (tcg_mod gbl_env) name
 504           then  -- It's defined in this module
 505               case lookupNameEnv (tcg_type_env gbl_env) name of
 506                 Just thing -> return (AGlobal thing)
 507                 Nothing    -> failWithTc (notInEnv name)
 508
 509           else do               -- It's imported
 510         { (eps,hpt) <- getEpsAndHpt
 511         ; case lookupType hpt (eps_PTE eps) name of
 512             Just thing -> return (AGlobal thing)
 513             Nothing    -> do { thing <- tcImportDecl name
 514                              ; return (AGlobal thing) }
 515                 -- Imported names should always be findable;
 516                 -- if not, we fail hard in tcImportDecl
 517     }}}
 518
 519 mk_uniq :: Int# -> Unique
 520 mk_uniq u = mkUniqueGrimily (I# u)
 521
 522 notInScope :: TH.Name -> SDoc
 523 notInScope th_name = quotes (text (TH.pprint th_name)) <+>
 524                      ptext SLIT("is not in scope at a reify")
 525         -- Ugh! Rather an indirect way to display the name
 526
 527 notInEnv :: Name -> SDoc
 528 notInEnv name = quotes (ppr name) <+>
 529                      ptext SLIT("is not in the type environment at a reify")
 530
 531 ------------------------------
 532 reifyThing :: TcTyThing -> TcM TH.Info
 533 -- The only reason this is monadic is for error reporting,
 534 -- which in turn is mainly for the case when TH can't express
 535 -- some random GHC extension
 536
 537 reifyThing (AGlobal (AnId id))
 538   = do  { ty <- reifyType (idType id)
 539         ; fix <- reifyFixity (idName id)
 540         ; let v = reifyName id
 541         ; case globalIdDetails id of
 542             ClassOpId cls    -> return (TH.ClassOpI v ty (reifyName cls) fix)
 543             other            -> return (TH.VarI     v ty Nothing fix)
 544     }
 545
 546 reifyThing (AGlobal (ATyCon tc))  = reifyTyCon tc
 547 reifyThing (AGlobal (AClass cls)) = reifyClass cls
 548 reifyThing (AGlobal (ADataCon dc))
 549   = do  { let name = dataConName dc
 550         ; ty <- reifyType (idType (dataConWrapId dc))
 551         ; fix <- reifyFixity name
 552         ; return (TH.DataConI (reifyName name) ty (reifyName (dataConTyCon dc)) fix) }
 553
 554 reifyThing (ATcId id _ _)
 555   = do  { ty1 <- zonkTcType (idType id) -- Make use of all the info we have, even
 556                                         -- though it may be incomplete
 557         ; ty2 <- reifyType ty1
 558         ; fix <- reifyFixity (idName id)
 559         ; return (TH.VarI (reifyName id) ty2 Nothing fix) }
 560
 561 reifyThing (ATyVar tv ty)
 562   = do  { ty1 <- zonkTcType ty
 563         ; ty2 <- reifyType ty1
 564         ; return (TH.TyVarI (reifyName tv) ty2) }
 565
 566 ------------------------------
 567 reifyTyCon :: TyCon -> TcM TH.Info
 568 reifyTyCon tc
 569   | isFunTyCon tc  = return (TH.PrimTyConI (reifyName tc) 2               False)
 570   | isPrimTyCon tc = return (TH.PrimTyConI (reifyName tc) (tyConArity tc) (isUnLiftedTyCon tc))
 571   | isSynTyCon tc
 572   = do  { let (tvs, rhs) = getSynTyConDefn tc
 573         ; rhs' <- reifyType rhs
 574         ; return (TH.TyConI $ TH.TySynD (reifyName tc) (reifyTyVars tvs) rhs') }
 575
 576 reifyTyCon tc
 577   = case algTyConRhs tc of
 578       NewTyCon data_con _ _
 579         -> do   { con <- reifyDataCon data_con
 580                 ; return (TH.TyConI $ TH.NewtypeD [] (reifyName tc) (reifyTyVars (tyConTyVars tc))
 581                                                   con [{- Don't know about deriving -}]) }
 582
 583       DataTyCon mb_cxt cons _
 584         -> do   { cxt <- reifyCxt (mb_cxt `orElse` [])
 585                 ; cons <- mapM reifyDataCon (tyConDataCons tc)
 586                 ; return (TH.TyConI $ TH.DataD cxt (reifyName tc) (reifyTyVars (tyConTyVars tc))
 587                                                cons [{- Don't know about deriving -}]) }
 588
 589 reifyDataCon :: DataCon -> TcM TH.Con
 590 reifyDataCon dc
 591   | isVanillaDataCon dc
 592   = do  { arg_tys <- reifyTypes (dataConOrigArgTys dc)
 593         ; let stricts = map reifyStrict (dataConStrictMarks dc)
 594               fields  = dataConFieldLabels dc
 595               name    = reifyName dc
 596               [a1,a2] = arg_tys
 597               [s1,s2] = stricts
 598         ; ASSERT( length arg_tys == length stricts )
 599           if not (null fields) then
 600              return (TH.RecC name (zip3 (map reifyName fields) stricts arg_tys))
 601           else
 602           if dataConIsInfix dc then
 603              ASSERT( length arg_tys == 2 )
 604              return (TH.InfixC (s1,a1) name (s1,a2))
 605           else
 606              return (TH.NormalC name (stricts `zip` arg_tys)) }
 607   | otherwise
 608   = failWithTc (ptext SLIT("Can't reify a non-Haskell-98 data constructor:")
 609                 <+> quotes (ppr dc))
 610
 611 ------------------------------
 612 reifyClass :: Class -> TcM TH.Info
 613 reifyClass cls
 614   = do  { cxt <- reifyCxt theta
 615         ; ops <- mapM reify_op op_stuff
 616         ; return (TH.ClassI $ TH.ClassD cxt (reifyName cls) (reifyTyVars tvs) fds' ops) }
 617   where
 618     (tvs, fds, theta, _, op_stuff) = classExtraBigSig cls
 619     fds' = map reifyFunDep fds
 620     reify_op (op, _) = do { ty <- reifyType (idType op)
 621                           ; return (TH.SigD (reifyName op) ty) }
 622
 623 ------------------------------
 624 reifyType :: TypeRep.Type -> TcM TH.Type
 625 reifyType (TyVarTy tv)      = return (TH.VarT (reifyName tv))
 626 reifyType (TyConApp tc tys) = reify_tc_app (reifyName tc) tys
 627 reifyType (NoteTy _ ty)     = reifyType ty
 628 reifyType (AppTy t1 t2)     = do { [r1,r2] <- reifyTypes [t1,t2] ; return (r1 `TH.AppT` r2) }
 629 reifyType (FunTy t1 t2)     = do { [r1,r2] <- reifyTypes [t1,t2] ; return (TH.ArrowT `TH.AppT` r1 `TH.AppT` r2) }
 630 reifyType ty@(ForAllTy _ _) = do { cxt' <- reifyCxt cxt;
 631                                  ; tau' <- reifyType tau
 632                                  ; return (TH.ForallT (reifyTyVars tvs) cxt' tau') }
 633                             where
 634                                 (tvs, cxt, tau) = tcSplitSigmaTy ty
 635 reifyTypes = mapM reifyType
 636 reifyCxt   = mapM reifyPred
 637
 638 reifyFunDep :: ([TyVar], [TyVar]) -> TH.FunDep
 639 reifyFunDep (xs, ys) = TH.FunDep (map reifyName xs) (map reifyName ys)
 640
 641 reifyTyVars :: [TyVar] -> [TH.Name]
 642 reifyTyVars = map reifyName
 643
 644 reify_tc_app :: TH.Name -> [TypeRep.Type] -> TcM TH.Type
 645 reify_tc_app tc tys = do { tys' <- reifyTypes tys
 646                          ; return (foldl TH.AppT (TH.ConT tc) tys') }
 647
 648 reifyPred :: TypeRep.PredType -> TcM TH.Type
 649 reifyPred (ClassP cls tys) = reify_tc_app (reifyName cls) tys
 650 reifyPred p@(IParam _ _)   = noTH SLIT("implicit parameters") (ppr p)
 651
 652
 653 ------------------------------
 654 reifyName :: NamedThing n => n -> TH.Name
 655 reifyName thing
 656   | isExternalName name = mk_varg mod occ_str
 657   | otherwise           = TH.mkNameU occ_str (getKey (getUnique name))
 658         -- Many of the things we reify have local bindings, and
 659         -- NameL's aren't supposed to appear in binding positions, so
 660         -- we use NameU.  When/if we start to reify nested things, that
 661         -- have free variables, we may need to generate NameL's for them.
 662   where
 663     name    = getName thing
 664     mod     = moduleUserString (nameModule name)
 665     occ_str = occNameUserString occ
 666     occ     = nameOccName name
 667     mk_varg | OccName.isDataOcc occ = TH.mkNameG_d
 668             | OccName.isVarOcc  occ = TH.mkNameG_v
 669             | OccName.isTcOcc   occ = TH.mkNameG_tc
 670             | otherwise             = pprPanic "reifyName" (ppr name)
 671
 672 ------------------------------
 673 reifyFixity :: Name -> TcM TH.Fixity
 674 reifyFixity name
 675   = do  { fix <- lookupFixityRn name
 676         ; return (conv_fix fix) }
 677     where
 678       conv_fix (BasicTypes.Fixity i d) = TH.Fixity i (conv_dir d)
 679       conv_dir BasicTypes.InfixR = TH.InfixR
 680       conv_dir BasicTypes.InfixL = TH.InfixL
 681       conv_dir BasicTypes.InfixN = TH.InfixN
 682
 683 reifyStrict :: BasicTypes.StrictnessMark -> TH.Strict
 684 reifyStrict MarkedStrict    = TH.IsStrict
 685 reifyStrict MarkedUnboxed   = TH.IsStrict
 686 reifyStrict NotMarkedStrict = TH.NotStrict
 687
 688 ------------------------------
 689 noTH :: LitString -> SDoc -> TcM a
 690 noTH s d = failWithTc (hsep [ptext SLIT("Can't represent") <+> ptext s <+>
 691                                 ptext SLIT("in Template Haskell:"),
 692                              nest 2 d])
 693 \end{code}