ghc/interpreter/library/Complex.hs

   1
   2 module Complex(Complex((:+)), realPart, imagPart, conjugate, mkPolar,
   3                cis, polar, magnitude, phase)  where
   4
   5 infix  6  :+
   6
   7 data  (RealFloat a)     => Complex a = !a :+ !a  deriving (Eq,Read,Show)
   8
   9
  10 realPart, imagPart :: (RealFloat a) => Complex a -> a
  11 realPart (x:+y)  =  x
  12 imagPart (x:+y)  =  y
  13
  14 conjugate        :: (RealFloat a) => Complex a -> Complex a
  15 conjugate (x:+y) =  x :+ (-y)
  16
  17 mkPolar          :: (RealFloat a) => a -> a -> Complex a
  18 mkPolar r theta  =  r * cos theta :+ r * sin theta
  19
  20 cis              :: (RealFloat a) => a -> Complex a
  21 cis theta        =  cos theta :+ sin theta
  22
  23 polar            :: (RealFloat a) => Complex a -> (a,a)
  24 polar z          =  (magnitude z, phase z)
  25
  26 magnitude, phase :: (RealFloat a) => Complex a -> a
  27 magnitude (x:+y) =  scaleFloat k
  28                      (sqrt ((scaleFloat mk x)^2 + (scaleFloat mk y)^2))
  29                     where k  = max (exponent x) (exponent y)
  30                           mk = - k
  31
  32 phase (x:+y)     =  atan2 y x
  33
  34
  35 instance  (RealFloat a) => Num (Complex a)  where
  36     (x:+y) + (x':+y')   =  (x+x') :+ (y+y')
  37     (x:+y) - (x':+y')   =  (x-x') :+ (y-y')
  38     (x:+y) * (x':+y')   =  (x*x'-y*y') :+ (x*y'+y*x')
  39     negate (x:+y)       =  negate x :+ negate y
  40     abs z               =  magnitude z :+ 0
  41     signum 0            =  0
  42     signum z@(x:+y)     =  x/r :+ y/r  where r = magnitude z
  43     fromInteger n       =  fromInteger n :+ 0
  44
  45 instance  (RealFloat a) => Fractional (Complex a)  where
  46     (x:+y) / (x':+y')   =  (x*x''+y*y'') / d :+ (y*x''-x*y'') / d
  47                            where x'' = scaleFloat k x'
  48                                  y'' = scaleFloat k y'
  49                                  k   = - max (exponent x') (exponent y')
  50                                  d   = x'*x'' + y'*y''
  51
  52     fromRational a      =  fromRational a :+ 0
  53
  54 instance  (RealFloat a) => Floating (Complex a) where
  55     pi             =  pi :+ 0
  56     exp (x:+y)     =  expx * cos y :+ expx * sin y
  57                       where expx = exp x
  58     log z          =  log (magnitude z) :+ phase z
  59
  60     sqrt 0         =  0
  61     sqrt z@(x:+y)  =  u :+ (if y < 0 then -v else v)
  62                       where (u,v) = if x < 0 then (v',u') else (u',v')
  63                             v'    = abs y / (u'*2)
  64                             u'    = sqrt ((magnitude z + abs x) / 2)
  65
  66     sin (x:+y)     =  sin x * cosh y :+ cos x * sinh y
  67     cos (x:+y)     =  cos x * cosh y :+ (- sin x * sinh y)
  68     tan (x:+y)     =  (sinx*coshy:+cosx*sinhy)/(cosx*coshy:+(-sinx*sinhy))
  69                       where sinx  = sin x
  70                             cosx  = cos x
  71                             sinhy = sinh y
  72                             coshy = cosh y
  73
  74     sinh (x:+y)    =  cos y * sinh x :+ sin  y * cosh x
  75     cosh (x:+y)    =  cos y * cosh x :+ sin y * sinh x
  76     tanh (x:+y)    =  (cosy*sinhx:+siny*coshx)/(cosy*coshx:+siny*sinhx)
  77                       where siny  = sin y
  78                             cosy  = cos y
  79                             sinhx = sinh x
  80                             coshx = cosh x
  81
  82     asin z@(x:+y)  =  y':+(-x')
  83                       where  (x':+y') = log (((-y):+x) + sqrt (1 - z*z))
  84     acos z@(x:+y)  =  y'':+(-x'')
  85                       where (x'':+y'') = log (z + ((-y'):+x'))
  86                             (x':+y')   = sqrt (1 - z*z)
  87     atan z@(x:+y)  =  y':+(-x')
  88                       where (x':+y') = log (((1-y):+x) / sqrt (1+z*z))
  89
  90     asinh z        =  log (z + sqrt (1+z*z))
  91     acosh z        =  log (z + (z+1) * sqrt ((z-1)/(z+1)))
  92     atanh z        =  log ((1+z) / sqrt (1-z*z))