ghc/lib/std/PrelNum.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1996
   3 %
   4
   5 \section[PrelNum]{Module @PrelNum@}
   6
   7 The class
   8
   9         Num
  10
  11 and the type
  12
  13         Integer
  14
  15
  16 \begin{code}
  17 {-# OPTIONS -fno-implicit-prelude #-}
  18
  19 module PrelNum where
  20
  21 import {-# SOURCE #-} PrelErr
  22 import PrelBase
  23 import PrelList
  24 import PrelEnum
  25 import PrelShow
  26
  27 infixl 7  *
  28 infixl 6  +, -
  29
  30 default ()              -- Double isn't available yet,
  31                         -- and we shouldn't be using defaults anyway
  32 \end{code}
  33
  34 %*********************************************************
  35 %*                                                      *
  36 \subsection{Standard numeric class}
  37 %*                                                      *
  38 %*********************************************************
  39
  40 \begin{code}
  41 class  (Eq a, Show a) => Num a  where
  42     (+), (-), (*)       :: a -> a -> a
  43     negate              :: a -> a
  44     abs, signum         :: a -> a
  45     fromInteger         :: Integer -> a
  46     fromInt             :: Int -> a -- partain: Glasgow extension
  47
  48     x - y               = x + negate y
  49     negate x            = 0 - x
  50     fromInt (I# i#)     = fromInteger (S# i#)
  51                                         -- Go via the standard class-op if the
  52                                         -- non-standard one ain't provided
  53 \end{code}
  54
  55 A few small numeric functions
  56
  57 \begin{code}
  58 subtract        :: (Num a) => a -> a -> a
  59 {-# INLINE subtract #-}
  60 subtract x y    =  y - x
  61
  62 ord_0 :: Num a => a
  63 ord_0 = fromInt (ord '0')
  64 \end{code}
  65
  66
  67 %*********************************************************
  68 %*                                                      *
  69 \subsection{Instances for @Int@}
  70 %*                                                      *
  71 %*********************************************************
  72
  73 \begin{code}
  74 instance  Num Int  where
  75     (+)    x y =  plusInt x y
  76     (-)    x y =  minusInt x y
  77     negate x   =  negateInt x
  78     (*)    x y =  timesInt x y
  79     abs    n   = if n `geInt` 0 then n else (negateInt n)
  80
  81     signum n | n `ltInt` 0 = negateInt 1
  82              | n `eqInt` 0 = 0
  83              | otherwise   = 1
  84
  85     fromInteger n = integer2Int n
  86     fromInt n     = n
  87 \end{code}
  88
  89
  90 \begin{code}
  91 -- These can't go in PrelBase with the defn of Int, because
  92 -- we don't have pairs defined at that time!
  93
  94 quotRemInt :: Int -> Int -> (Int, Int)
  95 a@(I# _) `quotRemInt` b@(I# _) = (a `quotInt` b, a `remInt` b)
  96     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
  97
  98 divModInt ::  Int -> Int -> (Int, Int)
  99 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
 100     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
 101 \end{code}
 102
 103
 104 %*********************************************************
 105 %*                                                      *
 106 \subsection{The @Integer@ type}
 107 %*                                                      *
 108 %*********************************************************
 109
 110 \begin{code}
 111 data Integer
 112    = S# Int#                            -- small integers
 113    | J# Int# ByteArray#                 -- large integers
 114 \end{code}
 115
 116 Convenient boxed Integer PrimOps.
 117
 118 \begin{code}
 119 zeroInteger :: Integer
 120 zeroInteger = S# 0#
 121
 122 int2Integer :: Int -> Integer
 123 {-# INLINE int2Integer #-}
 124 int2Integer (I# i) = S# i
 125
 126 integer2Int :: Integer -> Int
 127 integer2Int (S# i)   = I# i
 128 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 129
 130 addr2Integer :: Addr# -> Integer
 131 {-# INLINE addr2Integer #-}
 132 addr2Integer x = case addr2Integer# x of (# s, d #) -> J# s d
 133
 134 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 135 toBig i@(J# _ _) = i
 136 \end{code}
 137
 138
 139 %*********************************************************
 140 %*                                                      *
 141 \subsection{Dividing @Integers@}
 142 %*                                                      *
 143 %*********************************************************
 144
 145 \begin{code}
 146 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 147 quotRemInteger a@(S# (-2147483648#)) b = quotRemInteger (toBig a) b
 148 quotRemInteger (S# i) (S# j)
 149   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 150 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 151 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 152 quotRemInteger (J# s1 d1) (J# s2 d2)
 153   = case (quotRemInteger# s1 d1 s2 d2) of
 154           (# s3, d3, s4, d4 #)
 155             -> (J# s3 d3, J# s4 d4)
 156
 157 divModInteger a@(S# (-2147483648#)) b = divModInteger (toBig a) b
 158 divModInteger (S# i) (S# j)
 159   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 160 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 161 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 162 divModInteger (J# s1 d1) (J# s2 d2)
 163   = case (divModInteger# s1 d1 s2 d2) of
 164           (# s3, d3, s4, d4 #)
 165             -> (J# s3 d3, J# s4 d4)
 166
 167 remInteger :: Integer -> Integer -> Integer
 168 remInteger ia 0
 169   = error "Prelude.Integral.rem{Integer}: divide by 0"
 170 remInteger a@(S# (-2147483648#)) b = remInteger (toBig a) b
 171 remInteger (S# a) (S# b) = S# (remInt# a b)
 172 {- Special case doesn't work, because a 1-element J# has the range
 173    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
 174 remInteger ia@(S# a) (J# sb b)
 175   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 176   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 177   | 0# <# sb   = ia
 178   | otherwise  = S# (0# -# a)
 179 -}
 180 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
 181 remInteger (J# sa a) (S# b)
 182   = case int2Integer# b of { (# sb, b #) ->
 183     case remInteger# sa a sb b of { (# sr, r #) ->
 184     S# (sr *# (word2Int# (integer2Word# sr r))) }}
 185 remInteger (J# sa a) (J# sb b)
 186   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 187
 188 quotInteger :: Integer -> Integer -> Integer
 189 quotInteger ia 0
 190   = error "Prelude.Integral.quot{Integer}: divide by 0"
 191 quotInteger a@(S# (-2147483648#)) b = quotInteger (toBig a) b
 192 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 193 {- Special case disabled, see remInteger above
 194 quotInteger (S# a) (J# sb b)
 195   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 196   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 197   | otherwise  = zeroInteger
 198 -}
 199 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
 200 quotInteger (J# sa a) (S# b)
 201   = case int2Integer# b of { (# sb, b #) ->
 202     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 203 quotInteger (J# sa a) (J# sb b)
 204   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 205 \end{code}
 206
 207
 208
 209 \begin{code}
 210 gcdInteger :: Integer -> Integer -> Integer
 211 gcdInteger a@(S# (-2147483648#)) b = gcdInteger (toBig a) b
 212 gcdInteger a b@(S# (-2147483648#)) = gcdInteger a (toBig b)
 213 gcdInteger (S# a) (S# b) = S# (gcdInt# a b)
 214 gcdInteger ia@(S# a) ib@(J# sb b)
 215   | a  ==# 0#  = abs ib
 216   | sb ==# 0#  = abs ia
 217   | otherwise  = S# (gcdIntegerInt# sb b a)
 218 gcdInteger ia@(J# sa a) ib@(S# b)
 219   | sa ==# 0#  = abs ib
 220   | b ==# 0#   = abs ia
 221   | otherwise  = S# (gcdIntegerInt# sa a b)
 222 gcdInteger (J# sa a) (J# sb b)
 223   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 224
 225 lcmInteger :: Integer -> Integer -> Integer
 226 lcmInteger a 0
 227   = zeroInteger
 228 lcmInteger 0 b
 229   = zeroInteger
 230 lcmInteger a b
 231   = (divExact aa (gcdInteger aa ab)) * ab
 232   where aa = abs a
 233         ab = abs b
 234
 235 divExact :: Integer -> Integer -> Integer
 236 divExact a@(S# (-2147483648#)) b = divExact (toBig a) b
 237 divExact (S# a) (S# b) = S# (quotInt# a b)
 238 divExact (S# a) (J# sb b)
 239   = S# (quotInt# a (sb *# (word2Int# (integer2Word# sb b))))
 240 divExact (J# sa a) (S# b)
 241   = case int2Integer# b of
 242      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 243 divExact (J# sa a) (J# sb b)
 244   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 245 \end{code}
 246
 247
 248 %*********************************************************
 249 %*                                                      *
 250 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 251 %*                                                      *
 252 %*********************************************************
 253
 254 \begin{code}
 255 instance  Eq Integer  where
 256     (S# i)     ==  (S# j)     = i ==# j
 257     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 258     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 259     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 260
 261     (S# i)     /=  (S# j)     = i /=# j
 262     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 263     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 264     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 265
 266 ------------------------------------------------------------------------
 267 instance  Ord Integer  where
 268     (S# i)     <=  (S# j)     = i <=# j
 269     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 270     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 271     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 272
 273     (S# i)     >   (S# j)     = i ># j
 274     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 275     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 276     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 277
 278     (S# i)     <   (S# j)     = i <# j
 279     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 280     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 281     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 282
 283     (S# i)     >=  (S# j)     = i >=# j
 284     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 285     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 286     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 287
 288     compare (S# i)  (S# j)
 289        | i ==# j = EQ
 290        | i <=# j = LT
 291        | otherwise = GT
 292     compare (J# s d) (S# i)
 293        = case cmpIntegerInt# s d i of { res# ->
 294          if res# <# 0# then LT else
 295          if res# ># 0# then GT else EQ
 296          }
 297     compare (S# i) (J# s d)
 298        = case cmpIntegerInt# s d i of { res# ->
 299          if res# ># 0# then LT else
 300          if res# <# 0# then GT else EQ
 301          }
 302     compare (J# s1 d1) (J# s2 d2)
 303        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 304          if res# <# 0# then LT else
 305          if res# ># 0# then GT else EQ
 306          }
 307 \end{code}
 308
 309
 310 %*********************************************************
 311 %*                                                      *
 312 \subsection{The @Integer@ instances for @Num@}
 313 %*                                                      *
 314 %*********************************************************
 315
 316 \begin{code}
 317 instance  Num Integer  where
 318     (+) i1@(S# i) i2@(S# j)
 319         = case addIntC# i j of { (# r, c #) ->
 320           if c ==# 0# then S# r
 321           else toBig i1 + toBig i2 }
 322     (+) i1@(J# _ _) i2@(S# _)   = i1 + toBig i2
 323     (+) i1@(S# _) i2@(J# _ _)   = toBig i1 + i2
 324     (+) (J# s1 d1) (J# s2 d2)
 325       = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 326
 327     (-) i1@(S# i) i2@(S# j)
 328         = case subIntC# i j of { (# r, c #) ->
 329           if c ==# 0# then S# r
 330           else toBig i1 - toBig i2 }
 331     (-) i1@(J# _ _) i2@(S# _)   = i1 - toBig i2
 332     (-) i1@(S# _) i2@(J# _ _)   = toBig i1 - i2
 333     (-) (J# s1 d1) (J# s2 d2)
 334       = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 335
 336     (*) i1@(S# i) i2@(S# j)
 337         = case mulIntC# i j of { (# r, c #) ->
 338           if c ==# 0# then S# r
 339           else toBig i1 * toBig i2 }
 340     (*) i1@(J# _ _) i2@(S# _)   = i1 * toBig i2
 341     (*) i1@(S# _) i2@(J# _ _)   = toBig i1 * i2
 342     (*) (J# s1 d1) (J# s2 d2)
 343       = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 344
 345     negate (S# (-2147483648#)) = 2147483648
 346     negate (S# i) = S# (negateInt# i)
 347     negate (J# s d) = J# (negateInt# s) d
 348
 349     -- ORIG: abs n = if n >= 0 then n else -n
 350
 351     abs (S# (-2147483648#)) = 2147483648
 352     abs (S# i) = case abs (I# i) of I# j -> S# j
 353     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 354
 355     signum (S# i) = case signum (I# i) of I# j -> S# j
 356     signum (J# s d)
 357       = let
 358             cmp = cmpIntegerInt# s d 0#
 359         in
 360         if      cmp >#  0# then S# 1#
 361         else if cmp ==# 0# then S# 0#
 362         else                    S# (negateInt# 1#)
 363
 364     fromInteger x       =  x
 365
 366     fromInt (I# i)      =  S# i
 367 \end{code}
 368
 369
 370 %*********************************************************
 371 %*                                                      *
 372 \subsection{The @Integer@ instance for @Enum@}
 373 %*                                                      *
 374 %*********************************************************
 375
 376 \begin{code}
 377 instance  Enum Integer  where
 378     succ x               = x + 1
 379     pred x               = x - 1
 380     toEnum n             = int2Integer n
 381     fromEnum n           = integer2Int n
 382
 383     {-# INLINE enumFrom #-}
 384     {-# INLINE enumFromThen #-}
 385     {-# INLINE enumFromTo #-}
 386     {-# INLINE enumFromThenTo #-}
 387     enumFrom x             = efdInteger  x 1
 388     enumFromThen x y       = efdInteger  x (y-x)
 389     enumFromTo x lim       = efdtInteger x 1     lim
 390     enumFromThenTo x y lim = efdtInteger x (y-x) lim
 391
 392
 393 efdInteger  = enumDeltaIntegerList
 394 efdtInteger = enumDeltaToIntegerList
 395
 396 {-# RULES
 397 "efdInteger"            forall x y.  efdInteger x y         = build (\c _ -> enumDeltaIntegerFB c x y)
 398 "efdtInteger"           forall x y l.efdtInteger x y l      = build (\c n -> enumDeltaToIntegerFB c n x y l)
 399 "enumDeltaInteger"      enumDeltaIntegerFB   (:)    = enumDeltaIntegerList
 400 "enumDeltaToInteger"    enumDeltaToIntegerFB (:) [] = enumDeltaToIntegerList
 401  #-}
 402
 403 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 404 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 405
 406 enumDeltaIntegerList :: Integer -> Integer -> [Integer]
 407 enumDeltaIntegerList x d = x : enumDeltaIntegerList (x+d) d
 408
 409 enumDeltaToIntegerFB c n x delta lim
 410   | delta >= 0 = up_fb c n x delta lim
 411   | otherwise  = dn_fb c n x delta lim
 412
 413 enumDeltaToIntegerList x delta lim
 414   | delta >= 0 = up_list x delta lim
 415   | otherwise  = dn_list x delta lim
 416
 417 up_fb c n x delta lim = go (x::Integer)
 418                       where
 419                         go x | x > lim   = n
 420                              | otherwise = x `c` go (x+delta)
 421 dn_fb c n x delta lim = go (x::Integer)
 422                       where
 423                         go x | x < lim   = n
 424                              | otherwise = x `c` go (x+delta)
 425
 426 up_list x delta lim = go (x::Integer)
 427                     where
 428                         go x | x > lim   = []
 429                              | otherwise = x : go (x+delta)
 430 dn_list x delta lim = go (x::Integer)
 431                     where
 432                         go x | x < lim   = []
 433                              | otherwise = x : go (x+delta)
 434
 435 \end{code}
 436
 437
 438 %*********************************************************
 439 %*                                                      *
 440 \subsection{The @Integer@ instances for @Show@}
 441 %*                                                      *
 442 %*********************************************************
 443
 444 \begin{code}
 445 instance  Show Integer  where
 446     showsPrec   x = showSignedInteger x
 447     showList = showList__ (showsPrec 0)
 448
 449 showSignedInteger :: Int -> Integer -> ShowS
 450 showSignedInteger p n r
 451   | n < 0 && p > 6 = '(':jtos n (')':r)
 452   | otherwise      = jtos n r
 453
 454 jtos :: Integer -> String -> String
 455 jtos i rs
 456  | i < 0     = '-' : jtos' (-i) rs
 457  | otherwise = jtos' i rs
 458  where
 459   jtos' :: Integer -> String -> String
 460   jtos' n cs
 461    | n < 10    = chr (fromInteger n + (ord_0::Int)) : cs
 462    | otherwise = jtos' q (chr (integer2Int r + (ord_0::Int)) : cs)
 463     where
 464      (q,r) = n `quotRemInteger` 10
 465 \end{code}