ghc/compiler/types/Type.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1998
   3 %
   4 \section[Type]{Type - public interface}
   5
   6 \begin{code}
   7 module Type (
   8         -- re-exports from TypeRep:
   9         Type,
  10         Kind, TyVarSubst,
  11
  12         superKind, superBoxity,                         -- :: SuperKind
  13
  14         boxedKind,                                      -- :: Kind :: BX
  15         anyBoxKind,                                     -- :: Kind :: BX
  16         typeCon,                                        -- :: KindCon :: BX -> KX
  17         anyBoxCon,                                      -- :: KindCon :: BX
  18
  19         boxedTypeKind, unboxedTypeKind, openTypeKind,   -- Kind :: superKind
  20
  21         mkArrowKind, mkArrowKinds, -- mentioned below: hasMoreBoxityInfo,
  22
  23         funTyCon,
  24
  25         -- exports from this module:
  26         hasMoreBoxityInfo,
  27
  28         mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, isTyVarTy,
  29
  30         mkAppTy, mkAppTys, splitAppTy, splitAppTys, splitAppTy_maybe,
  31
  32         mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe, splitFunTys, splitFunTysN,
  33         funResultTy, funArgTy, zipFunTys,
  34
  35         mkTyConApp, mkTyConTy, splitTyConApp_maybe,
  36         splitAlgTyConApp_maybe, splitAlgTyConApp,
  37         mkDictTy, mkDictTys, mkPredTy, splitPredTy_maybe, splitDictTy_maybe, isDictTy,
  38
  39         mkSynTy, isSynTy, deNoteType,
  40
  41         repType, splitRepFunTys, splitNewType_maybe, typePrimRep,
  42
  43         UsageAnn(..), mkUsgTy, isUsgTy{- dont use -}, isNotUsgTy, splitUsgTy, unUsgTy, tyUsg,
  44         mkUsForAllTy, mkUsForAllTys, splitUsForAllTys, substUsTy,
  45
  46         mkForAllTy, mkForAllTys, splitForAllTy_maybe, splitForAllTys,
  47         applyTy, applyTys, hoistForAllTys,
  48
  49         TauType, RhoType, SigmaType, PredType(..), ThetaType,
  50         ClassPred, ClassContext, mkClassPred,
  51         getClassTys_maybe, ipName_maybe, classesToPreds, classesOfPreds,
  52         isTauTy, mkRhoTy, splitRhoTy,
  53         mkSigmaTy, isSigmaTy, splitSigmaTy,
  54
  55         -- Lifting and boxity
  56         isUnLiftedType, isUnboxedType, isUnboxedTupleType, isAlgType, isDataType, isNewType,
  57
  58         -- Free variables
  59         tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
  60         namesOfType, typeKind, addFreeTyVars,
  61
  62         -- Tidying up for printing
  63         tidyType,     tidyTypes,
  64         tidyOpenType, tidyOpenTypes,
  65         tidyTyVar,    tidyTyVars,
  66         tidyTopType,
  67
  68         -- Seq
  69         seqType, seqTypes
  70
  71     ) where
  72
  73 #include "HsVersions.h"
  74
  75 -- We import the representation and primitive functions from TypeRep.
  76 -- Many things are reexported, but not the representation!
  77
  78 import TypeRep
  79
  80 -- Other imports:
  81
  82 import {-# SOURCE #-}   DataCon( DataCon, dataConRepType )
  83 import {-# SOURCE #-}   PprType( pprType, pprPred )     -- Only called in debug messages
  84 import {-# SOURCE #-}   Subst  ( mkTyVarSubst, substTy )
  85
  86 -- friends:
  87 import Var      ( TyVar, Var, UVar,
  88                   tyVarKind, tyVarName, setTyVarName, isId, idType,
  89                 )
  90 import VarEnv
  91 import VarSet
  92
  93 import Name     ( Name, NamedThing(..), mkLocalName, tidyOccName
  94                 )
  95 import NameSet
  96 import Class    ( classTyCon, Class, ClassPred, ClassContext )
  97 import TyCon    ( TyCon,
  98                   isUnboxedTupleTyCon, isUnLiftedTyCon,
  99                   isFunTyCon, isDataTyCon, isNewTyCon, newTyConRep,
 100                   isAlgTyCon, isSynTyCon, tyConArity,
 101                   tyConKind, tyConDataCons, getSynTyConDefn,
 102                   tyConPrimRep, tyConClass_maybe
 103                 )
 104
 105 -- others
 106 import SrcLoc           ( noSrcLoc )
 107 import Maybes           ( maybeToBool )
 108 import PrimRep          ( PrimRep(..), isFollowableRep )
 109 import Unique           ( Uniquable(..) )
 110 import Util             ( mapAccumL, seqList )
 111 import Outputable
 112 import UniqSet          ( sizeUniqSet )         -- Should come via VarSet
 113 \end{code}
 114
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Stuff to do with kinds.}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 \begin{code}
 123 hasMoreBoxityInfo :: Kind -> Kind -> Bool
 124 hasMoreBoxityInfo k1 k2
 125   | k2 == openTypeKind = ASSERT( is_type_kind k1) True
 126   | otherwise          = k1 == k2
 127   where
 128         -- Returns true for things of form (Type x)
 129     is_type_kind k = case splitTyConApp_maybe k of
 130                         Just (tc,[_]) -> tc == typeCon
 131                         Nothing       -> False
 132 \end{code}
 133
 134
 135 %************************************************************************
 136 %*                                                                      *
 137 \subsection{Constructor-specific functions}
 138 %*                                                                      *
 139 %************************************************************************
 140
 141
 142 ---------------------------------------------------------------------
 143                                 TyVarTy
 144                                 ~~~~~~~
 145 \begin{code}
 146 mkTyVarTy  :: TyVar   -> Type
 147 mkTyVarTy  = TyVarTy
 148
 149 mkTyVarTys :: [TyVar] -> [Type]
 150 mkTyVarTys = map mkTyVarTy -- a common use of mkTyVarTy
 151
 152 getTyVar :: String -> Type -> TyVar
 153 getTyVar msg (TyVarTy tv) = tv
 154 getTyVar msg (NoteTy _ t) = getTyVar msg t
 155 getTyVar msg other        = panic ("getTyVar: " ++ msg)
 156
 157 getTyVar_maybe :: Type -> Maybe TyVar
 158 getTyVar_maybe (TyVarTy tv) = Just tv
 159 getTyVar_maybe (NoteTy _ t) = getTyVar_maybe t
 160 getTyVar_maybe other        = Nothing
 161
 162 isTyVarTy :: Type -> Bool
 163 isTyVarTy (TyVarTy tv)  = True
 164 isTyVarTy (NoteTy _ ty) = isTyVarTy ty
 165 isTyVarTy other         = False
 166 \end{code}
 167
 168
 169 ---------------------------------------------------------------------
 170                                 AppTy
 171                                 ~~~~~
 172 We need to be pretty careful with AppTy to make sure we obey the
 173 invariant that a TyConApp is always visibly so.  mkAppTy maintains the
 174 invariant: use it.
 175
 176 \begin{code}
 177 mkAppTy orig_ty1 orig_ty2 = ASSERT2( isNotUsgTy orig_ty1 && isNotUsgTy orig_ty2, pprType orig_ty1 <+> text "to" <+> pprType orig_ty2 )
 178                             mk_app orig_ty1
 179   where
 180     mk_app (NoteTy _ ty1)    = mk_app ty1
 181     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ [orig_ty2])
 182     mk_app ty1               = AppTy orig_ty1 orig_ty2
 183
 184 mkAppTys :: Type -> [Type] -> Type
 185 mkAppTys orig_ty1 []        = orig_ty1
 186         -- This check for an empty list of type arguments
 187         -- avoids the needless of a type synonym constructor.
 188         -- For example: mkAppTys Rational []
 189         --   returns to (Ratio Integer), which has needlessly lost
 190         --   the Rational part.
 191 mkAppTys orig_ty1 orig_tys2 = ASSERT2( isNotUsgTy orig_ty1, pprType orig_ty1 )
 192                               mk_app orig_ty1
 193   where
 194     mk_app (NoteTy _ ty1)    = mk_app ty1
 195     mk_app (TyConApp tc tys) = mkTyConApp tc (tys ++ orig_tys2)
 196     mk_app ty1               = ASSERT2( all isNotUsgTy orig_tys2, pprType orig_ty1 <+> text "to" <+> hsep (map pprType orig_tys2) )
 197                                foldl AppTy orig_ty1 orig_tys2
 198
 199 splitAppTy_maybe :: Type -> Maybe (Type, Type)
 200 splitAppTy_maybe (FunTy ty1 ty2)   = Just (TyConApp funTyCon [ty1], ty2)
 201 splitAppTy_maybe (AppTy ty1 ty2)   = Just (ty1, ty2)
 202 splitAppTy_maybe (NoteTy _ ty)     = splitAppTy_maybe ty
 203 splitAppTy_maybe (TyConApp tc [])  = Nothing
 204 splitAppTy_maybe (TyConApp tc tys) = split tys []
 205                             where
 206                                split [ty2]    acc = Just (TyConApp tc (reverse acc), ty2)
 207                                split (ty:tys) acc = split tys (ty:acc)
 208
 209 splitAppTy_maybe other            = Nothing
 210
 211 splitAppTy :: Type -> (Type, Type)
 212 splitAppTy ty = case splitAppTy_maybe ty of
 213                         Just pr -> pr
 214                         Nothing -> panic "splitAppTy"
 215
 216 splitAppTys :: Type -> (Type, [Type])
 217 splitAppTys ty = split ty ty []
 218   where
 219     split orig_ty (AppTy ty arg)        args = split ty ty (arg:args)
 220     split orig_ty (NoteTy _ ty)         args = split orig_ty ty args
 221     split orig_ty (FunTy ty1 ty2)       args = ASSERT( null args )
 222                                                (TyConApp funTyCon [], [ty1,ty2])
 223     split orig_ty (TyConApp tc tc_args) args = (TyConApp tc [], tc_args ++ args)
 224     split orig_ty ty                    args = (orig_ty, args)
 225 \end{code}
 226
 227
 228 ---------------------------------------------------------------------
 229                                 FunTy
 230                                 ~~~~~
 231
 232 \begin{code}
 233 mkFunTy :: Type -> Type -> Type
 234 mkFunTy arg res = FunTy arg res
 235
 236 mkFunTys :: [Type] -> Type -> Type
 237 mkFunTys tys ty = foldr FunTy ty tys
 238
 239 splitFunTy :: Type -> (Type, Type)
 240 splitFunTy (FunTy arg res) = (arg, res)
 241 splitFunTy (NoteTy _ ty)   = splitFunTy ty
 242
 243 splitFunTy_maybe :: Type -> Maybe (Type, Type)
 244 splitFunTy_maybe (FunTy arg res)        = Just (arg, res)
 245 splitFunTy_maybe (NoteTy (IPNote _) ty) = Nothing
 246 splitFunTy_maybe (NoteTy _ ty)          = splitFunTy_maybe ty
 247 splitFunTy_maybe other                  = Nothing
 248
 249 splitFunTys :: Type -> ([Type], Type)
 250 splitFunTys ty = split [] ty ty
 251   where
 252     split args orig_ty (FunTy arg res) = split (arg:args) res res
 253     split args orig_ty (NoteTy (IPNote _) ty)
 254                                        = (reverse args, orig_ty)
 255     split args orig_ty (NoteTy _ ty)   = split args orig_ty ty
 256     split args orig_ty ty              = (reverse args, orig_ty)
 257
 258 splitFunTysN :: String -> Int -> Type -> ([Type], Type)
 259 splitFunTysN msg orig_n orig_ty = split orig_n [] orig_ty orig_ty
 260   where
 261     split 0 args syn_ty ty              = (reverse args, syn_ty)
 262     split n args syn_ty (FunTy arg res) = split (n-1) (arg:args) res    res
 263     split n args syn_ty (NoteTy _ ty)   = split n     args       syn_ty ty
 264     split n args syn_ty ty              = pprPanic ("splitFunTysN: " ++ msg) (int orig_n <+> pprType orig_ty)
 265
 266 zipFunTys :: Outputable a => [a] -> Type -> ([(a,Type)], Type)
 267 zipFunTys orig_xs orig_ty = split [] orig_xs orig_ty orig_ty
 268   where
 269     split acc []     nty ty              = (reverse acc, nty)
 270     split acc (x:xs) nty (FunTy arg res) = split ((x,arg):acc) xs res res
 271     split acc xs     nty (NoteTy _ ty)   = split acc           xs nty ty
 272     split acc (x:xs) nty ty              = pprPanic "zipFunTys" (ppr orig_xs <+> pprType orig_ty)
 273
 274 funResultTy :: Type -> Type
 275 funResultTy (FunTy arg res) = res
 276 funResultTy (NoteTy _ ty)   = funResultTy ty
 277 funResultTy ty              = pprPanic "funResultTy" (pprType ty)
 278
 279 funArgTy :: Type -> Type
 280 funArgTy (FunTy arg res) = arg
 281 funArgTy (NoteTy _ ty)   = funArgTy ty
 282 funArgTy ty              = pprPanic "funArgTy" (pprType ty)
 283 \end{code}
 284
 285
 286 ---------------------------------------------------------------------
 287                                 TyConApp
 288                                 ~~~~~~~~
 289
 290 \begin{code}
 291 mkTyConApp :: TyCon -> [Type] -> Type
 292 mkTyConApp tycon tys
 293   | isFunTyCon tycon && length tys == 2
 294   = case tys of
 295         (ty1:ty2:_) -> FunTy ty1 ty2
 296
 297   | otherwise
 298   = ASSERT(not (isSynTyCon tycon))
 299     TyConApp tycon tys
 300
 301 mkTyConTy :: TyCon -> Type
 302 mkTyConTy tycon = ASSERT( not (isSynTyCon tycon) )
 303                   TyConApp tycon []
 304
 305 -- splitTyConApp "looks through" synonyms, because they don't
 306 -- mean a distinct type, but all other type-constructor applications
 307 -- including functions are returned as Just ..
 308
 309 splitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 310 splitTyConApp_maybe (TyConApp tc tys)      = Just (tc, tys)
 311 splitTyConApp_maybe (FunTy arg res)        = Just (funTyCon, [arg,res])
 312 splitTyConApp_maybe (NoteTy _ ty)          = splitTyConApp_maybe ty
 313 splitTyConApp_maybe other                  = Nothing
 314
 315 -- splitAlgTyConApp_maybe looks for
 316 --      *saturated* applications of *algebraic* data types
 317 -- "Algebraic" => newtype, data type, or dictionary (not function types)
 318 -- We return the constructors too, so there had better be some.
 319
 320 splitAlgTyConApp_maybe :: Type -> Maybe (TyCon, [Type], [DataCon])
 321 splitAlgTyConApp_maybe (TyConApp tc tys)
 322   | isAlgTyCon tc &&
 323     tyConArity tc == length tys      = Just (tc, tys, tyConDataCons tc)
 324 splitAlgTyConApp_maybe (NoteTy (IPNote _) ty)
 325                                      = Nothing
 326 splitAlgTyConApp_maybe (NoteTy _ ty) = splitAlgTyConApp_maybe ty
 327 splitAlgTyConApp_maybe other         = Nothing
 328
 329 splitAlgTyConApp :: Type -> (TyCon, [Type], [DataCon])
 330         -- Here the "algebraic" property is an *assertion*
 331 splitAlgTyConApp (TyConApp tc tys) = ASSERT( isAlgTyCon tc && tyConArity tc == length tys )
 332                                      (tc, tys, tyConDataCons tc)
 333 splitAlgTyConApp (NoteTy _ ty)     = splitAlgTyConApp ty
 334 #ifdef DEBUG
 335 splitAlgTyConApp ty = pprPanic "splitAlgTyConApp" (pprType ty)
 336 #endif
 337 \end{code}
 338
 339 "Dictionary" types are just ordinary data types, but you can
 340 tell from the type constructor whether it's a dictionary or not.
 341
 342 \begin{code}
 343 mkDictTy :: Class -> [Type] -> Type
 344 mkDictTy clas tys = TyConApp (classTyCon clas) tys
 345
 346 mkDictTys :: ClassContext -> [Type]
 347 mkDictTys cxt = [mkDictTy cls tys | (cls,tys) <- cxt]
 348
 349 mkPredTy :: PredType -> Type
 350 mkPredTy (Class clas tys) = TyConApp (classTyCon clas) tys
 351 mkPredTy (IParam n ty)    = NoteTy (IPNote n) ty
 352
 353 splitPredTy_maybe :: Type -> Maybe PredType
 354 splitPredTy_maybe (TyConApp tc tys)
 355   |  maybeToBool maybe_class
 356   && tyConArity tc == length tys = Just (Class clas tys)
 357   where
 358      maybe_class = tyConClass_maybe tc
 359      Just clas   = maybe_class
 360
 361 splitPredTy_maybe (NoteTy (IPNote n) ty)
 362                                 = Just (IParam n ty)
 363 splitPredTy_maybe (NoteTy _ ty) = splitPredTy_maybe ty
 364 splitPredTy_maybe other         = Nothing
 365
 366 splitDictTy_maybe :: Type -> Maybe (Class, [Type])
 367 splitDictTy_maybe ty
 368   = case splitPredTy_maybe ty of
 369     Just p  -> getClassTys_maybe p
 370     Nothing -> Nothing
 371
 372 isDictTy :: Type -> Bool
 373         -- This version is slightly more efficient than (maybeToBool . splitDictTy)
 374 isDictTy (TyConApp tc tys)
 375   |  maybeToBool (tyConClass_maybe tc)
 376   && tyConArity tc == length tys
 377   = True
 378 isDictTy (NoteTy _ ty)  = isDictTy ty
 379 isDictTy other          = False
 380 \end{code}
 381
 382 ---------------------------------------------------------------------
 383                                 SynTy
 384                                 ~~~~~
 385
 386 \begin{code}
 387 mkSynTy syn_tycon tys
 388   = ASSERT( isSynTyCon syn_tycon )
 389     ASSERT( isNotUsgTy body )
 390     ASSERT( length tyvars == length tys )
 391     NoteTy (SynNote (TyConApp syn_tycon tys))
 392            (substTy (mkTyVarSubst tyvars tys) body)
 393   where
 394     (tyvars, body) = getSynTyConDefn syn_tycon
 395
 396 isSynTy (NoteTy (SynNote _) _) = True
 397 isSynTy other                  = False
 398
 399 deNoteType :: Type -> Type
 400         -- Sorry for the cute name
 401 deNoteType ty@(TyVarTy tyvar)   = ty
 402 deNoteType (TyConApp tycon tys) = TyConApp tycon (map deNoteType tys)
 403 deNoteType (NoteTy _ ty)        = deNoteType ty
 404 deNoteType (AppTy fun arg)      = AppTy (deNoteType fun) (deNoteType arg)
 405 deNoteType (FunTy fun arg)      = FunTy (deNoteType fun) (deNoteType arg)
 406 deNoteType (ForAllTy tv ty)     = ForAllTy tv (deNoteType ty)
 407 \end{code}
 408
 409 Notes on type synonyms
 410 ~~~~~~~~~~~~~~~~~~~~~~
 411 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
 412 to return type synonyms whereever possible. Thus
 413
 414         type Foo a = a -> a
 415
 416 we want
 417         splitFunTys (a -> Foo a) = ([a], Foo a)
 418 not                                ([a], a -> a)
 419
 420 The reason is that we then get better (shorter) type signatures in
 421 interfaces.  Notably this plays a role in tcTySigs in TcBinds.lhs.
 422
 423
 424                 Representation types
 425                 ~~~~~~~~~~~~~~~~~~~~
 426
 427 repType looks through
 428         (a) for-alls, and
 429         (b) newtypes
 430         (c) synonyms
 431 It's useful in the back end where we're not
 432 interested in newtypes anymore.
 433
 434 \begin{code}
 435 repType :: Type -> Type
 436 repType (ForAllTy _ ty) = repType ty
 437 repType (NoteTy   _ ty) = repType ty
 438 repType ty              = case splitNewType_maybe ty of
 439                             Just ty' -> repType ty'     -- Still re-apply repType in case of for-all
 440                             Nothing  -> ty
 441
 442 splitRepFunTys :: Type -> ([Type], Type)
 443 -- Like splitFunTys, but looks through newtypes and for-alls
 444 splitRepFunTys ty = split [] (repType ty)
 445   where
 446     split args (FunTy arg res)  = split (arg:args) (repType res)
 447     split args ty               = (reverse args, ty)
 448
 449 typePrimRep :: Type -> PrimRep
 450 typePrimRep ty = case repType ty of
 451                    TyConApp tc _ -> tyConPrimRep tc
 452                    FunTy _ _     -> PtrRep
 453                    AppTy _ _     -> PtrRep      -- ??
 454                    TyVarTy _     -> PtrRep
 455
 456 splitNewType_maybe :: Type -> Maybe Type
 457 -- Find the representation of a newtype, if it is one
 458 -- Looks through multiple levels of newtype, but does not look through for-alls
 459 splitNewType_maybe (NoteTy (IPNote _) ty)
 460                                      = Nothing
 461 splitNewType_maybe (NoteTy _ ty)     = splitNewType_maybe ty
 462 splitNewType_maybe (TyConApp tc tys) = case newTyConRep tc of
 463                                          Just rep_ty -> ASSERT( length tys == tyConArity tc )
 464                                                 -- The assert should hold because repType should
 465                                                 -- only be applied to *types* (of kind *)
 466                                                         Just (applyTys rep_ty tys)
 467                                          Nothing     -> Nothing
 468 splitNewType_maybe other             = Nothing
 469 \end{code}
 470
 471
 472
 473 ---------------------------------------------------------------------
 474                                 UsgNote
 475                                 ~~~~~~~
 476
 477 NB: Invariant: if present, usage note is at the very top of the type.
 478 This should be carefully preserved.
 479
 480 In some parts of the compiler, comments use the _Once Upon a
 481 Polymorphic Type_ (POPL'99) usage of "rho = generalised
 482 usage-annotated type; sigma = usage-annotated type; tau =
 483 usage-annotated type except on top"; unfortunately this conflicts with
 484 the rho/tau/theta/sigma usage in the rest of the compiler.  (KSW
 485 1999-07)
 486
 487 \begin{code}
 488 mkUsgTy :: UsageAnn -> Type -> Type
 489 #ifndef USMANY
 490 mkUsgTy UsMany ty = ASSERT2( isNotUsgTy ty, pprType ty )
 491                     ty
 492 #endif
 493 mkUsgTy usg    ty = ASSERT2( isNotUsgTy ty, pprType ty )
 494                     NoteTy (UsgNote usg) ty
 495
 496 -- The isUsgTy function is utterly useless if UsManys are omitted.
 497 -- Be warned!  KSW 1999-04.
 498 isUsgTy :: Type -> Bool
 499 #ifndef USMANY
 500 isUsgTy _ = True
 501 #else
 502 isUsgTy (NoteTy (UsgForAll _) ty) = isUsgTy ty
 503 isUsgTy (NoteTy (UsgNote   _) _ ) = True
 504 isUsgTy other                     = False
 505 #endif
 506
 507 -- The isNotUsgTy function may return a false True if UsManys are omitted;
 508 -- in other words, A SSERT( isNotUsgTy ty ) may be useful but
 509 -- A SSERT( not (isNotUsg ty) ) is asking for trouble.  KSW 1999-04.
 510 isNotUsgTy :: Type -> Bool
 511 isNotUsgTy (NoteTy (UsgForAll _) _) = False
 512 isNotUsgTy (NoteTy (UsgNote   _) _) = False
 513 isNotUsgTy other                    = True
 514
 515 -- splitUsgTy_maybe is not exported, since it is meaningless if
 516 -- UsManys are omitted.  It is used in several places in this module,
 517 -- however.  KSW 1999-04.
 518 splitUsgTy_maybe :: Type -> Maybe (UsageAnn,Type)
 519 splitUsgTy_maybe (NoteTy (UsgNote usg) ty2) = ASSERT( isNotUsgTy ty2 )
 520                                               Just (usg,ty2)
 521 splitUsgTy_maybe ty@(NoteTy (UsgForAll _) _) = pprPanic "splitUsgTy_maybe:" $ pprType ty
 522 splitUsgTy_maybe ty                          = Nothing
 523
 524 splitUsgTy :: Type -> (UsageAnn,Type)
 525 splitUsgTy ty = case splitUsgTy_maybe ty of
 526                   Just ans -> ans
 527                   Nothing  ->
 528 #ifndef USMANY
 529                               (UsMany,ty)
 530 #else
 531                               pprPanic "splitUsgTy: no usage annot:" $ pprType ty
 532 #endif
 533
 534 tyUsg :: Type -> UsageAnn
 535 tyUsg = fst . splitUsgTy
 536
 537 unUsgTy :: Type -> Type
 538 -- strip outer usage annotation if present
 539 unUsgTy ty = case splitUsgTy_maybe ty of
 540                Just (_,ty1) -> ASSERT2( isNotUsgTy ty1, pprType ty )
 541                                ty1
 542                Nothing      -> ty
 543
 544 mkUsForAllTy :: UVar -> Type -> Type
 545 mkUsForAllTy uv ty = NoteTy (UsgForAll uv) ty
 546
 547 mkUsForAllTys :: [UVar] -> Type -> Type
 548 mkUsForAllTys uvs ty = foldr (NoteTy . UsgForAll) ty uvs
 549
 550 splitUsForAllTys :: Type -> ([UVar],Type)
 551 splitUsForAllTys ty = split ty []
 552   where split (NoteTy (UsgForAll u) ty) uvs = split ty (u:uvs)
 553         split other_ty                  uvs = (reverse uvs, other_ty)
 554
 555 substUsTy :: VarEnv UsageAnn -> Type -> Type
 556 -- assumes range is fresh uvars, so no conflicts
 557 substUsTy ve    (NoteTy  note@(UsgNote (UsVar u))
 558                                             ty ) = NoteTy (case lookupVarEnv ve u of
 559                                                              Just ua -> UsgNote ua
 560                                                              Nothing -> note)
 561                                                           (substUsTy ve ty)
 562 substUsTy ve    (NoteTy  note@(UsgNote   _) ty ) = NoteTy note (substUsTy ve ty)
 563 substUsTy ve    (NoteTy  note@(UsgForAll _) ty ) = NoteTy note (substUsTy ve ty)
 564 substUsTy ve    (NoteTy  (SynNote ty1)      ty2) = NoteTy (SynNote (substUsTy ve ty1))
 565                                                           (substUsTy ve ty2)
 566 substUsTy ve    (NoteTy  note@(FTVNote _)   ty ) = NoteTy note (substUsTy ve ty)
 567 substUsTy ve ty@(TyVarTy _                     ) = ty
 568 substUsTy ve    (AppTy   ty1                ty2) = AppTy (substUsTy ve ty1)
 569                                                          (substUsTy ve ty2)
 570 substUsTy ve    (FunTy   ty1                ty2) = FunTy (substUsTy ve ty1)
 571                                                          (substUsTy ve ty2)
 572 substUsTy ve    (TyConApp tyc               tys) = TyConApp tyc (map (substUsTy ve) tys)
 573 substUsTy ve    (ForAllTy yv                ty ) = ForAllTy yv (substUsTy ve ty)
 574 \end{code}
 575
 576
 577 ---------------------------------------------------------------------
 578                                 ForAllTy
 579                                 ~~~~~~~~
 580
 581 We need to be clever here with usage annotations; they need to be
 582 lifted or lowered through the forall as appropriate.
 583
 584 \begin{code}
 585 mkForAllTy :: TyVar -> Type -> Type
 586 mkForAllTy tyvar ty = case splitUsgTy_maybe ty of
 587                         Just (usg,ty') -> NoteTy (UsgNote usg)
 588                                                  (ForAllTy tyvar ty')
 589                         Nothing        -> ForAllTy tyvar ty
 590
 591 mkForAllTys :: [TyVar] -> Type -> Type
 592 mkForAllTys tyvars ty = case splitUsgTy_maybe ty of
 593                           Just (usg,ty') -> NoteTy (UsgNote usg)
 594                                                    (foldr ForAllTy ty' tyvars)
 595                           Nothing        -> foldr ForAllTy ty tyvars
 596
 597 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
 598 splitForAllTy_maybe ty = case splitUsgTy_maybe ty of
 599                            Just (usg,ty') -> do (tyvar,ty'') <- splitFAT_m ty'
 600                                                 return (tyvar, NoteTy (UsgNote usg) ty'')
 601                            Nothing        -> splitFAT_m ty
 602   where
 603     splitFAT_m (NoteTy (IPNote _) ty)   = Nothing
 604     splitFAT_m (NoteTy _ ty)            = splitFAT_m ty
 605     splitFAT_m (ForAllTy tyvar ty)      = Just(tyvar, ty)
 606     splitFAT_m _                        = Nothing
 607
 608 splitForAllTys :: Type -> ([TyVar], Type)
 609 splitForAllTys ty = case splitUsgTy_maybe ty of
 610                       Just (usg,ty') -> let (tvs,ty'') = split ty' ty' []
 611                                         in  (tvs, NoteTy (UsgNote usg) ty'')
 612                       Nothing        -> split ty ty []
 613    where
 614      split orig_ty (ForAllTy tv ty)       tvs = split ty ty (tv:tvs)
 615      split orig_ty (NoteTy (IPNote _) ty) tvs = (reverse tvs, orig_ty)
 616      split orig_ty (NoteTy _ ty)          tvs = split orig_ty ty tvs
 617      split orig_ty t                      tvs = (reverse tvs, orig_ty)
 618 \end{code}
 619
 620 -- (mkPiType now in CoreUtils)
 621
 622 Applying a for-all to its arguments
 623
 624 \begin{code}
 625 applyTy :: Type -> Type -> Type
 626 applyTy (NoteTy note@(UsgNote   _) fun) arg = NoteTy note (applyTy fun arg)
 627 applyTy (NoteTy note@(UsgForAll _) fun) arg = NoteTy note (applyTy fun arg)
 628 applyTy (NoteTy _ fun)                  arg = applyTy fun arg
 629 applyTy (ForAllTy tv ty)                arg = ASSERT( isNotUsgTy arg )
 630                                               substTy (mkTyVarSubst [tv] [arg]) ty
 631 applyTy other                           arg = panic "applyTy"
 632
 633 applyTys :: Type -> [Type] -> Type
 634 applyTys fun_ty arg_tys
 635  = substTy (mkTyVarSubst tvs arg_tys) ty
 636  where
 637    (tvs, ty) = split fun_ty arg_tys
 638
 639    split fun_ty               []         = ([], fun_ty)
 640    split (NoteTy note@(UsgNote   _) fun_ty)
 641                               args       = case split fun_ty args of
 642                                              (tvs, ty) -> (tvs, NoteTy note ty)
 643    split (NoteTy note@(UsgForAll _) fun_ty)
 644                               args       = case split fun_ty args of
 645                                              (tvs, ty) -> (tvs, NoteTy note ty)
 646    split (NoteTy _ fun_ty)    args       = split fun_ty args
 647    split (ForAllTy tv fun_ty) (arg:args) = ASSERT2( isNotUsgTy arg, vcat (map pprType arg_tys) $$
 648                                                                     text "in application of" <+> pprType fun_ty)
 649                                            case split fun_ty args of
 650                                                   (tvs, ty) -> (tv:tvs, ty)
 651    split other_ty             args       = panic "applyTys"
 652 \end{code}
 653
 654 Note that we allow applications to be of usage-annotated- types, as an
 655 extension: we handle them by lifting the annotation outside.  The
 656 argument, however, must still be unannotated.
 657
 658 \begin{code}
 659 hoistForAllTys :: Type -> Type
 660         -- Move all the foralls to the top
 661         -- e.g.  T -> forall a. a  ==>   forall a. T -> a
 662 hoistForAllTys ty
 663   = case hoist ty of { (tvs, body) -> mkForAllTys tvs body }
 664   where
 665     hoist :: Type -> ([TyVar], Type)
 666     hoist ty = case splitFunTys    ty  of { (args, res) ->
 667                case splitForAllTys res of {
 668                   ([], body)  -> ([], ty) ;
 669                   (tvs1, body1) -> case hoist body1 of { (tvs2,body2) ->
 670                                    (tvs1 ++ tvs2, mkFunTys args body2)
 671                }}}
 672 \end{code}
 673
 674
 675 %************************************************************************
 676 %*                                                                      *
 677 \subsection{Stuff to do with the source-language types}
 678
 679 PredType and ThetaType are used in types for expressions and bindings.
 680 ClassPred and ClassContext are used in class and instance declarations.
 681 %*                                                                      *
 682 %************************************************************************
 683
 684 \begin{code}
 685 data PredType  = Class  Class [Type]
 686                | IParam Name  Type
 687                deriving( Eq, Ord )
 688
 689 type ThetaType    = [PredType]
 690 type RhoType      = Type
 691 type TauType      = Type
 692 type SigmaType    = Type
 693 \end{code}
 694
 695 \begin{code}
 696 instance Outputable PredType where
 697     ppr = pprPred
 698 \end{code}
 699
 700 \begin{code}
 701 mkClassPred clas tys = Class clas tys
 702
 703 getClassTys_maybe :: PredType -> Maybe ClassPred
 704 getClassTys_maybe (Class clas tys) = Just (clas, tys)
 705 getClassTys_maybe _                = Nothing
 706
 707 ipName_maybe :: PredType -> Maybe Name
 708 ipName_maybe (IParam n _) = Just n
 709 ipName_maybe _            = Nothing
 710
 711 classesToPreds cts = map (uncurry Class) cts
 712
 713 classesOfPreds theta = concatMap cvt theta
 714     where cvt (Class clas tys) = [(clas, tys)]
 715           cvt (IParam _   _  ) = []
 716 \end{code}
 717
 718 @isTauTy@ tests for nested for-alls.
 719
 720 \begin{code}
 721 isTauTy :: Type -> Bool
 722 isTauTy (TyVarTy v)             = True
 723 isTauTy (TyConApp _ tys)        = all isTauTy tys
 724 isTauTy (AppTy a b)             = isTauTy a && isTauTy b
 725 isTauTy (FunTy a b)             = isTauTy a && isTauTy b
 726 isTauTy (NoteTy (IPNote _) ty)  = False
 727 isTauTy (NoteTy _ ty)           = isTauTy ty
 728 isTauTy other                   = False
 729 \end{code}
 730
 731 \begin{code}
 732 mkRhoTy :: [PredType] -> Type -> Type
 733 mkRhoTy theta ty = foldr (\p r -> FunTy (mkPredTy p) r) ty theta
 734
 735 splitRhoTy :: Type -> ([PredType], Type)
 736 splitRhoTy ty = split ty ty []
 737  where
 738   split orig_ty (FunTy arg res) ts = case splitPredTy_maybe arg of
 739                                         Just p -> split res res (p:ts)
 740                                         Nothing   -> (reverse ts, orig_ty)
 741   split orig_ty (NoteTy (IPNote _) ty)  ts = (reverse ts, orig_ty)
 742   split orig_ty (NoteTy _ ty)           ts = split orig_ty ty ts
 743   split orig_ty ty                      ts = (reverse ts, orig_ty)
 744 \end{code}
 745
 746
 747
 748 \begin{code}
 749 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkRhoTy theta tau)
 750
 751 isSigmaTy :: Type -> Bool
 752 isSigmaTy (FunTy a b)           = isPredTy a
 753     where isPredTy (NoteTy (IPNote _) _) = True
 754           -- JRL could be a dict ty, but that would be polymorphic,
 755           -- and thus there would have been an outer ForAllTy
 756           isPredTy _                     = False
 757 isSigmaTy (NoteTy (IPNote _) _) = False
 758 isSigmaTy (NoteTy _ ty)         = isSigmaTy ty
 759 isSigmaTy (ForAllTy tyvar ty)   = True
 760 isSigmaTy _                     = False
 761
 762 splitSigmaTy :: Type -> ([TyVar], [PredType], Type)
 763 splitSigmaTy ty =
 764   (tyvars, theta, tau)
 765  where
 766   (tyvars,rho) = splitForAllTys ty
 767   (theta,tau)  = splitRhoTy rho
 768 \end{code}
 769
 770
 771 %************************************************************************
 772 %*                                                                      *
 773 \subsection{Kinds and free variables}
 774 %*                                                                      *
 775 %************************************************************************
 776
 777 ---------------------------------------------------------------------
 778                 Finding the kind of a type
 779                 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 780 \begin{code}
 781 typeKind :: Type -> Kind
 782
 783 typeKind (TyVarTy tyvar)        = tyVarKind tyvar
 784 typeKind (TyConApp tycon tys)   = foldr (\_ k -> funResultTy k) (tyConKind tycon) tys
 785 typeKind (NoteTy _ ty)          = typeKind ty
 786 typeKind (AppTy fun arg)        = funResultTy (typeKind fun)
 787
 788 typeKind (FunTy arg res)        = boxedTypeKind -- A function is boxed regardless of its result type
 789                                                 -- No functions at the type level, hence we don't need
 790                                                 -- to say (typeKind res).
 791
 792 typeKind (ForAllTy tv ty)       = typeKind ty
 793 \end{code}
 794
 795
 796 ---------------------------------------------------------------------
 797                 Free variables of a type
 798                 ~~~~~~~~~~~~~~~~~~~~~~~~
 799 \begin{code}
 800 tyVarsOfType :: Type -> TyVarSet
 801
 802 tyVarsOfType (TyVarTy tv)               = unitVarSet tv
 803 tyVarsOfType (TyConApp tycon tys)       = tyVarsOfTypes tys
 804 tyVarsOfType (NoteTy (FTVNote tvs) ty2) = tvs
 805 tyVarsOfType (NoteTy (SynNote ty1) ty2) = tyVarsOfType ty1
 806 tyVarsOfType (NoteTy (UsgNote _) ty)    = tyVarsOfType ty
 807 tyVarsOfType (NoteTy (UsgForAll _) ty)  = tyVarsOfType ty
 808 tyVarsOfType (NoteTy (IPNote _) ty)     = tyVarsOfType ty
 809 tyVarsOfType (FunTy arg res)            = tyVarsOfType arg `unionVarSet` tyVarsOfType res
 810 tyVarsOfType (AppTy fun arg)            = tyVarsOfType fun `unionVarSet` tyVarsOfType arg
 811 tyVarsOfType (ForAllTy tyvar ty)        = tyVarsOfType ty `minusVarSet` unitVarSet tyvar
 812
 813 tyVarsOfTypes :: [Type] -> TyVarSet
 814 tyVarsOfTypes tys = foldr (unionVarSet.tyVarsOfType) emptyVarSet tys
 815
 816 tyVarsOfPred :: PredType -> TyVarSet
 817 tyVarsOfPred (Class clas tys) = tyVarsOfTypes tys
 818 tyVarsOfPred (IParam n ty)    = tyVarsOfType ty
 819
 820 tyVarsOfTheta :: ThetaType -> TyVarSet
 821 tyVarsOfTheta = foldr (unionVarSet . tyVarsOfPred) emptyVarSet
 822
 823 -- Add a Note with the free tyvars to the top of the type
 824 -- (but under a usage if there is one)
 825 addFreeTyVars :: Type -> Type
 826 addFreeTyVars (NoteTy note@(UsgNote   _) ty) = NoteTy note (addFreeTyVars ty)
 827 addFreeTyVars (NoteTy note@(UsgForAll _) ty) = NoteTy note (addFreeTyVars ty)
 828 addFreeTyVars ty@(NoteTy (FTVNote _) _)      = ty
 829 addFreeTyVars ty                             = NoteTy (FTVNote (tyVarsOfType ty)) ty
 830
 831 -- Find the free names of a type, including the type constructors and classes it mentions
 832 namesOfType :: Type -> NameSet
 833 namesOfType (TyVarTy tv)                = unitNameSet (getName tv)
 834 namesOfType (TyConApp tycon tys)        = unitNameSet (getName tycon) `unionNameSets`
 835                                           namesOfTypes tys
 836 namesOfType (NoteTy (SynNote ty1) ty2)  = namesOfType ty1
 837 namesOfType (NoteTy other_note    ty2)  = namesOfType ty2
 838 namesOfType (FunTy arg res)             = namesOfType arg `unionNameSets` namesOfType res
 839 namesOfType (AppTy fun arg)             = namesOfType fun `unionNameSets` namesOfType arg
 840 namesOfType (ForAllTy tyvar ty)         = namesOfType ty `minusNameSet` unitNameSet (getName tyvar)
 841
 842 namesOfTypes tys = foldr (unionNameSets . namesOfType) emptyNameSet tys
 843 \end{code}
 844
 845
 846 %************************************************************************
 847 %*                                                                      *
 848 \subsection{TidyType}
 849 %*                                                                      *
 850 %************************************************************************
 851
 852 tidyTy tidies up a type for printing in an error message, or in
 853 an interface file.
 854
 855 It doesn't change the uniques at all, just the print names.
 856
 857 \begin{code}
 858 tidyTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 859 tidyTyVar env@(tidy_env, subst) tyvar
 860   = case lookupVarEnv subst tyvar of
 861
 862         Just tyvar' ->  -- Already substituted
 863                 (env, tyvar')
 864
 865         Nothing ->      -- Make a new nice name for it
 866
 867                 case tidyOccName tidy_env (getOccName name) of
 868                     (tidy', occ') ->    -- New occname reqd
 869                                 ((tidy', subst'), tyvar')
 870                               where
 871                                 subst' = extendVarEnv subst tyvar tyvar'
 872                                 tyvar' = setTyVarName tyvar name'
 873                                 name'  = mkLocalName (getUnique name) occ' noSrcLoc
 874                                         -- Note: make a *user* tyvar, so it printes nicely
 875                                         -- Could extract src loc, but no need.
 876   where
 877     name = tyVarName tyvar
 878
 879 tidyTyVars env tyvars = mapAccumL tidyTyVar env tyvars
 880
 881 tidyType :: TidyEnv -> Type -> Type
 882 tidyType env@(tidy_env, subst) ty
 883   = go ty
 884   where
 885     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 886                                 Nothing  -> TyVarTy tv
 887                                 Just tv' -> TyVarTy tv'
 888     go (TyConApp tycon tys) = let args = map go tys
 889                               in args `seqList` TyConApp tycon args
 890     go (NoteTy note ty)     = (NoteTy SAPPLY (go_note note)) SAPPLY (go ty)
 891     go (AppTy fun arg)      = (AppTy SAPPLY (go fun)) SAPPLY (go arg)
 892     go (FunTy fun arg)      = (FunTy SAPPLY (go fun)) SAPPLY (go arg)
 893     go (ForAllTy tv ty)     = ForAllTy tvp SAPPLY (tidyType envp ty)
 894                               where
 895                                 (envp, tvp) = tidyTyVar env tv
 896
 897     go_note (SynNote ty)        = SynNote SAPPLY (go ty)
 898     go_note note@(FTVNote ftvs) = note  -- No need to tidy the free tyvars
 899     go_note note@(UsgNote _)    = note  -- Usage annotation is already tidy
 900     go_note note@(UsgForAll _)  = note  -- Uvar binder is already tidy
 901     go_note (IPNote n)          = IPNote (tidyIPName n)
 902
 903 tidyTypes  env tys    = map (tidyType env) tys
 904 \end{code}
 905
 906
 907 @tidyOpenType@ grabs the free type variables, tidies them
 908 and then uses @tidyType@ to work over the type itself
 909
 910 \begin{code}
 911 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 912 tidyOpenType env ty
 913   = (env', tidyType env' ty)
 914   where
 915     env'         = foldl go env (varSetElems (tyVarsOfType ty))
 916     go env tyvar = fst (tidyTyVar env tyvar)
 917
 918 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 919 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 920
 921 tidyTopType :: Type -> Type
 922 tidyTopType ty = tidyType emptyTidyEnv ty
 923 \end{code}
 924
 925 \begin{code}
 926 tidyIPName :: Name -> Name
 927 tidyIPName name
 928   = mkLocalName (getUnique name) (getOccName name) noSrcLoc
 929 \end{code}
 930
 931
 932 %************************************************************************
 933 %*                                                                      *
 934 \subsection{Boxedness and liftedness}
 935 %*                                                                      *
 936 %************************************************************************
 937
 938 \begin{code}
 939 isUnboxedType :: Type -> Bool
 940 isUnboxedType ty = not (isFollowableRep (typePrimRep ty))
 941
 942 isUnLiftedType :: Type -> Bool
 943         -- isUnLiftedType returns True for forall'd unlifted types:
 944         --      x :: forall a. Int#
 945         -- I found bindings like these were getting floated to the top level.
 946         -- They are pretty bogus types, mind you.  It would be better never to
 947         -- construct them
 948
 949 isUnLiftedType (ForAllTy tv ty) = isUnLiftedType ty
 950 isUnLiftedType (NoteTy _ ty)    = isUnLiftedType ty
 951 isUnLiftedType (TyConApp tc _)  = isUnLiftedTyCon tc
 952 isUnLiftedType other            = False
 953
 954 isUnboxedTupleType :: Type -> Bool
 955 isUnboxedTupleType ty = case splitTyConApp_maybe ty of
 956                            Just (tc, ty_args) -> isUnboxedTupleTyCon tc
 957                            other              -> False
 958
 959 -- Should only be applied to *types*; hence the assert
 960 isAlgType :: Type -> Bool
 961 isAlgType ty = case splitTyConApp_maybe ty of
 962                         Just (tc, ty_args) -> ASSERT( length ty_args == tyConArity tc )
 963                                               isAlgTyCon tc
 964                         other              -> False
 965
 966 -- Should only be applied to *types*; hence the assert
 967 isDataType :: Type -> Bool
 968 isDataType ty = case splitTyConApp_maybe ty of
 969                         Just (tc, ty_args) -> ASSERT( length ty_args == tyConArity tc )
 970                                               isDataTyCon tc
 971                         other              -> False
 972
 973 isNewType :: Type -> Bool
 974 isNewType ty = case splitTyConApp_maybe ty of
 975                         Just (tc, ty_args) -> ASSERT( length ty_args == tyConArity tc )
 976                                               isNewTyCon tc
 977                         other              -> False
 978 \end{code}
 979
 980
 981 %************************************************************************
 982 %*                                                                      *
 983 \subsection{Sequencing on types
 984 %*                                                                      *
 985 %************************************************************************
 986
 987 \begin{code}
 988 seqType :: Type -> ()
 989 seqType (TyVarTy tv)      = tv `seq` ()
 990 seqType (AppTy t1 t2)     = seqType t1 `seq` seqType t2
 991 seqType (FunTy t1 t2)     = seqType t1 `seq` seqType t2
 992 seqType (NoteTy note t2)  = seqNote note `seq` seqType t2
 993 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
 994 seqType (ForAllTy tv ty)  = tv `seq` seqType ty
 995
 996 seqTypes :: [Type] -> ()
 997 seqTypes []       = ()
 998 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
 999
1000 seqNote :: TyNote -> ()
1001 seqNote (SynNote ty)  = seqType ty
1002 seqNote (FTVNote set) = sizeUniqSet set `seq` ()
1003 seqNote (UsgNote usg) = usg `seq` ()
1004 seqNote (IPNote nm)   = nm `seq` ()
1005 \end{code}