ghc/compiler/typecheck/TcType.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcType]{Types used in the typechecker}
   5
   6 This module provides the Type interface for front-end parts of the
   7 compiler.  These parts
   8
   9         * treat "source types" as opaque:
  10                 newtypes, and predicates are meaningful.
  11         * look through usage types
  12
  13 The "tc" prefix is for "typechechecker", because the type checker
  14 is the principal client.
  15
  16 \begin{code}
  17 module TcType (
  18   --------------------------------
  19   -- Types
  20   TcType, TcSigmaType, TcRhoType, TcTauType, TcPredType, TcThetaType,
  21   TcTyVar, TcTyVarSet, TcKind,
  22
  23   --------------------------------
  24   -- TyVarDetails
  25   TyVarDetails(..), isUserTyVar, isSkolemTyVar, isHoleTyVar,
  26   tyVarBindingInfo,
  27
  28   --------------------------------
  29   -- Builders
  30   mkPhiTy, mkSigmaTy,
  31
  32   --------------------------------
  33   -- Splitters
  34   -- These are important because they do not look through newtypes
  35   tcSplitForAllTys, tcSplitPhiTy,
  36   tcSplitFunTy_maybe, tcSplitFunTys, tcFunArgTy, tcFunResultTy,
  37   tcSplitTyConApp, tcSplitTyConApp_maybe, tcTyConAppTyCon, tcTyConAppArgs,
  38   tcSplitAppTy_maybe, tcSplitAppTy, tcSplitSigmaTy,
  39   tcSplitMethodTy, tcGetTyVar_maybe, tcGetTyVar,
  40
  41   ---------------------------------
  42   -- Predicates.
  43   -- Again, newtypes are opaque
  44   tcEqType, tcEqTypes, tcEqPred, tcCmpType, tcCmpTypes, tcCmpPred,
  45   isSigmaTy, isOverloadedTy,
  46   isDoubleTy, isFloatTy, isIntTy,
  47   isIntegerTy, isAddrTy, isBoolTy, isUnitTy,
  48   isTauTy, tcIsTyVarTy, tcIsForAllTy,
  49   allDistinctTyVars,
  50
  51   ---------------------------------
  52   -- Misc type manipulators
  53   deNoteType, classNamesOfTheta,
  54   tyClsNamesOfType, tyClsNamesOfDFunHead,
  55   getDFunTyKey,
  56
  57   ---------------------------------
  58   -- Predicate types
  59   getClassPredTys_maybe, getClassPredTys,
  60   isPredTy, isClassPred, isTyVarClassPred, predHasFDs,
  61   mkDictTy, tcSplitPredTy_maybe,
  62   isDictTy, tcSplitDFunTy, predTyUnique,
  63   mkClassPred, isInheritablePred, isLinearPred, isIPPred, mkPredName,
  64
  65   ---------------------------------
  66   -- Foreign import and export
  67   isFFIArgumentTy,     -- :: DynFlags -> Safety -> Type -> Bool
  68   isFFIImportResultTy, -- :: DynFlags -> Type -> Bool
  69   isFFIExportResultTy, -- :: Type -> Bool
  70   isFFIExternalTy,     -- :: Type -> Bool
  71   isFFIDynArgumentTy,  -- :: Type -> Bool
  72   isFFIDynResultTy,    -- :: Type -> Bool
  73   isFFILabelTy,        -- :: Type -> Bool
  74
  75   ---------------------------------
  76   -- Unifier and matcher
  77   unifyTysX, unifyTyListsX, unifyExtendTysX,
  78   matchTy, matchTys, match,
  79
  80   --------------------------------
  81   -- Rexported from Type
  82   Kind,         -- Stuff to do with kinds is insensitive to pre/post Tc
  83   unliftedTypeKind, liftedTypeKind, openTypeKind, mkArrowKind, mkArrowKinds,
  84   superBoxity, liftedBoxity, hasMoreBoxityInfo, defaultKind, superKind,
  85   isTypeKind, isAnyTypeKind,
  86
  87   Type, SourceType(..), PredType, ThetaType,
  88   mkForAllTy, mkForAllTys,
  89   mkFunTy, mkFunTys, zipFunTys,
  90   mkTyConApp, mkGenTyConApp, mkAppTy, mkAppTys, mkSynTy, applyTy, applyTys,
  91   mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
  92
  93   isUnLiftedType,       -- Source types are always lifted
  94   isUnboxedTupleType,   -- Ditto
  95   isPrimitiveType, isTyVarTy,
  96
  97   tidyTopType, tidyType, tidyPred, tidyTypes, tidyFreeTyVars, tidyOpenType, tidyOpenTypes,
  98   tidyTyVarBndr, tidyOpenTyVar, tidyOpenTyVars,
  99   typeKind, eqKind, eqUsage,
 100
 101   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta
 102   ) where
 103
 104 #include "HsVersions.h"
 105
 106
 107 import {-# SOURCE #-} PprType( pprType )
 108 -- PprType imports TcType so that it can print intelligently
 109
 110 -- friends:
 111 import TypeRep          ( Type(..), TyNote(..), funTyCon )  -- friend
 112
 113 import Type             (       -- Re-exports
 114                           tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
 115                           Kind, Type, SourceType(..), PredType, ThetaType,
 116                           unliftedTypeKind, liftedTypeKind, openTypeKind, mkArrowKind, mkArrowKinds,
 117                           mkForAllTy, mkForAllTys, defaultKind, isTypeKind, isAnyTypeKind,
 118                           mkFunTy, mkFunTys, zipFunTys, isTyVarTy,
 119                           mkTyConApp, mkGenTyConApp, mkAppTy, mkAppTys, mkSynTy, applyTy, applyTys,
 120                           mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
 121                           isUnLiftedType, isUnboxedTupleType, isPrimitiveType,
 122                           splitNewType_maybe, splitTyConApp_maybe,
 123                           tidyTopType, tidyType, tidyPred, tidyTypes, tidyFreeTyVars, tidyOpenType, tidyOpenTypes,
 124                           tidyTyVarBndr, tidyOpenTyVar, tidyOpenTyVars, eqKind, eqUsage,
 125                           hasMoreBoxityInfo, liftedBoxity, superBoxity, typeKind, superKind
 126                         )
 127 import TyCon            ( TyCon, isUnLiftedTyCon )
 128 import Class            ( classHasFDs, Class )
 129 import Var              ( TyVar, tyVarKind, isMutTyVar, mutTyVarDetails )
 130 import ForeignCall      ( Safety, playSafe )
 131 import VarEnv
 132 import VarSet
 133
 134 -- others:
 135 import CmdLineOpts      ( DynFlags, DynFlag( Opt_GlasgowExts ), dopt )
 136 import Name             ( Name, NamedThing(..), mkInternalName, getSrcLoc )
 137 import OccName          ( OccName, mkDictOcc )
 138 import NameSet
 139 import PrelNames        -- Lots (e.g. in isFFIArgumentTy)
 140 import TysWiredIn       ( ptrTyCon, funPtrTyCon, addrTyCon, unitTyCon )
 141 import BasicTypes       ( IPName(..), ipNameName )
 142 import Unique           ( Unique, Uniquable(..) )
 143 import SrcLoc           ( SrcLoc )
 144 import Util             ( cmpList, thenCmp, equalLength )
 145 import Maybes           ( maybeToBool, expectJust )
 146 import Outputable
 147 \end{code}
 148
 149
 150 %************************************************************************
 151 %*                                                                      *
 152 \subsection{Types}
 153 %*                                                                      *
 154 %************************************************************************
 155
 156 The type checker divides the generic Type world into the
 157 following more structured beasts:
 158
 159 sigma ::= forall tyvars. phi
 160         -- A sigma type is a qualified type
 161         --
 162         -- Note that even if 'tyvars' is empty, theta
 163         -- may not be: e.g.   (?x::Int) => Int
 164
 165         -- Note that 'sigma' is in prenex form:
 166         -- all the foralls are at the front.
 167         -- A 'phi' type has no foralls to the right of
 168         -- an arrow
 169
 170 phi :: theta => rho
 171
 172 rho ::= sigma -> rho
 173      |  tau
 174
 175 -- A 'tau' type has no quantification anywhere
 176 -- Note that the args of a type constructor must be taus
 177 tau ::= tyvar
 178      |  tycon tau_1 .. tau_n
 179      |  tau_1 tau_2
 180      |  tau_1 -> tau_2
 181
 182 -- In all cases, a (saturated) type synonym application is legal,
 183 -- provided it expands to the required form.
 184
 185
 186 \begin{code}
 187 type SigmaType = Type
 188 type RhoType   = Type
 189 type TauType   = Type
 190 \end{code}
 191
 192 \begin{code}
 193 type TcTyVar    = TyVar         -- Might be a mutable tyvar
 194 type TcTyVarSet = TyVarSet
 195
 196 type TcType = Type              -- A TcType can have mutable type variables
 197         -- Invariant on ForAllTy in TcTypes:
 198         --      forall a. T
 199         -- a cannot occur inside a MutTyVar in T; that is,
 200         -- T is "flattened" before quantifying over a
 201
 202 type TcPredType     = PredType
 203 type TcThetaType    = ThetaType
 204 type TcSigmaType    = TcType
 205 type TcRhoType      = TcType
 206 type TcTauType      = TcType
 207 type TcKind         = TcType
 208 \end{code}
 209
 210
 211 %************************************************************************
 212 %*                                                                      *
 213 \subsection{TyVarDetails}
 214 %*                                                                      *
 215 %************************************************************************
 216
 217 TyVarDetails gives extra info about type variables, used during type
 218 checking.  It's attached to mutable type variables only.
 219 It's knot-tied back to Var.lhs.  There is no reason in principle
 220 why Var.lhs shouldn't actually have the definition, but it "belongs" here.
 221
 222 \begin{code}
 223 data TyVarDetails
 224   = HoleTv      -- Used *only* by the type checker when passing in a type
 225                 -- variable that should be side-effected to the result type.
 226                 -- Always has kind openTypeKind.
 227                 -- Never appears in types
 228
 229   | SigTv       -- Introduced when instantiating a type signature,
 230                 -- prior to checking that the defn of a fn does
 231                 -- have the expected type.  Should not be instantiated.
 232                 --
 233                 --      f :: forall a. a -> a
 234                 --      f = e
 235                 -- When checking e, with expected type (a->a), we
 236                 -- should not instantiate a
 237
 238    | ClsTv      -- Scoped type variable introduced by a class decl
 239                 --      class C a where ...
 240
 241    | InstTv     -- Ditto, but instance decl
 242
 243    | PatSigTv   -- Scoped type variable, introduced by a pattern
 244                 -- type signature
 245                 --      \ x::a -> e
 246
 247    | VanillaTv  -- Everything else
 248
 249 isUserTyVar :: TcTyVar -> Bool  -- Avoid unifying these if possible
 250 isUserTyVar tv = case mutTyVarDetails tv of
 251                    VanillaTv -> False
 252                    other     -> True
 253
 254 isSkolemTyVar :: TcTyVar -> Bool
 255 isSkolemTyVar tv = case mutTyVarDetails tv of
 256                       SigTv  -> True
 257                       ClsTv  -> True
 258                       InstTv -> True
 259                       oteher -> False
 260
 261 isHoleTyVar :: TcTyVar -> Bool
 262 -- NB:  the hole might be filled in by now, and this
 263 --      function does not check for that
 264 isHoleTyVar tv = ASSERT( isMutTyVar tv )
 265                  case mutTyVarDetails tv of
 266                         HoleTv -> True
 267                         other  -> False
 268
 269 tyVarBindingInfo :: TyVar -> SDoc       -- Used in checkSigTyVars
 270 tyVarBindingInfo tv
 271   | isMutTyVar tv
 272   = sep [ptext SLIT("is bound by the") <+> details (mutTyVarDetails tv),
 273          ptext SLIT("at") <+> ppr (getSrcLoc tv)]
 274   | otherwise
 275   = empty
 276   where
 277     details SigTv     = ptext SLIT("type signature")
 278     details ClsTv     = ptext SLIT("class declaration")
 279     details InstTv    = ptext SLIT("instance declaration")
 280     details PatSigTv  = ptext SLIT("pattern type signature")
 281     details HoleTv    = ptext SLIT("//hole//")          -- Should not happen
 282     details VanillaTv = ptext SLIT("//vanilla//")       -- Ditto
 283 \end{code}
 284
 285
 286 %************************************************************************
 287 %*                                                                      *
 288 \subsection{Tau, sigma and rho}
 289 %*                                                                      *
 290 %************************************************************************
 291
 292 \begin{code}
 293 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkPhiTy theta tau)
 294
 295 mkPhiTy :: [SourceType] -> Type -> Type
 296 mkPhiTy theta ty = foldr (\p r -> FunTy (mkPredTy p) r) ty theta
 297 \end{code}
 298
 299
 300 @isTauTy@ tests for nested for-alls.
 301
 302 \begin{code}
 303 isTauTy :: Type -> Bool
 304 isTauTy (TyVarTy v)      = True
 305 isTauTy (TyConApp _ tys) = all isTauTy tys
 306 isTauTy (AppTy a b)      = isTauTy a && isTauTy b
 307 isTauTy (FunTy a b)      = isTauTy a && isTauTy b
 308 isTauTy (SourceTy p)     = True         -- Don't look through source types
 309 isTauTy (NoteTy _ ty)    = isTauTy ty
 310 isTauTy other            = False
 311 \end{code}
 312
 313 \begin{code}
 314 getDFunTyKey :: Type -> OccName -- Get some string from a type, to be used to
 315                                 -- construct a dictionary function name
 316 getDFunTyKey (TyVarTy tv)            = getOccName tv
 317 getDFunTyKey (TyConApp tc _)         = getOccName tc
 318 getDFunTyKey (AppTy fun _)           = getDFunTyKey fun
 319 getDFunTyKey (NoteTy _ t)            = getDFunTyKey t
 320 getDFunTyKey (FunTy arg _)           = getOccName funTyCon
 321 getDFunTyKey (ForAllTy _ t)          = getDFunTyKey t
 322 getDFunTyKey (SourceTy (NType tc _)) = getOccName tc    -- Newtypes are quite reasonable
 323 getDFunTyKey ty                      = pprPanic "getDFunTyKey" (pprType ty)
 324 -- SourceTy shouldn't happen
 325 \end{code}
 326
 327
 328 %************************************************************************
 329 %*                                                                      *
 330 \subsection{Expanding and splitting}
 331 %*                                                                      *
 332 %************************************************************************
 333
 334 These tcSplit functions are like their non-Tc analogues, but
 335         a) they do not look through newtypes
 336         b) they do not look through PredTys
 337         c) [future] they ignore usage-type annotations
 338
 339 However, they are non-monadic and do not follow through mutable type
 340 variables.  It's up to you to make sure this doesn't matter.
 341
 342 \begin{code}
 343 tcSplitForAllTys :: Type -> ([TyVar], Type)
 344 tcSplitForAllTys ty = split ty ty []
 345    where
 346      split orig_ty (ForAllTy tv ty) tvs = split ty ty (tv:tvs)
 347      split orig_ty (NoteTy n  ty)   tvs = split orig_ty ty tvs
 348      split orig_ty t                tvs = (reverse tvs, orig_ty)
 349
 350 tcIsForAllTy (ForAllTy tv ty) = True
 351 tcIsForAllTy (NoteTy n ty)    = tcIsForAllTy ty
 352 tcIsForAllTy t                = False
 353
 354 tcSplitPhiTy :: Type -> ([PredType], Type)
 355 tcSplitPhiTy ty = split ty ty []
 356  where
 357   split orig_ty (FunTy arg res) ts = case tcSplitPredTy_maybe arg of
 358                                         Just p  -> split res res (p:ts)
 359                                         Nothing -> (reverse ts, orig_ty)
 360   split orig_ty (NoteTy n ty)   ts = split orig_ty ty ts
 361   split orig_ty ty              ts = (reverse ts, orig_ty)
 362
 363 tcSplitSigmaTy ty = case tcSplitForAllTys ty of
 364                         (tvs, rho) -> case tcSplitPhiTy rho of
 365                                         (theta, tau) -> (tvs, theta, tau)
 366
 367 tcTyConAppTyCon :: Type -> TyCon
 368 tcTyConAppTyCon ty = fst (tcSplitTyConApp ty)
 369
 370 tcTyConAppArgs :: Type -> [Type]
 371 tcTyConAppArgs ty = snd (tcSplitTyConApp ty)
 372
 373 tcSplitTyConApp :: Type -> (TyCon, [Type])
 374 tcSplitTyConApp ty = case tcSplitTyConApp_maybe ty of
 375                         Just stuff -> stuff
 376                         Nothing    -> pprPanic "tcSplitTyConApp" (pprType ty)
 377
 378 tcSplitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 379 tcSplitTyConApp_maybe (TyConApp tc tys)         = Just (tc, tys)
 380 tcSplitTyConApp_maybe (FunTy arg res)           = Just (funTyCon, [arg,res])
 381 tcSplitTyConApp_maybe (NoteTy n ty)             = tcSplitTyConApp_maybe ty
 382 tcSplitTyConApp_maybe (SourceTy (NType tc tys)) = Just (tc,tys)
 383         -- Newtypes are opaque, so they may be split
 384         -- However, predicates are not treated
 385         -- as tycon applications by the type checker
 386 tcSplitTyConApp_maybe other                     = Nothing
 387
 388 tcSplitFunTys :: Type -> ([Type], Type)
 389 tcSplitFunTys ty = case tcSplitFunTy_maybe ty of
 390                         Nothing        -> ([], ty)
 391                         Just (arg,res) -> (arg:args, res')
 392                                        where
 393                                           (args,res') = tcSplitFunTys res
 394
 395 tcSplitFunTy_maybe :: Type -> Maybe (Type, Type)
 396 tcSplitFunTy_maybe (FunTy arg res)  = Just (arg, res)
 397 tcSplitFunTy_maybe (NoteTy n ty)    = tcSplitFunTy_maybe ty
 398 tcSplitFunTy_maybe other            = Nothing
 399
 400 tcFunArgTy    ty = case tcSplitFunTy_maybe ty of { Just (arg,res) -> arg }
 401 tcFunResultTy ty = case tcSplitFunTy_maybe ty of { Just (arg,res) -> res }
 402
 403
 404 tcSplitAppTy_maybe :: Type -> Maybe (Type, Type)
 405 tcSplitAppTy_maybe (FunTy ty1 ty2)           = Just (TyConApp funTyCon [ty1], ty2)
 406 tcSplitAppTy_maybe (AppTy ty1 ty2)           = Just (ty1, ty2)
 407 tcSplitAppTy_maybe (NoteTy n ty)             = tcSplitAppTy_maybe ty
 408 tcSplitAppTy_maybe (SourceTy (NType tc tys)) = tc_split_app tc tys
 409         --- Don't forget that newtype!
 410 tcSplitAppTy_maybe (TyConApp tc tys)         = tc_split_app tc tys
 411 tcSplitAppTy_maybe other                     = Nothing
 412
 413 tc_split_app tc []  = Nothing
 414 tc_split_app tc tys = split tys []
 415                     where
 416                       split [ty2]    acc = Just (TyConApp tc (reverse acc), ty2)
 417                       split (ty:tys) acc = split tys (ty:acc)
 418
 419 tcSplitAppTy ty = case tcSplitAppTy_maybe ty of
 420                     Just stuff -> stuff
 421                     Nothing    -> pprPanic "tcSplitAppTy" (pprType ty)
 422
 423 tcGetTyVar_maybe :: Type -> Maybe TyVar
 424 tcGetTyVar_maybe (TyVarTy tv)   = Just tv
 425 tcGetTyVar_maybe (NoteTy _ t)   = tcGetTyVar_maybe t
 426 tcGetTyVar_maybe other          = Nothing
 427
 428 tcGetTyVar :: String -> Type -> TyVar
 429 tcGetTyVar msg ty = expectJust msg (tcGetTyVar_maybe ty)
 430
 431 tcIsTyVarTy :: Type -> Bool
 432 tcIsTyVarTy ty = maybeToBool (tcGetTyVar_maybe ty)
 433 \end{code}
 434
 435 The type of a method for class C is always of the form:
 436         Forall a1..an. C a1..an => sig_ty
 437 where sig_ty is the type given by the method's signature, and thus in general
 438 is a ForallTy.  At the point that splitMethodTy is called, it is expected
 439 that the outer Forall has already been stripped off.  splitMethodTy then
 440 returns (C a1..an, sig_ty') where sig_ty' is sig_ty with any Notes or
 441 Usages stripped off.
 442
 443 \begin{code}
 444 tcSplitMethodTy :: Type -> (PredType, Type)
 445 tcSplitMethodTy ty = split ty
 446  where
 447   split (FunTy arg res) = case tcSplitPredTy_maybe arg of
 448                             Just p  -> (p, res)
 449                             Nothing -> panic "splitMethodTy"
 450   split (NoteTy n ty)   = split ty
 451   split _               = panic "splitMethodTy"
 452
 453 tcSplitDFunTy :: Type -> ([TyVar], [SourceType], Class, [Type])
 454 -- Split the type of a dictionary function
 455 tcSplitDFunTy ty
 456   = case tcSplitSigmaTy ty       of { (tvs, theta, tau) ->
 457     case tcSplitPredTy_maybe tau of { Just (ClassP clas tys) ->
 458     (tvs, theta, clas, tys) }}
 459 \end{code}
 460
 461 (allDistinctTyVars tys tvs) = True
 462         iff
 463 all the types tys are type variables,
 464 distinct from each other and from tvs.
 465
 466 This is useful when checking that unification hasn't unified signature
 467 type variables.  For example, if the type sig is
 468         f :: forall a b. a -> b -> b
 469 we want to check that 'a' and 'b' havn't
 470         (a) been unified with a non-tyvar type
 471         (b) been unified with each other (all distinct)
 472         (c) been unified with a variable free in the environment
 473
 474 \begin{code}
 475 allDistinctTyVars :: [Type] -> TyVarSet -> Bool
 476
 477 allDistinctTyVars []       acc
 478   = True
 479 allDistinctTyVars (ty:tys) acc
 480   = case tcGetTyVar_maybe ty of
 481         Nothing                       -> False  -- (a)
 482         Just tv | tv `elemVarSet` acc -> False  -- (b) or (c)
 483                 | otherwise           -> allDistinctTyVars tys (acc `extendVarSet` tv)
 484 \end{code}
 485
 486
 487 %************************************************************************
 488 %*                                                                      *
 489 \subsection{Predicate types}
 490 %*                                                                      *
 491 %************************************************************************
 492
 493 "Predicates" are particular source types, namelyClassP or IParams
 494
 495 \begin{code}
 496 isPred :: SourceType -> Bool
 497 isPred (ClassP _ _) = True
 498 isPred (IParam _ _) = True
 499 isPred (NType _ _)  = False
 500
 501 isPredTy :: Type -> Bool
 502 isPredTy (NoteTy _ ty)  = isPredTy ty
 503 isPredTy (SourceTy sty) = isPred sty
 504 isPredTy _              = False
 505
 506 tcSplitPredTy_maybe :: Type -> Maybe PredType
 507    -- Returns Just for predicates only
 508 tcSplitPredTy_maybe (NoteTy _ ty)           = tcSplitPredTy_maybe ty
 509 tcSplitPredTy_maybe (SourceTy p) | isPred p = Just p
 510 tcSplitPredTy_maybe other                   = Nothing
 511
 512 predTyUnique :: PredType -> Unique
 513 predTyUnique (IParam n _)      = getUnique (ipNameName n)
 514 predTyUnique (ClassP clas tys) = getUnique clas
 515
 516 predHasFDs :: PredType -> Bool
 517 -- True if the predicate has functional depenencies;
 518 -- I.e. should participate in improvement
 519 predHasFDs (IParam _ _)   = True
 520 predHasFDs (ClassP cls _) = classHasFDs cls
 521
 522 mkPredName :: Unique -> SrcLoc -> SourceType -> Name
 523 mkPredName uniq loc (ClassP cls tys) = mkInternalName uniq (mkDictOcc (getOccName cls)) loc
 524 mkPredName uniq loc (IParam ip ty)   = mkInternalName uniq (getOccName (ipNameName ip)) loc
 525 \end{code}
 526
 527
 528 --------------------- Dictionary types ---------------------------------
 529
 530 \begin{code}
 531 mkClassPred clas tys = ClassP clas tys
 532
 533 isClassPred :: SourceType -> Bool
 534 isClassPred (ClassP clas tys) = True
 535 isClassPred other             = False
 536
 537 isTyVarClassPred (ClassP clas tys) = all tcIsTyVarTy tys
 538 isTyVarClassPred other             = False
 539
 540 getClassPredTys_maybe :: SourceType -> Maybe (Class, [Type])
 541 getClassPredTys_maybe (ClassP clas tys) = Just (clas, tys)
 542 getClassPredTys_maybe _                 = Nothing
 543
 544 getClassPredTys :: PredType -> (Class, [Type])
 545 getClassPredTys (ClassP clas tys) = (clas, tys)
 546
 547 mkDictTy :: Class -> [Type] -> Type
 548 mkDictTy clas tys = mkPredTy (ClassP clas tys)
 549
 550 isDictTy :: Type -> Bool
 551 isDictTy (SourceTy p)   = isClassPred p
 552 isDictTy (NoteTy _ ty)  = isDictTy ty
 553 isDictTy other          = False
 554 \end{code}
 555
 556 --------------------- Implicit parameters ---------------------------------
 557
 558 \begin{code}
 559 isIPPred :: SourceType -> Bool
 560 isIPPred (IParam _ _) = True
 561 isIPPred other        = False
 562
 563 isInheritablePred :: PredType -> Bool
 564 -- Can be inherited by a context.  For example, consider
 565 --      f x = let g y = (?v, y+x)
 566 --            in (g 3 with ?v = 8,
 567 --                g 4 with ?v = 9)
 568 -- The point is that g's type must be quantifed over ?v:
 569 --      g :: (?v :: a) => a -> a
 570 -- but it doesn't need to be quantified over the Num a dictionary
 571 -- which can be free in g's rhs, and shared by both calls to g
 572 isInheritablePred (ClassP _ _) = True
 573 isInheritablePred other      = False
 574
 575 isLinearPred :: TcPredType -> Bool
 576 isLinearPred (IParam (Linear n) _) = True
 577 isLinearPred other                 = False
 578 \end{code}
 579
 580
 581 %************************************************************************
 582 %*                                                                      *
 583 \subsection{Comparison}
 584 %*                                                                      *
 585 %************************************************************************
 586
 587 Comparison, taking note of newtypes, predicates, etc,
 588 But ignoring usage types
 589
 590 \begin{code}
 591 tcEqType :: Type -> Type -> Bool
 592 tcEqType ty1 ty2 = case ty1 `tcCmpType` ty2 of { EQ -> True; other -> False }
 593
 594 tcEqTypes :: [Type] -> [Type] -> Bool
 595 tcEqTypes ty1 ty2 = case ty1 `tcCmpTypes` ty2 of { EQ -> True; other -> False }
 596
 597 tcEqPred :: PredType -> PredType -> Bool
 598 tcEqPred p1 p2 = case p1 `tcCmpPred` p2 of { EQ -> True; other -> False }
 599
 600 -------------
 601 tcCmpType :: Type -> Type -> Ordering
 602 tcCmpType ty1 ty2 = cmpTy emptyVarEnv ty1 ty2
 603
 604 tcCmpTypes tys1 tys2 = cmpTys emptyVarEnv tys1 tys2
 605
 606 tcCmpPred p1 p2 = cmpSourceTy emptyVarEnv p1 p2
 607 -------------
 608 cmpTys env tys1 tys2 = cmpList (cmpTy env) tys1 tys2
 609
 610 -------------
 611 cmpTy :: TyVarEnv TyVar -> Type -> Type -> Ordering
 612   -- The "env" maps type variables in ty1 to type variables in ty2
 613   -- So when comparing for-alls.. (forall tv1 . t1) (forall tv2 . t2)
 614   -- we in effect substitute tv2 for tv1 in t1 before continuing
 615
 616     -- Look through NoteTy
 617 cmpTy env (NoteTy _ ty1) ty2 = cmpTy env ty1 ty2
 618 cmpTy env ty1 (NoteTy _ ty2) = cmpTy env ty1 ty2
 619
 620     -- Deal with equal constructors
 621 cmpTy env (TyVarTy tv1) (TyVarTy tv2) = case lookupVarEnv env tv1 of
 622                                           Just tv1a -> tv1a `compare` tv2
 623                                           Nothing   -> tv1  `compare` tv2
 624
 625 cmpTy env (SourceTy p1) (SourceTy p2) = cmpSourceTy env p1 p2
 626 cmpTy env (AppTy f1 a1) (AppTy f2 a2) = cmpTy env f1 f2 `thenCmp` cmpTy env a1 a2
 627 cmpTy env (FunTy f1 a1) (FunTy f2 a2) = cmpTy env f1 f2 `thenCmp` cmpTy env a1 a2
 628 cmpTy env (TyConApp tc1 tys1) (TyConApp tc2 tys2) = (tc1 `compare` tc2) `thenCmp` (cmpTys env tys1 tys2)
 629 cmpTy env (ForAllTy tv1 t1)   (ForAllTy tv2 t2)   = cmpTy (extendVarEnv env tv1 tv2) t1 t2
 630
 631     -- Deal with the rest: TyVarTy < AppTy < FunTy < TyConApp < ForAllTy < SourceTy
 632 cmpTy env (AppTy _ _) (TyVarTy _) = GT
 633
 634 cmpTy env (FunTy _ _) (TyVarTy _) = GT
 635 cmpTy env (FunTy _ _) (AppTy _ _) = GT
 636
 637 cmpTy env (TyConApp _ _) (TyVarTy _) = GT
 638 cmpTy env (TyConApp _ _) (AppTy _ _) = GT
 639 cmpTy env (TyConApp _ _) (FunTy _ _) = GT
 640
 641 cmpTy env (ForAllTy _ _) (TyVarTy _)    = GT
 642 cmpTy env (ForAllTy _ _) (AppTy _ _)    = GT
 643 cmpTy env (ForAllTy _ _) (FunTy _ _)    = GT
 644 cmpTy env (ForAllTy _ _) (TyConApp _ _) = GT
 645
 646 cmpTy env (SourceTy _)   t2             = GT
 647
 648 cmpTy env _ _ = LT
 649 \end{code}
 650
 651 \begin{code}
 652 cmpSourceTy :: TyVarEnv TyVar -> SourceType -> SourceType -> Ordering
 653 cmpSourceTy env (IParam n1 ty1) (IParam n2 ty2) = (n1 `compare` n2) `thenCmp` (cmpTy env ty1 ty2)
 654         -- Compare types as well as names for implicit parameters
 655         -- This comparison is used exclusively (I think) for the
 656         -- finite map built in TcSimplify
 657 cmpSourceTy env (IParam _ _)     sty              = LT
 658
 659 cmpSourceTy env (ClassP _ _)     (IParam _ _)     = GT
 660 cmpSourceTy env (ClassP c1 tys1) (ClassP c2 tys2) = (c1 `compare` c2) `thenCmp` (cmpTys env tys1 tys2)
 661 cmpSourceTy env (ClassP _ _)     (NType _ _)      = LT
 662
 663 cmpSourceTy env (NType tc1 tys1) (NType tc2 tys2) = (tc1 `compare` tc2) `thenCmp` (cmpTys env tys1 tys2)
 664 cmpSourceTy env (NType _ _)      sty              = GT
 665 \end{code}
 666
 667 PredTypes are used as a FM key in TcSimplify,
 668 so we take the easy path and make them an instance of Ord
 669
 670 \begin{code}
 671 instance Eq  SourceType where { (==)    = tcEqPred }
 672 instance Ord SourceType where { compare = tcCmpPred }
 673 \end{code}
 674
 675
 676 %************************************************************************
 677 %*                                                                      *
 678 \subsection{Predicates}
 679 %*                                                                      *
 680 %************************************************************************
 681
 682 isSigmaTy returns true of any qualified type.  It doesn't *necessarily* have
 683 any foralls.  E.g.
 684         f :: (?x::Int) => Int -> Int
 685
 686 \begin{code}
 687 isSigmaTy :: Type -> Bool
 688 isSigmaTy (ForAllTy tyvar ty) = True
 689 isSigmaTy (FunTy a b)         = isPredTy a
 690 isSigmaTy (NoteTy n ty)       = isSigmaTy ty
 691 isSigmaTy _                   = False
 692
 693 isOverloadedTy :: Type -> Bool
 694 isOverloadedTy (ForAllTy tyvar ty) = isOverloadedTy ty
 695 isOverloadedTy (FunTy a b)         = isPredTy a
 696 isOverloadedTy (NoteTy n ty)       = isOverloadedTy ty
 697 isOverloadedTy _                   = False
 698 \end{code}
 699
 700 \begin{code}
 701 isFloatTy      = is_tc floatTyConKey
 702 isDoubleTy     = is_tc doubleTyConKey
 703 isIntegerTy    = is_tc integerTyConKey
 704 isIntTy        = is_tc intTyConKey
 705 isAddrTy       = is_tc addrTyConKey
 706 isBoolTy       = is_tc boolTyConKey
 707 isUnitTy       = is_tc unitTyConKey
 708
 709 is_tc :: Unique -> Type -> Bool
 710 -- Newtypes are opaque to this
 711 is_tc uniq ty = case tcSplitTyConApp_maybe ty of
 712                         Just (tc, _) -> uniq == getUnique tc
 713                         Nothing      -> False
 714 \end{code}
 715
 716
 717 %************************************************************************
 718 %*                                                                      *
 719 \subsection{Misc}
 720 %*                                                                      *
 721 %************************************************************************
 722
 723 \begin{code}
 724 deNoteType :: Type -> Type
 725         -- Remove synonyms, but not source types
 726 deNoteType ty@(TyVarTy tyvar)   = ty
 727 deNoteType (TyConApp tycon tys) = TyConApp tycon (map deNoteType tys)
 728 deNoteType (SourceTy p)         = SourceTy (deNoteSourceType p)
 729 deNoteType (NoteTy _ ty)        = deNoteType ty
 730 deNoteType (AppTy fun arg)      = AppTy (deNoteType fun) (deNoteType arg)
 731 deNoteType (FunTy fun arg)      = FunTy (deNoteType fun) (deNoteType arg)
 732 deNoteType (ForAllTy tv ty)     = ForAllTy tv (deNoteType ty)
 733
 734 deNoteSourceType :: SourceType -> SourceType
 735 deNoteSourceType (ClassP c tys)   = ClassP c (map deNoteType tys)
 736 deNoteSourceType (IParam n ty)    = IParam n (deNoteType ty)
 737 deNoteSourceType (NType tc tys)   = NType tc (map deNoteType tys)
 738 \end{code}
 739
 740 Find the free tycons and classes of a type.  This is used in the front
 741 end of the compiler.
 742
 743 \begin{code}
 744 tyClsNamesOfType :: Type -> NameSet
 745 tyClsNamesOfType (TyVarTy tv)               = emptyNameSet
 746 tyClsNamesOfType (TyConApp tycon tys)       = unitNameSet (getName tycon) `unionNameSets` tyClsNamesOfTypes tys
 747 tyClsNamesOfType (NoteTy (SynNote ty1) ty2) = tyClsNamesOfType ty1
 748 tyClsNamesOfType (NoteTy other_note    ty2) = tyClsNamesOfType ty2
 749 tyClsNamesOfType (SourceTy (IParam n ty))   = tyClsNamesOfType ty
 750 tyClsNamesOfType (SourceTy (ClassP cl tys)) = unitNameSet (getName cl) `unionNameSets` tyClsNamesOfTypes tys
 751 tyClsNamesOfType (SourceTy (NType tc tys))  = unitNameSet (getName tc) `unionNameSets` tyClsNamesOfTypes tys
 752 tyClsNamesOfType (FunTy arg res)            = tyClsNamesOfType arg `unionNameSets` tyClsNamesOfType res
 753 tyClsNamesOfType (AppTy fun arg)            = tyClsNamesOfType fun `unionNameSets` tyClsNamesOfType arg
 754 tyClsNamesOfType (ForAllTy tyvar ty)        = tyClsNamesOfType ty
 755
 756 tyClsNamesOfTypes tys = foldr (unionNameSets . tyClsNamesOfType) emptyNameSet tys
 757
 758 tyClsNamesOfDFunHead :: Type -> NameSet
 759 -- Find the free type constructors and classes
 760 -- of the head of the dfun instance type
 761 -- The 'dfun_head_type' is because of
 762 --      instance Foo a => Baz T where ...
 763 -- The decl is an orphan if Baz and T are both not locally defined,
 764 --      even if Foo *is* locally defined
 765 tyClsNamesOfDFunHead dfun_ty
 766   = case tcSplitSigmaTy dfun_ty of
 767         (tvs,_,head_ty) -> tyClsNamesOfType head_ty
 768
 769 classNamesOfTheta :: ThetaType -> [Name]
 770 -- Looks just for ClassP things; maybe it should check
 771 classNamesOfTheta preds = [ getName c | ClassP c _ <- preds ]
 772 \end{code}
 773
 774
 775 %************************************************************************
 776 %*                                                                      *
 777 \subsection[TysWiredIn-ext-type]{External types}
 778 %*                                                                      *
 779 %************************************************************************
 780
 781 The compiler's foreign function interface supports the passing of a
 782 restricted set of types as arguments and results (the restricting factor
 783 being the )
 784
 785 \begin{code}
 786 isFFIArgumentTy :: DynFlags -> Safety -> Type -> Bool
 787 -- Checks for valid argument type for a 'foreign import'
 788 isFFIArgumentTy dflags safety ty
 789    = checkRepTyCon (legalOutgoingTyCon dflags safety) ty
 790
 791 isFFIExternalTy :: Type -> Bool
 792 -- Types that are allowed as arguments of a 'foreign export'
 793 isFFIExternalTy ty = checkRepTyCon legalFEArgTyCon ty
 794
 795 isFFIImportResultTy :: DynFlags -> Type -> Bool
 796 isFFIImportResultTy dflags ty
 797   = checkRepTyCon (legalFIResultTyCon dflags) ty
 798
 799 isFFIExportResultTy :: Type -> Bool
 800 isFFIExportResultTy ty = checkRepTyCon legalFEResultTyCon ty
 801
 802 isFFIDynArgumentTy :: Type -> Bool
 803 -- The argument type of a foreign import dynamic must be Ptr, FunPtr, Addr,
 804 -- or a newtype of either.
 805 isFFIDynArgumentTy = checkRepTyCon (\tc -> tc == ptrTyCon || tc == funPtrTyCon || tc == addrTyCon)
 806
 807 isFFIDynResultTy :: Type -> Bool
 808 -- The result type of a foreign export dynamic must be Ptr, FunPtr, Addr,
 809 -- or a newtype of either.
 810 isFFIDynResultTy = checkRepTyCon (\tc -> tc == ptrTyCon || tc == funPtrTyCon || tc == addrTyCon)
 811
 812 isFFILabelTy :: Type -> Bool
 813 -- The type of a foreign label must be Ptr, FunPtr, Addr,
 814 -- or a newtype of either.
 815 isFFILabelTy = checkRepTyCon (\tc -> tc == ptrTyCon || tc == funPtrTyCon || tc == addrTyCon)
 816
 817 checkRepTyCon :: (TyCon -> Bool) -> Type -> Bool
 818         -- Look through newtypes
 819         -- Non-recursive ones are transparent to splitTyConApp,
 820         -- but recursive ones aren't; hence the splitNewType_maybe
 821 checkRepTyCon check_tc ty
 822   | Just ty'    <- splitNewType_maybe ty  = checkRepTyCon check_tc ty'
 823   | Just (tc,_) <- splitTyConApp_maybe ty = check_tc tc
 824   | otherwise                             = False
 825 \end{code}
 826
 827 ----------------------------------------------
 828 These chaps do the work; they are not exported
 829 ----------------------------------------------
 830
 831 \begin{code}
 832 legalFEArgTyCon :: TyCon -> Bool
 833 -- It's illegal to return foreign objects and (mutable)
 834 -- bytearrays from a _ccall_ / foreign declaration
 835 -- (or be passed them as arguments in foreign exported functions).
 836 legalFEArgTyCon tc
 837   | getUnique tc `elem` [ byteArrayTyConKey, mutableByteArrayTyConKey ]
 838   = False
 839   -- It's also illegal to make foreign exports that take unboxed
 840   -- arguments.  The RTS API currently can't invoke such things.  --SDM 7/2000
 841   | otherwise
 842   = boxedMarshalableTyCon tc
 843
 844 legalFIResultTyCon :: DynFlags -> TyCon -> Bool
 845 legalFIResultTyCon dflags tc
 846   | getUnique tc `elem`
 847         [ byteArrayTyConKey, mutableByteArrayTyConKey ]  = False
 848   | tc == unitTyCon = True
 849   | otherwise       = marshalableTyCon dflags tc
 850
 851 legalFEResultTyCon :: TyCon -> Bool
 852 legalFEResultTyCon tc
 853   | getUnique tc `elem`
 854         [ byteArrayTyConKey, mutableByteArrayTyConKey ]  = False
 855   | tc == unitTyCon = True
 856   | otherwise       = boxedMarshalableTyCon tc
 857
 858 legalOutgoingTyCon :: DynFlags -> Safety -> TyCon -> Bool
 859 -- Checks validity of types going from Haskell -> external world
 860 legalOutgoingTyCon dflags safety tc
 861   | playSafe safety && getUnique tc `elem` [byteArrayTyConKey, mutableByteArrayTyConKey]
 862   = False
 863   | otherwise
 864   = marshalableTyCon dflags tc
 865
 866 marshalableTyCon dflags tc
 867   =  (dopt Opt_GlasgowExts dflags && isUnLiftedTyCon tc)
 868   || boxedMarshalableTyCon tc
 869
 870 boxedMarshalableTyCon tc
 871    = getUnique tc `elem` [ intTyConKey, int8TyConKey, int16TyConKey
 872                          , int32TyConKey, int64TyConKey
 873                          , wordTyConKey, word8TyConKey, word16TyConKey
 874                          , word32TyConKey, word64TyConKey
 875                          , floatTyConKey, doubleTyConKey
 876                          , addrTyConKey, ptrTyConKey, funPtrTyConKey
 877                          , charTyConKey
 878                          , stablePtrTyConKey
 879                          , byteArrayTyConKey, mutableByteArrayTyConKey
 880                          , boolTyConKey
 881                          ]
 882 \end{code}
 883
 884
 885 %************************************************************************
 886 %*                                                                      *
 887 \subsection{Unification with an explicit substitution}
 888 %*                                                                      *
 889 %************************************************************************
 890
 891 Unify types with an explicit substitution and no monad.
 892 Ignore usage annotations.
 893
 894 \begin{code}
 895 type MySubst
 896    = (TyVarSet,         -- Set of template tyvars
 897       TyVarSubstEnv)    -- Not necessarily idempotent
 898
 899 unifyTysX :: TyVarSet           -- Template tyvars
 900           -> Type
 901           -> Type
 902           -> Maybe TyVarSubstEnv
 903 unifyTysX tmpl_tyvars ty1 ty2
 904   = uTysX ty1 ty2 (\(_,s) -> Just s) (tmpl_tyvars, emptySubstEnv)
 905
 906 unifyExtendTysX :: TyVarSet             -- Template tyvars
 907                 -> TyVarSubstEnv        -- Substitution to start with
 908                 -> Type
 909                 -> Type
 910                 -> Maybe TyVarSubstEnv  -- Extended substitution
 911 unifyExtendTysX tmpl_tyvars subst ty1 ty2
 912   = uTysX ty1 ty2 (\(_,s) -> Just s) (tmpl_tyvars, subst)
 913
 914 unifyTyListsX :: TyVarSet -> [Type] -> [Type]
 915               -> Maybe TyVarSubstEnv
 916 unifyTyListsX tmpl_tyvars tys1 tys2
 917   = uTyListsX tys1 tys2 (\(_,s) -> Just s) (tmpl_tyvars, emptySubstEnv)
 918
 919
 920 uTysX :: Type
 921       -> Type
 922       -> (MySubst -> Maybe result)
 923       -> MySubst
 924       -> Maybe result
 925
 926 uTysX (NoteTy _ ty1) ty2 k subst = uTysX ty1 ty2 k subst
 927 uTysX ty1 (NoteTy _ ty2) k subst = uTysX ty1 ty2 k subst
 928
 929         -- Variables; go for uVar
 930 uTysX (TyVarTy tyvar1) (TyVarTy tyvar2) k subst
 931   | tyvar1 == tyvar2
 932   = k subst
 933 uTysX (TyVarTy tyvar1) ty2 k subst@(tmpls,_)
 934   | tyvar1 `elemVarSet` tmpls
 935   = uVarX tyvar1 ty2 k subst
 936 uTysX ty1 (TyVarTy tyvar2) k subst@(tmpls,_)
 937   | tyvar2 `elemVarSet` tmpls
 938   = uVarX tyvar2 ty1 k subst
 939
 940         -- Predicates
 941 uTysX (SourceTy (IParam n1 t1)) (SourceTy (IParam n2 t2)) k subst
 942   | n1 == n2 = uTysX t1 t2 k subst
 943 uTysX (SourceTy (ClassP c1 tys1)) (SourceTy (ClassP c2 tys2)) k subst
 944   | c1 == c2 = uTyListsX tys1 tys2 k subst
 945 uTysX (SourceTy (NType tc1 tys1)) (SourceTy (NType tc2 tys2)) k subst
 946   | tc1 == tc2 = uTyListsX tys1 tys2 k subst
 947
 948         -- Functions; just check the two parts
 949 uTysX (FunTy fun1 arg1) (FunTy fun2 arg2) k subst
 950   = uTysX fun1 fun2 (uTysX arg1 arg2 k) subst
 951
 952         -- Type constructors must match
 953 uTysX (TyConApp con1 tys1) (TyConApp con2 tys2) k subst
 954   | (con1 == con2 && equalLength tys1 tys2)
 955   = uTyListsX tys1 tys2 k subst
 956
 957         -- Applications need a bit of care!
 958         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 959         -- NB: we've already dealt with type variables and Notes,
 960         -- so if one type is an App the other one jolly well better be too
 961 uTysX (AppTy s1 t1) ty2 k subst
 962   = case tcSplitAppTy_maybe ty2 of
 963       Just (s2, t2) -> uTysX s1 s2 (uTysX t1 t2 k) subst
 964       Nothing       -> Nothing    -- Fail
 965
 966 uTysX ty1 (AppTy s2 t2) k subst
 967   = case tcSplitAppTy_maybe ty1 of
 968       Just (s1, t1) -> uTysX s1 s2 (uTysX t1 t2 k) subst
 969       Nothing       -> Nothing    -- Fail
 970
 971         -- Not expecting for-alls in unification
 972 #ifdef DEBUG
 973 uTysX (ForAllTy _ _) ty2 k subst = panic "Unify.uTysX subst:ForAllTy (1st arg)"
 974 uTysX ty1 (ForAllTy _ _) k subst = panic "Unify.uTysX subst:ForAllTy (2nd arg)"
 975 #endif
 976
 977         -- Anything else fails
 978 uTysX ty1 ty2 k subst = Nothing
 979
 980
 981 uTyListsX []         []         k subst = k subst
 982 uTyListsX (ty1:tys1) (ty2:tys2) k subst = uTysX ty1 ty2 (uTyListsX tys1 tys2 k) subst
 983 uTyListsX tys1       tys2       k subst = Nothing   -- Fail if the lists are different lengths
 984 \end{code}
 985
 986 \begin{code}
 987 -- Invariant: tv1 is a unifiable variable
 988 uVarX tv1 ty2 k subst@(tmpls, env)
 989   = case lookupSubstEnv env tv1 of
 990       Just (DoneTy ty1) ->    -- Already bound
 991                      uTysX ty1 ty2 k subst
 992
 993       Nothing        -- Not already bound
 994                |  typeKind ty2 `eqKind` tyVarKind tv1
 995                && occur_check_ok ty2
 996                ->     -- No kind mismatch nor occur check
 997                   k (tmpls, extendSubstEnv env tv1 (DoneTy ty2))
 998
 999                | otherwise -> Nothing   -- Fail if kind mis-match or occur check
1000   where
1001     occur_check_ok ty = all occur_check_ok_tv (varSetElems (tyVarsOfType ty))
1002     occur_check_ok_tv tv | tv1 == tv = False
1003                          | otherwise = case lookupSubstEnv env tv of
1004                                          Nothing           -> True
1005                                          Just (DoneTy ty)  -> occur_check_ok ty
1006 \end{code}
1007
1008
1009
1010 %************************************************************************
1011 %*                                                                      *
1012 \subsection{Matching on types}
1013 %*                                                                      *
1014 %************************************************************************
1015
1016 Matching is a {\em unidirectional} process, matching a type against a
1017 template (which is just a type with type variables in it).  The
1018 matcher assumes that there are no repeated type variables in the
1019 template, so that it simply returns a mapping of type variables to
1020 types.  It also fails on nested foralls.
1021
1022 @matchTys@ matches corresponding elements of a list of templates and
1023 types.  It and @matchTy@ both ignore usage annotations, unlike the
1024 main function @match@.
1025
1026 \begin{code}
1027 matchTy :: TyVarSet                     -- Template tyvars
1028         -> Type                         -- Template
1029         -> Type                         -- Proposed instance of template
1030         -> Maybe TyVarSubstEnv          -- Matching substitution
1031
1032
1033 matchTys :: TyVarSet                    -- Template tyvars
1034          -> [Type]                      -- Templates
1035          -> [Type]                      -- Proposed instance of template
1036          -> Maybe (TyVarSubstEnv,               -- Matching substitution
1037                    [Type])              -- Left over instance types
1038
1039 matchTy tmpls ty1 ty2 = match ty1 ty2 tmpls (\ senv -> Just senv) emptySubstEnv
1040
1041 matchTys tmpls tys1 tys2 = match_list tys1 tys2 tmpls
1042                                       (\ (senv,tys) -> Just (senv,tys))
1043                                       emptySubstEnv
1044 \end{code}
1045
1046 @match@ is the main function.  It takes a flag indicating whether
1047 usage annotations are to be respected.
1048
1049 \begin{code}
1050 match :: Type -> Type                           -- Current match pair
1051       -> TyVarSet                               -- Template vars
1052       -> (TyVarSubstEnv -> Maybe result)        -- Continuation
1053       -> TyVarSubstEnv                          -- Current subst
1054       -> Maybe result
1055
1056 -- When matching against a type variable, see if the variable
1057 -- has already been bound.  If so, check that what it's bound to
1058 -- is the same as ty; if not, bind it and carry on.
1059
1060 match (TyVarTy v) ty tmpls k senv
1061   | v `elemVarSet` tmpls
1062   =     -- v is a template variable
1063     case lookupSubstEnv senv v of
1064         Nothing | typeKind ty `eqKind` tyVarKind v
1065                         -- We do a kind check, just as in the uVarX above
1066                         -- The kind check is needed to avoid bogus matches
1067                         -- of   (a b) with (c d), where the kinds don't match
1068                         -- An occur check isn't needed when matching.
1069                 -> k (extendSubstEnv senv v (DoneTy ty))
1070
1071                 | otherwise  -> Nothing -- Fails
1072
1073         Just (DoneTy ty')  | ty' `tcEqType` ty   -> k senv   -- Succeeds
1074                            | otherwise           -> Nothing  -- Fails
1075
1076   | otherwise
1077   =     -- v is not a template variable; ty had better match
1078         -- Can't use (==) because types differ
1079     case tcGetTyVar_maybe ty of
1080         Just v' | v == v' -> k senv    -- Success
1081         other             -> Nothing   -- Failure
1082     -- This tcGetTyVar_maybe is *required* because it must strip Notes.
1083     -- I guess the reason the Note-stripping case is *last* rather than first
1084     -- is to preserve type synonyms etc., so I'm not moving it to the
1085     -- top; but this means that (without the deNotetype) a type
1086     -- variable may not match the pattern (TyVarTy v') as one would
1087     -- expect, due to an intervening Note.  KSW 2000-06.
1088
1089         -- Predicates
1090 match (SourceTy (IParam n1 t1)) (SourceTy (IParam n2 t2)) tmpls k senv
1091   | n1 == n2 = match t1 t2 tmpls k senv
1092 match (SourceTy (ClassP c1 tys1)) (SourceTy (ClassP c2 tys2)) tmpls k senv
1093   | c1 == c2 = match_list_exactly tys1 tys2 tmpls k senv
1094 match (SourceTy (NType tc1 tys1)) (SourceTy (NType tc2 tys2)) tmpls k senv
1095   | tc1 == tc2 = match_list_exactly tys1 tys2 tmpls k senv
1096
1097         -- Functions; just check the two parts
1098 match (FunTy arg1 res1) (FunTy arg2 res2) tmpls k senv
1099   = match arg1 arg2 tmpls (match res1 res2 tmpls k) senv
1100
1101 match (AppTy fun1 arg1) ty2 tmpls k senv
1102   = case tcSplitAppTy_maybe ty2 of
1103         Just (fun2,arg2) -> match fun1 fun2 tmpls (match arg1 arg2 tmpls k) senv
1104         Nothing          -> Nothing     -- Fail
1105
1106 match (TyConApp tc1 tys1) (TyConApp tc2 tys2) tmpls k senv
1107   | tc1 == tc2 = match_list_exactly tys1 tys2 tmpls k senv
1108
1109 -- Newtypes are opaque; other source types should not happen
1110 match (SourceTy (NType tc1 tys1)) (SourceTy (NType tc2 tys2)) tmpls k senv
1111   | tc1 == tc2 = match_list_exactly tys1 tys2 tmpls k senv
1112
1113         -- With type synonyms, we have to be careful for the exact
1114         -- same reasons as in the unifier.  Please see the
1115         -- considerable commentary there before changing anything
1116         -- here! (WDP 95/05)
1117 match (NoteTy n1 ty1) ty2      tmpls k senv = match ty1 ty2 tmpls k senv
1118 match ty1      (NoteTy n2 ty2) tmpls k senv = match ty1 ty2 tmpls k senv
1119
1120 -- Catch-all fails
1121 match _ _ _ _ _ = Nothing
1122
1123 match_list_exactly tys1 tys2 tmpls k senv
1124   = match_list tys1 tys2 tmpls k' senv
1125   where
1126     k' (senv', tys2') | null tys2' = k senv'    -- Succeed
1127                       | otherwise  = Nothing    -- Fail
1128
1129 match_list []         tys2       tmpls k senv = k (senv, tys2)
1130 match_list (ty1:tys1) []         tmpls k senv = Nothing -- Not enough arg tys => failure
1131 match_list (ty1:tys1) (ty2:tys2) tmpls k senv
1132   = match ty1 ty2 tmpls (match_list tys1 tys2 tmpls k) senv
1133 \end{code}