ghc/compiler/types/PprType.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[PprType]{Printing Types, TyVars, Classes, TyCons}
   5
   6 \begin{code}
   7 module PprType(
   8         pprKind, pprParendKind,
   9         pprType, pprParendType,
  10         pprSourceType, pprPred, pprTheta, pprClassPred,
  11         pprTyVarBndr, pprTyVarBndrs,
  12
  13         -- Junk
  14         getTyDescription, showTypeCategory
  15  ) where
  16
  17 #include "HsVersions.h"
  18
  19 -- friends:
  20 -- (PprType can see all the representations it's trying to print)
  21 import TypeRep          ( Type(..), TyNote(..),
  22                           Kind, liftedTypeKind ) -- friend
  23 import Type             ( SourceType(..), eqKind )
  24 import TcType           ( ThetaType, PredType,
  25                           tcSplitSigmaTy, isPredTy, isDictTy,
  26                           tcSplitTyConApp_maybe, tcSplitFunTy_maybe
  27                         )
  28 import Var              ( TyVar, tyVarKind )
  29 import Class            ( Class )
  30 import TyCon            ( TyCon, isPrimTyCon, isTupleTyCon, tupleTyConBoxity,
  31                           maybeTyConSingleCon, isEnumerationTyCon,
  32                           tyConArity, tyConName
  33                         )
  34
  35 -- others:
  36 import Maybes           ( maybeToBool )
  37 import Name             ( getOccString, getOccName )
  38 import OccName          ( occNameUserString )
  39 import Outputable
  40 import Unique           ( Uniquable(..) )
  41 import Util             ( lengthIs )
  42 import BasicTypes       ( IPName(..), tupleParens, ipNameName )
  43 import PrelNames                -- quite a few *Keys
  44 \end{code}
  45
  46 %************************************************************************
  47 %*                                                                      *
  48 \subsection{The external interface}
  49 %*                                                                      *
  50 %************************************************************************
  51
  52 @pprType@ is the standard @Type@ printer; the overloaded @ppr@ function is
  53 defined to use this.  @pprParendType@ is the same, except it puts
  54 parens around the type, except for the atomic cases.  @pprParendType@
  55 works just by setting the initial context precedence very high.
  56
  57 \begin{code}
  58 pprType, pprParendType :: Type -> SDoc
  59 pprType       ty = ppr_ty tOP_PREC   ty
  60 pprParendType ty = ppr_ty tYCON_PREC ty
  61
  62 pprKind, pprParendKind :: Kind -> SDoc
  63 pprKind       = pprType
  64 pprParendKind = pprParendType
  65
  66 pprPred :: PredType -> SDoc
  67 pprPred = pprSourceType
  68
  69 pprSourceType :: SourceType -> SDoc
  70 pprSourceType (ClassP clas tys) = pprClassPred clas tys
  71 pprSourceType (IParam n ty)     = hsep [ppr n, dcolon, ppr ty]
  72 pprSourceType (NType tc tys)    = ppr tc <+> sep (map pprParendType tys)
  73
  74 pprClassPred :: Class -> [Type] -> SDoc
  75 pprClassPred clas tys = ppr clas <+> sep (map pprParendType tys)
  76
  77 pprTheta :: ThetaType -> SDoc
  78 pprTheta theta = parens (sep (punctuate comma (map pprPred theta)))
  79
  80 instance Outputable Type where
  81     ppr ty = pprType ty
  82
  83 instance Outputable SourceType where
  84     ppr = pprPred
  85
  86 instance Outputable name => Outputable (IPName name) where
  87     ppr (Dupable n) = char '?' <> ppr n -- Ordinary implicit parameters
  88     ppr (Linear  n) = char '%' <> ppr n -- Splittable implicit parameters
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{Pretty printing}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 Precedence
  99 ~~~~~~~~~~
 100 @ppr_ty@ takes an @Int@ that is the precedence of the context.
 101 The precedence levels are:
 102 \begin{description}
 103 \item[tOP_PREC]   No parens required.
 104 \item[fUN_PREC]   Left hand argument of a function arrow.
 105 \item[tYCON_PREC] Argument of a type constructor.
 106 \end{description}
 107
 108
 109 \begin{code}
 110 tOP_PREC    = (0 :: Int)  -- type   in ParseIface.y
 111 fUN_PREC    = (1 :: Int)  -- btype  in ParseIface.y
 112 tYCON_PREC  = (2 :: Int)  -- atype  in ParseIface.y
 113
 114 maybeParen ctxt_prec inner_prec pretty
 115   | ctxt_prec < inner_prec = pretty
 116   | otherwise              = parens pretty
 117 \end{code}
 118
 119 \begin{code}
 120 ppr_ty :: Int -> Type -> SDoc
 121 ppr_ty ctxt_prec (TyVarTy tyvar)
 122   = ppr tyvar
 123
 124 ppr_ty ctxt_prec ty@(TyConApp tycon tys)
 125         -- KIND CASE; it's of the form (Type x)
 126   | tycon `hasKey` typeConKey,
 127     [ty] <- tys
 128   =     -- For kinds, print (Type x) as just x if x is a
 129         --      type constructor (must be Boxed, Unboxed, AnyBox)
 130         -- Otherwise print as (Type x)
 131     case ty of
 132         TyConApp bx [] -> ppr (getOccName bx)   -- Always unqualified
 133         other          -> maybeParen ctxt_prec tYCON_PREC
 134                                      (ppr tycon <+> ppr_ty tYCON_PREC ty)
 135
 136         -- USAGE CASE
 137   | (tycon `hasKey` usOnceTyConKey || tycon `hasKey` usManyTyConKey),
 138     null tys
 139   =     -- For usages (! and .), always print bare OccName, without pkg/mod/uniq
 140     ppr (getOccName (tyConName tycon))
 141
 142         -- TUPLE CASE (boxed and unboxed)
 143   |  isTupleTyCon tycon,
 144       tys `lengthIs` tyConArity tycon   -- No magic if partially applied
 145   = tupleParens (tupleTyConBoxity tycon)
 146                 (sep (punctuate comma (map (ppr_ty tOP_PREC) tys)))
 147
 148         -- LIST CASE
 149   | tycon `hasKey` listTyConKey,
 150     [ty] <- tys
 151   = brackets (ppr_ty tOP_PREC ty)
 152
 153         -- PARALLEL ARRAY CASE
 154   | tycon `hasKey` parrTyConKey,
 155     [ty] <- tys
 156   = pabrackets (ppr_ty tOP_PREC ty)
 157
 158         -- GENERAL CASE
 159   | otherwise
 160   = ppr_tc_app ctxt_prec tycon tys
 161
 162   where
 163     pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 164
 165
 166 ppr_ty ctxt_prec ty@(ForAllTy _ _)
 167   = getPprStyle $ \ sty ->
 168     maybeParen ctxt_prec fUN_PREC $
 169     sep [ ptext SLIT("forall") <+> pp_tyvars sty <> ptext SLIT("."),
 170           ppr_theta theta,
 171           ppr_ty tOP_PREC tau
 172     ]
 173  where
 174     (tyvars, theta, tau) = tcSplitSigmaTy ty
 175     pp_tyvars sty        = sep (map pprTyVarBndr tyvars)
 176
 177     ppr_theta []     = empty
 178     ppr_theta theta  = pprTheta theta <+> ptext SLIT("=>")
 179
 180
 181 ppr_ty ctxt_prec (FunTy ty1 ty2)
 182   -- we don't want to lose usage annotations or synonyms,
 183   -- so we mustn't use splitFunTys here.
 184   = maybeParen ctxt_prec fUN_PREC $
 185     sep [ ppr_ty fUN_PREC ty1
 186         , ptext arrow <+> ppr_ty tOP_PREC ty2
 187         ]
 188   where arrow | isPredTy ty1 = SLIT("=>")
 189               | otherwise    = SLIT("->")
 190
 191 ppr_ty ctxt_prec (AppTy ty1 ty2)
 192   = maybeParen ctxt_prec tYCON_PREC $
 193     ppr_ty fUN_PREC ty1 <+> ppr_ty tYCON_PREC ty2
 194
 195 ppr_ty ctxt_prec (NoteTy (SynNote ty) expansion)
 196   = ppr_ty ctxt_prec ty
 197 --  = ppr_ty ctxt_prec expansion -- if we don't want to see syntys
 198
 199 ppr_ty ctxt_prec (NoteTy (FTVNote _) ty) = ppr_ty ctxt_prec ty
 200
 201 ppr_ty ctxt_prec (SourceTy (NType tc tys)) = ppr_tc_app ctxt_prec tc tys
 202 ppr_ty ctxt_prec (SourceTy pred)           = braces (pprPred pred)
 203
 204 ppr_tc_app ctxt_prec tc []  = ppr tc
 205 ppr_tc_app ctxt_prec tc tys = maybeParen ctxt_prec tYCON_PREC
 206                                          (sep [ppr tc, nest 4 (sep (map (ppr_ty tYCON_PREC) tys))])
 207 \end{code}
 208
 209
 210 %************************************************************************
 211 %*                                                                      *
 212 \subsection[TyVar]{@TyVar@}
 213 %*                                                                      *
 214 %************************************************************************
 215
 216 We print type-variable binders with their kinds in interface files,
 217 and when in debug mode.
 218
 219 \begin{code}
 220 pprTyVarBndr :: TyVar -> SDoc
 221 pprTyVarBndr tyvar
 222   = getPprStyle $ \ sty ->
 223     if debugStyle sty then
 224         hsep [ppr tyvar, dcolon, pprParendKind kind]
 225                 -- See comments with ppDcolon in PprCore.lhs
 226     else
 227         ppr tyvar
 228   where
 229     kind = tyVarKind tyvar
 230
 231 pprTyVarBndrs tyvars = hsep (map pprTyVarBndr tyvars)
 232 \end{code}
 233
 234
 235 %************************************************************************
 236 %*                                                                      *
 237 \subsection{Mumbo jumbo}
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 Grab a name for the type. This is used to determine the type
 242 description for profiling.
 243
 244 \begin{code}
 245 getTyDescription :: Type -> String
 246
 247 getTyDescription ty
 248   = case (tcSplitSigmaTy ty) of { (_, _, tau_ty) ->
 249     case tau_ty of
 250       TyVarTy _              -> "*"
 251       AppTy fun _            -> getTyDescription fun
 252       FunTy _ res            -> '-' : '>' : fun_result res
 253       TyConApp tycon _       -> occNameUserString (getOccName tycon)
 254       NoteTy (FTVNote _) ty  -> getTyDescription ty
 255       NoteTy (SynNote ty1) _ -> getTyDescription ty1
 256       SourceTy sty           -> getSourceTyDescription sty
 257       ForAllTy _ ty          -> getTyDescription ty
 258     }
 259   where
 260     fun_result (FunTy _ res) = '>' : fun_result res
 261     fun_result other         = getTyDescription other
 262
 263 getSourceTyDescription (ClassP cl tys) = getOccString cl
 264 getSourceTyDescription (NType  tc tys) = getOccString tc
 265 getSourceTyDescription (IParam ip ty)  = getOccString (ipNameName ip)
 266 \end{code}
 267
 268
 269 \begin{code}
 270 showTypeCategory :: Type -> Char
 271   {-
 272         {C,I,F,D}   char, int, float, double
 273         T           tuple
 274         S           other single-constructor type
 275         {c,i,f,d}   unboxed ditto
 276         t           *unpacked* tuple
 277         s           *unpacked" single-cons...
 278
 279         v           void#
 280         a           primitive array
 281
 282         E           enumeration type
 283         +           dictionary, unless it's a ...
 284         L           List
 285         >           function
 286         M           other (multi-constructor) data-con type
 287         .           other type
 288         -           reserved for others to mark as "uninteresting"
 289     -}
 290 showTypeCategory ty
 291   = if isDictTy ty
 292     then '+'
 293     else
 294       case tcSplitTyConApp_maybe ty of
 295         Nothing -> if maybeToBool (tcSplitFunTy_maybe ty)
 296                    then '>'
 297                    else '.'
 298
 299         Just (tycon, _) ->
 300           let utc = getUnique tycon in
 301           if      utc == charDataConKey    then 'C'
 302           else if utc == intDataConKey     then 'I'
 303           else if utc == floatDataConKey   then 'F'
 304           else if utc == doubleDataConKey  then 'D'
 305           else if utc == smallIntegerDataConKey ||
 306                   utc == largeIntegerDataConKey   then 'J'
 307           else if utc == charPrimTyConKey  then 'c'
 308           else if (utc == intPrimTyConKey || utc == wordPrimTyConKey
 309                 || utc == addrPrimTyConKey)                then 'i'
 310           else if utc  == floatPrimTyConKey                then 'f'
 311           else if utc  == doublePrimTyConKey               then 'd'
 312           else if isPrimTyCon tycon {- array, we hope -}   then 'A'     -- Bogus
 313           else if isEnumerationTyCon tycon                 then 'E'
 314           else if isTupleTyCon tycon                       then 'T'
 315           else if maybeToBool (maybeTyConSingleCon tycon)  then 'S'
 316           else if utc == listTyConKey                      then 'L'
 317           else 'M' -- oh, well...
 318 \end{code}