ghc/lib/std/PrelFloat.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1996
   3 %
   4
   5 \section[PrelNum]{Module @PrelNum@}
   6
   7 The types
   8
   9         Float
  10         Double
  11
  12 and the classes
  13
  14         Floating
  15         RealFloat
  16
  17
  18 \begin{code}
  19 {-# OPTIONS -fno-implicit-prelude #-}
  20
  21 #include "../../includes/ieee-flpt.h"
  22
  23 module PrelFloat( module PrelFloat, Float#, Double# )  where
  24
  25 import {-# SOURCE #-} PrelErr
  26 import PrelBase
  27 import PrelList
  28 import PrelEnum
  29 import PrelShow
  30 import PrelNum
  31 import PrelReal
  32 import PrelArr
  33 import PrelMaybe
  34
  35 infixr 8  **
  36 \end{code}
  37
  38 %*********************************************************
  39 %*                                                      *
  40 \subsection{Standard numeric classes}
  41 %*                                                      *
  42 %*********************************************************
  43
  44 \begin{code}
  45 class  (Fractional a) => Floating a  where
  46     pi                  :: a
  47     exp, log, sqrt      :: a -> a
  48     (**), logBase       :: a -> a -> a
  49     sin, cos, tan       :: a -> a
  50     asin, acos, atan    :: a -> a
  51     sinh, cosh, tanh    :: a -> a
  52     asinh, acosh, atanh :: a -> a
  53
  54     x ** y              =  exp (log x * y)
  55     logBase x y         =  log y / log x
  56     sqrt x              =  x ** 0.5
  57     tan  x              =  sin  x / cos  x
  58     tanh x              =  sinh x / cosh x
  59
  60 class  (RealFrac a, Floating a) => RealFloat a  where
  61     floatRadix          :: a -> Integer
  62     floatDigits         :: a -> Int
  63     floatRange          :: a -> (Int,Int)
  64     decodeFloat         :: a -> (Integer,Int)
  65     encodeFloat         :: Integer -> Int -> a
  66     exponent            :: a -> Int
  67     significand         :: a -> a
  68     scaleFloat          :: Int -> a -> a
  69     isNaN, isInfinite, isDenormalized, isNegativeZero, isIEEE
  70                         :: a -> Bool
  71     atan2               :: a -> a -> a
  72
  73
  74     exponent x          =  if m == 0 then 0 else n + floatDigits x
  75                            where (m,n) = decodeFloat x
  76
  77     significand x       =  encodeFloat m (negate (floatDigits x))
  78                            where (m,_) = decodeFloat x
  79
  80     scaleFloat k x      =  encodeFloat m (n+k)
  81                            where (m,n) = decodeFloat x
  82
  83     atan2 y x
  84       | x > 0            =  atan (y/x)
  85       | x == 0 && y > 0  =  pi/2
  86       | x <  0 && y > 0  =  pi + atan (y/x)
  87       |(x <= 0 && y < 0)            ||
  88        (x <  0 && isNegativeZero y) ||
  89        (isNegativeZero x && isNegativeZero y)
  90                          = -atan2 (-y) x
  91       | y == 0 && (x < 0 || isNegativeZero x)
  92                           =  pi    -- must be after the previous test on zero y
  93       | x==0 && y==0      =  y     -- must be after the other double zero tests
  94       | otherwise         =  x + y -- x or y is a NaN, return a NaN (via +)
  95 \end{code}
  96
  97
  98 %*********************************************************
  99 %*                                                      *
 100 \subsection{Type @Integer@, @Float@, @Double@}
 101 %*                                                      *
 102 %*********************************************************
 103
 104 \begin{code}
 105 data Float      = F# Float#
 106 data Double     = D# Double#
 107
 108 instance CCallable   Float
 109 instance CReturnable Float
 110
 111 instance CCallable   Double
 112 instance CReturnable Double
 113 \end{code}
 114
 115
 116 %*********************************************************
 117 %*                                                      *
 118 \subsection{Type @Float@}
 119 %*                                                      *
 120 %*********************************************************
 121
 122 \begin{code}
 123 instance Eq Float where
 124     (F# x) == (F# y) = x `eqFloat#` y
 125
 126 instance Ord Float where
 127     (F# x) `compare` (F# y) | x `ltFloat#` y = LT
 128                             | x `eqFloat#` y = EQ
 129                             | otherwise      = GT
 130
 131     (F# x) <  (F# y) = x `ltFloat#`  y
 132     (F# x) <= (F# y) = x `leFloat#`  y
 133     (F# x) >= (F# y) = x `geFloat#`  y
 134     (F# x) >  (F# y) = x `gtFloat#`  y
 135
 136 instance  Num Float  where
 137     (+)         x y     =  plusFloat x y
 138     (-)         x y     =  minusFloat x y
 139     negate      x       =  negateFloat x
 140     (*)         x y     =  timesFloat x y
 141     abs x | x >= 0.0    =  x
 142           | otherwise   =  negateFloat x
 143     signum x | x == 0.0  = 0
 144              | x > 0.0   = 1
 145              | otherwise = negate 1
 146
 147     {-# INLINE fromInteger #-}
 148     fromInteger n       =  encodeFloat n 0
 149         -- It's important that encodeFloat inlines here, and that
 150         -- fromInteger in turn inlines,
 151         -- so that if fromInteger is applied to an (S# i) the right thing happens
 152
 153     {-# INLINE fromInt #-}
 154     fromInt i           =  int2Float i
 155
 156 instance  Real Float  where
 157     toRational x        =  (m%1)*(b%1)^^n
 158                            where (m,n) = decodeFloat x
 159                                  b     = floatRadix  x
 160
 161 instance  Fractional Float  where
 162     (/) x y             =  divideFloat x y
 163     fromRational x      =  fromRat x
 164     recip x             =  1.0 / x
 165
 166 {-# RULES "truncate/Float->Int" truncate = float2Int #-}
 167 instance  RealFrac Float  where
 168
 169     {-# SPECIALIZE properFraction :: Float -> (Int, Float) #-}
 170     {-# SPECIALIZE round    :: Float -> Int #-}
 171     {-# SPECIALIZE ceiling  :: Float -> Int #-}
 172     {-# SPECIALIZE floor    :: Float -> Int #-}
 173
 174     {-# SPECIALIZE properFraction :: Float -> (Integer, Float) #-}
 175     {-# SPECIALIZE truncate :: Float -> Integer #-}
 176     {-# SPECIALIZE round    :: Float -> Integer #-}
 177     {-# SPECIALIZE ceiling  :: Float -> Integer #-}
 178     {-# SPECIALIZE floor    :: Float -> Integer #-}
 179
 180     properFraction x
 181       = case (decodeFloat x)      of { (m,n) ->
 182         let  b = floatRadix x     in
 183         if n >= 0 then
 184             (fromInteger m * fromInteger b ^ n, 0.0)
 185         else
 186             case (quotRem m (b^(negate n))) of { (w,r) ->
 187             (fromInteger w, encodeFloat r n)
 188             }
 189         }
 190
 191     truncate x  = case properFraction x of
 192                      (n,_) -> n
 193
 194     round x     = case properFraction x of
 195                      (n,r) -> let
 196                                 m         = if r < 0.0 then n - 1 else n + 1
 197                                 half_down = abs r - 0.5
 198                               in
 199                               case (compare half_down 0.0) of
 200                                 LT -> n
 201                                 EQ -> if even n then n else m
 202                                 GT -> m
 203
 204     ceiling x   = case properFraction x of
 205                     (n,r) -> if r > 0.0 then n + 1 else n
 206
 207     floor x     = case properFraction x of
 208                     (n,r) -> if r < 0.0 then n - 1 else n
 209
 210 instance  Floating Float  where
 211     pi                  =  3.141592653589793238
 212     exp x               =  expFloat x
 213     log x               =  logFloat x
 214     sqrt x              =  sqrtFloat x
 215     sin x               =  sinFloat x
 216     cos x               =  cosFloat x
 217     tan x               =  tanFloat x
 218     asin x              =  asinFloat x
 219     acos x              =  acosFloat x
 220     atan x              =  atanFloat x
 221     sinh x              =  sinhFloat x
 222     cosh x              =  coshFloat x
 223     tanh x              =  tanhFloat x
 224     (**) x y            =  powerFloat x y
 225     logBase x y         =  log y / log x
 226
 227     asinh x = log (x + sqrt (1.0+x*x))
 228     acosh x = log (x + (x+1.0) * sqrt ((x-1.0)/(x+1.0)))
 229     atanh x = log ((x+1.0) / sqrt (1.0-x*x))
 230
 231 instance  RealFloat Float  where
 232     floatRadix _        =  FLT_RADIX        -- from float.h
 233     floatDigits _       =  FLT_MANT_DIG     -- ditto
 234     floatRange _        =  (FLT_MIN_EXP, FLT_MAX_EXP) -- ditto
 235
 236     decodeFloat (F# f#)
 237       = case decodeFloat# f#    of
 238           (# exp#, s#, d# #) -> (J# s# d#, I# exp#)
 239
 240     encodeFloat (S# i) j     = int_encodeFloat# i j
 241     encodeFloat (J# s# d#) e = encodeFloat# s# d# e
 242
 243     exponent x          = case decodeFloat x of
 244                             (m,n) -> if m == 0 then 0 else n + floatDigits x
 245
 246     significand x       = case decodeFloat x of
 247                             (m,_) -> encodeFloat m (negate (floatDigits x))
 248
 249     scaleFloat k x      = case decodeFloat x of
 250                             (m,n) -> encodeFloat m (n+k)
 251     isNaN x          = 0 /= isFloatNaN x
 252     isInfinite x     = 0 /= isFloatInfinite x
 253     isDenormalized x = 0 /= isFloatDenormalized x
 254     isNegativeZero x = 0 /= isFloatNegativeZero x
 255     isIEEE _         = True
 256
 257 instance  Show Float  where
 258     showsPrec   x = showSigned showFloat x
 259     showList = showList__ (showsPrec 0)
 260 \end{code}
 261
 262 %*********************************************************
 263 %*                                                      *
 264 \subsection{Type @Double@}
 265 %*                                                      *
 266 %*********************************************************
 267
 268 \begin{code}
 269 instance Eq Double where
 270     (D# x) == (D# y) = x ==## y
 271
 272 instance Ord Double where
 273     (D# x) `compare` (D# y) | x <## y   = LT
 274                             | x ==## y  = EQ
 275                             | otherwise = GT
 276
 277     (D# x) <  (D# y) = x <##  y
 278     (D# x) <= (D# y) = x <=## y
 279     (D# x) >= (D# y) = x >=## y
 280     (D# x) >  (D# y) = x >##  y
 281
 282 instance  Num Double  where
 283     (+)         x y     =  plusDouble x y
 284     (-)         x y     =  minusDouble x y
 285     negate      x       =  negateDouble x
 286     (*)         x y     =  timesDouble x y
 287     abs x | x >= 0.0    =  x
 288           | otherwise   =  negateDouble x
 289     signum x | x == 0.0  = 0
 290              | x > 0.0   = 1
 291              | otherwise = negate 1
 292
 293     {-# INLINE fromInteger #-}
 294         -- See comments with Num Float
 295     fromInteger n       =  encodeFloat n 0
 296     fromInt (I# n#)     =  case (int2Double# n#) of { d# -> D# d# }
 297
 298 instance  Real Double  where
 299     toRational x        =  (m%1)*(b%1)^^n
 300                            where (m,n) = decodeFloat x
 301                                  b     = floatRadix  x
 302
 303 instance  Fractional Double  where
 304     (/) x y             =  divideDouble x y
 305     fromRational x      =  fromRat x
 306     recip x             =  1.0 / x
 307
 308 instance  Floating Double  where
 309     pi                  =  3.141592653589793238
 310     exp x               =  expDouble x
 311     log x               =  logDouble x
 312     sqrt x              =  sqrtDouble x
 313     sin  x              =  sinDouble x
 314     cos  x              =  cosDouble x
 315     tan  x              =  tanDouble x
 316     asin x              =  asinDouble x
 317     acos x              =  acosDouble x
 318     atan x              =  atanDouble x
 319     sinh x              =  sinhDouble x
 320     cosh x              =  coshDouble x
 321     tanh x              =  tanhDouble x
 322     (**) x y            =  powerDouble x y
 323     logBase x y         =  log y / log x
 324
 325     asinh x = log (x + sqrt (1.0+x*x))
 326     acosh x = log (x + (x+1.0) * sqrt ((x-1.0)/(x+1.0)))
 327     atanh x = log ((x+1.0) / sqrt (1.0-x*x))
 328
 329 {-# RULES "truncate/Double->Int" truncate = double2Int #-}
 330 instance  RealFrac Double  where
 331
 332     {-# SPECIALIZE properFraction :: Double -> (Int, Double) #-}
 333     {-# SPECIALIZE round    :: Double -> Int #-}
 334     {-# SPECIALIZE ceiling  :: Double -> Int #-}
 335     {-# SPECIALIZE floor    :: Double -> Int #-}
 336
 337     {-# SPECIALIZE properFraction :: Double -> (Integer, Double) #-}
 338     {-# SPECIALIZE truncate :: Double -> Integer #-}
 339     {-# SPECIALIZE round    :: Double -> Integer #-}
 340     {-# SPECIALIZE ceiling  :: Double -> Integer #-}
 341     {-# SPECIALIZE floor    :: Double -> Integer #-}
 342
 343     properFraction x
 344       = case (decodeFloat x)      of { (m,n) ->
 345         let  b = floatRadix x     in
 346         if n >= 0 then
 347             (fromInteger m * fromInteger b ^ n, 0.0)
 348         else
 349             case (quotRem m (b^(negate n))) of { (w,r) ->
 350             (fromInteger w, encodeFloat r n)
 351             }
 352         }
 353
 354     truncate x  = case properFraction x of
 355                      (n,_) -> n
 356
 357     round x     = case properFraction x of
 358                      (n,r) -> let
 359                                 m         = if r < 0.0 then n - 1 else n + 1
 360                                 half_down = abs r - 0.5
 361                               in
 362                               case (compare half_down 0.0) of
 363                                 LT -> n
 364                                 EQ -> if even n then n else m
 365                                 GT -> m
 366
 367     ceiling x   = case properFraction x of
 368                     (n,r) -> if r > 0.0 then n + 1 else n
 369
 370     floor x     = case properFraction x of
 371                     (n,r) -> if r < 0.0 then n - 1 else n
 372
 373 instance  RealFloat Double  where
 374     floatRadix _        =  FLT_RADIX        -- from float.h
 375     floatDigits _       =  DBL_MANT_DIG     -- ditto
 376     floatRange _        =  (DBL_MIN_EXP, DBL_MAX_EXP) -- ditto
 377
 378     decodeFloat (D# x#)
 379       = case decodeDouble# x#   of
 380           (# exp#, s#, d# #) -> (J# s# d#, I# exp#)
 381
 382     encodeFloat (S# i) j     = int_encodeDouble# i j
 383     encodeFloat (J# s# d#) e = encodeDouble# s# d# e
 384
 385     exponent x          = case decodeFloat x of
 386                             (m,n) -> if m == 0 then 0 else n + floatDigits x
 387
 388     significand x       = case decodeFloat x of
 389                             (m,_) -> encodeFloat m (negate (floatDigits x))
 390
 391     scaleFloat k x      = case decodeFloat x of
 392                             (m,n) -> encodeFloat m (n+k)
 393
 394     isNaN x             = 0 /= isDoubleNaN x
 395     isInfinite x        = 0 /= isDoubleInfinite x
 396     isDenormalized x    = 0 /= isDoubleDenormalized x
 397     isNegativeZero x    = 0 /= isDoubleNegativeZero x
 398     isIEEE _            = True
 399
 400 instance  Show Double  where
 401     showsPrec   x = showSigned showFloat x
 402     showList = showList__ (showsPrec 0)
 403 \end{code}
 404
 405 %*********************************************************
 406 %*                                                      *
 407 \subsection{@Enum@ instances}
 408 %*                                                      *
 409 %*********************************************************
 410
 411 The @Enum@ instances for Floats and Doubles are slightly unusual.
 412 The @toEnum@ function truncates numbers to Int.  The definitions
 413 of @enumFrom@ and @enumFromThen@ allow floats to be used in arithmetic
 414 series: [0,0.1 .. 1.0].  However, roundoff errors make these somewhat
 415 dubious.  This example may have either 10 or 11 elements, depending on
 416 how 0.1 is represented.
 417
 418 NOTE: The instances for Float and Double do not make use of the default
 419 methods for @enumFromTo@ and @enumFromThenTo@, as these rely on there being
 420 a `non-lossy' conversion to and from Ints. Instead we make use of the
 421 1.2 default methods (back in the days when Enum had Ord as a superclass)
 422 for these (@numericEnumFromTo@ and @numericEnumFromThenTo@ below.)
 423
 424 \begin{code}
 425 instance  Enum Float  where
 426     succ x         = x + 1
 427     pred x         = x - 1
 428     toEnum         =  fromInt
 429     fromEnum       =  fromInteger . truncate   -- may overflow
 430     enumFrom       =  numericEnumFrom
 431     enumFromTo     =  numericEnumFromTo
 432     enumFromThen   =  numericEnumFromThen
 433     enumFromThenTo =  numericEnumFromThenTo
 434
 435 instance  Enum Double  where
 436     succ x         = x + 1
 437     pred x         = x - 1
 438     toEnum         =  fromInt
 439     fromEnum       =  fromInteger . truncate   -- may overflow
 440     enumFrom       =  numericEnumFrom
 441     enumFromTo     =  numericEnumFromTo
 442     enumFromThen   =  numericEnumFromThen
 443     enumFromThenTo =  numericEnumFromThenTo
 444 \end{code}
 445
 446
 447 %*********************************************************
 448 %*                                                      *
 449 \subsection{Printing floating point}
 450 %*                                                      *
 451 %*********************************************************
 452
 453
 454 \begin{code}
 455 showFloat :: (RealFloat a) => a -> ShowS
 456 showFloat x  =  showString (formatRealFloat FFGeneric Nothing x)
 457
 458 -- These are the format types.  This type is not exported.
 459
 460 data FFFormat = FFExponent | FFFixed | FFGeneric
 461
 462 formatRealFloat :: (RealFloat a) => FFFormat -> Maybe Int -> a -> String
 463 formatRealFloat fmt decs x
 464    | isNaN x                   = "NaN"
 465    | isInfinite x              = if x < 0 then "-Infinity" else "Infinity"
 466    | x < 0 || isNegativeZero x = '-':doFmt fmt (floatToDigits (toInteger base) (-x))
 467    | otherwise                 = doFmt fmt (floatToDigits (toInteger base) x)
 468  where
 469   base = 10
 470
 471   doFmt format (is, e) =
 472     let ds = map intToDigit is in
 473     case format of
 474      FFGeneric ->
 475       doFmt (if e < 0 || e > 7 then FFExponent else FFFixed)
 476             (is,e)
 477      FFExponent ->
 478       case decs of
 479        Nothing ->
 480         let show_e' = show (e-1) in
 481         case ds of
 482           "0"     -> "0.0e0"
 483           [d]     -> d : ".0e" ++ show_e'
 484           (d:ds') -> d : '.' : ds' ++ "e" ++ show_e'
 485        Just dec ->
 486         let dec' = max dec 1 in
 487         case is of
 488          [0] -> '0' :'.' : take dec' (repeat '0') ++ "e0"
 489          _ ->
 490           let
 491            (ei,is') = roundTo base (dec'+1) is
 492            (d:ds') = map intToDigit (if ei > 0 then init is' else is')
 493           in
 494           d:'.':ds' ++ 'e':show (e-1+ei)
 495      FFFixed ->
 496       let
 497        mk0 ls = case ls of { "" -> "0" ; _ -> ls}
 498       in
 499       case decs of
 500        Nothing ->
 501          let
 502           f 0 s    rs  = mk0 (reverse s) ++ '.':mk0 rs
 503           f n s    ""  = f (n-1) ('0':s) ""
 504           f n s (r:rs) = f (n-1) (r:s) rs
 505          in
 506          f e "" ds
 507        Just dec ->
 508         let dec' = max dec 0 in
 509         if e >= 0 then
 510          let
 511           (ei,is') = roundTo base (dec' + e) is
 512           (ls,rs)  = splitAt (e+ei) (map intToDigit is')
 513          in
 514          mk0 ls ++ (if null rs then "" else '.':rs)
 515         else
 516          let
 517           (ei,is') = roundTo base dec' (replicate (-e) 0 ++ is)
 518           d:ds' = map intToDigit (if ei > 0 then is' else 0:is')
 519          in
 520          d : '.' : ds'
 521
 522
 523 roundTo :: Int -> Int -> [Int] -> (Int,[Int])
 524 roundTo base d is =
 525   case f d is of
 526     x@(0,_) -> x
 527     (1,xs)  -> (1, 1:xs)
 528  where
 529   b2 = base `div` 2
 530
 531   f n []     = (0, replicate n 0)
 532   f 0 (x:_)  = (if x >= b2 then 1 else 0, [])
 533   f n (i:xs)
 534      | i' == base = (1,0:ds)
 535      | otherwise  = (0,i':ds)
 536       where
 537        (c,ds) = f (n-1) xs
 538        i'     = c + i
 539
 540 --
 541 -- Based on "Printing Floating-Point Numbers Quickly and Accurately"
 542 -- by R.G. Burger and R.K. Dybvig in PLDI 96.
 543 -- This version uses a much slower logarithm estimator. It should be improved.
 544
 545 -- This function returns a list of digits (Ints in [0..base-1]) and an
 546 -- exponent.
 547
 548 floatToDigits :: (RealFloat a) => Integer -> a -> ([Int], Int)
 549 floatToDigits _ 0 = ([0], 0)
 550 floatToDigits base x =
 551  let
 552   (f0, e0) = decodeFloat x
 553   (minExp0, _) = floatRange x
 554   p = floatDigits x
 555   b = floatRadix x
 556   minExp = minExp0 - p -- the real minimum exponent
 557   -- Haskell requires that f be adjusted so denormalized numbers
 558   -- will have an impossibly low exponent.  Adjust for this.
 559   (f, e) =
 560    let n = minExp - e0 in
 561    if n > 0 then (f0 `div` (b^n), e0+n) else (f0, e0)
 562   (r, s, mUp, mDn) =
 563    if e >= 0 then
 564     let be = b^ e in
 565     if f == b^(p-1) then
 566       (f*be*b*2, 2*b, be*b, b)
 567     else
 568       (f*be*2, 2, be, be)
 569    else
 570     if e > minExp && f == b^(p-1) then
 571       (f*b*2, b^(-e+1)*2, b, 1)
 572     else
 573       (f*2, b^(-e)*2, 1, 1)
 574   k =
 575    let
 576     k0 =
 577      if b == 2 && base == 10 then
 578         -- logBase 10 2 is slightly bigger than 3/10 so
 579         -- the following will err on the low side.  Ignoring
 580         -- the fraction will make it err even more.
 581         -- Haskell promises that p-1 <= logBase b f < p.
 582         (p - 1 + e0) * 3 `div` 10
 583      else
 584         ceiling ((log (fromInteger (f+1)) +
 585                  fromInt e * log (fromInteger b)) /
 586                    log (fromInteger base))
 587 --WAS:            fromInt e * log (fromInteger b))
 588
 589     fixup n =
 590       if n >= 0 then
 591         if r + mUp <= expt base n * s then n else fixup (n+1)
 592       else
 593         if expt base (-n) * (r + mUp) <= s then n else fixup (n+1)
 594    in
 595    fixup k0
 596
 597   gen ds rn sN mUpN mDnN =
 598    let
 599     (dn, rn') = (rn * base) `divMod` sN
 600     mUpN' = mUpN * base
 601     mDnN' = mDnN * base
 602    in
 603    case (rn' < mDnN', rn' + mUpN' > sN) of
 604     (True,  False) -> dn : ds
 605     (False, True)  -> dn+1 : ds
 606     (True,  True)  -> if rn' * 2 < sN then dn : ds else dn+1 : ds
 607     (False, False) -> gen (dn:ds) rn' sN mUpN' mDnN'
 608
 609   rds =
 610    if k >= 0 then
 611       gen [] r (s * expt base k) mUp mDn
 612    else
 613      let bk = expt base (-k) in
 614      gen [] (r * bk) s (mUp * bk) (mDn * bk)
 615  in
 616  (map toInt (reverse rds), k)
 617
 618 \end{code}
 619
 620
 621 %*********************************************************
 622 %*                                                      *
 623 \subsection{Converting from a Rational to a RealFloat
 624 %*                                                      *
 625 %*********************************************************
 626
 627 [In response to a request for documentation of how fromRational works,
 628 Joe Fasel writes:] A quite reasonable request!  This code was added to
 629 the Prelude just before the 1.2 release, when Lennart, working with an
 630 early version of hbi, noticed that (read . show) was not the identity
 631 for floating-point numbers.  (There was a one-bit error about half the
 632 time.)  The original version of the conversion function was in fact
 633 simply a floating-point divide, as you suggest above. The new version
 634 is, I grant you, somewhat denser.
 635
 636 Unfortunately, Joe's code doesn't work!  Here's an example:
 637
 638 main = putStr (shows (1.82173691287639817263897126389712638972163e-300::Double) "\n")
 639
 640 This program prints
 641         0.0000000000000000
 642 instead of
 643         1.8217369128763981e-300
 644
 645 Here's Joe's code:
 646
 647 \begin{pseudocode}
 648 fromRat :: (RealFloat a) => Rational -> a
 649 fromRat x = x'
 650         where x' = f e
 651
 652 --              If the exponent of the nearest floating-point number to x
 653 --              is e, then the significand is the integer nearest xb^(-e),
 654 --              where b is the floating-point radix.  We start with a good
 655 --              guess for e, and if it is correct, the exponent of the
 656 --              floating-point number we construct will again be e.  If
 657 --              not, one more iteration is needed.
 658
 659               f e   = if e' == e then y else f e'
 660                       where y      = encodeFloat (round (x * (1 % b)^^e)) e
 661                             (_,e') = decodeFloat y
 662               b     = floatRadix x'
 663
 664 --              We obtain a trial exponent by doing a floating-point
 665 --              division of x's numerator by its denominator.  The
 666 --              result of this division may not itself be the ultimate
 667 --              result, because of an accumulation of three rounding
 668 --              errors.
 669
 670               (s,e) = decodeFloat (fromInteger (numerator x) `asTypeOf` x'
 671                                         / fromInteger (denominator x))
 672 \end{pseudocode}
 673
 674 Now, here's Lennart's code (which works)
 675
 676 \begin{code}
 677 {-# SPECIALISE fromRat ::
 678         Rational -> Double,
 679         Rational -> Float #-}
 680 fromRat :: (RealFloat a) => Rational -> a
 681 fromRat x
 682   | x == 0    =  encodeFloat 0 0                -- Handle exceptional cases
 683   | x <  0    =  - fromRat' (-x)                -- first.
 684   | otherwise =  fromRat' x
 685
 686 -- Conversion process:
 687 -- Scale the rational number by the RealFloat base until
 688 -- it lies in the range of the mantissa (as used by decodeFloat/encodeFloat).
 689 -- Then round the rational to an Integer and encode it with the exponent
 690 -- that we got from the scaling.
 691 -- To speed up the scaling process we compute the log2 of the number to get
 692 -- a first guess of the exponent.
 693
 694 fromRat' :: (RealFloat a) => Rational -> a
 695 fromRat' x = r
 696   where b = floatRadix r
 697         p = floatDigits r
 698         (minExp0, _) = floatRange r
 699         minExp = minExp0 - p            -- the real minimum exponent
 700         xMin   = toRational (expt b (p-1))
 701         xMax   = toRational (expt b p)
 702         p0 = (integerLogBase b (numerator x) - integerLogBase b (denominator x) - p) `max` minExp
 703         f = if p0 < 0 then 1 % expt b (-p0) else expt b p0 % 1
 704         (x', p') = scaleRat (toRational b) minExp xMin xMax p0 (x / f)
 705         r = encodeFloat (round x') p'
 706
 707 -- Scale x until xMin <= x < xMax, or p (the exponent) <= minExp.
 708 scaleRat :: Rational -> Int -> Rational -> Rational -> Int -> Rational -> (Rational, Int)
 709 scaleRat b minExp xMin xMax p x
 710  | p <= minExp = (x, p)
 711  | x >= xMax   = scaleRat b minExp xMin xMax (p+1) (x/b)
 712  | x < xMin    = scaleRat b minExp xMin xMax (p-1) (x*b)
 713  | otherwise   = (x, p)
 714
 715 -- Exponentiation with a cache for the most common numbers.
 716 minExpt, maxExpt :: Int
 717 minExpt = 0
 718 maxExpt = 1100
 719
 720 expt :: Integer -> Int -> Integer
 721 expt base n =
 722     if base == 2 && n >= minExpt && n <= maxExpt then
 723         expts!n
 724     else
 725         base^n
 726
 727 expts :: Array Int Integer
 728 expts = array (minExpt,maxExpt) [(n,2^n) | n <- [minExpt .. maxExpt]]
 729
 730 -- Compute the (floor of the) log of i in base b.
 731 -- Simplest way would be just divide i by b until it's smaller then b, but that would
 732 -- be very slow!  We are just slightly more clever.
 733 integerLogBase :: Integer -> Integer -> Int
 734 integerLogBase b i
 735    | i < b     = 0
 736    | otherwise = doDiv (i `div` (b^l)) l
 737        where
 738         -- Try squaring the base first to cut down the number of divisions.
 739          l = 2 * integerLogBase (b*b) i
 740
 741          doDiv :: Integer -> Int -> Int
 742          doDiv x y
 743             | x < b     = y
 744             | otherwise = doDiv (x `div` b) (y+1)
 745
 746 \end{code}
 747
 748
 749 %*********************************************************
 750 %*                                                      *
 751 \subsection{Floating point numeric primops}
 752 %*                                                      *
 753 %*********************************************************
 754
 755 Definitions of the boxed PrimOps; these will be
 756 used in the case of partial applications, etc.
 757
 758 \begin{code}
 759 plusFloat, minusFloat, timesFloat, divideFloat :: Float -> Float -> Float
 760 plusFloat   (F# x) (F# y) = F# (plusFloat# x y)
 761 minusFloat  (F# x) (F# y) = F# (minusFloat# x y)
 762 timesFloat  (F# x) (F# y) = F# (timesFloat# x y)
 763 divideFloat (F# x) (F# y) = F# (divideFloat# x y)
 764
 765 negateFloat :: Float -> Float
 766 negateFloat (F# x)        = F# (negateFloat# x)
 767
 768 gtFloat, geFloat, eqFloat, neFloat, ltFloat, leFloat :: Float -> Float -> Bool
 769 gtFloat     (F# x) (F# y) = gtFloat# x y
 770 geFloat     (F# x) (F# y) = geFloat# x y
 771 eqFloat     (F# x) (F# y) = eqFloat# x y
 772 neFloat     (F# x) (F# y) = neFloat# x y
 773 ltFloat     (F# x) (F# y) = ltFloat# x y
 774 leFloat     (F# x) (F# y) = leFloat# x y
 775
 776 float2Int :: Float -> Int
 777 float2Int   (F# x) = I# (float2Int# x)
 778
 779 int2Float :: Int -> Float
 780 int2Float   (I# x) = F# (int2Float# x)
 781
 782 expFloat, logFloat, sqrtFloat :: Float -> Float
 783 sinFloat, cosFloat, tanFloat  :: Float -> Float
 784 asinFloat, acosFloat, atanFloat  :: Float -> Float
 785 sinhFloat, coshFloat, tanhFloat  :: Float -> Float
 786 expFloat    (F# x) = F# (expFloat# x)
 787 logFloat    (F# x) = F# (logFloat# x)
 788 sqrtFloat   (F# x) = F# (sqrtFloat# x)
 789 sinFloat    (F# x) = F# (sinFloat# x)
 790 cosFloat    (F# x) = F# (cosFloat# x)
 791 tanFloat    (F# x) = F# (tanFloat# x)
 792 asinFloat   (F# x) = F# (asinFloat# x)
 793 acosFloat   (F# x) = F# (acosFloat# x)
 794 atanFloat   (F# x) = F# (atanFloat# x)
 795 sinhFloat   (F# x) = F# (sinhFloat# x)
 796 coshFloat   (F# x) = F# (coshFloat# x)
 797 tanhFloat   (F# x) = F# (tanhFloat# x)
 798
 799 powerFloat :: Float -> Float -> Float
 800 powerFloat  (F# x) (F# y) = F# (powerFloat# x y)
 801
 802 -- definitions of the boxed PrimOps; these will be
 803 -- used in the case of partial applications, etc.
 804
 805 plusDouble, minusDouble, timesDouble, divideDouble :: Double -> Double -> Double
 806 plusDouble   (D# x) (D# y) = D# (x +## y)
 807 minusDouble  (D# x) (D# y) = D# (x -## y)
 808 timesDouble  (D# x) (D# y) = D# (x *## y)
 809 divideDouble (D# x) (D# y) = D# (x /## y)
 810
 811 negateDouble :: Double -> Double
 812 negateDouble (D# x)        = D# (negateDouble# x)
 813
 814 gtDouble, geDouble, eqDouble, neDouble, leDouble, ltDouble :: Double -> Double -> Bool
 815 gtDouble    (D# x) (D# y) = x >## y
 816 geDouble    (D# x) (D# y) = x >=## y
 817 eqDouble    (D# x) (D# y) = x ==## y
 818 neDouble    (D# x) (D# y) = x /=## y
 819 ltDouble    (D# x) (D# y) = x <## y
 820 leDouble    (D# x) (D# y) = x <=## y
 821
 822 double2Int :: Double -> Int
 823 double2Int   (D# x) = I# (double2Int#   x)
 824
 825 int2Double :: Int -> Double
 826 int2Double   (I# x) = D# (int2Double#   x)
 827
 828 double2Float :: Double -> Float
 829 double2Float (D# x) = F# (double2Float# x)
 830
 831 float2Double :: Float -> Double
 832 float2Double (F# x) = D# (float2Double# x)
 833
 834 expDouble, logDouble, sqrtDouble :: Double -> Double
 835 sinDouble, cosDouble, tanDouble  :: Double -> Double
 836 asinDouble, acosDouble, atanDouble  :: Double -> Double
 837 sinhDouble, coshDouble, tanhDouble  :: Double -> Double
 838 expDouble    (D# x) = D# (expDouble# x)
 839 logDouble    (D# x) = D# (logDouble# x)
 840 sqrtDouble   (D# x) = D# (sqrtDouble# x)
 841 sinDouble    (D# x) = D# (sinDouble# x)
 842 cosDouble    (D# x) = D# (cosDouble# x)
 843 tanDouble    (D# x) = D# (tanDouble# x)
 844 asinDouble   (D# x) = D# (asinDouble# x)
 845 acosDouble   (D# x) = D# (acosDouble# x)
 846 atanDouble   (D# x) = D# (atanDouble# x)
 847 sinhDouble   (D# x) = D# (sinhDouble# x)
 848 coshDouble   (D# x) = D# (coshDouble# x)
 849 tanhDouble   (D# x) = D# (tanhDouble# x)
 850
 851 powerDouble :: Double -> Double -> Double
 852 powerDouble  (D# x) (D# y) = D# (x **## y)
 853 \end{code}
 854
 855 \begin{code}
 856 foreign import ccall "__encodeFloat" unsafe
 857         encodeFloat# :: Int# -> ByteArray# -> Int -> Float
 858 foreign import ccall "__int_encodeFloat" unsafe
 859         int_encodeFloat# :: Int# -> Int -> Float
 860
 861
 862 foreign import ccall "isFloatNaN" unsafe isFloatNaN :: Float -> Int
 863 foreign import ccall "isFloatInfinite" unsafe isFloatInfinite :: Float -> Int
 864 foreign import ccall "isFloatDenormalized" unsafe isFloatDenormalized :: Float -> Int
 865 foreign import ccall "isFloatNegativeZero" unsafe isFloatNegativeZero :: Float -> Int
 866
 867
 868 foreign import ccall "__encodeDouble" unsafe
 869         encodeDouble# :: Int# -> ByteArray# -> Int -> Double
 870 foreign import ccall "__int_encodeDouble" unsafe
 871         int_encodeDouble# :: Int# -> Int -> Double
 872
 873 foreign import ccall "isDoubleNaN" unsafe isDoubleNaN :: Double -> Int
 874 foreign import ccall "isDoubleInfinite" unsafe isDoubleInfinite :: Double -> Int
 875 foreign import ccall "isDoubleDenormalized" unsafe isDoubleDenormalized :: Double -> Int
 876 foreign import ccall "isDoubleNegativeZero" unsafe isDoubleNegativeZero :: Double -> Int
 877 \end{code}