rts/gmp/mpn/hppa/hppa1_1/pa7100/lshift.s

   1 ; HP-PA  __gmpn_lshift --
   2 ; This is optimized for the PA7100, where is runs at 3.25 cycles/limb
   3
   4 ; Copyright (C) 1992, 1994, 2000 Free Software Foundation, Inc.
   5
   6 ; This file is part of the GNU MP Library.
   7
   8 ; The GNU MP Library is free software; you can redistribute it and/or modify
   9 ; it under the terms of the GNU Lesser General Public License as published by
  10 ; the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ; option) any later version.
  12
  13 ; The GNU MP Library is distributed in the hope that it will be useful, but
  14 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ; License for more details.
  17
  18 ; You should have received a copy of the GNU Lesser General Public License
  19 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ; MA 02111-1307, USA.
  22
  23
  24 ; INPUT PARAMETERS
  25 ; res_ptr       gr26
  26 ; s_ptr         gr25
  27 ; size          gr24
  28 ; cnt           gr23
  29
  30         .code
  31         .export         __gmpn_lshift
  32 __gmpn_lshift
  33         .proc
  34         .callinfo       frame=64,no_calls
  35         .entry
  36
  37         sh2add          %r24,%r25,%r25
  38         sh2add          %r24,%r26,%r26
  39         ldws,mb         -4(0,%r25),%r22
  40         subi            32,%r23,%r1
  41         mtsar           %r1
  42         addib,=         -1,%r24,L$0004
  43         vshd            %r0,%r22,%r28           ; compute carry out limb
  44         ldws,mb         -4(0,%r25),%r29
  45         addib,<=        -5,%r24,L$rest
  46         vshd            %r22,%r29,%r20
  47
  48 L$loop  ldws,mb         -4(0,%r25),%r22
  49         stws,mb         %r20,-4(0,%r26)
  50         vshd            %r29,%r22,%r20
  51         ldws,mb         -4(0,%r25),%r29
  52         stws,mb         %r20,-4(0,%r26)
  53         vshd            %r22,%r29,%r20
  54         ldws,mb         -4(0,%r25),%r22
  55         stws,mb         %r20,-4(0,%r26)
  56         vshd            %r29,%r22,%r20
  57         ldws,mb         -4(0,%r25),%r29
  58         stws,mb         %r20,-4(0,%r26)
  59         addib,>         -4,%r24,L$loop
  60         vshd            %r22,%r29,%r20
  61
  62 L$rest  addib,=         4,%r24,L$end1
  63         nop
  64 L$eloop ldws,mb         -4(0,%r25),%r22
  65         stws,mb         %r20,-4(0,%r26)
  66         addib,<=        -1,%r24,L$end2
  67         vshd            %r29,%r22,%r20
  68         ldws,mb         -4(0,%r25),%r29
  69         stws,mb         %r20,-4(0,%r26)
  70         addib,>         -1,%r24,L$eloop
  71         vshd            %r22,%r29,%r20
  72
  73 L$end1  stws,mb         %r20,-4(0,%r26)
  74         vshd            %r29,%r0,%r20
  75         bv              0(%r2)
  76         stw             %r20,-4(0,%r26)
  77 L$end2  stws,mb         %r20,-4(0,%r26)
  78 L$0004  vshd            %r22,%r0,%r20
  79         bv              0(%r2)
  80         stw             %r20,-4(0,%r26)
  81
  82         .exit
  83         .procend