ghc/compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Type subsumption and unification}
   5
   6 \begin{code}
   7 module TcUnify (
   8         -- Full-blown subsumption
   9   tcSubExp, tcGen,
  10   checkSigTyVars, checkSigTyVarsWrt, bleatEscapedTvs, sigCtxt,
  11
  12         -- Various unifications
  13   unifyType, unifyTypeList, unifyTheta,
  14   unifyKind, unifyKinds, unifyFunKind,
  15   checkExpectedKind,
  16   boxySubMatchType, boxyMatchTypes,
  17
  18   --------------------------------
  19   -- Holes
  20   tcInfer, subFunTys, unBox, stripBoxyType, withBox,
  21   boxyUnify, boxyUnifyList, zapToMonotype,
  22   boxySplitListTy, boxySplitTyConApp, boxySplitAppTy,
  23   wrapFunResCoercion
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn            ( ExprCoFn(..), idCoercion, isIdCoercion, (<.>) )
  29 import TypeRep          ( Type(..), PredType(..) )
  30
  31 import TcMType          ( lookupTcTyVar, LookupTyVarResult(..),
  32                           tcInstSkolType, newKindVar, newMetaTyVar,
  33                           tcInstBoxy, newBoxyTyVar, newBoxyTyVarTys, readFilledBox,
  34                           readMetaTyVar, writeMetaTyVar, newFlexiTyVarTy,
  35                           tcInstSkolTyVars,
  36                           zonkTcKind, zonkType, zonkTcType,  zonkTcTyVarsAndFV,
  37                           readKindVar, writeKindVar )
  38 import TcSimplify       ( tcSimplifyCheck )
  39 import TcEnv            ( tcGetGlobalTyVars, findGlobals )
  40 import TcIface          ( checkWiredInTyCon )
  41 import TcRnMonad         -- TcType, amongst others
  42 import TcType           ( TcKind, TcType, TcTyVar, TcTauType,
  43                           BoxySigmaType, BoxyRhoType, BoxyType,
  44                           TcTyVarSet, TcThetaType, TcTyVarDetails(..), BoxInfo(..),
  45                           SkolemInfo( GenSkol, UnkSkol ), MetaDetails(..), isImmutableTyVar,
  46                           pprSkolTvBinding, isTauTy, isTauTyCon, isSigmaTy,
  47                           mkFunTy, mkFunTys, mkTyConApp, isMetaTyVar,
  48                           tcSplitForAllTys, tcSplitAppTy_maybe, mkTyVarTys,
  49                           tyVarsOfType, mkPhiTy, mkTyVarTy, mkPredTy,
  50                           typeKind, mkForAllTys, mkAppTy, isBoxyTyVar,
  51                           tidyOpenType, tidyOpenTypes, tidyOpenTyVar, tidyOpenTyVars,
  52                           pprType, tidyKind, tidySkolemTyVar, isSkolemTyVar, tcView,
  53                           TvSubst, mkTvSubst, zipTyEnv, substTy, emptyTvSubst,
  54                           lookupTyVar, extendTvSubst )
  55 import Kind             ( Kind(..), SimpleKind, KindVar, isArgTypeKind,
  56                           openTypeKind, liftedTypeKind, mkArrowKind, defaultKind,
  57                           isOpenTypeKind, argTypeKind, isLiftedTypeKind, isUnliftedTypeKind,
  58                           isSubKind, pprKind, splitKindFunTys )
  59 import TysPrim          ( alphaTy, betaTy )
  60 import Inst             ( newDicts, instToId )
  61 import TyCon            ( TyCon, tyConArity, tyConTyVars, isSynTyCon )
  62 import TysWiredIn       ( listTyCon )
  63 import Id               ( Id, mkSysLocal )
  64 import Var              ( Var, varName, tyVarKind, isTcTyVar, tcTyVarDetails )
  65 import VarSet           ( emptyVarSet, mkVarSet, unitVarSet, unionVarSet, elemVarSet, varSetElems,
  66                           extendVarSet, intersectsVarSet )
  67 import VarEnv
  68 import Name             ( isSystemName )
  69 import ErrUtils         ( Message )
  70 import Maybes           ( fromJust, isNothing )
  71 import BasicTypes       ( Arity )
  72 import UniqSupply       ( uniqsFromSupply )
  73 import Util             ( notNull, equalLength )
  74 import Outputable
  75
  76 -- Assertion imports
  77 #ifdef DEBUG
  78 import TcType           ( isBoxyTy, isFlexi )
  79 #endif
  80 \end{code}
  81
  82 %************************************************************************
  83 %*                                                                      *
  84 \subsection{'hole' type variables}
  85 %*                                                                      *
  86 %************************************************************************
  87
  88 \begin{code}
  89 tcInfer :: (BoxyType -> TcM a) -> TcM (a, TcType)
  90 tcInfer tc_infer
  91   = do  { box <- newBoxyTyVar openTypeKind
  92         ; res <- tc_infer (mkTyVarTy box)
  93         ; res_ty <- readFilledBox box   -- Guaranteed filled-in by now
  94         ; return (res, res_ty) }
  95 \end{code}
  96
  97
  98 %************************************************************************
  99 %*                                                                      *
 100         subFunTys
 101 %*                                                                      *
 102 %************************************************************************
 103
 104 \begin{code}
 105 subFunTys :: SDoc  -- Somthing like "The function f has 3 arguments"
 106                    -- or "The abstraction (\x.e) takes 1 argument"
 107           -> Arity              -- Expected # of args
 108           -> BoxyRhoType        -- res_ty
 109           -> ([BoxySigmaType] -> BoxyRhoType -> TcM a)
 110           -> TcM (ExprCoFn, a)
 111 -- Attempt to decompse res_ty to have enough top-level arrows to
 112 -- match the number of patterns in the match group
 113 --
 114 -- If (subFunTys n_args res_ty thing_inside) = (co_fn, res)
 115 -- and the inner call to thing_inside passes args: [a1,...,an], b
 116 -- then co_fn :: (a1 -> ... -> an -> b) -> res_ty
 117 --
 118 -- Note that it takes a BoxyRho type, and guarantees to return a BoxyRhoType
 119
 120
 121 {-      Error messages from subFunTys
 122
 123    The abstraction `\Just 1 -> ...' has two arguments
 124    but its type `Maybe a -> a' has only one
 125
 126    The equation(s) for `f' have two arguments
 127    but its type `Maybe a -> a' has only one
 128
 129    The section `(f 3)' requires 'f' to take two arguments
 130    but its type `Int -> Int' has only one
 131
 132    The function 'f' is applied to two arguments
 133    but its type `Int -> Int' has only one
 134 -}
 135
 136
 137 subFunTys error_herald n_pats res_ty thing_inside
 138   = loop n_pats [] res_ty
 139   where
 140         -- In 'loop', the parameter 'arg_tys' accumulates
 141         -- the arg types so far, in *reverse order*
 142     loop n args_so_far res_ty
 143         | Just res_ty' <- tcView res_ty  = loop n args_so_far res_ty'
 144
 145     loop n args_so_far res_ty
 146         | isSigmaTy res_ty      -- Do this before checking n==0, because we
 147                                 -- guarantee to return a BoxyRhoType, not a BoxySigmaType
 148         = do { (gen_fn, (co_fn, res)) <- tcGen res_ty emptyVarSet $ \ res_ty' ->
 149                                          loop n args_so_far res_ty'
 150              ; return (gen_fn <.> co_fn, res) }
 151
 152     loop 0 args_so_far res_ty
 153         = do { res <- thing_inside (reverse args_so_far) res_ty
 154              ; return (idCoercion, res) }
 155
 156     loop n args_so_far (FunTy arg_ty res_ty)
 157         = do { (co_fn, res) <- loop (n-1) (arg_ty:args_so_far) res_ty
 158              ; co_fn' <- wrapFunResCoercion [arg_ty] co_fn
 159              ; return (co_fn', res) }
 160
 161         -- res_ty might have a type variable at the head, such as (a b c),
 162         -- in which case we must fill in with (->).  Simplest thing to do
 163         -- is to use boxyUnify, but we catch failure and generate our own
 164         -- error message on failure
 165     loop n args_so_far res_ty@(AppTy _ _)
 166         = do { [arg_ty',res_ty'] <- newBoxyTyVarTys [argTypeKind, openTypeKind]
 167              ; (_, mb_unit) <- tryTcErrs $ boxyUnify res_ty (FunTy arg_ty' res_ty')
 168              ; if isNothing mb_unit then bale_out args_so_far res_ty
 169                else loop n args_so_far (FunTy arg_ty' res_ty') }
 170
 171     loop n args_so_far (TyVarTy tv)
 172         | not (isImmutableTyVar tv)
 173         = do { cts <- readMetaTyVar tv
 174              ; case cts of
 175                  Indirect ty -> loop n args_so_far ty
 176                  Flexi -> do { (res_ty:arg_tys) <- withMetaTvs tv kinds mk_res_ty
 177                              ; res <- thing_inside (reverse args_so_far ++ arg_tys) res_ty
 178                              ; return (idCoercion, res) } }
 179         where
 180           mk_res_ty (res_ty' : arg_tys') = mkFunTys arg_tys' res_ty'
 181           kinds = openTypeKind : take n (repeat argTypeKind)
 182                 -- Note argTypeKind: the args can have an unboxed type,
 183                 -- but not an unboxed tuple.
 184
 185     loop n args_so_far res_ty = bale_out args_so_far res_ty
 186
 187     bale_out args_so_far res_ty
 188         = do { env0 <- tcInitTidyEnv
 189              ; res_ty' <- zonkTcType res_ty
 190              ; let (env1, res_ty'') = tidyOpenType env0 res_ty'
 191              ; failWithTcM (env1, mk_msg res_ty'' (length args_so_far)) }
 192
 193     mk_msg res_ty n_actual
 194       = error_herald <> comma $$
 195         sep [ptext SLIT("but its type") <+> quotes (pprType res_ty),
 196              if n_actual == 0 then ptext SLIT("has none")
 197              else ptext SLIT("has only") <+> speakN n_actual]
 198 \end{code}
 199
 200 \begin{code}
 201 ----------------------
 202 boxySplitTyConApp :: TyCon                      -- T :: k1 -> ... -> kn -> *
 203                   -> BoxyRhoType                -- Expected type (T a b c)
 204                   -> TcM [BoxySigmaType]        -- Element types, a b c
 205   -- It's used for wired-in tycons, so we call checkWiredInTyCOn
 206   -- Precondition: never called with FunTyCon
 207   -- Precondition: input type :: *
 208
 209 boxySplitTyConApp tc orig_ty
 210   = do  { checkWiredInTyCon tc
 211         ; loop (tyConArity tc) [] orig_ty }
 212   where
 213     loop n_req args_so_far ty
 214       | Just ty' <- tcView ty = loop n_req args_so_far ty'
 215
 216     loop n_req args_so_far (TyConApp tycon args)
 217       | tc == tycon
 218       = ASSERT( n_req == length args)   -- ty::*
 219         return (args ++ args_so_far)
 220
 221     loop n_req args_so_far (AppTy fun arg)
 222       = loop (n_req - 1) (arg:args_so_far) fun
 223
 224     loop n_req args_so_far (TyVarTy tv)
 225       | not (isImmutableTyVar tv)
 226       = do { cts <- readMetaTyVar tv
 227            ; case cts of
 228                Indirect ty -> loop n_req args_so_far ty
 229                Flexi       -> do { arg_tys <- withMetaTvs tv arg_kinds mk_res_ty
 230                                  ; return (arg_tys ++ args_so_far) }
 231         }
 232       where
 233         mk_res_ty arg_tys' = mkTyConApp tc arg_tys'
 234         arg_kinds = map tyVarKind (take n_req (tyConTyVars tc))
 235
 236     loop _ _ _ = boxySplitFailure (mkTyConApp tc (mkTyVarTys (tyConTyVars tc))) orig_ty
 237
 238 ----------------------
 239 boxySplitListTy :: BoxyRhoType -> TcM BoxySigmaType     -- Special case for lists
 240 boxySplitListTy exp_ty = do { [elt_ty] <- boxySplitTyConApp listTyCon exp_ty
 241                             ; return elt_ty }
 242
 243
 244 ----------------------
 245 boxySplitAppTy :: BoxyRhoType                           -- Type to split: m a
 246                -> TcM (BoxySigmaType, BoxySigmaType)    -- Returns m, a
 247 -- Assumes (m: * -> k), where k is the kind of the incoming type
 248 -- If the incoming type is boxy, then so are the result types; and vice versa
 249
 250 boxySplitAppTy orig_ty
 251   = loop orig_ty
 252   where
 253     loop ty
 254       | Just ty' <- tcView ty = loop ty'
 255
 256     loop ty
 257       | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
 258       = return (fun_ty, arg_ty)
 259
 260     loop (TyVarTy tv)
 261       | not (isImmutableTyVar tv)
 262       = do { cts <- readMetaTyVar tv
 263            ; case cts of
 264                Indirect ty -> loop ty
 265                Flexi       -> do { [fun_ty,arg_ty] <- withMetaTvs tv kinds mk_res_ty
 266                                  ; return (fun_ty, arg_ty) } }
 267       where
 268         mk_res_ty [fun_ty', arg_ty'] = mkAppTy fun_ty' arg_ty'
 269         tv_kind = tyVarKind tv
 270         kinds = [mkArrowKind liftedTypeKind (defaultKind tv_kind),
 271                                                 -- m :: * -> k
 272                  liftedTypeKind]                -- arg type :: *
 273         -- The defaultKind is a bit smelly.  If you remove it,
 274         -- try compiling        f x = do { x }
 275         -- and you'll get a kind mis-match.  It smells, but
 276         -- not enough to lose sleep over.
 277
 278     loop _ = boxySplitFailure (mkAppTy alphaTy betaTy) orig_ty
 279
 280 ------------------
 281 boxySplitFailure actual_ty expected_ty
 282   = unifyMisMatch False actual_ty expected_ty
 283 \end{code}
 284
 285
 286 --------------------------------
 287 -- withBoxes: the key utility function
 288 --------------------------------
 289
 290 \begin{code}
 291 withMetaTvs :: TcTyVar  -- An unfilled-in, non-skolem, meta type variable
 292             -> [Kind]   -- Make fresh boxes (with the same BoxTv/TauTv setting as tv)
 293             -> ([BoxySigmaType] -> BoxySigmaType)
 294                                         -- Constructs the type to assign
 295                                         -- to the original var
 296             -> TcM [BoxySigmaType]      -- Return the fresh boxes
 297
 298 -- It's entirely possible for the [kind] to be empty.
 299 -- For example, when pattern-matching on True,
 300 -- we call boxySplitTyConApp passing a boolTyCon
 301
 302 -- Invariant: tv is still Flexi
 303
 304 withMetaTvs tv kinds mk_res_ty
 305   | isBoxyTyVar tv
 306   = do  { box_tvs <- mapM (newMetaTyVar BoxTv) kinds
 307         ; let box_tys = mkTyVarTys box_tvs
 308         ; writeMetaTyVar tv (mk_res_ty box_tys)
 309         ; return box_tys }
 310
 311   | otherwise                   -- Non-boxy meta type variable
 312   = do  { tau_tys <- mapM newFlexiTyVarTy kinds
 313         ; writeMetaTyVar tv (mk_res_ty tau_tys) -- Write it *first*
 314                                                 -- Sure to be a tau-type
 315         ; return tau_tys }
 316
 317 withBox :: Kind -> (BoxySigmaType -> TcM a) -> TcM (a, TcType)
 318 -- Allocate a *boxy* tyvar
 319 withBox kind thing_inside
 320   = do  { box_tv <- newMetaTyVar BoxTv kind
 321         ; res <- thing_inside (mkTyVarTy box_tv)
 322         ; ty  <- readFilledBox box_tv
 323         ; return (res, ty) }
 324 \end{code}
 325
 326
 327 %************************************************************************
 328 %*                                                                      *
 329                 Approximate boxy matching
 330 %*                                                                      *
 331 %************************************************************************
 332
 333 \begin{code}
 334 boxySubMatchType
 335         :: TcTyVarSet -> TcType -- The "template"; the tyvars are skolems
 336         -> BoxyRhoType          -- Type to match (note a *Rho* type)
 337         -> TvSubst              -- Substitution of the [TcTyVar] to BoxySigmaTypes
 338
 339 boxyMatchTypes
 340         :: TcTyVarSet -> [TcType] -- The "template"; the tyvars are skolems
 341         -> [BoxySigmaType]        -- Type to match
 342         -> TvSubst                -- Substitution of the [TcTyVar] to BoxySigmaTypes
 343
 344 -- Find a *boxy* substitution that makes the template look as much
 345 --      like the BoxySigmaType as possible.
 346 -- It's always ok to return an empty substitution;
 347 --      anything more is jam on the pudding
 348 --
 349 -- NB1: This is a pure, non-monadic function.
 350 --      It does no unification, and cannot fail
 351 --
 352 -- Note [Matching kinds]
 353 --      The target type might legitimately not be a sub-kind of template.
 354 --      For example, suppose the target is simply a box with an OpenTypeKind,
 355 --      and the template is a type variable with LiftedTypeKind.
 356 --      Then it's ok (because the target type will later be refined).
 357 --      We simply don't bind the template type variable.
 358 --
 359 --      It might also be that the kind mis-match is an error. For example,
 360 --      suppose we match the template (a -> Int) against (Int# -> Int),
 361 --      where the template type variable 'a' has LiftedTypeKind.  This
 362 --      matching function does not fail; it simply doesn't bind the template.
 363 --      Later stuff will fail.
 364 --
 365 -- Precondition: the arg lengths are equal
 366 -- Precondition: none of the template type variables appear in the [BoxySigmaType]
 367 -- Precondition: any nested quantifiers in either type differ from
 368 --               the template type variables passed as arguments
 369 --
 370 -- Note [Sub-match]
 371 -- ~~~~~~~~~~~~~~~~
 372 -- Consider this
 373 --      head :: [a] -> a
 374 --      |- head xs : <rhobox>
 375 -- We will do a boxySubMatchType between        a ~ <rhobox>
 376 -- But we *don't* want to match [a |-> <rhobox>] because
 377 --     (a)      The box should be filled in with a rho-type, but
 378 --      but the returned substitution maps TyVars to boxy *sigma*
 379 --      types
 380 --     (b) In any case, the right final answer might be *either*
 381 --      instantiate 'a' with a rho-type or a sigma type
 382 --         head xs : Int   vs   head xs : forall b. b->b
 383 -- So the matcher MUST NOT make a choice here.   In general, we only
 384 -- bind a template type variable in boxyMatchType, not in boxySubMatchType.
 385
 386 boxySubMatchType tmpl_tvs tmpl_ty boxy_ty
 387   = go tmpl_ty boxy_ty
 388   where
 389     go t_ty b_ty
 390         | Just t_ty' <- tcView t_ty = go t_ty' b_ty
 391         | Just b_ty' <- tcView b_ty = go t_ty b_ty'
 392
 393     go (FunTy arg1 res1) (FunTy arg2 res2)
 394         = do_match arg1 arg2 (go res1 res2)
 395                 -- Match the args, and sub-match the results
 396
 397     go (TyVarTy _) b_ty = emptyTvSubst  -- Do not bind!  See Note [Sub-match]
 398
 399     go t_ty b_ty = do_match t_ty b_ty emptyTvSubst      -- Otherwise we are safe to bind
 400
 401     do_match t_ty b_ty subst = boxy_match tmpl_tvs t_ty emptyVarSet b_ty subst
 402
 403 ------------
 404 boxyMatchTypes tmpl_tvs tmpl_tys boxy_tys
 405   = ASSERT( length tmpl_tys == length boxy_tys )
 406     boxy_match_s tmpl_tvs tmpl_tys emptyVarSet boxy_tys emptyTvSubst
 407         -- ToDo: add error context?
 408
 409 boxy_match_s tmpl_tvs [] boxy_tvs [] subst
 410   = subst
 411 boxy_match_s tmpl_tvs (t_ty:t_tys) boxy_tvs (b_ty:b_tys) subst
 412   = boxy_match_s tmpl_tvs t_tys boxy_tvs b_tys $
 413     boxy_match tmpl_tvs t_ty boxy_tvs b_ty subst
 414
 415 ------------
 416 boxy_match :: TcTyVarSet -> TcType      -- Template
 417            -> TcTyVarSet                -- boxy_tvs: do not bind template tyvars to any of these
 418            -> BoxySigmaType             -- Match against this type
 419            -> TvSubst
 420            -> TvSubst
 421
 422 -- The boxy_tvs argument prevents this match:
 423 --      [a]  forall b. a  ~  forall b. b
 424 -- We don't want to bind the template variable 'a'
 425 -- to the quantified type variable 'b'!
 426
 427 boxy_match tmpl_tvs orig_tmpl_ty boxy_tvs orig_boxy_ty subst
 428   = go orig_tmpl_ty orig_boxy_ty
 429   where
 430     go t_ty b_ty
 431         | Just t_ty' <- tcView t_ty = go t_ty' b_ty
 432         | Just b_ty' <- tcView b_ty = go t_ty b_ty'
 433
 434     go (ForAllTy _ ty1) (ForAllTy tv2 ty2)
 435         = boxy_match tmpl_tvs ty1 (boxy_tvs `extendVarSet` tv2) ty2 subst
 436
 437     go (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 438         | tc1 == tc2 = go_s tys1 tys2
 439
 440     go (FunTy arg1 res1) (FunTy arg2 res2)
 441         = go_s [arg1,res1] [arg2,res2]
 442
 443     go t_ty b_ty
 444         | Just (s1,t1) <- tcSplitAppTy_maybe t_ty,
 445           Just (s2,t2) <- tcSplitAppTy_maybe b_ty,
 446           typeKind t2 `isSubKind` typeKind t1   -- Maintain invariant
 447         = go_s [s1,t1] [s2,t2]
 448
 449     go (TyVarTy tv) b_ty
 450         | tv `elemVarSet` tmpl_tvs      -- Template type variable in the template
 451         , not (intersectsVarSet boxy_tvs (tyVarsOfType orig_boxy_ty))
 452         , typeKind b_ty `isSubKind` tyVarKind tv
 453         = extendTvSubst subst tv boxy_ty'
 454         where
 455           boxy_ty' = case lookupTyVar subst tv of
 456                         Nothing -> orig_boxy_ty
 457                         Just ty -> ty `boxyLub` orig_boxy_ty
 458
 459     go _ _ = subst      -- Always safe
 460
 461     --------
 462     go_s tys1 tys2 = boxy_match_s tmpl_tvs tys1 boxy_tvs tys2 subst
 463
 464
 465 boxyLub :: BoxySigmaType -> BoxySigmaType -> BoxySigmaType
 466 -- Combine boxy information from the two types
 467 -- If there is a conflict, return the first
 468 boxyLub orig_ty1 orig_ty2
 469   = go orig_ty1 orig_ty2
 470   where
 471     go (AppTy f1 a1) (AppTy f2 a2) = AppTy (boxyLub f1 f2) (boxyLub a1 a2)
 472     go (FunTy f1 a1) (FunTy f2 a2) = FunTy (boxyLub f1 f2) (boxyLub a1 a2)
 473     go (TyConApp tc1 ts1) (TyConApp tc2 ts2)
 474       | tc1 == tc2, length ts1 == length ts2
 475       = TyConApp tc1 (zipWith boxyLub ts1 ts2)
 476
 477     go (TyVarTy tv1) ty2                -- This is the whole point;
 478       | isTcTyVar tv1, isMetaTyVar tv1  -- choose ty2 if ty2 is a box
 479       = ty2
 480
 481         -- Look inside type synonyms, but only if the naive version fails
 482     go ty1 ty2 | Just ty1' <- tcView ty1 = go ty1' ty2
 483                | Just ty2' <- tcView ty1 = go ty1 ty2'
 484
 485     -- For now, we don't look inside ForAlls, PredTys
 486     go ty1 ty2 = orig_ty1       -- Default
 487 \end{code}
 488
 489
 490 %************************************************************************
 491 %*                                                                      *
 492                 Subsumption checking
 493 %*                                                                      *
 494 %************************************************************************
 495
 496 All the tcSub calls have the form
 497
 498                 tcSub expected_ty offered_ty
 499 which checks
 500                 offered_ty <= expected_ty
 501
 502 That is, that a value of type offered_ty is acceptable in
 503 a place expecting a value of type expected_ty.
 504
 505 It returns a coercion function
 506         co_fn :: offered_ty -> expected_ty
 507 which takes an HsExpr of type offered_ty into one of type
 508 expected_ty.
 509
 510 \begin{code}
 511 -----------------
 512 tcSubExp :: BoxySigmaType -> BoxySigmaType -> TcM ExprCoFn      -- Locally used only
 513         -- (tcSub act exp) checks that
 514         --      act <= exp
 515 tcSubExp actual_ty expected_ty
 516   = traceTc (text "tcSub" <+> details)          `thenM_`
 517     addErrCtxtM (unifyCtxt "type" actual_ty expected_ty)
 518                 (tc_sub actual_ty actual_ty expected_ty expected_ty)
 519   where
 520     details = vcat [text "Expected:" <+> ppr expected_ty,
 521                     text "Actual:  " <+> ppr actual_ty]
 522
 523 -----------------
 524 tc_sub :: BoxySigmaType         -- actual_ty, before expanding synonyms
 525        -> BoxySigmaType         --              ..and after
 526        -> BoxySigmaType         -- expected_ty, before
 527        -> BoxySigmaType         --              ..and after
 528        -> TcM ExprCoFn
 529
 530 tc_sub act_sty act_ty exp_sty exp_ty
 531   | Just exp_ty' <- tcView exp_ty = tc_sub act_sty act_ty exp_sty exp_ty'
 532 tc_sub act_sty act_ty exp_sty exp_ty
 533   | Just act_ty' <- tcView act_ty = tc_sub act_sty act_ty' exp_sty exp_ty
 534
 535 -----------------------------------
 536 -- Rule SBOXY, plus other cases when act_ty is a type variable
 537 -- Just defer to boxy matching
 538 -- This rule takes precedence over SKOL!
 539 tc_sub act_sty (TyVarTy tv) exp_sty exp_ty
 540   = do  { uVar False tv False exp_sty exp_ty
 541         ; return idCoercion }
 542
 543 -----------------------------------
 544 -- Skolemisation case (rule SKOL)
 545 --      actual_ty:   d:Eq b => b->b
 546 --      expected_ty: forall a. Ord a => a->a
 547 --      co_fn e      /\a. \d2:Ord a. let d = eqFromOrd d2 in e
 548
 549 -- It is essential to do this *before* the specialisation case
 550 -- Example:  f :: (Eq a => a->a) -> ...
 551 --           g :: Ord b => b->b
 552 -- Consider  f g !
 553
 554 tc_sub act_sty act_ty exp_sty exp_ty
 555   | isSigmaTy exp_ty
 556   = do  { (gen_fn, co_fn) <- tcGen exp_ty act_tvs $ \ body_exp_ty ->
 557                              tc_sub act_sty act_ty body_exp_ty body_exp_ty
 558         ; return (gen_fn <.> co_fn) }
 559   where
 560     act_tvs = tyVarsOfType act_ty
 561                 -- It's really important to check for escape wrt the free vars of
 562                 -- both expected_ty *and* actual_ty
 563
 564 -----------------------------------
 565 -- Specialisation case (rule ASPEC):
 566 --      actual_ty:   forall a. Ord a => a->a
 567 --      expected_ty: Int -> Int
 568 --      co_fn e =    e Int dOrdInt
 569
 570 tc_sub act_sty actual_ty exp_sty expected_ty
 571   | isSigmaTy actual_ty
 572   = do  { (tyvars, theta, tau) <- tcInstBoxy actual_ty
 573         ; dicts <- newDicts InstSigOrigin theta
 574         ; extendLIEs dicts
 575         ; let inst_fn = CoApps (CoTyApps CoHole (mkTyVarTys tyvars))
 576                                (map instToId dicts)
 577         ; co_fn <- tc_sub tau tau exp_sty expected_ty
 578         ; return (co_fn <.> inst_fn) }
 579
 580 -----------------------------------
 581 -- Function case (rule F1)
 582 tc_sub _ (FunTy act_arg act_res) _ (FunTy exp_arg exp_res)
 583   = tc_sub_funs act_arg act_res exp_arg exp_res
 584
 585 -- Function case (rule F2)
 586 tc_sub act_sty act_ty@(FunTy act_arg act_res) exp_sty (TyVarTy exp_tv)
 587   | isBoxyTyVar exp_tv
 588   = do  { cts <- readMetaTyVar exp_tv
 589         ; case cts of
 590             Indirect ty -> do { u_tys False act_sty act_ty True exp_sty ty
 591                               ; return idCoercion }
 592             Flexi       -> do { [arg_ty,res_ty] <- withMetaTvs exp_tv fun_kinds mk_res_ty
 593                               ; tc_sub_funs act_arg act_res arg_ty res_ty } }
 594  where
 595     mk_res_ty [arg_ty', res_ty'] = mkFunTy arg_ty' res_ty'
 596     fun_kinds = [argTypeKind, openTypeKind]
 597
 598 -- Everything else: defer to boxy matching
 599 tc_sub act_sty actual_ty exp_sty expected_ty
 600   = do  { u_tys False act_sty actual_ty False exp_sty expected_ty
 601         ; return idCoercion }
 602
 603
 604 -----------------------------------
 605 tc_sub_funs act_arg act_res exp_arg exp_res
 606   = do  { uTys False act_arg False exp_arg
 607         ; co_fn_res <- tc_sub act_res act_res exp_res exp_res
 608         ; wrapFunResCoercion [exp_arg] co_fn_res }
 609
 610 -----------------------------------
 611 wrapFunResCoercion
 612         :: [TcType]     -- Type of args
 613         -> ExprCoFn     -- HsExpr a -> HsExpr b
 614         -> TcM ExprCoFn -- HsExpr (arg_tys -> a) -> HsExpr (arg_tys -> b)
 615 wrapFunResCoercion arg_tys co_fn_res
 616   | isIdCoercion co_fn_res = return idCoercion
 617   | null arg_tys           = return co_fn_res
 618   | otherwise
 619   = do  { us <- newUniqueSupply
 620         ; let arg_ids = zipWith (mkSysLocal FSLIT("sub")) (uniqsFromSupply us) arg_tys
 621         ; return (CoLams arg_ids (co_fn_res <.> (CoApps CoHole arg_ids))) }
 622 \end{code}
 623
 624
 625
 626 %************************************************************************
 627 %*                                                                      *
 628 \subsection{Generalisation}
 629 %*                                                                      *
 630 %************************************************************************
 631
 632 \begin{code}
 633 tcGen :: BoxySigmaType                          -- expected_ty
 634       -> TcTyVarSet                             -- Extra tyvars that the universally
 635                                                 --      quantified tyvars of expected_ty
 636                                                 --      must not be unified
 637       -> (BoxyRhoType -> TcM result)            -- spec_ty
 638       -> TcM (ExprCoFn, result)
 639         -- The expression has type: spec_ty -> expected_ty
 640
 641 tcGen expected_ty extra_tvs thing_inside        -- We expect expected_ty to be a forall-type
 642                                                 -- If not, the call is a no-op
 643   = do  {       -- We want the GenSkol info in the skolemised type variables to
 644                 -- mention the *instantiated* tyvar names, so that we get a
 645                 -- good error message "Rigid variable 'a' is bound by (forall a. a->a)"
 646                 -- Hence the tiresome but innocuous fixM
 647           ((forall_tvs, theta, rho_ty), skol_info) <- fixM (\ ~(_, skol_info) ->
 648                 do { (forall_tvs, theta, rho_ty) <- tcInstSkolType skol_info expected_ty
 649                    ; span <- getSrcSpanM
 650                    ; let skol_info = GenSkol forall_tvs (mkPhiTy theta rho_ty) span
 651                    ; return ((forall_tvs, theta, rho_ty), skol_info) })
 652
 653 #ifdef DEBUG
 654         ; traceTc (text "tcGen" <+> vcat [text "extra_tvs" <+> ppr extra_tvs,
 655                                     text "expected_ty" <+> ppr expected_ty,
 656                                     text "inst ty" <+> ppr forall_tvs <+> ppr theta <+> ppr rho_ty,
 657                                     text "free_tvs" <+> ppr free_tvs,
 658                                     text "forall_tvs" <+> ppr forall_tvs])
 659 #endif
 660
 661         -- Type-check the arg and unify with poly type
 662         ; (result, lie) <- getLIE (thing_inside rho_ty)
 663
 664         -- Check that the "forall_tvs" havn't been constrained
 665         -- The interesting bit here is that we must include the free variables
 666         -- of the expected_ty.  Here's an example:
 667         --       runST (newVar True)
 668         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 669         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 670         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 671         -- So now s' isn't unconstrained because it's linked to a.
 672         -- Conclusion: include the free vars of the expected_ty in the
 673         -- list of "free vars" for the signature check.
 674
 675         ; dicts <- newDicts (SigOrigin skol_info) theta
 676         ; inst_binds <- tcSimplifyCheck sig_msg forall_tvs dicts lie
 677
 678         ; checkSigTyVarsWrt free_tvs forall_tvs
 679         ; traceTc (text "tcGen:done")
 680
 681         ; let
 682             -- This HsLet binds any Insts which came out of the simplification.
 683             -- It's a bit out of place here, but using AbsBind involves inventing
 684             -- a couple of new names which seems worse.
 685                 dict_ids   = map instToId dicts
 686                 co_fn = CoTyLams forall_tvs $ CoLams dict_ids $ CoLet inst_binds CoHole
 687         ; returnM (co_fn, result) }
 688   where
 689     free_tvs = tyVarsOfType expected_ty `unionVarSet` extra_tvs
 690     sig_msg  = ptext SLIT("expected type of an expression")
 691 \end{code}
 692
 693
 694
 695 %************************************************************************
 696 %*                                                                      *
 697                 Boxy unification
 698 %*                                                                      *
 699 %************************************************************************
 700
 701 The exported functions are all defined as versions of some
 702 non-exported generic functions.
 703
 704 \begin{code}
 705 boxyUnify :: BoxyType -> BoxyType -> TcM ()
 706 -- Acutal and expected, respectively
 707 boxyUnify ty1 ty2
 708   = addErrCtxtM (unifyCtxt "type" ty1 ty2) $
 709     uTys False ty1 False ty2
 710
 711 ---------------
 712 boxyUnifyList :: [BoxyType] -> [BoxyType] -> TcM ()
 713 -- Arguments should have equal length
 714 -- Acutal and expected types
 715 boxyUnifyList tys1 tys2 = uList boxyUnify tys1 tys2
 716
 717 ---------------
 718 unifyType :: TcTauType -> TcTauType -> TcM ()
 719 -- No boxes expected inside these types
 720 -- Acutal and expected types
 721 unifyType ty1 ty2       -- ty1 expected, ty2 inferred
 722   = ASSERT2( not (isBoxyTy ty1), ppr ty1 )
 723     ASSERT2( not (isBoxyTy ty2), ppr ty2 )
 724     addErrCtxtM (unifyCtxt "type" ty1 ty2) $
 725     uTys True ty1 True ty2
 726
 727 ---------------
 728 unifyPred :: PredType -> PredType -> TcM ()
 729 -- Acutal and expected types
 730 unifyPred p1 p2 = addErrCtxtM (unifyCtxt "type constraint" (mkPredTy p1) (mkPredTy p2)) $
 731                   uPred True p1 True p2
 732
 733 unifyTheta :: TcThetaType -> TcThetaType -> TcM ()
 734 -- Acutal and expected types
 735 unifyTheta theta1 theta2
 736   = do  { checkTc (equalLength theta1 theta2)
 737                   (ptext SLIT("Contexts differ in length"))
 738         ; uList unifyPred theta1 theta2 }
 739
 740 ---------------
 741 uList :: (a -> a -> TcM ())
 742        -> [a] -> [a] -> TcM ()
 743 -- Unify corresponding elements of two lists of types, which
 744 -- should be f equal length.  We charge down the list explicitly so that
 745 -- we can complain if their lengths differ.
 746 uList unify []         []         = return ()
 747 uList unify (ty1:tys1) (ty2:tys2) = do { unify ty1 ty2; uList unify tys1 tys2 }
 748 uList unify ty1s ty2s = panic "Unify.uList: mismatched type lists!"
 749 \end{code}
 750
 751 @unifyTypeList@ takes a single list of @TauType@s and unifies them
 752 all together.  It is used, for example, when typechecking explicit
 753 lists, when all the elts should be of the same type.
 754
 755 \begin{code}
 756 unifyTypeList :: [TcTauType] -> TcM ()
 757 unifyTypeList []                 = returnM ()
 758 unifyTypeList [ty]               = returnM ()
 759 unifyTypeList (ty1:tys@(ty2:_)) = do { unifyType ty1 ty2
 760                                       ; unifyTypeList tys }
 761 \end{code}
 762
 763 %************************************************************************
 764 %*                                                                      *
 765 \subsection[Unify-uTys]{@uTys@: getting down to business}
 766 %*                                                                      *
 767 %************************************************************************
 768
 769 @uTys@ is the heart of the unifier.  Each arg happens twice, because
 770 we want to report errors in terms of synomyms if poss.  The first of
 771 the pair is used in error messages only; it is always the same as the
 772 second, except that if the first is a synonym then the second may be a
 773 de-synonym'd version.  This way we get better error messages.
 774
 775 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
 776
 777 \begin{code}
 778 type NoBoxes = Bool     -- True  <=> definitely no boxes in this type
 779                         -- False <=> there might be boxes (always safe)
 780
 781 uTys :: NoBoxes -> TcType       -- ty1 is the *expected* type
 782      -> NoBoxes -> TcType       -- ty2 is the *actual* type
 783      -> TcM ()
 784 uTys nb1 ty1 nb2 ty2 = u_tys nb1 ty1 ty1 nb2 ty2 ty2
 785
 786
 787 --------------
 788 uTys_s :: NoBoxes -> [TcType]   -- ty1 is the *actual* types
 789        -> NoBoxes -> [TcType]   -- ty2 is the *expected* types
 790        -> TcM ()
 791 uTys_s nb1 []           nb2 []         = returnM ()
 792 uTys_s nb1 (ty1:tys1) nb2 (ty2:tys2) = do { uTys nb1 ty1 nb2 ty2
 793                                             ; uTys_s nb1 tys1 nb2 tys2 }
 794 uTys_s nb1 ty1s nb2 ty2s = panic "Unify.uTys_s: mismatched type lists!"
 795
 796 --------------
 797 u_tys :: NoBoxes -> TcType -> TcType    -- ty1 is the *actual* type
 798       -> NoBoxes -> TcType -> TcType    -- ty2 is the *expected* type
 799       -> TcM ()
 800
 801 u_tys nb1 orig_ty1 ty1 nb2 orig_ty2 ty2
 802   = go ty1 ty2
 803   where
 804
 805         -- Always expand synonyms (see notes at end)
 806         -- (this also throws away FTVs)
 807     go ty1 ty2
 808       | Just ty1' <- tcView ty1 = go ty1' ty2
 809       | Just ty2' <- tcView ty2 = go ty1 ty2'
 810
 811         -- Variables; go for uVar
 812     go (TyVarTy tyvar1) ty2 = uVar False tyvar1 nb2 orig_ty2 ty2
 813     go ty1 (TyVarTy tyvar2) = uVar True  tyvar2 nb1 orig_ty1 ty1
 814                                 -- "True" means args swapped
 815         -- Predicates
 816     go (PredTy p1) (PredTy p2) = uPred nb1 p1 nb2 p2
 817
 818         -- Type constructors must match
 819     go (TyConApp con1 tys1) (TyConApp con2 tys2)
 820       | con1 == con2 = uTys_s nb1 tys1 nb2 tys2
 821         -- See Note [TyCon app]
 822
 823         -- Functions; just check the two parts
 824     go (FunTy fun1 arg1) (FunTy fun2 arg2)
 825       = do { uTys nb1 fun1 nb2 fun2
 826            ; uTys nb1 arg1 nb2 arg2 }
 827
 828         -- Applications need a bit of care!
 829         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 830         -- NB: we've already dealt with type variables and Notes,
 831         -- so if one type is an App the other one jolly well better be too
 832     go (AppTy s1 t1) ty2
 833       = case tcSplitAppTy_maybe ty2 of
 834           Just (s2,t2) -> do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 835           Nothing      -> unifyMisMatch False orig_ty1 orig_ty2
 836
 837         -- Now the same, but the other way round
 838         -- Don't swap the types, because the error messages get worse
 839     go ty1 (AppTy s2 t2)
 840       = case tcSplitAppTy_maybe ty1 of
 841           Just (s1,t1) -> do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 842           Nothing      -> unifyMisMatch False orig_ty1 orig_ty2
 843
 844     go ty1@(ForAllTy _ _) ty2@(ForAllTy _ _)
 845       | length tvs1 == length tvs2
 846       = do   { tvs <- tcInstSkolTyVars UnkSkol tvs1     -- Not a helpful SkolemInfo
 847              ; let tys      = mkTyVarTys tvs
 848                    in_scope = mkInScopeSet (mkVarSet tvs)
 849                    subst1   = mkTvSubst in_scope (zipTyEnv tvs1 tys)
 850                    subst2   = mkTvSubst in_scope (zipTyEnv tvs2 tys)
 851              ; uTys nb1 (substTy subst1 body1) nb2 (substTy subst2 body2)
 852
 853                 -- If both sides are inside a box, we should not have
 854                 -- a polytype at all.  This check comes last, because
 855                 -- the error message is extremely unhelpful.
 856              ; ifM (nb1 && nb2) (notMonoType ty1)
 857              }
 858       where
 859         (tvs1, body1) = tcSplitForAllTys ty1
 860         (tvs2, body2) = tcSplitForAllTys ty2
 861
 862         -- Anything else fails
 863     go _ _ = unifyMisMatch False orig_ty1 orig_ty2
 864
 865 ----------
 866 uPred nb1 (IParam n1 t1) nb2 (IParam n2 t2)
 867   | n1 == n2 = uTys nb1 t1 nb2 t2
 868 uPred nb1 (ClassP c1 tys1) nb2 (ClassP c2 tys2)
 869   | c1 == c2 = uTys_s nb1 tys1 nb2 tys2         -- Guaranteed equal lengths because the kinds check
 870 uPred _ p1 _ p2 = unifyMisMatch False (mkPredTy p1) (mkPredTy p2)
 871 \end{code}
 872
 873 Note [Tycon app]
 874 ~~~~~~~~~~~~~~~~
 875 When we find two TyConApps, the argument lists are guaranteed equal
 876 length.  Reason: intially the kinds of the two types to be unified is
 877 the same. The only way it can become not the same is when unifying two
 878 AppTys (f1 a1):=:(f2 a2).  In that case there can't be a TyConApp in
 879 the f1,f2 (because it'd absorb the app).  If we unify f1:=:f2 first,
 880 which we do, that ensures that f1,f2 have the same kind; and that
 881 means a1,a2 have the same kind.  And now the argument repeats.
 882
 883
 884 Notes on synonyms
 885 ~~~~~~~~~~~~~~~~~
 886 If you are tempted to make a short cut on synonyms, as in this
 887 pseudocode...
 888
 889 \begin{verbatim}
 890 -- NO   uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
 891 -- NO     = if (con1 == con2) then
 892 -- NO   -- Good news!  Same synonym constructors, so we can shortcut
 893 -- NO   -- by unifying their arguments and ignoring their expansions.
 894 -- NO   unifyTypepeLists args1 args2
 895 -- NO    else
 896 -- NO   -- Never mind.  Just expand them and try again
 897 -- NO   uTys ty1 ty2
 898 \end{verbatim}
 899
 900 then THINK AGAIN.  Here is the whole story, as detected and reported
 901 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
 902 \begin{quotation}
 903 Here's a test program that should detect the problem:
 904
 905 \begin{verbatim}
 906         type Bogus a = Int
 907         x = (1 :: Bogus Char) :: Bogus Bool
 908 \end{verbatim}
 909
 910 The problem with [the attempted shortcut code] is that
 911 \begin{verbatim}
 912         con1 == con2
 913 \end{verbatim}
 914 is not a sufficient condition to be able to use the shortcut!
 915 You also need to know that the type synonym actually USES all
 916 its arguments.  For example, consider the following type synonym
 917 which does not use all its arguments.
 918 \begin{verbatim}
 919         type Bogus a = Int
 920 \end{verbatim}
 921
 922 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
 923 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
 924 would fail, even though the expanded forms (both \tr{Int}) should
 925 match.
 926
 927 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
 928 unnecessarily bind \tr{t} to \tr{Char}.
 929
 930 ... You could explicitly test for the problem synonyms and mark them
 931 somehow as needing expansion, perhaps also issuing a warning to the
 932 user.
 933 \end{quotation}
 934
 935
 936 %************************************************************************
 937 %*                                                                      *
 938 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
 939 %*                                                                      *
 940 %************************************************************************
 941
 942 @uVar@ is called when at least one of the types being unified is a
 943 variable.  It does {\em not} assume that the variable is a fixed point
 944 of the substitution; rather, notice that @uVar@ (defined below) nips
 945 back into @uTys@ if it turns out that the variable is already bound.
 946
 947 \begin{code}
 948 uVar :: Bool            -- False => tyvar is the "expected"
 949                         -- True  => ty    is the "expected" thing
 950      -> TcTyVar
 951      -> NoBoxes         -- True <=> definitely no boxes in t2
 952      -> TcTauType -> TcTauType  -- printing and real versions
 953      -> TcM ()
 954
 955 uVar swapped tv1 nb2 ps_ty2 ty2
 956   = do  { let expansion | showSDoc (ppr ty2) == showSDoc (ppr ps_ty2) = empty
 957                         | otherwise = brackets (equals <+> ppr ty2)
 958         ; traceTc (text "uVar" <+> ppr swapped <+>
 959                         sep [ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1 ),
 960                                 nest 2 (ptext SLIT(" :=: ")),
 961                              ppr ps_ty2 <+> dcolon <+> ppr (typeKind ty2) <+> expansion])
 962         ; details <- lookupTcTyVar tv1
 963         ; case details of
 964             IndirectTv ty1
 965                 | swapped   -> u_tys nb2  ps_ty2 ty2 True ty1    ty1    -- Swap back
 966                 | otherwise -> u_tys True ty1    ty1 nb2  ps_ty2 ty2    -- Same order
 967                         -- The 'True' here says that ty1
 968                         -- is definitely box-free
 969             DoneTv details1 -> uUnfilledVar swapped tv1 details1 nb2 ps_ty2 ty2
 970         }
 971
 972 ----------------
 973 uUnfilledVar :: Bool                            -- Args are swapped
 974              -> TcTyVar -> TcTyVarDetails               -- Tyvar 1
 975              -> NoBoxes -> TcTauType -> TcTauType       -- Type 2
 976              -> TcM ()
 977 -- Invariant: tyvar 1 is not unified with anything
 978
 979 uUnfilledVar swapped tv1 details1 nb2 ps_ty2 ty2
 980   | Just ty2' <- tcView ty2
 981   =     -- Expand synonyms; ignore FTVs
 982     uUnfilledVar swapped tv1 details1 nb2 ps_ty2 ty2'
 983
 984 uUnfilledVar swapped tv1 details1 nb2 ps_ty2 ty2@(TyVarTy tv2)
 985         -- Same type variable => no-op
 986   | tv1 == tv2
 987   = returnM ()
 988
 989         -- Distinct type variables
 990   | otherwise
 991   = do  { lookup2 <- lookupTcTyVar tv2
 992         ; case lookup2 of
 993             IndirectTv ty2' -> uUnfilledVar  swapped tv1 details1 True ty2' ty2'
 994             DoneTv details2 -> uUnfilledVars swapped tv1 details1 tv2 details2
 995         }
 996
 997 uUnfilledVar swapped tv1 details1 nb2 ps_ty2 non_var_ty2        -- ty2 is not a type variable
 998   = case details1 of
 999         MetaTv (SigTv _) ref1 -> mis_match      -- Can't update a skolem with a non-type-variable
1000         MetaTv info ref1      -> uMetaVar swapped tv1 info ref1 nb2 ps_ty2 non_var_ty2
1001         skolem_details        -> mis_match
1002   where
1003     mis_match = unifyMisMatch swapped (TyVarTy tv1) ps_ty2
1004
1005 ----------------
1006 uMetaVar :: Bool
1007          -> TcTyVar -> BoxInfo -> IORef MetaDetails
1008          -> NoBoxes -> TcType -> TcType
1009          -> TcM ()
1010 -- tv1 is an un-filled-in meta type variable (maybe boxy, maybe tau)
1011 -- ty2 is not a type variable
1012
1013 uMetaVar swapped tv1 info1 ref1 nb2 ps_ty2 non_var_ty2
1014   = do  { final_ty <- case info1 of
1015                         BoxTv -> unBox ps_ty2                   -- No occurs check
1016                         other -> checkTauTvUpdate tv1 ps_ty2    -- Occurs check + monotype check
1017         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1018
1019 ----------------
1020 uUnfilledVars :: Bool                   -- Args are swapped
1021               -> TcTyVar -> TcTyVarDetails      -- Tyvar 1
1022               -> TcTyVar -> TcTyVarDetails      -- Tyvar 2
1023               -> TcM ()
1024 -- Invarant: The type variables are distinct,
1025 --           Neither is filled in yet
1026 --           They might be boxy or not
1027
1028 uUnfilledVars swapped tv1 (SkolemTv _) tv2 (SkolemTv _)
1029   = unifyMisMatch swapped (mkTyVarTy tv1) (mkTyVarTy tv2)
1030
1031 uUnfilledVars swapped tv1 (MetaTv info1 ref1) tv2 (SkolemTv _)
1032   = checkUpdateMeta swapped tv1 ref1 (mkTyVarTy tv2)
1033 uUnfilledVars swapped tv1 (SkolemTv _) tv2 (MetaTv info2 ref2)
1034   = checkUpdateMeta (not swapped) tv2 ref2 (mkTyVarTy tv1)
1035
1036 -- ToDo: this function seems too long for what it acutally does!
1037 uUnfilledVars swapped tv1 (MetaTv info1 ref1) tv2 (MetaTv info2 ref2)
1038   = case (info1, info2) of
1039         (BoxTv,   BoxTv)   -> box_meets_box
1040
1041         -- If a box meets a TauTv, but the fomer has the smaller kind
1042         -- then we must create a fresh TauTv with the smaller kind
1043         (_,       BoxTv)   | k1_sub_k2 -> update_tv2
1044                            | otherwise -> box_meets_box
1045         (BoxTv,   _    )   | k2_sub_k1 -> update_tv1
1046                            | otherwise -> box_meets_box
1047
1048         -- Avoid SigTvs if poss
1049         (SigTv _, _      ) | k1_sub_k2 -> update_tv2
1050         (_,       SigTv _) | k2_sub_k1 -> update_tv1
1051
1052         (_,   _) | k1_sub_k2 -> if k2_sub_k1 && nicer_to_update_tv1
1053                                 then update_tv1         -- Same kinds
1054                                 else update_tv2
1055                  | k2_sub_k1 -> update_tv1
1056                  | otherwise -> kind_err
1057
1058         -- Update the variable with least kind info
1059         -- See notes on type inference in Kind.lhs
1060         -- The "nicer to" part only applies if the two kinds are the same,
1061         -- so we can choose which to do.
1062   where
1063         -- Kinds should be guaranteed ok at this point
1064     update_tv1 = updateMeta tv1 ref1 (mkTyVarTy tv2)
1065     update_tv2 = updateMeta tv2 ref2 (mkTyVarTy tv1)
1066
1067     box_meets_box | k1_sub_k2 = fill_with k1
1068                   | k2_sub_k1 = fill_with k2
1069                   | otherwise = kind_err
1070
1071     fill_with kind = do { tau_ty <- newFlexiTyVarTy kind
1072                         ; updateMeta tv1 ref1 tau_ty
1073                         ; updateMeta tv2 ref2 tau_ty }
1074
1075     kind_err = addErrCtxtM (unifyKindCtxt swapped tv1 (mkTyVarTy tv2))  $
1076                unifyKindMisMatch k1 k2
1077
1078     k1 = tyVarKind tv1
1079     k2 = tyVarKind tv2
1080     k1_sub_k2 = k1 `isSubKind` k2
1081     k2_sub_k1 = k2 `isSubKind` k1
1082
1083     nicer_to_update_tv1 = isSystemName (varName tv1)
1084         -- Try to update sys-y type variables in preference to ones
1085         -- gotten (say) by instantiating a polymorphic function with
1086         -- a user-written type sig
1087
1088 ----------------
1089 checkUpdateMeta :: Bool -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1090 -- Update tv1, which is flexi; occurs check is alrady done
1091 -- The 'check' version does a kind check too
1092 -- We do a sub-kind check here: we might unify (a b) with (c d)
1093 --      where b::*->* and d::*; this should fail
1094
1095 checkUpdateMeta swapped tv1 ref1 ty2
1096   = do  { checkKinds swapped tv1 ty2
1097         ; updateMeta tv1 ref1 ty2 }
1098
1099 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1100 updateMeta tv1 ref1 ty2
1101   = ASSERT( isMetaTyVar tv1 )
1102     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
1103     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
1104         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
1105         ; writeMutVar ref1 (Indirect ty2) }
1106
1107 ----------------
1108 checkKinds swapped tv1 ty2
1109 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
1110 -- ty2 has been zonked at this stage, which ensures that
1111 -- its kind has as much boxity information visible as possible.
1112   | tk2 `isSubKind` tk1 = returnM ()
1113
1114   | otherwise
1115         -- Either the kinds aren't compatible
1116         --      (can happen if we unify (a b) with (c d))
1117         -- or we are unifying a lifted type variable with an
1118         --      unlifted type: e.g.  (id 3#) is illegal
1119   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
1120     unifyKindMisMatch k1 k2
1121   where
1122     (k1,k2) | swapped   = (tk2,tk1)
1123             | otherwise = (tk1,tk2)
1124     tk1 = tyVarKind tv1
1125     tk2 = typeKind ty2
1126
1127 ----------------
1128 checkTauTvUpdate :: TcTyVar -> TcType -> TcM TcType
1129 --    (checkTauTvUpdate tv ty)
1130 -- We are about to update the TauTv tv with ty.
1131 -- Check (a) that tv doesn't occur in ty (occurs check)
1132 --       (b) that ty is a monotype
1133 -- Furthermore, in the interest of (b), if you find an
1134 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
1135 --
1136 -- Returns the (non-boxy) type to update the type variable with, or fails
1137
1138 checkTauTvUpdate orig_tv orig_ty
1139   = go orig_ty
1140   where
1141     go (TyConApp tc tys)
1142         | isSynTyCon tc  = go_syn tc tys
1143         | otherwise      = do { tys' <- mappM go tys; return (TyConApp tc tys') }
1144     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
1145     go (PredTy p)        = do { p' <- go_pred p; return (PredTy p') }
1146     go (FunTy arg res)   = do { arg' <- go arg; res' <- go res; return (FunTy arg' res') }
1147     go (AppTy fun arg)   = do { fun' <- go fun; arg' <- go arg; return (mkAppTy fun' arg') }
1148                 -- NB the mkAppTy; we might have instantiated a
1149                 -- type variable to a type constructor, so we need
1150                 -- to pull the TyConApp to the top.
1151     go (ForAllTy tv ty) = notMonoType orig_ty           -- (b)
1152
1153     go (TyVarTy tv)
1154         | orig_tv == tv = occurCheck tv orig_ty         -- (a)
1155         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
1156         | otherwise     = return (TyVarTy tv)
1157                  -- Ordinary (non Tc) tyvars
1158                  -- occur inside quantified types
1159
1160     go_pred (ClassP c tys) = do { tys' <- mapM go tys; return (ClassP c tys') }
1161     go_pred (IParam n ty)  = do { ty' <- go ty;        return (IParam n ty') }
1162
1163     go_tyvar tv (SkolemTv _) = return (TyVarTy tv)
1164     go_tyvar tv (MetaTv box ref)
1165         = do { cts <- readMutVar ref
1166              ; case cts of
1167                   Indirect ty -> go ty
1168                   Flexi -> case box of
1169                                 BoxTv -> do { tau <- newFlexiTyVarTy (tyVarKind tv)
1170                                             ; writeMutVar ref (Indirect tau)
1171                                             ; return tau }
1172                                 other -> return (TyVarTy tv)
1173              }
1174
1175         -- go_syn is called for synonyms only
1176         -- See Note [Type synonyms and the occur check]
1177     go_syn tc tys
1178         | not (isTauTyCon tc)
1179         = notMonoType orig_ty   -- (b) again
1180         | otherwise
1181         = do { (msgs, mb_tys') <- tryTc (mapM go tys)
1182              ; case mb_tys' of
1183                 Just tys' -> return (TyConApp tc tys')
1184                                 -- Retain the synonym (the common case)
1185                 Nothing   -> go (fromJust (tcView (TyConApp tc tys)))
1186                                 -- Try again, expanding the synonym
1187              }
1188 \end{code}
1189
1190 Note [Type synonyms and the occur check]
1191 ~~~~~~~~~~~~~~~~~~~~
1192 Basically we want to update     tv1 := ps_ty2
1193 because ps_ty2 has type-synonym info, which improves later error messages
1194
1195 But consider
1196         type A a = ()
1197
1198         f :: (A a -> a -> ()) -> ()
1199         f = \ _ -> ()
1200
1201         x :: ()
1202         x = f (\ x p -> p x)
1203
1204 In the application (p x), we try to match "t" with "A t".  If we go
1205 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
1206 an infinite loop later.
1207 But we should not reject the program, because A t = ().
1208 Rather, we should bind t to () (= non_var_ty2).
1209
1210 \begin{code}
1211 stripBoxyType :: BoxyType -> TcM TcType
1212 -- Strip all boxes from the input type, returning a non-boxy type.
1213 -- It's fine for there to be a polytype inside a box (c.f. unBox)
1214 -- All of the boxes should have been filled in by now;
1215 -- hence we return a TcType
1216 stripBoxyType ty = zonkType strip_tv ty
1217   where
1218     strip_tv tv = ASSERT( not (isBoxyTyVar tv) ) return (TyVarTy tv)
1219         -- strip_tv will be called for *Flexi* meta-tyvars
1220         -- There should not be any Boxy ones; hence the ASSERT
1221
1222 zapToMonotype :: BoxySigmaType -> TcM TcTauType
1223 -- Subtle... we must zap the boxy res_ty
1224 -- to kind * before using it to instantiate a LitInst
1225 -- Calling unBox instead doesn't do the job, because the box
1226 -- often has an openTypeKind, and we don't want to instantiate
1227 -- with that type.
1228 zapToMonotype res_ty
1229   = do  { res_tau <- newFlexiTyVarTy liftedTypeKind
1230         ; boxyUnify res_tau res_ty
1231         ; return res_tau }
1232
1233 unBox :: BoxyType -> TcM TcType
1234 -- unBox implements the judgement
1235 --      |- s' ~ box(s)
1236 -- with input s', and result s
1237 --
1238 -- It remove all boxes from the input type, returning a non-boxy type.
1239 -- A filled box in the type can only contain a monotype; unBox fails if not
1240 -- The type can have empty boxes, which unBox fills with a monotype
1241 --
1242 -- Compare this wth checkTauTvUpdate
1243 --
1244 -- For once, it's safe to treat synonyms as opaque!
1245
1246 unBox (NoteTy n ty)     = do { ty' <- unBox ty; return (NoteTy n ty') }
1247 unBox (TyConApp tc tys) = do { tys' <- mapM unBox tys; return (TyConApp tc tys') }
1248 unBox (AppTy f a)       = do { f' <- unBox f; a' <- unBox a; return (mkAppTy f' a') }
1249 unBox (FunTy f a)       = do { f' <- unBox f; a' <- unBox a; return (FunTy f' a') }
1250 unBox (PredTy p)        = do { p' <- unBoxPred p; return (PredTy p') }
1251 unBox (ForAllTy tv ty)  = ASSERT( isImmutableTyVar tv )
1252                           do { ty' <- unBox ty; return (ForAllTy tv ty') }
1253 unBox (TyVarTy tv)
1254   | isTcTyVar tv                                -- It's a boxy type variable
1255   , MetaTv BoxTv ref <- tcTyVarDetails tv       -- NB: non-TcTyVars are possible
1256   = do  { cts <- readMutVar ref                 --     under nested quantifiers
1257         ; case cts of
1258             Indirect ty -> do { non_boxy_ty <- unBox ty
1259                               ; if isTauTy non_boxy_ty
1260                                 then return non_boxy_ty
1261                                 else notMonoType non_boxy_ty }
1262             Flexi -> do { tau <- newFlexiTyVarTy (tyVarKind tv)
1263                         ; writeMutVar ref (Indirect tau)
1264                         ; return tau }
1265         }
1266   | otherwise   -- Skolems, and meta-tau-variables
1267   = return (TyVarTy tv)
1268
1269 unBoxPred (ClassP cls tys) = do { tys' <- mapM unBox tys; return (ClassP cls tys') }
1270 unBoxPred (IParam ip ty)   = do { ty' <- unBox ty; return (IParam ip ty') }
1271 \end{code}
1272
1273
1274
1275 %************************************************************************
1276 %*                                                                      *
1277                 Kind unification
1278 %*                                                                      *
1279 %************************************************************************
1280
1281 Unifying kinds is much, much simpler than unifying types.
1282
1283 \begin{code}
1284 unifyKind :: TcKind                 -- Expected
1285           -> TcKind                 -- Actual
1286           -> TcM ()
1287 unifyKind LiftedTypeKind   LiftedTypeKind   = returnM ()
1288 unifyKind UnliftedTypeKind UnliftedTypeKind = returnM ()
1289
1290 unifyKind OpenTypeKind k2 | isOpenTypeKind k2 = returnM ()
1291 unifyKind ArgTypeKind  k2 | isArgTypeKind k2    = returnM ()
1292   -- Respect sub-kinding
1293
1294 unifyKind (FunKind a1 r1) (FunKind a2 r2)
1295  = do { unifyKind a2 a1; unifyKind r1 r2 }
1296                 -- Notice the flip in the argument,
1297                 -- so that the sub-kinding works right
1298
1299 unifyKind (KindVar kv1) k2 = uKVar False kv1 k2
1300 unifyKind k1 (KindVar kv2) = uKVar True kv2 k1
1301 unifyKind k1 k2 = unifyKindMisMatch k1 k2
1302
1303 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
1304 unifyKinds []       []       = returnM ()
1305 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenM_`
1306                                unifyKinds ks1 ks2
1307 unifyKinds _ _               = panic "unifyKinds: length mis-match"
1308
1309 ----------------
1310 uKVar :: Bool -> KindVar -> TcKind -> TcM ()
1311 uKVar swapped kv1 k2
1312   = do  { mb_k1 <- readKindVar kv1
1313         ; case mb_k1 of
1314             Nothing -> uUnboundKVar swapped kv1 k2
1315             Just k1 | swapped   -> unifyKind k2 k1
1316                     | otherwise -> unifyKind k1 k2 }
1317
1318 ----------------
1319 uUnboundKVar :: Bool -> KindVar -> TcKind -> TcM ()
1320 uUnboundKVar swapped kv1 k2@(KindVar kv2)
1321   | kv1 == kv2 = returnM ()
1322   | otherwise   -- Distinct kind variables
1323   = do  { mb_k2 <- readKindVar kv2
1324         ; case mb_k2 of
1325             Just k2 -> uUnboundKVar swapped kv1 k2
1326             Nothing -> writeKindVar kv1 k2 }
1327
1328 uUnboundKVar swapped kv1 non_var_k2
1329   = do  { k2' <- zonkTcKind non_var_k2
1330         ; kindOccurCheck kv1 k2'
1331         ; k2'' <- kindSimpleKind swapped k2'
1332                 -- KindVars must be bound only to simple kinds
1333                 -- Polarities: (kindSimpleKind True ?) succeeds
1334                 -- returning *, corresponding to unifying
1335                 --      expected: ?
1336                 --      actual:   kind-ver
1337         ; writeKindVar kv1 k2'' }
1338
1339 ----------------
1340 kindOccurCheck kv1 k2   -- k2 is zonked
1341   = checkTc (not_in k2) (kindOccurCheckErr kv1 k2)
1342   where
1343     not_in (KindVar kv2)   = kv1 /= kv2
1344     not_in (FunKind a2 r2) = not_in a2 && not_in r2
1345     not_in other           = True
1346
1347 kindSimpleKind :: Bool -> Kind -> TcM SimpleKind
1348 -- (kindSimpleKind True k) returns a simple kind sk such that sk <: k
1349 -- If the flag is False, it requires k <: sk
1350 -- E.g.         kindSimpleKind False ?? = *
1351 -- What about (kv -> *) :=: ?? -> *
1352 kindSimpleKind orig_swapped orig_kind
1353   = go orig_swapped orig_kind
1354   where
1355     go sw (FunKind k1 k2) = do { k1' <- go (not sw) k1
1356                                ; k2' <- go sw k2
1357                                ; return (FunKind k1' k2') }
1358     go True OpenTypeKind = return liftedTypeKind
1359     go True ArgTypeKind  = return liftedTypeKind
1360     go sw LiftedTypeKind  = return liftedTypeKind
1361     go sw k@(KindVar _)   = return k    -- KindVars are always simple
1362     go swapped kind = failWithTc (ptext SLIT("Unexpected kind unification failure:")
1363                                   <+> ppr orig_swapped <+> ppr orig_kind)
1364         -- I think this can't actually happen
1365
1366 -- T v = MkT v           v must be a type
1367 -- T v w = MkT (v -> w)  v must not be an umboxed tuple
1368
1369 ----------------
1370 kindOccurCheckErr tyvar ty
1371   = hang (ptext SLIT("Occurs check: cannot construct the infinite kind:"))
1372        2 (sep [ppr tyvar, char '=', ppr ty])
1373
1374 unifyKindMisMatch ty1 ty2
1375   = zonkTcKind ty1      `thenM` \ ty1' ->
1376     zonkTcKind ty2      `thenM` \ ty2' ->
1377     let
1378         msg = hang (ptext SLIT("Couldn't match kind"))
1379                    2 (sep [quotes (ppr ty1'),
1380                            ptext SLIT("against"),
1381                            quotes (ppr ty2')])
1382     in
1383     failWithTc msg
1384 \end{code}
1385
1386 \begin{code}
1387 unifyFunKind :: TcKind -> TcM (Maybe (TcKind, TcKind))
1388 -- Like unifyFunTy, but does not fail; instead just returns Nothing
1389
1390 unifyFunKind (KindVar kvar)
1391   = readKindVar kvar    `thenM` \ maybe_kind ->
1392     case maybe_kind of
1393         Just fun_kind -> unifyFunKind fun_kind
1394         Nothing       -> do { arg_kind <- newKindVar
1395                             ; res_kind <- newKindVar
1396                             ; writeKindVar kvar (mkArrowKind arg_kind res_kind)
1397                             ; returnM (Just (arg_kind,res_kind)) }
1398
1399 unifyFunKind (FunKind arg_kind res_kind) = returnM (Just (arg_kind,res_kind))
1400 unifyFunKind other                       = returnM Nothing
1401 \end{code}
1402
1403 %************************************************************************
1404 %*                                                                      *
1405 \subsection[Unify-context]{Errors and contexts}
1406 %*                                                                      *
1407 %************************************************************************
1408
1409 Errors
1410 ~~~~~~
1411
1412 \begin{code}
1413 unifyCtxt s ty1 ty2 tidy_env    -- ty1 inferred, ty2 expected
1414   = zonkTcType ty1      `thenM` \ ty1' ->
1415     zonkTcType ty2      `thenM` \ ty2' ->
1416     returnM (err ty1' ty2')
1417   where
1418     err ty1 ty2 = (env1,
1419                    nest 2
1420                         (vcat [
1421                            text "Expected" <+> text s <> colon <+> ppr tidy_ty2,
1422                            text "Inferred" <+> text s <> colon <+> ppr tidy_ty1
1423                         ]))
1424                   where
1425                     (env1, [tidy_ty1,tidy_ty2]) = tidyOpenTypes tidy_env [ty1,ty2]
1426
1427 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
1428         -- tv1 and ty2 are zonked already
1429   = returnM msg
1430   where
1431     msg = (env2, ptext SLIT("When matching the kinds of") <+>
1432                  sep [quotes pp_expected <+> ptext SLIT("and"), quotes pp_actual])
1433
1434     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
1435                              | otherwise = (pp1, pp2)
1436     (env1, tv1') = tidyOpenTyVar tidy_env tv1
1437     (env2, ty2') = tidyOpenType  env1 ty2
1438     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
1439     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
1440
1441 unifyMisMatch swapped ty1 ty2
1442   = do  { (env, msg) <- if swapped then misMatchMsg ty2 ty1
1443                                    else misMatchMsg ty1 ty2
1444         ; failWithTcM (env, msg) }
1445
1446 misMatchMsg ty1 ty2
1447   = do  { env0 <- tcInitTidyEnv
1448         ; (env1, pp1, extra1) <- ppr_ty env0 ty1
1449         ; (env2, pp2, extra2) <- ppr_ty env1 ty2
1450         ; return (env2, sep [sep [ptext SLIT("Couldn't match") <+> pp1,
1451                                   nest 7 (ptext SLIT("against") <+> pp2)],
1452                              nest 2 extra1, nest 2 extra2]) }
1453
1454 ppr_ty :: TidyEnv -> TcType -> TcM (TidyEnv, SDoc, SDoc)
1455 ppr_ty env ty
1456   = do { ty' <- zonkTcType ty
1457        ; let (env1,tidy_ty) = tidyOpenType env ty'
1458              simple_result  = (env1, quotes (ppr tidy_ty), empty)
1459        ; case tidy_ty of
1460            TyVarTy tv
1461                 | isSkolemTyVar tv -> return (env2, pp_rigid tv',
1462                                               pprSkolTvBinding tv')
1463                 | otherwise -> return simple_result
1464                 where
1465                   (env2, tv') = tidySkolemTyVar env1 tv
1466            other -> return simple_result }
1467   where
1468     pp_rigid tv = ptext SLIT("the rigid variable") <+> quotes (ppr tv)
1469
1470
1471 notMonoType ty
1472   = do  { ty' <- zonkTcType ty
1473         ; env0 <- tcInitTidyEnv
1474         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1475               msg = ptext SLIT("Cannot match a monotype with") <+> ppr tidy_ty
1476         ; failWithTcM (env1, msg) }
1477
1478 occurCheck tyvar ty
1479   = do  { env0 <- tcInitTidyEnv
1480         ; ty'  <- zonkTcType ty
1481         ; let (env1, tidy_tyvar) = tidyOpenTyVar env0 tyvar
1482               (env2, tidy_ty)    = tidyOpenType  env1 ty
1483               extra = sep [ppr tidy_tyvar, char '=', ppr tidy_ty]
1484         ; failWithTcM (env2, hang msg 2 extra) }
1485   where
1486     msg = ptext SLIT("Occurs check: cannot construct the infinite type:")
1487 \end{code}
1488
1489
1490 %************************************************************************
1491 %*                                                                      *
1492         Checking kinds
1493 %*                                                                      *
1494 %************************************************************************
1495
1496 ---------------------------
1497 -- We would like to get a decent error message from
1498 --   (a) Under-applied type constructors
1499 --              f :: (Maybe, Maybe)
1500 --   (b) Over-applied type constructors
1501 --              f :: Int x -> Int x
1502 --
1503
1504 \begin{code}
1505 checkExpectedKind :: Outputable a => a -> TcKind -> TcKind -> TcM ()
1506 -- A fancy wrapper for 'unifyKind', which tries
1507 -- to give decent error messages.
1508 checkExpectedKind ty act_kind exp_kind
1509   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
1510   = returnM ()
1511   | otherwise
1512   = tryTc (unifyKind exp_kind act_kind) `thenM` \ (_errs, mb_r) ->
1513     case mb_r of {
1514         Just r  -> returnM () ; -- Unification succeeded
1515         Nothing ->
1516
1517         -- So there's definitely an error
1518         -- Now to find out what sort
1519     zonkTcKind exp_kind         `thenM` \ exp_kind ->
1520     zonkTcKind act_kind         `thenM` \ act_kind ->
1521
1522     tcInitTidyEnv               `thenM` \ env0 ->
1523     let (exp_as, _) = splitKindFunTys exp_kind
1524         (act_as, _) = splitKindFunTys act_kind
1525         n_exp_as = length exp_as
1526         n_act_as = length act_as
1527
1528         (env1, tidy_exp_kind) = tidyKind env0 exp_kind
1529         (env2, tidy_act_kind) = tidyKind env1 act_kind
1530
1531         err | n_exp_as < n_act_as       -- E.g. [Maybe]
1532             = quotes (ppr ty) <+> ptext SLIT("is not applied to enough type arguments")
1533
1534                 -- Now n_exp_as >= n_act_as. In the next two cases,
1535                 -- n_exp_as == 0, and hence so is n_act_as
1536             | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
1537             = ptext SLIT("Expecting a lifted type, but") <+> quotes (ppr ty)
1538                 <+> ptext SLIT("is unlifted")
1539
1540             | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
1541             = ptext SLIT("Expecting an unlifted type, but") <+> quotes (ppr ty)
1542                 <+> ptext SLIT("is lifted")
1543
1544             | otherwise                 -- E.g. Monad [Int]
1545             = ptext SLIT("Kind mis-match")
1546
1547         more_info = sep [ ptext SLIT("Expected kind") <+>
1548                                 quotes (pprKind tidy_exp_kind) <> comma,
1549                           ptext SLIT("but") <+> quotes (ppr ty) <+>
1550                                 ptext SLIT("has kind") <+> quotes (pprKind tidy_act_kind)]
1551    in
1552    failWithTcM (env2, err $$ more_info)
1553    }
1554 \end{code}
1555
1556 %************************************************************************
1557 %*                                                                      *
1558 \subsection{Checking signature type variables}
1559 %*                                                                      *
1560 %************************************************************************
1561
1562 @checkSigTyVars@ checks that a set of universally quantified type varaibles
1563 are not mentioned in the environment.  In particular:
1564
1565         (a) Not mentioned in the type of a variable in the envt
1566                 eg the signature for f in this:
1567
1568                         g x = ... where
1569                                         f :: a->[a]
1570                                         f y = [x,y]
1571
1572                 Here, f is forced to be monorphic by the free occurence of x.
1573
1574         (d) Not (unified with another type variable that is) in scope.
1575                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
1576             when checking the expression type signature, we find that
1577             even though there is nothing in scope whose type mentions r,
1578             nevertheless the type signature for the expression isn't right.
1579
1580             Another example is in a class or instance declaration:
1581                 class C a where
1582                    op :: forall b. a -> b
1583                    op x = x
1584             Here, b gets unified with a
1585
1586 Before doing this, the substitution is applied to the signature type variable.
1587
1588 \begin{code}
1589 checkSigTyVars :: [TcTyVar] -> TcM ()
1590 checkSigTyVars sig_tvs = check_sig_tyvars emptyVarSet sig_tvs
1591
1592 checkSigTyVarsWrt :: TcTyVarSet -> [TcTyVar] -> TcM ()
1593 -- The extra_tvs can include boxy type variables;
1594 --      e.g. TcMatches.tcCheckExistentialPat
1595 checkSigTyVarsWrt extra_tvs sig_tvs
1596   = do  { extra_tvs' <- zonkTcTyVarsAndFV (varSetElems extra_tvs)
1597         ; check_sig_tyvars extra_tvs' sig_tvs }
1598
1599 check_sig_tyvars
1600         :: TcTyVarSet   -- Global type variables. The universally quantified
1601                         --      tyvars should not mention any of these
1602                         --      Guaranteed already zonked.
1603         -> [TcTyVar]    -- Universally-quantified type variables in the signature
1604                         --      Guaranteed to be skolems
1605         -> TcM ()
1606 check_sig_tyvars extra_tvs []
1607   = returnM ()
1608 check_sig_tyvars extra_tvs sig_tvs
1609   = ASSERT( all isSkolemTyVar sig_tvs )
1610     do  { gbl_tvs <- tcGetGlobalTyVars
1611         ; traceTc (text "check_sig_tyvars" <+> (vcat [text "sig_tys" <+> ppr sig_tvs,
1612                                       text "gbl_tvs" <+> ppr gbl_tvs,
1613                                       text "extra_tvs" <+> ppr extra_tvs]))
1614
1615         ; let env_tvs = gbl_tvs `unionVarSet` extra_tvs
1616         ; ifM (any (`elemVarSet` env_tvs) sig_tvs)
1617               (bleatEscapedTvs env_tvs sig_tvs sig_tvs)
1618         }
1619
1620 bleatEscapedTvs :: TcTyVarSet   -- The global tvs
1621                 -> [TcTyVar]    -- The possibly-escaping type variables
1622                 -> [TcTyVar]    -- The zonked versions thereof
1623                 -> TcM ()
1624 -- Complain about escaping type variables
1625 -- We pass a list of type variables, at least one of which
1626 -- escapes.  The first list contains the original signature type variable,
1627 -- while the second  contains the type variable it is unified to (usually itself)
1628 bleatEscapedTvs globals sig_tvs zonked_tvs
1629   = do  { env0 <- tcInitTidyEnv
1630         ; let (env1, tidy_tvs)        = tidyOpenTyVars env0 sig_tvs
1631               (env2, tidy_zonked_tvs) = tidyOpenTyVars env1 zonked_tvs
1632
1633         ; (env3, msgs) <- foldlM check (env2, []) (tidy_tvs `zip` tidy_zonked_tvs)
1634         ; failWithTcM (env3, main_msg $$ nest 2 (vcat msgs)) }
1635   where
1636     main_msg = ptext SLIT("Inferred type is less polymorphic than expected")
1637
1638     check (tidy_env, msgs) (sig_tv, zonked_tv)
1639       | not (zonked_tv `elemVarSet` globals) = return (tidy_env, msgs)
1640       | otherwise
1641       = do { (tidy_env1, globs) <- findGlobals (unitVarSet zonked_tv) tidy_env
1642            ; returnM (tidy_env1, escape_msg sig_tv zonked_tv globs : msgs) }
1643
1644 -----------------------
1645 escape_msg sig_tv zonked_tv globs
1646   | notNull globs
1647   = vcat [sep [msg, ptext SLIT("is mentioned in the environment:")],
1648           nest 2 (vcat globs)]
1649   | otherwise
1650   = msg <+> ptext SLIT("escapes")
1651         -- Sigh.  It's really hard to give a good error message
1652         -- all the time.   One bad case is an existential pattern match.
1653         -- We rely on the "When..." context to help.
1654   where
1655     msg = ptext SLIT("Quantified type variable") <+> quotes (ppr sig_tv) <+> is_bound_to
1656     is_bound_to
1657         | sig_tv == zonked_tv = empty
1658         | otherwise = ptext SLIT("is unified with") <+> quotes (ppr zonked_tv) <+> ptext SLIT("which")
1659 \end{code}
1660
1661 These two context are used with checkSigTyVars
1662
1663 \begin{code}
1664 sigCtxt :: Id -> [TcTyVar] -> TcThetaType -> TcTauType
1665         -> TidyEnv -> TcM (TidyEnv, Message)
1666 sigCtxt id sig_tvs sig_theta sig_tau tidy_env
1667   = zonkTcType sig_tau          `thenM` \ actual_tau ->
1668     let
1669         (env1, tidy_sig_tvs)    = tidyOpenTyVars tidy_env sig_tvs
1670         (env2, tidy_sig_rho)    = tidyOpenType env1 (mkPhiTy sig_theta sig_tau)
1671         (env3, tidy_actual_tau) = tidyOpenType env2 actual_tau
1672         sub_msg = vcat [ptext SLIT("Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tvs tidy_sig_rho),
1673                         ptext SLIT("Type to generalise:") <+> pprType tidy_actual_tau
1674                    ]
1675         msg = vcat [ptext SLIT("When trying to generalise the type inferred for") <+> quotes (ppr id),
1676                     nest 2 sub_msg]
1677     in
1678     returnM (env3, msg)
1679 \end{code}