ghc/lib/std/Complex.lhs

   1 % -----------------------------------------------------------------------------
   2 % $Id: Complex.lhs,v 1.7 2001/09/19 14:06:03 simonmar Exp $
   3 %
   4 % (c) The University of Glasgow, 1994-2000
   5 %
   6
   7 \section[Complex]{Module @Complex@}
   8
   9 \begin{code}
  10 module Complex
  11         ( Complex((:+))
  12
  13         , realPart      -- :: (RealFloat a) => Complex a -> a
  14         , imagPart      -- :: (RealFloat a) => Complex a -> a
  15         , conjugate     -- :: (RealFloat a) => Complex a -> Complex a
  16         , mkPolar       -- :: (RealFloat a) => a -> a -> Complex a
  17         , cis           -- :: (RealFloat a) => a -> Complex a
  18         , polar         -- :: (RealFloat a) => Complex a -> (a,a)
  19         , magnitude     -- :: (RealFloat a) => Complex a -> a
  20         , phase         -- :: (RealFloat a) => Complex a -> a
  21
  22         -- Complex instances:
  23         --
  24         --  (RealFloat a) => Eq         (Complex a)
  25         --  (RealFloat a) => Read       (Complex a)
  26         --  (RealFloat a) => Show       (Complex a)
  27         --  (RealFloat a) => Num        (Complex a)
  28         --  (RealFloat a) => Fractional (Complex a)
  29         --  (RealFloat a) => Floating   (Complex a)
  30         --
  31         -- Implementation checked wrt. Haskell 98 lib report, 1/99.
  32
  33         )  where
  34
  35 import Prelude
  36
  37 infix  6  :+
  38 \end{code}
  39
  40 %*********************************************************
  41 %*                                                      *
  42 \subsection{The @Complex@ type}
  43 %*                                                      *
  44 %*********************************************************
  45
  46 \begin{code}
  47 data  (RealFloat a)     => Complex a = !a :+ !a  deriving (Eq, Read, Show)
  48 \end{code}
  49
  50
  51 %*********************************************************
  52 %*                                                      *
  53 \subsection{Functions over @Complex@}
  54 %*                                                      *
  55 %*********************************************************
  56
  57 \begin{code}
  58 realPart, imagPart :: (RealFloat a) => Complex a -> a
  59 realPart (x :+ _) =  x
  60 imagPart (_ :+ y) =  y
  61
  62 {-# SPECIALISE conjugate :: Complex Double -> Complex Double #-}
  63 conjugate        :: (RealFloat a) => Complex a -> Complex a
  64 conjugate (x:+y) =  x :+ (-y)
  65
  66 {-# SPECIALISE mkPolar :: Double -> Double -> Complex Double #-}
  67 mkPolar          :: (RealFloat a) => a -> a -> Complex a
  68 mkPolar r theta  =  r * cos theta :+ r * sin theta
  69
  70 {-# SPECIALISE cis :: Double -> Complex Double #-}
  71 cis              :: (RealFloat a) => a -> Complex a
  72 cis theta        =  cos theta :+ sin theta
  73
  74 {-# SPECIALISE polar :: Complex Double -> (Double,Double) #-}
  75 polar            :: (RealFloat a) => Complex a -> (a,a)
  76 polar z          =  (magnitude z, phase z)
  77
  78 {-# SPECIALISE magnitude :: Complex Double -> Double #-}
  79 magnitude :: (RealFloat a) => Complex a -> a
  80 magnitude (x:+y) =  scaleFloat k
  81                      (sqrt ((scaleFloat mk x)^(2::Int) + (scaleFloat mk y)^(2::Int)))
  82                     where k  = max (exponent x) (exponent y)
  83                           mk = - k
  84
  85 {-# SPECIALISE phase :: Complex Double -> Double #-}
  86 phase :: (RealFloat a) => Complex a -> a
  87 phase (0 :+ 0)   = 0            -- SLPJ July 97 from John Peterson
  88 phase (x:+y)     = atan2 y x
  89 \end{code}
  90
  91
  92 %*********************************************************
  93 %*                                                      *
  94 \subsection{Instances of @Complex@}
  95 %*                                                      *
  96 %*********************************************************
  97
  98 \begin{code}
  99 instance  (RealFloat a) => Num (Complex a)  where
 100     {-# SPECIALISE instance Num (Complex Float) #-}
 101     {-# SPECIALISE instance Num (Complex Double) #-}
 102     (x:+y) + (x':+y')   =  (x+x') :+ (y+y')
 103     (x:+y) - (x':+y')   =  (x-x') :+ (y-y')
 104     (x:+y) * (x':+y')   =  (x*x'-y*y') :+ (x*y'+y*x')
 105     negate (x:+y)       =  negate x :+ negate y
 106     abs z               =  magnitude z :+ 0
 107     signum 0            =  0
 108     signum z@(x:+y)     =  x/r :+ y/r  where r = magnitude z
 109     fromInteger n       =  fromInteger n :+ 0
 110
 111 instance  (RealFloat a) => Fractional (Complex a)  where
 112     {-# SPECIALISE instance Fractional (Complex Float) #-}
 113     {-# SPECIALISE instance Fractional (Complex Double) #-}
 114     (x:+y) / (x':+y')   =  (x*x''+y*y'') / d :+ (y*x''-x*y'') / d
 115                            where x'' = scaleFloat k x'
 116                                  y'' = scaleFloat k y'
 117                                  k   = - max (exponent x') (exponent y')
 118                                  d   = x'*x'' + y'*y''
 119
 120     fromRational a      =  fromRational a :+ 0
 121
 122 instance  (RealFloat a) => Floating (Complex a) where
 123     {-# SPECIALISE instance Floating (Complex Float) #-}
 124     {-# SPECIALISE instance Floating (Complex Double) #-}
 125     pi             =  pi :+ 0
 126     exp (x:+y)     =  expx * cos y :+ expx * sin y
 127                       where expx = exp x
 128     log z          =  log (magnitude z) :+ phase z
 129
 130     sqrt 0         =  0
 131     sqrt z@(x:+y)  =  u :+ (if y < 0 then -v else v)
 132                       where (u,v) = if x < 0 then (v',u') else (u',v')
 133                             v'    = abs y / (u'*2)
 134                             u'    = sqrt ((magnitude z + abs x) / 2)
 135
 136     sin (x:+y)     =  sin x * cosh y :+ cos x * sinh y
 137     cos (x:+y)     =  cos x * cosh y :+ (- sin x * sinh y)
 138     tan (x:+y)     =  (sinx*coshy:+cosx*sinhy)/(cosx*coshy:+(-sinx*sinhy))
 139                       where sinx  = sin x
 140                             cosx  = cos x
 141                             sinhy = sinh y
 142                             coshy = cosh y
 143
 144     sinh (x:+y)    =  cos y * sinh x :+ sin  y * cosh x
 145     cosh (x:+y)    =  cos y * cosh x :+ sin y * sinh x
 146     tanh (x:+y)    =  (cosy*sinhx:+siny*coshx)/(cosy*coshx:+siny*sinhx)
 147                       where siny  = sin y
 148                             cosy  = cos y
 149                             sinhx = sinh x
 150                             coshx = cosh x
 151
 152     asin z@(x:+y)  =  y':+(-x')
 153                       where  (x':+y') = log (((-y):+x) + sqrt (1 - z*z))
 154     acos z         =  y'':+(-x'')
 155                       where (x'':+y'') = log (z + ((-y'):+x'))
 156                             (x':+y')   = sqrt (1 - z*z)
 157     atan z@(x:+y)  =  y':+(-x')
 158                       where (x':+y') = log (((1-y):+x) / sqrt (1+z*z))
 159
 160     asinh z        =  log (z + sqrt (1+z*z))
 161     acosh z        =  log (z + (z+1) * sqrt ((z-1)/(z+1)))
 162     atanh z        =  log ((1+z) / sqrt (1-z*z))
 163 \end{code}