ghc/utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 --      - validate modules
  12 --      - expanding of variables in new-style package conf
  13 --      - version manipulation (checking whether old version exists,
  14 --        hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version  ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils  ( showError, ParseResult(..) )
  22 import Distribution.Package
  23 import Distribution.Version
  24 import Compat.Directory         ( getAppUserDataDirectory, createDirectoryIfMissing )
  25 import Compat.RawSystem         ( rawSystem )
  26 import Control.Exception        ( evaluate )
  27 import qualified Control.Exception as Exception
  28
  29 import Prelude
  30
  31 #include "../../includes/ghcconfig.h"
  32
  33 #if __GLASGOW_HASKELL__ >= 504
  34 import System.Console.GetOpt
  35 import Text.PrettyPrint
  36 import qualified Control.Exception as Exception
  37 #else
  38 import GetOpt
  39 import Pretty
  40 import qualified Exception
  41 #endif
  42
  43 import Data.Char        ( isSpace )
  44 import Monad
  45 import Directory
  46 import System   ( getArgs, getProgName,
  47                   exitWith, ExitCode(..)
  48                 )
  49 import System.IO
  50 import Data.List ( isPrefixOf, isSuffixOf, intersperse )
  51
  52 #ifdef mingw32_HOST_OS
  53 import Foreign
  54
  55 #if __GLASGOW_HASKELL__ >= 504
  56 import Foreign.C.String
  57 #else
  58 import CString
  59 #endif
  60 #endif
  61
  62 -- -----------------------------------------------------------------------------
  63 -- Entry point
  64
  65 main :: IO ()
  66 main = do
  67   args <- getArgs
  68
  69   case getOpt Permute flags args of
  70         (cli,_,[]) | FlagHelp `elem` cli -> do
  71            prog <- getProgramName
  72            bye (usageInfo (usageHeader prog) flags)
  73         (cli,_,[]) | FlagVersion `elem` cli ->
  74            bye ourCopyright
  75         (cli,nonopts,[]) ->
  76            runit cli nonopts
  77         (_,_,errors) -> tryOldCmdLine errors args
  78
  79 -- If the new command-line syntax fails, then we try the old.  If that
  80 -- fails too, then we output the original errors and the new syntax
  81 -- (so the old syntax is still available, but hidden).
  82 tryOldCmdLine :: [String] -> [String] -> IO ()
  83 tryOldCmdLine errors args = do
  84   case getOpt Permute oldFlags args of
  85         (cli@(_:_),[],[]) ->
  86            oldRunit cli
  87         _failed -> do
  88            prog <- getProgramName
  89            die (concat errors ++ usageInfo (usageHeader prog) flags)
  90
  91 -- -----------------------------------------------------------------------------
  92 -- Command-line syntax
  93
  94 data Flag
  95   = FlagUser
  96   | FlagGlobal
  97   | FlagHelp
  98   | FlagVersion
  99   | FlagConfig  FilePath
 100   | FlagGlobalConfig FilePath
 101   | FlagForce
 102   | FlagAutoGHCiLibs
 103   deriving Eq
 104
 105 flags :: [OptDescr Flag]
 106 flags = [
 107   Option [] ["user"] (NoArg FlagUser)
 108         "use the current user's package database",
 109   Option [] ["global"] (NoArg FlagGlobal)
 110         "(default) use the global package database",
 111   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 112         "act upon specified package config file (only)",
 113   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 114         "location of the global package config",
 115   Option [] ["force"] (NoArg FlagForce)
 116         "ignore missing dependencies, directories, and libraries",
 117   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 118         "automatically build libs for GHCi (with register)",
 119   Option ['?'] ["help"] (NoArg FlagHelp)
 120         "display this help and exit",
 121    Option ['V'] ["version"] (NoArg FlagVersion)
 122         "output version information and exit"
 123   ]
 124
 125 ourCopyright :: String
 126 ourCopyright = "GHC package manager version " ++ version ++ "\n"
 127
 128 usageHeader :: String -> String
 129 usageHeader prog = substProg prog $
 130   "Usage:\n" ++
 131   "  $p register {filename | -}\n" ++
 132   "    Register the package using the specified installed package\n" ++
 133   "    description. The syntax for the latter is given in the $p\n" ++
 134   "    documentation.\n" ++
 135   "\n" ++
 136   "  $p update {filename | -}\n" ++
 137   "    Register the package, overwriting any other package with the\n" ++
 138   "    same name.\n" ++
 139   "\n" ++
 140   "  $p unregister {pkg-id}\n" ++
 141   "    Unregister the specified package.\n" ++
 142   "\n" ++
 143   "  $p expose {pkg-id}\n" ++
 144   "    Expose the specified package.\n" ++
 145   "\n" ++
 146   "  $p hide {pkg-id}\n" ++
 147   "    Hide the specified package.\n" ++
 148   "\n" ++
 149   "  $p list\n" ++
 150   "    List all registered packages, both global and user (unless either\n" ++
 151   "    --global or --user is specified), and both hidden and exposed.\n" ++
 152   "\n" ++
 153   "  $p describe {pkg-id}\n" ++
 154   "    Give the registered description for the specified package. The\n" ++
 155   "    description is returned in precisely the syntax required by $p\n" ++
 156   "    register.\n" ++
 157   "\n" ++
 158   "  $p field {pkg-id} {field}\n" ++
 159   "    Extract the specified field of the package description for the\n" ++
 160   "    specified package.\n" ++
 161   "\n" ++
 162   " The following optional flags are also accepted:\n"
 163
 164 substProg :: String -> String -> String
 165 substProg _ [] = []
 166 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 167 substProg prog (c:xs) = c : substProg prog xs
 168
 169 -- -----------------------------------------------------------------------------
 170 -- Do the business
 171
 172 runit :: [Flag] -> [String] -> IO ()
 173 runit cli nonopts = do
 174   prog <- getProgramName
 175   dbs <- getPkgDatabases cli
 176   db_stack <- mapM readParseDatabase dbs
 177   let
 178         force = FlagForce `elem` cli
 179         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 180   --
 181   -- first, parse the command
 182   case nonopts of
 183     ["register", filename] ->
 184         registerPackage filename [] db_stack auto_ghci_libs False force
 185     ["update", filename] ->
 186         registerPackage filename [] db_stack auto_ghci_libs True force
 187     ["unregister", pkgid_str] -> do
 188         pkgid <- readPkgId pkgid_str
 189         unregisterPackage pkgid db_stack
 190     ["expose", pkgid_str] -> do
 191         pkgid <- readPkgId pkgid_str
 192         exposePackage pkgid db_stack
 193     ["hide",   pkgid_str] -> do
 194         pkgid <- readPkgId pkgid_str
 195         hidePackage pkgid db_stack
 196     ["list"] -> do
 197         listPackages db_stack
 198     ["describe", pkgid_str] -> do
 199         pkgid <- readPkgId pkgid_str
 200         describePackage db_stack pkgid
 201     ["field", pkgid_str, field] -> do
 202         pkgid <- readPkgId pkgid_str
 203         describeField db_stack pkgid field
 204     [] -> do
 205         die ("missing command\n" ++
 206                 usageInfo (usageHeader prog) flags)
 207     (_cmd:_) -> do
 208         die ("command-line syntax error\n" ++
 209                 usageInfo (usageHeader prog) flags)
 210
 211 parseCheck :: ReadP a a -> String -> String -> IO a
 212 parseCheck parser str what =
 213   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 214     [x] -> return x
 215     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 216
 217 readPkgId :: String -> IO PackageIdentifier
 218 readPkgId str = parseCheck parsePackageId str "package identifier"
 219
 220 -- -----------------------------------------------------------------------------
 221 -- Package databases
 222
 223 -- Some commands operate on a single database:
 224 --      register, unregister, expose, hide
 225 -- however these commands also check the union of the available databases
 226 -- in order to check consistency.  For example, register will check that
 227 -- dependencies exist before registering a package.
 228 --
 229 -- Some commands operate  on multiple databases, with overlapping semantics:
 230 --      list, describe, field
 231
 232 type PackageDBName  = FilePath
 233 type PackageDB      = [InstalledPackageInfo]
 234
 235 type PackageDBStack = [(PackageDBName,PackageDB)]
 236         -- A stack of package databases.  Convention: head is the topmost
 237         -- in the stack.  Earlier entries override later one.
 238
 239 -- The output of this function is the list of databases to act upon, with
 240 -- the "topmost" overlapped database last.  The commands which operate on a
 241 -- single database will use the last one.  Commands which operate on multiple
 242 -- databases will interpret the databases as overlapping.
 243 getPkgDatabases :: [Flag] -> IO [PackageDBName]
 244 getPkgDatabases flags = do
 245   -- first we determine the location of the global package config.  On Windows,
 246   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 247   -- location is passed to the binary using the --global-config flag by the
 248   -- wrapper script.
 249   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 250   global_conf <-
 251      case [ f | FlagGlobalConfig f <- flags ] of
 252         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 253                  case mb_dir of
 254                         Nothing  -> die err_msg
 255                         Just dir -> return (dir `joinFileName` "package.conf")
 256         fs -> return (last fs)
 257
 258   -- get the location of the user package database, and create it if necessary
 259   appdir <- getAppUserDataDirectory "ghc"
 260
 261   let
 262         subdir = targetARCH ++ '-':targetOS ++ '-':version
 263         archdir   = appdir `joinFileName` subdir
 264         user_conf = archdir `joinFileName` "package.conf"
 265   b <- doesFileExist user_conf
 266   when (not b) $ do
 267         putStrLn ("Creating user package database in " ++ user_conf)
 268         createDirectoryIfMissing True archdir
 269         writeFile user_conf emptyPackageConfig
 270
 271   let
 272         databases = foldl addDB [global_conf] flags
 273
 274         -- implement the following rules:
 275         --      global database is the default
 276         --      --user means overlap with the user database
 277         --      --global means reset to just the global database
 278         --      -f <file> means overlap with <file>
 279         addDB dbs FlagUser       = user_conf : dbs
 280         addDB dbs FlagGlobal     = [global_conf]
 281         addDB dbs (FlagConfig f) = f : dbs
 282         addDB dbs _              = dbs
 283
 284   return databases
 285
 286 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 287 readParseDatabase filename = do
 288   str <- readFile filename
 289   let packages = read str
 290   evaluate packages
 291     `Exception.catch` \_ ->
 292         die (filename ++ ": parse error in package config file")
 293   return (filename,packages)
 294
 295 emptyPackageConfig :: String
 296 emptyPackageConfig = "[]"
 297
 298 -- -----------------------------------------------------------------------------
 299 -- Registering
 300
 301 registerPackage :: FilePath
 302                 -> [(String,String)] --  defines, ToDo: maybe remove?
 303                 -> PackageDBStack
 304                 -> Bool         -- auto_ghci_libs
 305                 -> Bool         -- update
 306                 -> Bool         -- force
 307                 -> IO ()
 308 registerPackage input defines db_stack auto_ghci_libs update force = do
 309   let
 310         db_to_operate_on = my_head "db" db_stack
 311         db_filename      = fst db_to_operate_on
 312   --
 313   checkConfigAccess db_filename
 314
 315   s <-
 316     case input of
 317       "-" -> do
 318         putStr "Reading package info from stdin... "
 319         getContents
 320       f   -> do
 321         putStr ("Reading package info from " ++ show f ++ " ")
 322         readFile f
 323
 324   pkg <- parsePackageInfo s defines force
 325   putStrLn "done."
 326
 327   validatePackageConfig pkg db_stack auto_ghci_libs update force
 328   new_details <- updatePackageDB db_stack (snd db_to_operate_on) pkg
 329   savePackageConfig db_filename
 330   maybeRestoreOldConfig db_filename $
 331     writeNewConfig db_filename new_details
 332
 333 parsePackageInfo
 334         :: String
 335         -> [(String,String)]
 336         -> Bool
 337         -> IO InstalledPackageInfo
 338 parsePackageInfo str defines force =
 339   case parseInstalledPackageInfo str of
 340     ParseOk ok -> return ok
 341     ParseFailed err -> die (showError err)
 342
 343 -- Used for converting versionless package names to new
 344 -- PackageIdentifiers.  "Version [] []" is special: it means "no
 345 -- version" or "any version"
 346 pkgNameToId :: String -> PackageIdentifier
 347 pkgNameToId name = PackageIdentifier name (Version [] [])
 348
 349 -- -----------------------------------------------------------------------------
 350 -- Exposing, Hiding, Unregistering are all similar
 351
 352 exposePackage :: PackageIdentifier ->  PackageDBStack -> IO ()
 353 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 354
 355 hidePackage :: PackageIdentifier ->  PackageDBStack -> IO ()
 356 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 357
 358 unregisterPackage :: PackageIdentifier ->  PackageDBStack -> IO ()
 359 unregisterPackage = modifyPackage (\p -> [])
 360
 361 modifyPackage
 362   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 363   -> PackageIdentifier
 364   -> PackageDBStack
 365   -> IO ()
 366 modifyPackage _ _ [] = error "modifyPackage"
 367 modifyPackage fn pkgid ((db_name, pkgs) : _) = do
 368   checkConfigAccess db_name
 369   p <- findPackage [(db_name,pkgs)] pkgid
 370   let pid = package p
 371   savePackageConfig db_name
 372   let new_config = concat (map modify pkgs)
 373       modify pkg
 374         | package pkg == pid = fn pkg
 375         | otherwise          = [pkg]
 376   maybeRestoreOldConfig db_name $
 377     writeNewConfig db_name new_config
 378
 379 -- -----------------------------------------------------------------------------
 380 -- Listing packages
 381
 382 listPackages ::  PackageDBStack -> IO ()
 383 listPackages db_confs = do
 384   mapM_ show_pkgconf (reverse db_confs)
 385   where show_pkgconf (db_name,pkg_confs) =
 386           hPutStrLn stdout (render $
 387                 text (db_name ++ ":") $$ nest 4 packages
 388                 )
 389            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 390                  pp_pkg p
 391                    | exposed p = doc
 392                    | otherwise = parens doc
 393                    where doc = text (showPackageId (package p))
 394
 395 -- -----------------------------------------------------------------------------
 396 -- Describe
 397
 398 describePackage :: PackageDBStack -> PackageIdentifier -> IO ()
 399 describePackage db_stack pkgid = do
 400   p <- findPackage db_stack pkgid
 401   putStrLn (showInstalledPackageInfo p)
 402
 403 findPackage :: PackageDBStack -> PackageIdentifier -> IO InstalledPackageInfo
 404 findPackage db_stack pkgid
 405   = case [ p | p <- all_pkgs, pkgid `matches` p ] of
 406         []  -> die ("cannot find package " ++ showPackageId pkgid)
 407         [p] -> return p
 408         ps  -> die ("package " ++ showPackageId pkgid ++
 409                         " matches multiple packages: " ++
 410                         concat (intersperse ", " (
 411                                  map (showPackageId.package) ps)))
 412   where
 413         all_pkgs = concat (map snd db_stack)
 414
 415 matches :: PackageIdentifier -> InstalledPackageInfo -> Bool
 416 pid `matches` p =
 417  pid == package p ||
 418  not (realVersion pid) && pkgName pid == pkgName (package p)
 419
 420 -- -----------------------------------------------------------------------------
 421 -- Field
 422
 423 describeField :: PackageDBStack -> PackageIdentifier -> String -> IO ()
 424 describeField db_stack pkgid field = do
 425   case toField field of
 426     Nothing -> die ("unknown field: " ++ field)
 427     Just fn -> do
 428         p <- findPackage db_stack pkgid
 429         putStrLn (fn p)
 430
 431 toField :: String -> Maybe (InstalledPackageInfo -> String)
 432 -- backwards compatibility:
 433 toField "import_dirs"     = Just $ strList . importDirs
 434 toField "source_dirs"     = Just $ strList . importDirs
 435 toField "library_dirs"    = Just $ strList . libraryDirs
 436 toField "hs_libraries"    = Just $ strList . hsLibraries
 437 toField "extra_libraries" = Just $ strList . extraLibraries
 438 toField "include_dirs"    = Just $ strList . includeDirs
 439 toField "c_includes"      = Just $ strList . includes
 440 toField "package_deps"    = Just $ strList . map showPackageId. depends
 441 toField "extra_cc_opts"   = Just $ strList . extraCcOpts
 442 toField "extra_ld_opts"   = Just $ strList . extraLdOpts
 443 toField "framework_dirs"  = Just $ strList . frameworkDirs
 444 toField "extra_frameworks"= Just $ strList . extraFrameworks
 445 toField s                 = showInstalledPackageInfoField s
 446
 447 strList :: [String] -> String
 448 strList = show
 449
 450 -- -----------------------------------------------------------------------------
 451 -- Manipulating package.conf files
 452
 453 checkConfigAccess :: FilePath -> IO ()
 454 checkConfigAccess filename = do
 455   access <- getPermissions filename
 456   when (not (writable access))
 457       (die (filename ++ ": you don't have permission to modify this file"))
 458
 459 maybeRestoreOldConfig :: FilePath -> IO () -> IO ()
 460 maybeRestoreOldConfig filename io
 461   = io `catch` \e -> do
 462         hPutStrLn stderr (show e)
 463         hPutStr stdout ("\nWARNING: an error was encountered while the new \n"++
 464                           "configuration was being written.  Attempting to \n"++
 465                           "restore the old configuration... ")
 466         renameFile (filename ++ ".old")  filename
 467         hPutStrLn stdout "done."
 468         ioError e
 469
 470 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 471 writeNewConfig filename packages = do
 472   hPutStr stdout "Writing new package config file... "
 473   h <- openFile filename WriteMode
 474   hPutStrLn h (show packages)
 475   hClose h
 476   hPutStrLn stdout "done."
 477
 478 savePackageConfig :: FilePath -> IO ()
 479 savePackageConfig filename = do
 480   hPutStr stdout "Saving old package config file... "
 481     -- mv rather than cp because we've already done an hGetContents
 482     -- on this file so we won't be able to open it for writing
 483     -- unless we move the old one out of the way...
 484   let oldFile = filename ++ ".old"
 485   doesExist <- doesFileExist oldFile  `catch` (\ _ -> return False)
 486   when doesExist (removeFile oldFile `catch` (const $ return ()))
 487   catch (renameFile filename oldFile)
 488         (\ err -> do
 489                 hPutStrLn stderr (unwords [ "Unable to rename "
 490                                           , show filename
 491                                           , " to "
 492                                           , show oldFile
 493                                           ])
 494                 ioError err)
 495   hPutStrLn stdout "done."
 496
 497 -----------------------------------------------------------------------------
 498 -- Sanity-check a new package config, and automatically build GHCi libs
 499 -- if requested.
 500
 501 validatePackageConfig :: InstalledPackageInfo
 502                       -> PackageDBStack
 503                       -> Bool   -- auto-ghc-libs
 504                       -> Bool   -- update
 505                       -> Bool   -- force
 506                       -> IO ()
 507 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 508   checkDuplicates db_stack pkg update
 509   mapM_ (checkDep db_stack force) (depends pkg)
 510   mapM_ (checkDir force) (importDirs pkg)
 511   mapM_ (checkDir force) (libraryDirs pkg)
 512   mapM_ (checkDir force) (includeDirs pkg)
 513   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 514   -- ToDo: check these somehow?
 515   --    extra_libraries :: [String],
 516   --    c_includes      :: [String],
 517
 518
 519 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> IO ()
 520 checkDuplicates db_stack pkg update = do
 521   let
 522         pkgid = package pkg
 523
 524         (_top_db_name, pkgs) : _  = db_stack
 525
 526         pkgs_with_same_name =
 527                 [ p | p <- pkgs, pkgName (package p) == pkgName pkgid]
 528         exposed_pkgs_with_same_name =
 529                 filter exposed pkgs_with_same_name
 530   --
 531   -- Check whether this package id already exists in this DB
 532   --
 533   when (not update && (package pkg `elem` map package pkgs)) $
 534        die ("package " ++ showPackageId pkgid ++ " is already installed")
 535   --
 536   -- if we are exposing this new package, then check that
 537   -- there are no other exposed packages with the same name.
 538   --
 539   when (not update && exposed pkg && not (null exposed_pkgs_with_same_name)) $
 540         die ("trying to register " ++ showPackageId pkgid
 541                   ++ " as exposed, but "
 542                   ++ showPackageId (package (my_head "when" exposed_pkgs_with_same_name))
 543                   ++ " is also exposed.")
 544
 545
 546 checkDir :: Bool -> String -> IO ()
 547 checkDir force d
 548  | "$topdir" `isPrefixOf` d = return ()
 549         -- can't check this, because we don't know what $topdir is
 550  | otherwise = do
 551    there <- doesDirectoryExist d
 552    when (not there)
 553        (dieOrForce force (d ++ " doesn't exist or isn't a directory"))
 554
 555 checkDep :: PackageDBStack -> Bool -> PackageIdentifier -> IO ()
 556 checkDep db_stack force pkgid
 557   | real_version && pkgid `elem` pkgids = return ()
 558   | not real_version && pkgName pkgid `elem` pkg_names = return ()
 559   | otherwise = dieOrForce force ("dependency " ++ showPackageId pkgid
 560                                         ++ " doesn't exist")
 561   where
 562         -- for backwards compat, we treat 0.0 as a special version,
 563         -- and don't check that it actually exists.
 564         real_version = realVersion pkgid
 565
 566         all_pkgs = concat (map snd db_stack)
 567         pkgids = map package all_pkgs
 568         pkg_names = map pkgName pkgids
 569
 570 realVersion :: PackageIdentifier -> Bool
 571 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 572
 573 checkHSLib :: [String] -> Bool -> Bool -> String -> IO ()
 574 checkHSLib dirs auto_ghci_libs force lib = do
 575   let batch_lib_file = "lib" ++ lib ++ ".a"
 576   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 577   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 578         [] -> dieOrForce force ("cannot find " ++ batch_lib_file ++
 579                                  " on library path")
 580         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 581
 582 doesLibExistIn :: String -> String -> IO Bool
 583 doesLibExistIn lib d
 584  | "$topdir" `isPrefixOf` d = return True
 585  | otherwise                = doesFileExist (d ++ '/':lib)
 586
 587 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 588 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 589   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 590   | otherwise  = do
 591       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 592       case [dir | (exists,dir) <- zip bs dirs, exists] of
 593         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 594         (_:_) -> return ()
 595   where
 596     ghci_lib_file = lib ++ ".o"
 597
 598 -- automatically build the GHCi version of a batch lib,
 599 -- using ld --whole-archive.
 600
 601 autoBuildGHCiLib :: String -> String -> String -> IO ()
 602 autoBuildGHCiLib dir batch_file ghci_file = do
 603   let ghci_lib_file  = dir ++ '/':ghci_file
 604       batch_lib_file = dir ++ '/':batch_file
 605   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 606 #if defined(darwin_HOST_OS)
 607   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 608 #elif defined(mingw32_HOST_OS)
 609   execDir <- getExecDir "/bin/ghc-pkg.exe"
 610   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 611 #else
 612   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 613 #endif
 614   when (r /= ExitSuccess) $ exitWith r
 615   hPutStrLn stderr (" done.")
 616
 617 -- -----------------------------------------------------------------------------
 618 -- Updating the DB with the new package.
 619
 620 updatePackageDB
 621         :: PackageDBStack
 622         -> [InstalledPackageInfo]
 623         -> InstalledPackageInfo
 624         -> IO [InstalledPackageInfo]
 625 updatePackageDB db_stack pkgs new_pkg = do
 626   let
 627         -- The input package spec is allowed to give a package dependency
 628         -- without a version number; e.g.
 629         --      depends: base
 630         -- Here, we update these dependencies without version numbers to
 631         -- match the actual versions of the relevant packages installed.
 632         updateDeps p = p{depends = map resolveDep (depends p)}
 633
 634         resolveDep dep_pkgid
 635            | realVersion dep_pkgid  = dep_pkgid
 636            | otherwise              = lookupDep dep_pkgid
 637
 638         lookupDep dep_pkgid
 639            = let
 640                 name = pkgName dep_pkgid
 641              in
 642              case [ pid | p <- concat (map snd db_stack),
 643                           let pid = package p,
 644                           pkgName pid == name ] of
 645                 (pid:_) -> pid          -- Found installed package,
 646                                         -- replete with its version
 647                 []      -> dep_pkgid    -- No installed package; use
 648                                         -- the version-less one
 649
 650         is_exposed = exposed new_pkg
 651         pkgid      = package new_pkg
 652         name       = pkgName pkgid
 653
 654         pkgs' = [ maybe_hide p | p <- pkgs, package p /= pkgid ]
 655
 656         -- When update is on, and we're exposing the new package,
 657         -- we hide any packages with the same name (different versions)
 658         -- in the current DB.  Earlier checks will have failed if
 659         -- update isn't on.
 660         maybe_hide p
 661           | is_exposed && pkgName (package p) == name = p{ exposed = False }
 662           | otherwise = p
 663   --
 664   return (pkgs'++[updateDeps new_pkg])
 665
 666 -- -----------------------------------------------------------------------------
 667 -- Searching for modules
 668
 669 #if not_yet
 670
 671 findModules :: [FilePath] -> IO [String]
 672 findModules paths =
 673   mms <- mapM searchDir paths
 674   return (concat mms)
 675
 676 searchDir path prefix = do
 677   fs <- getDirectoryEntries path `catch` \_ -> return []
 678   searchEntries path prefix fs
 679
 680 searchEntries path prefix [] = return []
 681 searchEntries path prefix (f:fs)
 682   | looks_like_a_module  =  do
 683         ms <- searchEntries path prefix fs
 684         return (prefix `joinModule` f : ms)
 685   | looks_like_a_component  =  do
 686         ms <- searchDir (path `joinFilename` f) (prefix `joinModule` f)
 687         ms' <- searchEntries path prefix fs
 688         return (ms ++ ms')
 689   | otherwise
 690         searchEntries path prefix fs
 691
 692   where
 693         (base,suffix) = splitFileExt f
 694         looks_like_a_module =
 695                 suffix `elem` haskell_suffixes &&
 696                 all okInModuleName base
 697         looks_like_a_component =
 698                 null suffix && all okInModuleName base
 699
 700 okInModuleName c
 701
 702 #endif
 703
 704 -- -----------------------------------------------------------------------------
 705 -- The old command-line syntax, supported for backwards compatibility
 706
 707 data OldFlag
 708   = OF_Config FilePath
 709   | OF_Input FilePath
 710   | OF_List
 711   | OF_ListLocal
 712   | OF_Add Bool {- True => replace existing info -}
 713   | OF_Remove String | OF_Show String
 714   | OF_Field String | OF_AutoGHCiLibs | OF_Force
 715   | OF_DefinedName String String
 716   | OF_GlobalConfig FilePath
 717   deriving (Eq)
 718
 719 isAction :: OldFlag -> Bool
 720 isAction OF_Config{}        = False
 721 isAction OF_Field{}         = False
 722 isAction OF_Input{}         = False
 723 isAction OF_AutoGHCiLibs{}  = False
 724 isAction OF_Force{}         = False
 725 isAction OF_DefinedName{}   = False
 726 isAction OF_GlobalConfig{}  = False
 727 isAction _                  = True
 728
 729 oldFlags :: [OptDescr OldFlag]
 730 oldFlags = [
 731   Option ['f'] ["config-file"] (ReqArg OF_Config "FILE")
 732         "use the specified package config file",
 733   Option ['l'] ["list-packages"] (NoArg OF_List)
 734         "list packages in all config files",
 735   Option ['L'] ["list-local-packages"] (NoArg OF_ListLocal)
 736         "list packages in the specified config file",
 737   Option ['a'] ["add-package"] (NoArg (OF_Add False))
 738         "add a new package",
 739   Option ['u'] ["update-package"] (NoArg (OF_Add True))
 740         "update package with new configuration",
 741   Option ['i'] ["input-file"] (ReqArg OF_Input "FILE")
 742         "read new package info from specified file",
 743   Option ['s'] ["show-package"] (ReqArg OF_Show "NAME")
 744         "show the configuration for package NAME",
 745   Option [] ["field"] (ReqArg OF_Field "FIELD")
 746         "(with --show-package) Show field FIELD only",
 747   Option [] ["force"] (NoArg OF_Force)
 748         "ignore missing directories/libraries",
 749   Option ['r'] ["remove-package"] (ReqArg OF_Remove "NAME")
 750         "remove an installed package",
 751   Option ['g'] ["auto-ghci-libs"] (NoArg OF_AutoGHCiLibs)
 752         "automatically build libs for GHCi (with -a)",
 753   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 754         "define NAME as VALUE",
 755   Option [] ["global-conf"] (ReqArg OF_GlobalConfig "FILE")
 756         "location of the global package config"
 757   ]
 758  where
 759   toDefined str =
 760     case break (=='=') str of
 761       (nm,[]) -> OF_DefinedName nm []
 762       (nm,_:val) -> OF_DefinedName nm val
 763
 764 oldRunit :: [OldFlag] -> IO ()
 765 oldRunit clis = do
 766   let config_flags = [ f | Just f <- map conv clis ]
 767
 768       conv (OF_GlobalConfig f) = Just (FlagGlobalConfig f)
 769       conv (OF_Config f)       = Just (FlagConfig f)
 770       conv _                   = Nothing
 771
 772   db_names <- getPkgDatabases config_flags
 773   db_stack <- mapM readParseDatabase db_names
 774
 775   let fields = [ f | OF_Field f <- clis ]
 776
 777   let auto_ghci_libs = any isAuto clis
 778          where isAuto OF_AutoGHCiLibs = True; isAuto _ = False
 779       input_file = my_head "inp" ([ f | (OF_Input f) <- clis] ++ ["-"])
 780
 781       force = OF_Force `elem` clis
 782
 783       defines = [ (nm,val) | OF_DefinedName nm val <- clis ]
 784
 785   case [ c | c <- clis, isAction c ] of
 786     [ OF_List ]      -> listPackages db_stack
 787     [ OF_ListLocal ] -> listPackages db_stack
 788     [ OF_Add upd ]   -> registerPackage input_file defines db_stack
 789                                 auto_ghci_libs upd force
 790     [ OF_Remove p ]  -> unregisterPackage (pkgNameToId p) db_stack
 791     [ OF_Show p ]
 792         | null fields -> describePackage db_stack (pkgNameToId p)
 793         | otherwise   -> mapM_ (describeField db_stack (pkgNameToId p)) fields
 794     _            -> do prog <- getProgramName
 795                        die (usageInfo (usageHeader prog) flags)
 796
 797 my_head s [] = error s
 798 my_head s (x:xs) = x
 799
 800 -- ---------------------------------------------------------------------------
 801
 802 #ifdef OLD_STUFF
 803 -- ToDo: reinstate
 804 expandEnvVars :: PackageConfig -> [(String, String)]
 805         -> Bool -> IO PackageConfig
 806 expandEnvVars pkg defines force = do
 807    -- permit _all_ strings to contain ${..} environment variable references,
 808    -- arguably too flexible.
 809   nm       <- expandString  (name pkg)
 810   imp_dirs <- expandStrings (import_dirs pkg)
 811   src_dirs <- expandStrings (source_dirs pkg)
 812   lib_dirs <- expandStrings (library_dirs pkg)
 813   hs_libs  <- expandStrings (hs_libraries pkg)
 814   ex_libs  <- expandStrings (extra_libraries pkg)
 815   inc_dirs <- expandStrings (include_dirs pkg)
 816   c_incs   <- expandStrings (c_includes pkg)
 817   p_deps   <- expandStrings (package_deps pkg)
 818   e_g_opts <- expandStrings (extra_ghc_opts pkg)
 819   e_c_opts <- expandStrings (extra_cc_opts pkg)
 820   e_l_opts <- expandStrings (extra_ld_opts pkg)
 821   f_dirs   <- expandStrings (framework_dirs pkg)
 822   e_frames <- expandStrings (extra_frameworks pkg)
 823   return (pkg { name            = nm
 824               , import_dirs     = imp_dirs
 825               , source_dirs     = src_dirs
 826               , library_dirs    = lib_dirs
 827               , hs_libraries    = hs_libs
 828               , extra_libraries = ex_libs
 829               , include_dirs    = inc_dirs
 830               , c_includes      = c_incs
 831               , package_deps    = p_deps
 832               , extra_ghc_opts  = e_g_opts
 833               , extra_cc_opts   = e_c_opts
 834               , extra_ld_opts   = e_l_opts
 835               , framework_dirs  = f_dirs
 836               , extra_frameworks= e_frames
 837               })
 838   where
 839    expandStrings :: [String] -> IO [String]
 840    expandStrings = liftM concat . mapM expandSpecial
 841
 842    -- Permit substitutions for list-valued variables (but only when
 843    -- they occur alone), e.g., package_deps["${deps}"] where env var
 844    -- (say) 'deps' is "base,haskell98,network"
 845    expandSpecial :: String -> IO [String]
 846    expandSpecial str =
 847       let expand f = liftM f $ expandString str
 848       in case splitString str of
 849          [Var _] -> expand (wordsBy (== ','))
 850          _ -> expand (\x -> [x])
 851
 852    expandString :: String -> IO String
 853    expandString = liftM concat . mapM expandElem . splitString
 854
 855    expandElem :: Elem -> IO String
 856    expandElem (String s) = return s
 857    expandElem (Var v)    = lookupEnvVar v
 858
 859    lookupEnvVar :: String -> IO String
 860    lookupEnvVar nm =
 861      case lookup nm defines of
 862        Just x | not (null x) -> return x
 863        _      ->
 864         catch (System.getEnv nm)
 865            (\ _ -> do dieOrForce force ("Unable to expand variable " ++
 866                                         show nm)
 867                       return "")
 868
 869 data Elem = String String | Var String
 870
 871 splitString :: String -> [Elem]
 872 splitString "" = []
 873 splitString str =
 874    case break (== '$') str of
 875       (pre, _:'{':xs) ->
 876          case span (/= '}') xs of
 877             (var, _:suf) ->
 878                (if null pre then id else (String pre :)) (Var var : splitString suf)
 879             _ -> [String str]   -- no closing brace
 880       _ -> [String str]   -- no dollar/opening brace combo
 881
 882 -- wordsBy isSpace == words
 883 wordsBy :: (Char -> Bool) -> String -> [String]
 884 wordsBy p s = case dropWhile p s of
 885   "" -> []
 886   s' -> w : wordsBy p s'' where (w,s'') = break p s'
 887 #endif
 888
 889 -----------------------------------------------------------------------------
 890
 891 getProgramName :: IO String
 892 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
 893    where str `withoutSuffix` suff
 894             | suff `isSuffixOf` str = take (length str - length suff) str
 895             | otherwise             = str
 896
 897 bye :: String -> IO a
 898 bye s = putStr s >> exitWith ExitSuccess
 899
 900 die :: String -> IO a
 901 die s = do
 902   hFlush stdout
 903   prog <- getProgramName
 904   hPutStrLn stderr (prog ++ ": " ++ s)
 905   exitWith (ExitFailure 1)
 906
 907 dieOrForce :: Bool -> String -> IO ()
 908 dieOrForce force s
 909   | force     = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
 910   | otherwise = die s
 911
 912
 913 -----------------------------------------
 914 --      Cut and pasted from ghc/compiler/SysTools
 915
 916 #if defined(mingw32_HOST_OS)
 917 subst a b ls = map (\ x -> if x == a then b else x) ls
 918 unDosifyPath xs = subst '\\' '/' xs
 919
 920 getExecDir :: String -> IO (Maybe String)
 921 -- (getExecDir cmd) returns the directory in which the current
 922 --                  executable, which should be called 'cmd', is running
 923 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
 924 -- you'll get "/a/b/c" back as the result
 925 getExecDir cmd
 926   = allocaArray len $ \buf -> do
 927         ret <- getModuleFileName nullPtr buf len
 928         if ret == 0 then return Nothing
 929                     else do s <- peekCString buf
 930                             return (Just (reverse (drop (length cmd)
 931                                                         (reverse (unDosifyPath s)))))
 932   where
 933     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
 934
 935 foreign import stdcall unsafe  "GetModuleFileNameA"
 936   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
 937 #else
 938 getExecDir :: String -> IO (Maybe String)
 939 getExecDir _ = return Nothing
 940 #endif
 941
 942 -- -----------------------------------------------------------------------------
 943 -- FilePath utils
 944
 945 -- | The 'joinFileName' function is the opposite of 'splitFileName'.
 946 -- It joins directory and file names to form a complete file path.
 947 --
 948 -- The general rule is:
 949 --
 950 -- > dir `joinFileName` basename == path
 951 -- >   where
 952 -- >     (dir,basename) = splitFileName path
 953 --
 954 -- There might be an exceptions to the rule but in any case the
 955 -- reconstructed path will refer to the same object (file or directory).
 956 -- An example exception is that on Windows some slashes might be converted
 957 -- to backslashes.
 958 joinFileName :: String -> String -> FilePath
 959 joinFileName ""  fname = fname
 960 joinFileName "." fname = fname
 961 joinFileName dir ""    = dir
 962 joinFileName dir fname
 963   | isPathSeparator (last dir) = dir++fname
 964   | otherwise                  = dir++pathSeparator:fname
 965
 966 -- | Checks whether the character is a valid path separator for the host
 967 -- platform. The valid character is a 'pathSeparator' but since the Windows
 968 -- operating system also accepts a slash (\"\/\") since DOS 2, the function
 969 -- checks for it on this platform, too.
 970 isPathSeparator :: Char -> Bool
 971 isPathSeparator ch = ch == pathSeparator || ch == '/'
 972
 973 -- | Provides a platform-specific character used to separate directory levels in
 974 -- a path string that reflects a hierarchical file system organization. The
 975 -- separator is a slash (@\"\/\"@) on Unix and Macintosh, and a backslash
 976 -- (@\"\\\"@) on the Windows operating system.
 977 pathSeparator :: Char
 978 #ifdef mingw32_HOST_OS
 979 pathSeparator = '\\'
 980 #else
 981 pathSeparator = '/'
 982 #endif