ghc/rts/gmp/mpn/sparc64/lshift.asm

   1 ! SPARC v9 __gmpn_lshift --
   2
   3 ! Copyright (C) 1996, 2000 Free Software Foundation, Inc.
   4
   5 ! This file is part of the GNU MP Library.
   6
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Lesser General Public License as published by
   9 ! the Free Software Foundation; either version 2.1 of the License, or (at your
  10 ! option) any later version.
  11
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15 ! License for more details.
  16
  17 ! You should have received a copy of the GNU Lesser General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! res_ptr       %o0
  25 ! src_ptr       %o1
  26 ! size          %o2
  27 ! cnt           %o3
  28
  29 include(`../config.m4')
  30
  31 ASM_START()
  32         .register       %g2,#scratch
  33         .register       %g3,#scratch
  34 PROLOGUE(mpn_lshift)
  35         sllx    %o2,3,%g1
  36         add     %o1,%g1,%o1     ! make %o1 point at end of src
  37         ldx     [%o1-8],%g2     ! load first limb
  38         sub     %g0,%o3,%o5     ! negate shift count
  39         add     %o0,%g1,%o0     ! make %o0 point at end of res
  40         add     %o2,-1,%o2
  41         and     %o2,4-1,%g4     ! number of limbs in first loop
  42         srlx    %g2,%o5,%g1     ! compute function result
  43         brz,pn  %g4,L(0)                ! if multiple of 4 limbs, skip first loop
  44         mov     %g1,%g5
  45
  46         sub     %o2,%g4,%o2     ! adjust count for main loop
  47
  48 L(loop0):
  49         ldx     [%o1-16],%g3
  50         add     %o0,-8,%o0
  51         add     %o1,-8,%o1
  52         add     %g4,-1,%g4
  53         sllx    %g2,%o3,%o4
  54         srlx    %g3,%o5,%g1
  55         mov     %g3,%g2
  56         or      %o4,%g1,%o4
  57         brnz,pt %g4,L(loop0)
  58          stx    %o4,[%o0+0]
  59
  60 L(0):   brz,pn  %o2,L(end)
  61          nop
  62
  63 L(loop1):
  64         ldx     [%o1-16],%g3
  65         add     %o0,-32,%o0
  66         add     %o2,-4,%o2
  67         sllx    %g2,%o3,%o4
  68         srlx    %g3,%o5,%g1
  69
  70         ldx     [%o1-24],%g2
  71         sllx    %g3,%o3,%g4
  72         or      %o4,%g1,%o4
  73         stx     %o4,[%o0+24]
  74         srlx    %g2,%o5,%g1
  75
  76         ldx     [%o1-32],%g3
  77         sllx    %g2,%o3,%o4
  78         or      %g4,%g1,%g4
  79         stx     %g4,[%o0+16]
  80         srlx    %g3,%o5,%g1
  81
  82         ldx     [%o1-40],%g2
  83         sllx    %g3,%o3,%g4
  84         or      %o4,%g1,%o4
  85         stx     %o4,[%o0+8]
  86         srlx    %g2,%o5,%g1
  87
  88         add     %o1,-32,%o1
  89         or      %g4,%g1,%g4
  90         brnz,pt %o2,L(loop1)
  91          stx    %g4,[%o0+0]
  92
  93 L(end): sllx    %g2,%o3,%g2
  94         stx     %g2,[%o0-8]
  95         retl
  96         mov     %g5,%o0
  97 EPILOGUE(mpn_lshift)