ghc/lib/std/PrelNum.lhs

   1 % ------------------------------------------------------------------------------
   2 % $Id: PrelNum.lhs,v 1.40 2001/07/24 06:31:35 ken Exp $
   3 %
   4 % (c) The University of Glasgow, 1994-2000
   5 %
   6
   7 \section[PrelNum]{Module @PrelNum@}
   8
   9 The class
  10
  11         Num
  12
  13 and the type
  14
  15         Integer
  16
  17
  18 \begin{code}
  19 {-# OPTIONS -fno-implicit-prelude #-}
  20
  21 #include "MachDeps.h"
  22 #if WORD_SIZE_IN_BYTES == 4
  23 #define LEFTMOST_BIT 2147483648
  24 #elif WORD_SIZE_IN_BYTES == 8
  25 #define LEFTMOST_BIT 9223372036854775808
  26 #else
  27 #error Please define LEFTMOST_BIT to be 2^(WORD_SIZE_IN_BYTES*8-1)
  28 #endif
  29
  30 module PrelNum where
  31
  32 import {-# SOURCE #-} PrelErr
  33 import PrelBase
  34 import PrelList
  35 import PrelEnum
  36 import PrelShow
  37
  38 infixl 7  *
  39 infixl 6  +, -
  40
  41 default ()              -- Double isn't available yet,
  42                         -- and we shouldn't be using defaults anyway
  43 \end{code}
  44
  45 %*********************************************************
  46 %*                                                      *
  47 \subsection{Standard numeric class}
  48 %*                                                      *
  49 %*********************************************************
  50
  51 \begin{code}
  52 class  (Eq a, Show a) => Num a  where
  53     (+), (-), (*)       :: a -> a -> a
  54     negate              :: a -> a
  55     abs, signum         :: a -> a
  56     fromInteger         :: Integer -> a
  57
  58     x - y               = x + negate y
  59     negate x            = 0 - x
  60
  61 {-# INLINE subtract #-}
  62 subtract :: (Num a) => a -> a -> a
  63 subtract x y = y - x
  64 \end{code}
  65
  66
  67 %*********************************************************
  68 %*                                                      *
  69 \subsection{Instances for @Int@}
  70 %*                                                      *
  71 %*********************************************************
  72
  73 \begin{code}
  74 instance  Num Int  where
  75     (+)    = plusInt
  76     (-)    = minusInt
  77     negate = negateInt
  78     (*)    = timesInt
  79     abs n  = if n `geInt` 0 then n else negateInt n
  80
  81     signum n | n `ltInt` 0 = negateInt 1
  82              | n `eqInt` 0 = 0
  83              | otherwise   = 1
  84
  85     fromInteger = integer2Int
  86 \end{code}
  87
  88
  89 \begin{code}
  90 -- These can't go in PrelBase with the defn of Int, because
  91 -- we don't have pairs defined at that time!
  92
  93 quotRemInt :: Int -> Int -> (Int, Int)
  94 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
  95     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
  96
  97 divModInt ::  Int -> Int -> (Int, Int)
  98 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
  99     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
 100 \end{code}
 101
 102
 103 %*********************************************************
 104 %*                                                      *
 105 \subsection{The @Integer@ type}
 106 %*                                                      *
 107 %*********************************************************
 108
 109 \begin{code}
 110 data Integer
 111    = S# Int#                            -- small integers
 112    | J# Int# ByteArray#                 -- large integers
 113 \end{code}
 114
 115 Convenient boxed Integer PrimOps.
 116
 117 \begin{code}
 118 zeroInteger :: Integer
 119 zeroInteger = S# 0#
 120
 121 int2Integer :: Int -> Integer
 122 {-# INLINE int2Integer #-}
 123 int2Integer (I# i) = S# i
 124
 125 integer2Int :: Integer -> Int
 126 integer2Int (S# i)   = I# i
 127 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 128
 129 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 130 toBig i@(J# _ _) = i
 131 \end{code}
 132
 133
 134 %*********************************************************
 135 %*                                                      *
 136 \subsection{Dividing @Integers@}
 137 %*                                                      *
 138 %*********************************************************
 139
 140 \begin{code}
 141 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 142 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
 143 quotRemInteger (S# i) (S# j)
 144   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 145 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 146 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 147 quotRemInteger (J# s1 d1) (J# s2 d2)
 148   = case (quotRemInteger# s1 d1 s2 d2) of
 149           (# s3, d3, s4, d4 #)
 150             -> (J# s3 d3, J# s4 d4)
 151
 152 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
 153 divModInteger (S# i) (S# j)
 154   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 155 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 156 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 157 divModInteger (J# s1 d1) (J# s2 d2)
 158   = case (divModInteger# s1 d1 s2 d2) of
 159           (# s3, d3, s4, d4 #)
 160             -> (J# s3 d3, J# s4 d4)
 161
 162 remInteger :: Integer -> Integer -> Integer
 163 remInteger ia 0
 164   = error "Prelude.Integral.rem{Integer}: divide by 0"
 165 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
 166 remInteger (S# a) (S# b) = S# (remInt# a b)
 167 {- Special case doesn't work, because a 1-element J# has the range
 168    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
 169 remInteger ia@(S# a) (J# sb b)
 170   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 171   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 172   | 0# <# sb   = ia
 173   | otherwise  = S# (0# -# a)
 174 -}
 175 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
 176 remInteger (J# sa a) (S# b)
 177   = case int2Integer# b of { (# sb, b #) ->
 178     case remInteger# sa a sb b of { (# sr, r #) ->
 179     S# (integer2Int# sr r) }}
 180 remInteger (J# sa a) (J# sb b)
 181   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 182
 183 quotInteger :: Integer -> Integer -> Integer
 184 quotInteger ia 0
 185   = error "Prelude.Integral.quot{Integer}: divide by 0"
 186 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
 187 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 188 {- Special case disabled, see remInteger above
 189 quotInteger (S# a) (J# sb b)
 190   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 191   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 192   | otherwise  = zeroInteger
 193 -}
 194 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
 195 quotInteger (J# sa a) (S# b)
 196   = case int2Integer# b of { (# sb, b #) ->
 197     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 198 quotInteger (J# sa a) (J# sb b)
 199   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 200 \end{code}
 201
 202
 203
 204 \begin{code}
 205 gcdInteger :: Integer -> Integer -> Integer
 206 -- SUP: Do we really need the first two cases?
 207 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
 208 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
 209 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
 210 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "PrelNum.gcdInteger: gcd 0 0 is undefined"
 211 gcdInteger ia@(S# a)  ib@(J# sb b)
 212   | a  ==# 0#  = abs ib
 213   | sb ==# 0#  = abs ia
 214   | otherwise  = S# (gcdIntegerInt# absSb b absA)
 215        where absA  = if a  <# 0# then negateInt# a  else a
 216              absSb = if sb <# 0# then negateInt# sb else sb
 217 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
 218 gcdInteger (J# 0# _) (J# 0# _) = error "PrelNum.gcdInteger: gcd 0 0 is undefined"
 219 gcdInteger (J# sa a) (J# sb b)
 220   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 221
 222 lcmInteger :: Integer -> Integer -> Integer
 223 lcmInteger a 0
 224   = zeroInteger
 225 lcmInteger 0 b
 226   = zeroInteger
 227 lcmInteger a b
 228   = (divExact aa (gcdInteger aa ab)) * ab
 229   where aa = abs a
 230         ab = abs b
 231
 232 divExact :: Integer -> Integer -> Integer
 233 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
 234 divExact (S# a) (S# b) = S# (quotInt# a b)
 235 divExact (S# a) (J# sb b)
 236   = S# (quotInt# a (integer2Int# sb b))
 237 divExact (J# sa a) (S# b)
 238   = case int2Integer# b of
 239      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 240 divExact (J# sa a) (J# sb b)
 241   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 242 \end{code}
 243
 244
 245 %*********************************************************
 246 %*                                                      *
 247 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 248 %*                                                      *
 249 %*********************************************************
 250
 251 \begin{code}
 252 instance  Eq Integer  where
 253     (S# i)     ==  (S# j)     = i ==# j
 254     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 255     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 256     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 257
 258     (S# i)     /=  (S# j)     = i /=# j
 259     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 260     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 261     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 262
 263 ------------------------------------------------------------------------
 264 instance  Ord Integer  where
 265     (S# i)     <=  (S# j)     = i <=# j
 266     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 267     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 268     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 269
 270     (S# i)     >   (S# j)     = i ># j
 271     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 272     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 273     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 274
 275     (S# i)     <   (S# j)     = i <# j
 276     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 277     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 278     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 279
 280     (S# i)     >=  (S# j)     = i >=# j
 281     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 282     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 283     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 284
 285     compare (S# i)  (S# j)
 286        | i ==# j = EQ
 287        | i <=# j = LT
 288        | otherwise = GT
 289     compare (J# s d) (S# i)
 290        = case cmpIntegerInt# s d i of { res# ->
 291          if res# <# 0# then LT else
 292          if res# ># 0# then GT else EQ
 293          }
 294     compare (S# i) (J# s d)
 295        = case cmpIntegerInt# s d i of { res# ->
 296          if res# ># 0# then LT else
 297          if res# <# 0# then GT else EQ
 298          }
 299     compare (J# s1 d1) (J# s2 d2)
 300        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 301          if res# <# 0# then LT else
 302          if res# ># 0# then GT else EQ
 303          }
 304 \end{code}
 305
 306
 307 %*********************************************************
 308 %*                                                      *
 309 \subsection{The @Integer@ instances for @Num@}
 310 %*                                                      *
 311 %*********************************************************
 312
 313 \begin{code}
 314 instance  Num Integer  where
 315     (+) = plusInteger
 316     (-) = minusInteger
 317     (*) = timesInteger
 318     negate         = negateInteger
 319     fromInteger x  =  x
 320
 321     -- ORIG: abs n = if n >= 0 then n else -n
 322     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 323     abs (S# i) = case abs (I# i) of I# j -> S# j
 324     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 325
 326     signum (S# i) = case signum (I# i) of I# j -> S# j
 327     signum (J# s d)
 328       = let
 329             cmp = cmpIntegerInt# s d 0#
 330         in
 331         if      cmp >#  0# then S# 1#
 332         else if cmp ==# 0# then S# 0#
 333         else                    S# (negateInt# 1#)
 334
 335 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
 336                                    if c ==# 0# then S# r
 337                                    else toBig i1 + toBig i2 }
 338 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
 339 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
 340 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 341
 342 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
 343                                      if c ==# 0# then S# r
 344                                      else toBig i1 - toBig i2 }
 345 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
 346 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
 347 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 348
 349 timesInteger i1@(S# i) i2@(S# j)   = case mulIntC# i j of { (# r, c #) ->
 350                                      if c ==# 0# then S# r
 351                                      else toBig i1 * toBig i2 }
 352 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
 353 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
 354 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 355
 356 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 357 negateInteger (S# i)              = S# (negateInt# i)
 358 negateInteger (J# s d)            = J# (negateInt# s) d
 359 \end{code}
 360
 361
 362 %*********************************************************
 363 %*                                                      *
 364 \subsection{The @Integer@ instance for @Enum@}
 365 %*                                                      *
 366 %*********************************************************
 367
 368 \begin{code}
 369 instance  Enum Integer  where
 370     succ x               = x + 1
 371     pred x               = x - 1
 372     toEnum n             = int2Integer n
 373     fromEnum n           = integer2Int n
 374
 375     {-# INLINE enumFrom #-}
 376     {-# INLINE enumFromThen #-}
 377     {-# INLINE enumFromTo #-}
 378     {-# INLINE enumFromThenTo #-}
 379     enumFrom x             = efdInteger  x 1
 380     enumFromThen x y       = efdInteger  x (y-x)
 381     enumFromTo x lim       = efdtInteger x 1     lim
 382     enumFromThenTo x y lim = efdtInteger x (y-x) lim
 383
 384
 385 efdInteger  = enumDeltaIntegerList
 386 efdtInteger = enumDeltaToIntegerList
 387
 388 {-# RULES
 389 "efdInteger"            forall x y.  efdInteger x y         = build (\c _ -> enumDeltaIntegerFB c x y)
 390 "efdtInteger"           forall x y l.efdtInteger x y l      = build (\c n -> enumDeltaToIntegerFB c n x y l)
 391 "enumDeltaInteger"      enumDeltaIntegerFB   (:)    = enumDeltaIntegerList
 392 "enumDeltaToInteger"    enumDeltaToIntegerFB (:) [] = enumDeltaToIntegerList
 393  #-}
 394
 395 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 396 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 397
 398 enumDeltaIntegerList :: Integer -> Integer -> [Integer]
 399 enumDeltaIntegerList x d = x : enumDeltaIntegerList (x+d) d
 400
 401 enumDeltaToIntegerFB c n x delta lim
 402   | delta >= 0 = up_fb c n x delta lim
 403   | otherwise  = dn_fb c n x delta lim
 404
 405 enumDeltaToIntegerList x delta lim
 406   | delta >= 0 = up_list x delta lim
 407   | otherwise  = dn_list x delta lim
 408
 409 up_fb c n x delta lim = go (x::Integer)
 410                       where
 411                         go x | x > lim   = n
 412                              | otherwise = x `c` go (x+delta)
 413 dn_fb c n x delta lim = go (x::Integer)
 414                       where
 415                         go x | x < lim   = n
 416                              | otherwise = x `c` go (x+delta)
 417
 418 up_list x delta lim = go (x::Integer)
 419                     where
 420                         go x | x > lim   = []
 421                              | otherwise = x : go (x+delta)
 422 dn_list x delta lim = go (x::Integer)
 423                     where
 424                         go x | x < lim   = []
 425                              | otherwise = x : go (x+delta)
 426
 427 \end{code}
 428
 429
 430 %*********************************************************
 431 %*                                                      *
 432 \subsection{The @Integer@ instances for @Show@}
 433 %*                                                      *
 434 %*********************************************************
 435
 436 \begin{code}
 437 instance Show Integer where
 438     showsPrec p n r
 439         | n < 0 && p > 6 = '(' : jtos n (')' : r)
 440         | otherwise      = jtos n r
 441     showList = showList__ (showsPrec 0)
 442
 443 jtos :: Integer -> String -> String
 444 jtos n cs
 445     | n < 0     = '-' : jtos' (-n) cs
 446     | otherwise = jtos' n cs
 447     where
 448     jtos' :: Integer -> String -> String
 449     jtos' n' cs'
 450         | n' < 10    = case unsafeChr (ord '0' + fromInteger n') of
 451             c@(C# _) -> c:cs'
 452         | otherwise = case unsafeChr (ord '0' + fromInteger r) of
 453             c@(C# _) -> jtos' q (c:cs')
 454         where
 455         (q,r) = n' `quotRemInteger` 10
 456 \end{code}