sync-all

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Cwd;
   5
   6 # Usage:
   7 #
   8 # ./sync-all [-q] [-s] [--ignore-failure] [-r repo]
   9 #            [--nofib] [--testsuite] [--checked-out] cmd [git flags]
  10 #
  11 # Applies the command "cmd" to each repository in the tree.
  12 # sync-all will try to do the right thing for both git and darcs repositories.
  13 #
  14 # e.g.
  15 #      ./sync-all -r http://darcs.haskell.org/ghc get
  16 #          To get any repos which do not exist in the local tree
  17 #
  18 #      ./sync-all pull
  19 #          To pull everything from the default repos
  20 #
  21 # -------------- Flags -------------------
  22 #   -q says to be quite, and -s to be silent.
  23 #
  24 #   --ignore-failure says to ignore errors and move on to the next repository
  25 #
  26 #   -r repo says to use repo as the location of package repositories
  27 #
  28 #   --checked-out says that the remote repo is in checked-out layout, as
  29 #   opposed to the layout used for the main repo.  By default a repo on
  30 #   the local filesystem is assumed to be checked-out, and repos accessed
  31 #   via HTTP or SSH are assumed to be in the main repo layout; use
  32 #   --checked-out to override the latter.
  33 #
  34 #   --nofib, --testsuite also get the nofib and testsuite repos respectively
  35 #
  36 # ------------ Which repos to use -------------
  37 # sync-all uses the following algorithm to decide which remote repos to use
  38 #
  39 #  It always computes the remote repos from a single base, $repo_base
  40 #  How is $repo_base set?
  41 #    If you say "-r repo", then that's $repo_base
  42 #    otherwise $repo_base is set by asking git where the ghc repo came
  43 #    from, and removing the last component (e.g. /ghc.git/ of /ghc/).
  44 #
  45 #  Then sync-all iterates over the package found in the file
  46 #  ./packages; see that file for a description of the contents.
  47 #
  48 #    If $repo_base looks like a local filesystem path, or if you give
  49 #    the --checked-out flag, sync-all works on repos of form
  50 #          $repo_base/<local-path>
  51 #    otherwise sync-all works on repos of form
  52 #          $repo_base/<remote-path>
  53 #    This logic lets you say
  54 #      both    sync-all -r http://darcs.haskell.org/ghc-6.12 pull
  55 #      and     sync-all -r ../HEAD pull
  56 #    The latter is called a "checked-out tree".
  57
  58 # NB: sync-all *ignores* the defaultrepo of all repos other than the
  59 # root one.  So the remote repos must be laid out in one of the two
  60 # formats given by <local-path> and <remote-path> in the file 'packages'.
  61
  62 $| = 1; # autoflush stdout after each print, to avoid output after die
  63
  64 my $defaultrepo;
  65 my @packages;
  66 my $verbose = 2;
  67 my $ignore_failure = 0;
  68 my $want_remote_repo = 0;
  69 my $checked_out_flag = 0;
  70 my $get_mode;
  71
  72 # Flags specific to a particular command
  73 my $local_repo_unnecessary = 0;
  74
  75 my %tags;
  76
  77 # Figure out where to get the other repositories from.
  78 sub getrepo {
  79     my $basedir = ".";
  80     my $repo;
  81
  82     if (defined($defaultrepo)) {
  83         $repo = $defaultrepo;
  84         chomp $repo;
  85     } else {
  86         # Figure out where to get the other repositories from,
  87         # based on where this GHC repo came from.
  88         my $branch = `git branch | grep "\* " | sed "s/^\* //"`; chomp $branch;
  89         my $remote = `git config branch.$branch.remote`;         chomp $remote;
  90         $repo = `git config remote.$remote.url`;       chomp $repo;
  91     }
  92
  93     my $repo_base;
  94     my $checked_out_tree;
  95
  96     if ($repo =~ /^...*:/) {
  97         # HTTP or SSH
  98         # Above regex says "at least two chars before the :", to avoid
  99         # catching Win32 drives ("C:\").
 100         $repo_base = $repo;
 101
 102         # --checked-out is needed if you want to use a checked-out repo
 103         # over SSH or HTTP
 104         if ($checked_out_flag) {
 105             $checked_out_tree = 1;
 106         } else {
 107             $checked_out_tree = 0;
 108         }
 109
 110         # Don't drop the last part of the path if specified with -r, as
 111         # it expects repos of the form:
 112         #
 113         #   http://darcs.haskell.org
 114         #
 115         # rather than
 116         #
 117         #   http://darcs.haskell.org/ghc
 118         #
 119         if (!$defaultrepo) {
 120             $repo_base =~ s#/[^/]+/?$##;
 121         }
 122     }
 123     elsif ($repo =~ /^\/|\.\.\/|.:(\/|\\)/) {
 124         # Local filesystem, either absolute or relative path
 125         # (assumes a checked-out tree):
 126         $repo_base = $repo;
 127         $checked_out_tree = 1;
 128     }
 129     else {
 130         die "Couldn't work out repo";
 131     }
 132
 133     return $repo_base, $checked_out_tree;
 134 }
 135
 136 sub parsePackages {
 137     my @repos;
 138     my $lineNum;
 139
 140     open IN, "< packages" or die "Can't open packages file";
 141     @repos = <IN>;
 142     close IN;
 143
 144     @packages = ();
 145     $lineNum = 0;
 146     foreach (@repos) {
 147         chomp;
 148         $lineNum++;
 149         if (/^([^# ]+) +([^ ]+) +([^ ]+) +([^ ]+) +([^ ]+)$/) {
 150             my %line;
 151             $line{"localpath"}  = $1;
 152             $line{"tag"}        = $2;
 153             $line{"remotepath"} = $3;
 154             $line{"vcs"}        = $4;
 155             $line{"upstream"}   = $5;
 156             push @packages, \%line;
 157         }
 158         elsif (! /^(#.*)?$/) {
 159             die "Bad content on line $lineNum of packages file: $_";
 160         }
 161     }
 162 }
 163
 164 sub message {
 165     if ($verbose >= 2) {
 166         print "@_\n";
 167     }
 168 }
 169
 170 sub warning {
 171     if ($verbose >= 1) {
 172         print "warning: @_\n";
 173     }
 174 }
 175
 176 sub scm {
 177     my $dir = shift;
 178     my $scm = shift;
 179     my $pwd;
 180
 181     if ($dir eq '.') {
 182         message "== running $scm @_";
 183     } else {
 184         message "== $dir: running $scm @_";
 185         $pwd = getcwd();
 186         chdir($dir);
 187     }
 188
 189     system ($scm, @_) == 0
 190         or $ignore_failure
 191         or die "$scm failed: $?";
 192
 193     if ($dir ne '.') {
 194         chdir($pwd);
 195     }
 196 }
 197
 198 sub repoexists {
 199     my ($scm, $localpath) = @_;
 200
 201     if ($scm eq "darcs") {
 202         -d "$localpath/_darcs";
 203     }
 204     else {
 205         -d "$localpath/.git";
 206     }
 207 }
 208
 209 sub scmall {
 210     my $command = shift;
 211
 212     my $localpath;
 213     my $tag;
 214     my $remotepath;
 215     my $scm;
 216     my $upstream;
 217     my $line;
 218     my $branch_name;
 219     my $subcommand;
 220
 221     my $path;
 222     my $wd_before = getcwd;
 223
 224     my @scm_args;
 225
 226     my $pwd;
 227
 228     my ($repo_base, $checked_out_tree) = getrepo();
 229
 230     parsePackages;
 231
 232     if ($command =~ /^remote$/) {
 233         if (@_ < 2) {
 234             help();
 235         }
 236         $subcommand = shift;
 237         $branch_name = shift;
 238         if ($subcommand ne 'add' && $subcommand ne 'rm') {
 239             help();
 240         }
 241     } elsif ($command eq 'new' || $command eq 'fetch') {
 242         if (@_ < 1) {
 243             $branch_name = 'origin';
 244         } else {
 245             $branch_name = shift;
 246         }
 247     }
 248
 249     for $line (@packages) {
 250
 251             $localpath  = $$line{"localpath"};
 252             $tag        = $$line{"tag"};
 253             $remotepath = $$line{"remotepath"};
 254             $scm        = $$line{"vcs"};
 255             $upstream   = $$line{"upstream"};
 256
 257             # Check the SCM is OK as early as possible
 258             die "Unknown SCM: $scm" if (($scm ne "darcs") and ($scm ne "git"));
 259
 260             # Work out the path for this package in the repo we pulled from
 261             if ($checked_out_tree) {
 262                 $path = "$repo_base/$localpath";
 263             }
 264             else {
 265                 $path = "$repo_base/$remotepath";
 266             }
 267
 268             # Work out the arguments we should give to the SCM
 269             if ($command =~ /^(?:w|wh|wha|what|whats|whatsn|whatsne|whatsnew)$/) {
 270                 @scm_args = (($scm eq "darcs" and "whatsnew")
 271                           or ($scm eq "git" and "status"));
 272
 273                 # Hack around 'darcs whatsnew' failing if there are no changes
 274                 $ignore_failure = 1;
 275             }
 276             elsif ($command =~ /^(?:pus|push)$/) {
 277                 @scm_args = "push";
 278                 $want_remote_repo = 1;
 279             }
 280             elsif ($command =~ /^(?:pul|pull)$/) {
 281                 @scm_args = "pull";
 282                 $want_remote_repo = 1;
 283                 # Q: should we append the -a argument for darcs repos?
 284             }
 285             elsif ($command =~ /^(?:g|ge|get)$/) {
 286                 # Skip any repositories we have not included the tag for
 287                 if (not defined($tags{$tag})) {
 288                     next;
 289                 }
 290
 291                 if (-d $localpath) {
 292                     warning("$localpath already present; omitting") if $localpath ne ".";
 293                     next;
 294                 }
 295
 296                 # The first time round the loop, default the get-mode
 297                 if ($scm eq "darcs" && not defined($get_mode)) {
 298                     warning("adding --partial, to override use --complete");
 299                     $get_mode = "--partial";
 300                 }
 301
 302                 # The only command that doesn't need a repo
 303                 $local_repo_unnecessary = 1;
 304
 305                 if ($scm eq "darcs") {
 306                     # Note: we can only use the get-mode with darcs for now
 307                     @scm_args = ("get", $get_mode, $path, $localpath);
 308                 }
 309                 else {
 310                     @scm_args = ("clone", $path, $localpath);
 311                 }
 312             }
 313             elsif ($command =~ /^(?:s|se|sen|send)$/) {
 314                 @scm_args = (($scm eq "darcs" and "send")
 315                           or ($scm eq "git" and "send-email"));
 316                 $want_remote_repo = 1;
 317             }
 318             elsif ($command =~ /^set-origin$/) {
 319                 @scm_args = ("remote", "set-url", "origin", $path);
 320             }
 321             elsif ($command =~ /^set-push$/) {
 322                 @scm_args = ("remote", "set-url", "--push", "origin", $path);
 323             }
 324             elsif ($command =~ /^fetch$/) {
 325                 @scm_args = ("fetch", "$branch_name");
 326             }
 327             elsif ($command =~ /^new$/) {
 328                 @scm_args = ("log", "$branch_name..");
 329             }
 330             elsif ($command =~ /^remote$/) {
 331                 if ($subcommand eq 'add') {
 332                     @scm_args = ("remote", "add", $branch_name, $path);
 333                 } elsif ($subcommand eq 'rm') {
 334                     @scm_args = ("remote", "rm", $branch_name);
 335                 }
 336             }
 337             else {
 338                 die "Unknown command: $command";
 339             }
 340
 341             # Actually execute the command
 342             if (repoexists ($scm, $localpath)) {
 343                 if ($want_remote_repo) {
 344                     if ($scm eq "darcs") {
 345                         scm (".", $scm, @scm_args, @_, "--repodir=$localpath", $path);
 346                     } else {
 347                         # git pull doesn't like to be used with --work-dir
 348                         # I couldn't find an alternative to chdir() here
 349                         scm ($localpath, $scm, @scm_args, @_, $path, "master");
 350                     }
 351                 } else {
 352                     # git status *must* be used with --work-dir, if we don't chdir() to the dir
 353                     scm ($localpath, $scm, @scm_args, @_);
 354                 }
 355             }
 356             elsif ($local_repo_unnecessary) {
 357                 # Don't bother to change directory in this case
 358                 scm (".", $scm, @scm_args, @_);
 359             }
 360             elsif ($tag eq "") {
 361                 message "== Required repo $localpath is missing! Skipping";
 362             }
 363             else {
 364                 message "== $localpath repo not present; skipping";
 365             }
 366     }
 367 }
 368
 369
 370 sub help()
 371 {
 372         # Get the built in help
 373         my $help = <<END;
 374 What do you want to do?
 375 Supported commands:
 376
 377  * whatsnew
 378  * push
 379  * pull
 380  * get, with options:
 381   * --<package-tag>
 382   * --complete
 383   * --partial
 384  * fetch
 385  * send
 386  * set-origin
 387  * set-push
 388  * new
 389  * remote add <branch-name>
 390  * remote rm <branch-name>
 391
 392 Available package-tags are:
 393 END
 394
 395         # Collect all the tags in the packages file
 396         my %available_tags;
 397         open IN, "< packages" or die "Can't open packages file";
 398         while (<IN>) {
 399             chomp;
 400             if (/^([^# ]+) +(?:([^ ]+) +)?([^ ]+) +([^ ]+)/) {
 401                 if (defined($2) && $2 ne "-") {
 402                     $available_tags{$2} = 1;
 403                 }
 404             }
 405             elsif (! /^(#.*)?$/) {
 406                 die "Bad line: $_";
 407             }
 408         }
 409         close IN;
 410
 411         # Show those tags and the help text
 412         my @available_tags = keys %available_tags;
 413         print "$help@available_tags\n";
 414         exit 1;
 415 }
 416
 417 sub main {
 418     if (! -d ".git" || ! -d "compiler") {
 419         die "error: sync-all must be run from the top level of the ghc tree."
 420     }
 421
 422     $tags{"-"} = 1;
 423     $tags{"dph"} = 1;
 424
 425     while ($#_ ne -1) {
 426         my $arg = shift;
 427         # We handle -q here as well as lower down as we need to skip over it
 428         # if it comes before the source-control command
 429         if ($arg eq "-q") {
 430             $verbose = 1;
 431         }
 432         elsif ($arg eq "-s") {
 433             $verbose = 0;
 434         }
 435         elsif ($arg eq "-r") {
 436             $defaultrepo = shift;
 437         }
 438         elsif ($arg eq "--ignore-failure") {
 439             $ignore_failure = 1;
 440         }
 441         elsif ($arg eq "--complete" || $arg eq "--partial") {
 442             $get_mode = $arg;
 443         }
 444         # Use --checked-out if the remote repos are a checked-out tree,
 445         # rather than the master trees.
 446         elsif ($arg eq "--checked-out") {
 447             $checked_out_flag = 1;
 448         }
 449         # --<tag> says we grab the libs tagged 'tag' with
 450         # 'get'. It has no effect on the other commands.
 451         elsif ($arg =~ m/^--/) {
 452             $arg =~ s/^--//;
 453             $tags{$arg} = 1;
 454         }
 455         else {
 456             unshift @_, $arg;
 457             if (grep /^-q$/, @_) {
 458                 $verbose = 1;
 459             }
 460             last;
 461         }
 462     }
 463
 464     if ($#_ eq -1) {
 465         help();
 466     }
 467     else {
 468         # Give the command and rest of the arguments to the main loop
 469         scmall @_;
 470     }
 471 }
 472
 473 main(@ARGV);
 474