utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 --      - validate modules
  12 --      - expanding of variables in new-style package conf
  13 --      - version manipulation (checking whether old version exists,
  14 --        hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version  ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils  ( showError )
  22 import Distribution.Package
  23 import Distribution.Version
  24 import Compat.Directory         ( getAppUserDataDirectory, createDirectoryIfMissing )
  25 import Compat.RawSystem         ( rawSystem )
  26
  27 import Prelude
  28
  29 #include "../../includes/ghcconfig.h"
  30
  31 #if __GLASGOW_HASKELL__ >= 504
  32 import System.Console.GetOpt
  33 import Text.PrettyPrint
  34 import qualified Control.Exception as Exception
  35 import Data.Maybe
  36 #else
  37 import GetOpt
  38 import Pretty
  39 import qualified Exception
  40 import Maybe
  41 #endif
  42
  43 import Data.Char        ( isSpace )
  44 import Monad
  45 import Directory
  46 import System   ( getArgs, getProgName, getEnv,
  47                   exitWith, ExitCode(..)
  48                 )
  49 import System.IO
  50 #if __GLASGOW_HASKELL__ >= 600
  51 import System.IO.Error (try)
  52 #else
  53 import System.IO (try)
  54 #endif
  55 import Data.List ( isPrefixOf, isSuffixOf, intersperse, sortBy )
  56
  57 #ifdef mingw32_HOST_OS
  58 import Foreign
  59
  60 #if __GLASGOW_HASKELL__ >= 504
  61 import Foreign.C.String
  62 #else
  63 import CString
  64 #endif
  65 #endif
  66
  67 import IO ( isPermissionError, isDoesNotExistError )
  68
  69 -- -----------------------------------------------------------------------------
  70 -- Entry point
  71
  72 main :: IO ()
  73 main = do
  74   args <- getArgs
  75
  76   case getOpt Permute flags args of
  77         (cli,_,[]) | FlagHelp `elem` cli -> do
  78            prog <- getProgramName
  79            bye (usageInfo (usageHeader prog) flags)
  80         (cli,_,[]) | FlagVersion `elem` cli ->
  81            bye ourCopyright
  82         (cli,nonopts,[]) ->
  83            runit cli nonopts
  84         (_,_,errors) -> tryOldCmdLine errors args
  85
  86 -- If the new command-line syntax fails, then we try the old.  If that
  87 -- fails too, then we output the original errors and the new syntax
  88 -- (so the old syntax is still available, but hidden).
  89 tryOldCmdLine :: [String] -> [String] -> IO ()
  90 tryOldCmdLine errors args = do
  91   case getOpt Permute oldFlags args of
  92         (cli@(_:_),[],[]) ->
  93            oldRunit cli
  94         _failed -> do
  95            prog <- getProgramName
  96            die (concat errors ++ usageInfo (usageHeader prog) flags)
  97
  98 -- -----------------------------------------------------------------------------
  99 -- Command-line syntax
 100
 101 data Flag
 102   = FlagUser
 103   | FlagGlobal
 104   | FlagHelp
 105   | FlagVersion
 106   | FlagConfig  FilePath
 107   | FlagGlobalConfig FilePath
 108   | FlagForce
 109   | FlagForceFiles
 110   | FlagAutoGHCiLibs
 111   | FlagDefinedName String String
 112   | FlagSimpleOutput
 113   deriving Eq
 114
 115 flags :: [OptDescr Flag]
 116 flags = [
 117   Option [] ["user"] (NoArg FlagUser)
 118         "use the current user's package database",
 119   Option [] ["global"] (NoArg FlagGlobal)
 120         "(default) use the global package database",
 121   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 122         "act upon specified package config file (only)",
 123   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 124         "location of the global package config",
 125   Option [] ["force"] (NoArg FlagForce)
 126         "ignore missing dependencies, directories, and libraries",
 127   Option [] ["force-files"] (NoArg FlagForceFiles)
 128         "ignore missing directories and libraries only",
 129   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 130         "automatically build libs for GHCi (with register)",
 131   Option ['?'] ["help"] (NoArg FlagHelp)
 132         "display this help and exit",
 133   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 134         "define NAME as VALUE",
 135   Option ['V'] ["version"] (NoArg FlagVersion)
 136         "output version information and exit",
 137   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 138         "print output in easy-to-parse format for some commands"
 139   ]
 140  where
 141   toDefined str =
 142     case break (=='=') str of
 143       (nm,[])    -> FlagDefinedName nm []
 144       (nm,_:val) -> FlagDefinedName nm val
 145
 146 ourCopyright :: String
 147 ourCopyright = "GHC package manager version " ++ version ++ "\n"
 148
 149 usageHeader :: String -> String
 150 usageHeader prog = substProg prog $
 151   "Usage:\n" ++
 152   "  $p register {filename | -}\n" ++
 153   "    Register the package using the specified installed package\n" ++
 154   "    description. The syntax for the latter is given in the $p\n" ++
 155   "    documentation.\n" ++
 156   "\n" ++
 157   "  $p update {filename | -}\n" ++
 158   "    Register the package, overwriting any other package with the\n" ++
 159   "    same name.\n" ++
 160   "\n" ++
 161   "  $p unregister {pkg-id}\n" ++
 162   "    Unregister the specified package.\n" ++
 163   "\n" ++
 164   "  $p expose {pkg-id}\n" ++
 165   "    Expose the specified package.\n" ++
 166   "\n" ++
 167   "  $p hide {pkg-id}\n" ++
 168   "    Hide the specified package.\n" ++
 169   "\n" ++
 170   "  $p list [pkg]\n" ++
 171   "    List registered packages in the global database, and also the\n" ++
 172   "    user database if --user is given. If a package name is given\n" ++
 173   "    all the registered versions will be listed in ascending order.\n" ++
 174   "    Accepts the --simple-output flag.\n" ++
 175   "\n" ++
 176   "  $p latest pkg\n" ++
 177   "    Prints the highest registered version of a package.\n" ++
 178   "\n" ++
 179   "  $p check\n" ++
 180   "    Check the consistency of package depenencies and list broken packages.\n" ++
 181   "    Accepts the --simple-output flag.\n" ++
 182   "\n" ++
 183   "  $p describe {pkg-id}\n" ++
 184   "    Give the registered description for the specified package. The\n" ++
 185   "    description is returned in precisely the syntax required by $p\n" ++
 186   "    register.\n" ++
 187   "\n" ++
 188   "  $p field {pkg-id} {field}\n" ++
 189   "    Extract the specified field of the package description for the\n" ++
 190   "    specified package.\n" ++
 191   "\n" ++
 192   " The following optional flags are also accepted:\n"
 193
 194 substProg :: String -> String -> String
 195 substProg _ [] = []
 196 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 197 substProg prog (c:xs) = c : substProg prog xs
 198
 199 -- -----------------------------------------------------------------------------
 200 -- Do the business
 201
 202 data Force = ForceAll | ForceFiles | NoForce
 203
 204 runit :: [Flag] -> [String] -> IO ()
 205 runit cli nonopts = do
 206   prog <- getProgramName
 207   let
 208         force
 209           | FlagForce `elem` cli        = ForceAll
 210           | FlagForceFiles `elem` cli   = ForceFiles
 211           | otherwise                   = NoForce
 212         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 213         defines = [ (nm,val) | FlagDefinedName nm val <- cli ]
 214   --
 215   -- first, parse the command
 216   case nonopts of
 217     ["register", filename] ->
 218         registerPackage filename defines cli auto_ghci_libs False force
 219     ["update", filename] ->
 220         registerPackage filename defines cli auto_ghci_libs True force
 221     ["unregister", pkgid_str] -> do
 222         pkgid <- readGlobPkgId pkgid_str
 223         unregisterPackage pkgid cli
 224     ["expose", pkgid_str] -> do
 225         pkgid <- readGlobPkgId pkgid_str
 226         exposePackage pkgid cli
 227     ["hide",   pkgid_str] -> do
 228         pkgid <- readGlobPkgId pkgid_str
 229         hidePackage pkgid cli
 230     ["list"] -> do
 231         listPackages cli Nothing
 232     ["list", pkgid_str] -> do
 233         pkgid <- readGlobPkgId pkgid_str
 234         listPackages cli (Just pkgid)
 235     ["latest", pkgid_str] -> do
 236         pkgid <- readGlobPkgId pkgid_str
 237         latestPackage cli pkgid
 238     ["describe", pkgid_str] -> do
 239         pkgid <- readGlobPkgId pkgid_str
 240         describePackage cli pkgid
 241     ["field", pkgid_str, field] -> do
 242         pkgid <- readGlobPkgId pkgid_str
 243         describeField cli pkgid field
 244     ["check"] -> do
 245         checkConsistency cli
 246     [] -> do
 247         die ("missing command\n" ++
 248                 usageInfo (usageHeader prog) flags)
 249     (_cmd:_) -> do
 250         die ("command-line syntax error\n" ++
 251                 usageInfo (usageHeader prog) flags)
 252
 253 parseCheck :: ReadP a a -> String -> String -> IO a
 254 parseCheck parser str what =
 255   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 256     [x] -> return x
 257     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 258
 259 readPkgId :: String -> IO PackageIdentifier
 260 readPkgId str = parseCheck parsePackageId str "package identifier"
 261
 262 readGlobPkgId :: String -> IO PackageIdentifier
 263 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 264
 265 parseGlobPackageId :: ReadP r PackageIdentifier
 266 parseGlobPackageId =
 267   parsePackageId
 268      +++
 269   (do n <- parsePackageName; string "-*"
 270       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 271
 272 -- globVersion means "all versions"
 273 globVersion :: Version
 274 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 275
 276 -- -----------------------------------------------------------------------------
 277 -- Package databases
 278
 279 -- Some commands operate on a single database:
 280 --      register, unregister, expose, hide
 281 -- however these commands also check the union of the available databases
 282 -- in order to check consistency.  For example, register will check that
 283 -- dependencies exist before registering a package.
 284 --
 285 -- Some commands operate  on multiple databases, with overlapping semantics:
 286 --      list, describe, field
 287
 288 type PackageDBName  = FilePath
 289 type PackageDB      = [InstalledPackageInfo]
 290
 291 type PackageDBStack = [(PackageDBName,PackageDB)]
 292         -- A stack of package databases.  Convention: head is the topmost
 293         -- in the stack.  Earlier entries override later one.
 294
 295 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 296 getPkgDatabases modify flags = do
 297   -- first we determine the location of the global package config.  On Windows,
 298   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 299   -- location is passed to the binary using the --global-config flag by the
 300   -- wrapper script.
 301   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 302   global_conf <-
 303      case [ f | FlagGlobalConfig f <- flags ] of
 304         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 305                  case mb_dir of
 306                         Nothing  -> die err_msg
 307                         Just dir -> return (dir `joinFileName` "package.conf")
 308         fs -> return (last fs)
 309
 310   let global_conf_dir = global_conf ++ ".d"
 311   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 312   global_confs <-
 313     if global_conf_dir_exists
 314       then do files <- getDirectoryContents global_conf_dir
 315               return [ global_conf_dir ++ '/' : file
 316                      | file <- files
 317                      , isSuffixOf ".conf" file]
 318       else return []
 319
 320   -- get the location of the user package database, and create it if necessary
 321   appdir <- getAppUserDataDirectory "ghc"
 322
 323   let
 324         subdir = targetARCH ++ '-':targetOS ++ '-':version
 325         archdir   = appdir `joinFileName` subdir
 326         user_conf = archdir `joinFileName` "package.conf"
 327   user_exists <- doesFileExist user_conf
 328
 329   -- If the user database doesn't exist, and this command isn't a
 330   -- "modify" command, then we won't attempt to create or use it.
 331   let sys_databases
 332         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 333         | otherwise             = global_confs ++ [global_conf]
 334
 335   e_pkg_path <- try (getEnv "GHC_PACKAGE_PATH")
 336   let env_stack =
 337         case e_pkg_path of
 338                 Left  _ -> sys_databases
 339                 Right path
 340                   | last cs == ""  -> init cs ++ sys_databases
 341                   | otherwise      -> cs
 342                   where cs = parseSearchPath path
 343
 344         -- The "global" database is always the one at the bottom of the stack.
 345         -- This is the database we modify by default.
 346       virt_global_conf = last env_stack
 347
 348   -- -f flags on the command line add to the database stack, unless any
 349   -- of them are present in the stack already.
 350   let flag_stack = filter (`notElem` env_stack)
 351                         [ f | FlagConfig f <- reverse flags ] ++ env_stack
 352
 353   -- Now we have the full stack of databases.  Next, if the current
 354   -- command is a "modify" type command, then we truncate the stack
 355   -- so that the topmost element is the database being modified.
 356   final_stack <-
 357      if not modify
 358         then return flag_stack
 359         else let
 360                 go (FlagUser : fs)     = modifying user_conf
 361                 go (FlagGlobal : fs)   = modifying virt_global_conf
 362                 go (FlagConfig f : fs) = modifying f
 363                 go (_ : fs)            = go fs
 364                 go []                  = modifying virt_global_conf
 365
 366                 modifying f
 367                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 368                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 369              in
 370                 go flags
 371
 372   db_stack <- mapM readParseDatabase final_stack
 373   return db_stack
 374
 375 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 376 readParseDatabase filename = do
 377   str <- readFile filename `Exception.catch` \_ -> return emptyPackageConfig
 378   let packages = read str
 379   Exception.evaluate packages
 380     `Exception.catch` \_ ->
 381         die (filename ++ ": parse error in package config file")
 382   return (filename,packages)
 383
 384 emptyPackageConfig :: String
 385 emptyPackageConfig = "[]"
 386
 387 -- -----------------------------------------------------------------------------
 388 -- Registering
 389
 390 registerPackage :: FilePath
 391                 -> [(String,String)] -- defines
 392                 -> [Flag]
 393                 -> Bool         -- auto_ghci_libs
 394                 -> Bool         -- update
 395                 -> Force
 396                 -> IO ()
 397 registerPackage input defines flags auto_ghci_libs update force = do
 398   db_stack <- getPkgDatabases True flags
 399   let
 400         db_to_operate_on = my_head "db" db_stack
 401         db_filename      = fst db_to_operate_on
 402   --
 403
 404   s <-
 405     case input of
 406       "-" -> do
 407         putStr "Reading package info from stdin ... "
 408         getContents
 409       f   -> do
 410         putStr ("Reading package info from " ++ show f ++ " ... ")
 411         readFile f
 412
 413   expanded <- expandEnvVars s defines force
 414
 415   pkg0 <- parsePackageInfo expanded defines
 416   putStrLn "done."
 417
 418   let pkg = resolveDeps db_stack pkg0
 419   validatePackageConfig pkg db_stack auto_ghci_libs update force
 420   let new_details = filter not_this (snd db_to_operate_on) ++ [pkg]
 421       not_this p = package p /= package pkg
 422   savingOldConfig db_filename $
 423     writeNewConfig db_filename new_details
 424
 425 parsePackageInfo
 426         :: String
 427         -> [(String,String)]
 428         -> IO InstalledPackageInfo
 429 parsePackageInfo str defines =
 430   case parseInstalledPackageInfo str of
 431     ParseOk _warns ok -> return ok
 432     ParseFailed err -> die (showError err)
 433
 434 -- -----------------------------------------------------------------------------
 435 -- Exposing, Hiding, Unregistering are all similar
 436
 437 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 438 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 439
 440 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 441 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 442
 443 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 444 unregisterPackage = modifyPackage (\p -> [])
 445
 446 modifyPackage
 447   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 448   -> PackageIdentifier
 449   -> [Flag]
 450   -> IO ()
 451 modifyPackage fn pkgid flags  = do
 452   db_stack <- getPkgDatabases True{-modify-} flags
 453   let ((db_name, pkgs) : _) = db_stack
 454   ps <- findPackages [(db_name,pkgs)] pkgid
 455   let pids = map package ps
 456   let new_config = concat (map modify pkgs)
 457       modify pkg
 458           | package pkg `elem` pids = fn pkg
 459           | otherwise               = [pkg]
 460   savingOldConfig db_name $
 461       writeNewConfig db_name new_config
 462
 463 -- -----------------------------------------------------------------------------
 464 -- Listing packages
 465
 466 listPackages ::  [Flag] -> Maybe PackageIdentifier -> IO ()
 467 listPackages flags mPackageName = do
 468   let simple_output = FlagSimpleOutput `elem` flags
 469   db_stack <- getPkgDatabases False flags
 470   let db_stack_filtered -- if a package is given, filter out all other packages
 471         | Just this <- mPackageName =
 472             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 473                 db_stack
 474         | otherwise = db_stack
 475
 476       db_stack_sorted
 477           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 478           where sort_pkgs = sortBy cmpPkgIds
 479                 cmpPkgIds pkg1 pkg2 =
 480                    case pkgName p1 `compare` pkgName p2 of
 481                         LT -> LT
 482                         GT -> GT
 483                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 484                    where (p1,p2) = (package pkg1, package pkg2)
 485
 486       pkg_map = map (\p -> (package p, p)) $ concatMap snd db_stack
 487       show_func = if simple_output then show_simple else mapM_ (show_normal pkg_map)
 488
 489   show_func (reverse db_stack_sorted)
 490
 491   where show_normal pkg_map (db_name,pkg_confs) =
 492           hPutStrLn stdout (render $
 493                 text db_name <> colon $$ nest 4 packages
 494                 )
 495            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 496                  pp_pkg p
 497                    | isBrokenPackage p pkg_map = braces doc
 498                    | exposed p = doc
 499                    | otherwise = parens doc
 500                    where doc = text (showPackageId (package p))
 501
 502         show_simple db_stack = do
 503           let pkgs = map showPackageId $ sortBy compPkgIdVer $
 504                           map package (concatMap snd db_stack)
 505           when (null pkgs) $ die "no matches"
 506           hPutStrLn stdout $ concat $ intersperse " " pkgs
 507
 508 -- -----------------------------------------------------------------------------
 509 -- Prints the highest (hidden or exposed) version of a package
 510
 511 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 512 latestPackage flags pkgid = do
 513   db_stack <- getPkgDatabases False flags
 514   ps <- findPackages db_stack pkgid
 515   show_pkg (sortBy compPkgIdVer (map package ps))
 516   where
 517     show_pkg [] = die "no matches"
 518     show_pkg pids = hPutStrLn stdout (showPackageId (last pids))
 519
 520 -- -----------------------------------------------------------------------------
 521 -- Describe
 522
 523 describePackage :: [Flag] -> PackageIdentifier -> IO ()
 524 describePackage flags pkgid = do
 525   db_stack <- getPkgDatabases False flags
 526   ps <- findPackages db_stack pkgid
 527   mapM_ (putStrLn . showInstalledPackageInfo) ps
 528
 529 -- PackageId is can have globVersion for the version
 530 findPackages :: PackageDBStack -> PackageIdentifier -> IO [InstalledPackageInfo]
 531 findPackages db_stack pkgid
 532   = case [ p | p <- all_pkgs, pkgid `matchesPkg` p ] of
 533         []  -> die ("cannot find package " ++ showPackageId pkgid)
 534         ps -> return ps
 535   where
 536         all_pkgs = concat (map snd db_stack)
 537
 538 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 539 pid `matches` pid'
 540   = (pkgName pid == pkgName pid')
 541     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 542
 543 matchesPkg :: PackageIdentifier -> InstalledPackageInfo -> Bool
 544 pid `matchesPkg` pkg = pid `matches` package pkg
 545
 546 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 547 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 548
 549 -- -----------------------------------------------------------------------------
 550 -- Field
 551
 552 describeField :: [Flag] -> PackageIdentifier -> String -> IO ()
 553 describeField flags pkgid field = do
 554   db_stack <- getPkgDatabases False flags
 555   case toField field of
 556     Nothing -> die ("unknown field: " ++ field)
 557     Just fn -> do
 558         ps <- findPackages db_stack pkgid
 559         mapM_ (putStrLn.fn) ps
 560
 561 toField :: String -> Maybe (InstalledPackageInfo -> String)
 562 -- backwards compatibility:
 563 toField "import_dirs"     = Just $ strList . importDirs
 564 toField "source_dirs"     = Just $ strList . importDirs
 565 toField "library_dirs"    = Just $ strList . libraryDirs
 566 toField "hs_libraries"    = Just $ strList . hsLibraries
 567 toField "extra_libraries" = Just $ strList . extraLibraries
 568 toField "include_dirs"    = Just $ strList . includeDirs
 569 toField "c_includes"      = Just $ strList . includes
 570 toField "package_deps"    = Just $ strList . map showPackageId. depends
 571 toField "extra_cc_opts"   = Just $ strList . ccOptions
 572 toField "extra_ld_opts"   = Just $ strList . ldOptions
 573 toField "framework_dirs"  = Just $ strList . frameworkDirs
 574 toField "extra_frameworks"= Just $ strList . frameworks
 575 toField s                 = showInstalledPackageInfoField s
 576
 577 strList :: [String] -> String
 578 strList = show
 579
 580
 581 -- -----------------------------------------------------------------------------
 582 -- Check: Check consistency of installed packages
 583
 584 checkConsistency :: [Flag] -> IO ()
 585 checkConsistency flags = do
 586   db_stack <- getPkgDatabases False flags
 587   let pkgs = map (\p -> (package p, p)) $ concatMap snd db_stack
 588       broken_pkgs = do
 589         (pid, p) <- pkgs
 590         let broken_deps = missingPackageDeps p pkgs
 591         guard (not . null $ broken_deps)
 592         return (pid, broken_deps)
 593   mapM_ (putStrLn . render . show_func) broken_pkgs
 594   where
 595   show_func | FlagSimpleOutput `elem` flags = show_simple
 596             | otherwise = show_normal
 597   show_simple (pid,deps) =
 598     text (showPackageId pid) <> colon
 599       <+> fsep (punctuate comma (map (text . showPackageId) deps))
 600   show_normal (pid,deps) =
 601     text "package" <+> text (showPackageId pid) <+> text "has missing dependencies:"
 602       $$ nest 4 (fsep (punctuate comma (map (text . showPackageId) deps)))
 603
 604 missingPackageDeps :: InstalledPackageInfo
 605                    -> [(PackageIdentifier, InstalledPackageInfo)]
 606                    -> [PackageIdentifier]
 607 missingPackageDeps pkg pkg_map =
 608   [ d | d <- depends pkg, isNothing (lookup d pkg_map)] ++
 609   [ d | d <- depends pkg, Just p <- return (lookup d pkg_map), isBrokenPackage p pkg_map]
 610
 611 isBrokenPackage :: InstalledPackageInfo -> [(PackageIdentifier, InstalledPackageInfo)] -> Bool
 612 isBrokenPackage pkg pkg_map = not . null $ missingPackageDeps pkg pkg_map
 613
 614
 615 -- -----------------------------------------------------------------------------
 616 -- Manipulating package.conf files
 617
 618 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 619 writeNewConfig filename packages = do
 620   hPutStr stdout "Writing new package config file... "
 621   createDirectoryIfMissing True $ getFilenameDir filename
 622   h <- openFile filename WriteMode `catch` \e ->
 623       if isPermissionError e
 624       then die (filename ++ ": you don't have permission to modify this file")
 625       else ioError e
 626   hPutStrLn h (show packages)
 627   hClose h
 628   hPutStrLn stdout "done."
 629
 630 savingOldConfig :: FilePath -> IO () -> IO ()
 631 savingOldConfig filename io = Exception.block $ do
 632   hPutStr stdout "Saving old package config file... "
 633     -- mv rather than cp because we've already done an hGetContents
 634     -- on this file so we won't be able to open it for writing
 635     -- unless we move the old one out of the way...
 636   let oldFile = filename ++ ".old"
 637   restore_on_error <- catch (renameFile filename oldFile >> return True) $
 638       \err -> do
 639           unless (isDoesNotExistError err) $ do
 640               hPutStrLn stderr (unwords ["Unable to rename", show filename,
 641                                          "to", show oldFile])
 642               ioError err
 643           return False
 644   hPutStrLn stdout "done."
 645   io `catch` \e -> do
 646       hPutStrLn stderr (show e)
 647       hPutStr stdout ("\nWARNING: an error was encountered while writing"
 648                    ++ "the new configuration.\n")
 649       when restore_on_error $ do
 650           hPutStr stdout "Attempting to restore the old configuration..."
 651           do renameFile oldFile filename
 652              hPutStrLn stdout "done."
 653            `catch` \err -> hPutStrLn stdout ("Failed: " ++ show err)
 654       ioError e
 655
 656 -----------------------------------------------------------------------------
 657 -- Sanity-check a new package config, and automatically build GHCi libs
 658 -- if requested.
 659
 660 validatePackageConfig :: InstalledPackageInfo
 661                       -> PackageDBStack
 662                       -> Bool   -- auto-ghc-libs
 663                       -> Bool   -- update
 664                       -> Force
 665                       -> IO ()
 666 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 667   checkPackageId pkg
 668   checkDuplicates db_stack pkg update
 669   mapM_ (checkDep db_stack force) (depends pkg)
 670   mapM_ (checkDir force) (importDirs pkg)
 671   mapM_ (checkDir force) (libraryDirs pkg)
 672   mapM_ (checkDir force) (includeDirs pkg)
 673   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 674   -- ToDo: check these somehow?
 675   --    extra_libraries :: [String],
 676   --    c_includes      :: [String],
 677
 678 -- When the package name and version are put together, sometimes we can
 679 -- end up with a package id that cannot be parsed.  This will lead to
 680 -- difficulties when the user wants to refer to the package later, so
 681 -- we check that the package id can be parsed properly here.
 682 checkPackageId :: InstalledPackageInfo -> IO ()
 683 checkPackageId ipi =
 684   let str = showPackageId (package ipi) in
 685   case [ x | (x,ys) <- readP_to_S parsePackageId str, all isSpace ys ] of
 686     [_] -> return ()
 687     []  -> die ("invalid package identifier: " ++ str)
 688     _   -> die ("ambiguous package identifier: " ++ str)
 689
 690 resolveDeps :: PackageDBStack -> InstalledPackageInfo -> InstalledPackageInfo
 691 resolveDeps db_stack p = updateDeps p
 692   where
 693         -- The input package spec is allowed to give a package dependency
 694         -- without a version number; e.g.
 695         --      depends: base
 696         -- Here, we update these dependencies without version numbers to
 697         -- match the actual versions of the relevant packages installed.
 698         updateDeps p = p{depends = map resolveDep (depends p)}
 699
 700         resolveDep dep_pkgid
 701            | realVersion dep_pkgid  = dep_pkgid
 702            | otherwise              = lookupDep dep_pkgid
 703
 704         lookupDep dep_pkgid
 705            = let
 706                 name = pkgName dep_pkgid
 707              in
 708              case [ pid | p <- concat (map snd db_stack),
 709                           let pid = package p,
 710                           pkgName pid == name ] of
 711                 (pid:_) -> pid          -- Found installed package,
 712                                         -- replete with its version
 713                 []      -> dep_pkgid    -- No installed package; use
 714                                         -- the version-less one
 715
 716 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> IO ()
 717 checkDuplicates db_stack pkg update = do
 718   let
 719         pkgid = package pkg
 720         (_top_db_name, pkgs) : _  = db_stack
 721   --
 722   -- Check whether this package id already exists in this DB
 723   --
 724   when (not update && (pkgid `elem` map package pkgs)) $
 725        die ("package " ++ showPackageId pkgid ++ " is already installed")
 726
 727
 728
 729 checkDir :: Force -> String -> IO ()
 730 checkDir force d
 731  | "$topdir" `isPrefixOf` d = return ()
 732         -- can't check this, because we don't know what $topdir is
 733  | otherwise = do
 734    there <- doesDirectoryExist d
 735    when (not there)
 736        (dieOrForceFile force (d ++ " doesn't exist or isn't a directory"))
 737
 738 checkDep :: PackageDBStack -> Force -> PackageIdentifier -> IO ()
 739 checkDep db_stack force pkgid
 740   | pkgid `elem` pkgids || (not real_version && name_exists) = return ()
 741   | otherwise = dieOrForceAll force ("dependency " ++ showPackageId pkgid
 742                                         ++ " doesn't exist")
 743   where
 744         -- for backwards compat, we treat 0.0 as a special version,
 745         -- and don't check that it actually exists.
 746         real_version = realVersion pkgid
 747
 748         name_exists = any (\p -> pkgName (package p) == name) all_pkgs
 749         name = pkgName pkgid
 750
 751         all_pkgs = concat (map snd db_stack)
 752         pkgids = map package all_pkgs
 753
 754 realVersion :: PackageIdentifier -> Bool
 755 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 756
 757 checkHSLib :: [String] -> Bool -> Force -> String -> IO ()
 758 checkHSLib dirs auto_ghci_libs force lib = do
 759   let batch_lib_file = "lib" ++ lib ++ ".a"
 760   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 761   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 762         [] -> dieOrForceFile force ("cannot find " ++ batch_lib_file ++
 763                                  " on library path")
 764         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 765
 766 doesLibExistIn :: String -> String -> IO Bool
 767 doesLibExistIn lib d
 768  | "$topdir" `isPrefixOf` d = return True
 769  | otherwise                = doesFileExist (d ++ '/':lib)
 770
 771 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 772 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 773   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 774   | otherwise  = do
 775       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 776       case [dir | (exists,dir) <- zip bs dirs, exists] of
 777         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 778         (_:_) -> return ()
 779   where
 780     ghci_lib_file = lib ++ ".o"
 781
 782 -- automatically build the GHCi version of a batch lib,
 783 -- using ld --whole-archive.
 784
 785 autoBuildGHCiLib :: String -> String -> String -> IO ()
 786 autoBuildGHCiLib dir batch_file ghci_file = do
 787   let ghci_lib_file  = dir ++ '/':ghci_file
 788       batch_lib_file = dir ++ '/':batch_file
 789   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 790 #if defined(darwin_HOST_OS)
 791   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 792 #elif defined(mingw32_HOST_OS)
 793   execDir <- getExecDir "/bin/ghc-pkg.exe"
 794   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 795 #else
 796   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 797 #endif
 798   when (r /= ExitSuccess) $ exitWith r
 799   hPutStrLn stderr (" done.")
 800
 801 -- -----------------------------------------------------------------------------
 802 -- Searching for modules
 803
 804 #if not_yet
 805
 806 findModules :: [FilePath] -> IO [String]
 807 findModules paths =
 808   mms <- mapM searchDir paths
 809   return (concat mms)
 810
 811 searchDir path prefix = do
 812   fs <- getDirectoryEntries path `catch` \_ -> return []
 813   searchEntries path prefix fs
 814
 815 searchEntries path prefix [] = return []
 816 searchEntries path prefix (f:fs)
 817   | looks_like_a_module  =  do
 818         ms <- searchEntries path prefix fs
 819         return (prefix `joinModule` f : ms)
 820   | looks_like_a_component  =  do
 821         ms <- searchDir (path `joinFilename` f) (prefix `joinModule` f)
 822         ms' <- searchEntries path prefix fs
 823         return (ms ++ ms')
 824   | otherwise
 825         searchEntries path prefix fs
 826
 827   where
 828         (base,suffix) = splitFileExt f
 829         looks_like_a_module =
 830                 suffix `elem` haskell_suffixes &&
 831                 all okInModuleName base
 832         looks_like_a_component =
 833                 null suffix && all okInModuleName base
 834
 835 okInModuleName c
 836
 837 #endif
 838
 839 -- -----------------------------------------------------------------------------
 840 -- The old command-line syntax, supported for backwards compatibility
 841
 842 data OldFlag
 843   = OF_Config FilePath
 844   | OF_Input FilePath
 845   | OF_List
 846   | OF_ListLocal
 847   | OF_Add Bool {- True => replace existing info -}
 848   | OF_Remove String | OF_Show String
 849   | OF_Field String | OF_AutoGHCiLibs | OF_Force
 850   | OF_DefinedName String String
 851   | OF_GlobalConfig FilePath
 852   deriving (Eq)
 853
 854 isAction :: OldFlag -> Bool
 855 isAction OF_Config{}        = False
 856 isAction OF_Field{}         = False
 857 isAction OF_Input{}         = False
 858 isAction OF_AutoGHCiLibs{}  = False
 859 isAction OF_Force{}         = False
 860 isAction OF_DefinedName{}   = False
 861 isAction OF_GlobalConfig{}  = False
 862 isAction _                  = True
 863
 864 oldFlags :: [OptDescr OldFlag]
 865 oldFlags = [
 866   Option ['f'] ["config-file"] (ReqArg OF_Config "FILE")
 867         "use the specified package config file",
 868   Option ['l'] ["list-packages"] (NoArg OF_List)
 869         "list packages in all config files",
 870   Option ['L'] ["list-local-packages"] (NoArg OF_ListLocal)
 871         "list packages in the specified config file",
 872   Option ['a'] ["add-package"] (NoArg (OF_Add False))
 873         "add a new package",
 874   Option ['u'] ["update-package"] (NoArg (OF_Add True))
 875         "update package with new configuration",
 876   Option ['i'] ["input-file"] (ReqArg OF_Input "FILE")
 877         "read new package info from specified file",
 878   Option ['s'] ["show-package"] (ReqArg OF_Show "NAME")
 879         "show the configuration for package NAME",
 880   Option [] ["field"] (ReqArg OF_Field "FIELD")
 881         "(with --show-package) Show field FIELD only",
 882   Option [] ["force"] (NoArg OF_Force)
 883         "ignore missing directories/libraries",
 884   Option ['r'] ["remove-package"] (ReqArg OF_Remove "NAME")
 885         "remove an installed package",
 886   Option ['g'] ["auto-ghci-libs"] (NoArg OF_AutoGHCiLibs)
 887         "automatically build libs for GHCi (with -a)",
 888   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 889         "define NAME as VALUE",
 890   Option [] ["global-conf"] (ReqArg OF_GlobalConfig "FILE")
 891         "location of the global package config"
 892   ]
 893  where
 894   toDefined str =
 895     case break (=='=') str of
 896       (nm,[]) -> OF_DefinedName nm []
 897       (nm,_:val) -> OF_DefinedName nm val
 898
 899 oldRunit :: [OldFlag] -> IO ()
 900 oldRunit clis = do
 901   let new_flags = [ f | Just f <- map conv clis ]
 902
 903       conv (OF_GlobalConfig f) = Just (FlagGlobalConfig f)
 904       conv (OF_Config f)       = Just (FlagConfig f)
 905       conv _                   = Nothing
 906
 907
 908
 909   let fields = [ f | OF_Field f <- clis ]
 910
 911   let auto_ghci_libs = any isAuto clis
 912          where isAuto OF_AutoGHCiLibs = True; isAuto _ = False
 913       input_file = my_head "inp" ([ f | (OF_Input f) <- clis] ++ ["-"])
 914
 915       force = if OF_Force `elem` clis then ForceAll else NoForce
 916
 917       defines = [ (nm,val) | OF_DefinedName nm val <- clis ]
 918
 919   case [ c | c <- clis, isAction c ] of
 920     [ OF_List ]      -> listPackages new_flags Nothing
 921     [ OF_ListLocal ] -> listPackages new_flags Nothing
 922     [ OF_Add upd ]   ->
 923         registerPackage input_file defines new_flags auto_ghci_libs upd force
 924     [ OF_Remove pkgid_str ]  -> do
 925         pkgid <- readPkgId pkgid_str
 926         unregisterPackage pkgid new_flags
 927     [ OF_Show pkgid_str ]
 928         | null fields -> do
 929                 pkgid <- readPkgId pkgid_str
 930                 describePackage new_flags pkgid
 931         | otherwise   -> do
 932                 pkgid <- readPkgId pkgid_str
 933                 mapM_ (describeField new_flags pkgid) fields
 934     _ -> do
 935         prog <- getProgramName
 936         die (usageInfo (usageHeader prog) flags)
 937
 938 my_head :: String -> [a] -> a
 939 my_head s [] = error s
 940 my_head s (x:xs) = x
 941
 942 -- ---------------------------------------------------------------------------
 943 -- expanding environment variables in the package configuration
 944
 945 expandEnvVars :: String -> [(String, String)] -> Force -> IO String
 946 expandEnvVars str defines force = go str ""
 947  where
 948    go "" acc = return $! reverse acc
 949    go ('$':'{':str) acc | (var, '}':rest) <- break close str
 950         = do value <- lookupEnvVar var
 951              go rest (reverse value ++ acc)
 952         where close c = c == '}' || c == '\n' -- don't span newlines
 953    go (c:str) acc
 954         = go str (c:acc)
 955
 956    lookupEnvVar :: String -> IO String
 957    lookupEnvVar nm =
 958      case lookup nm defines of
 959        Just x | not (null x) -> return x
 960        _      ->
 961         catch (System.getEnv nm)
 962            (\ _ -> do dieOrForceAll force ("Unable to expand variable " ++
 963                                         show nm)
 964                       return "")
 965
 966 -----------------------------------------------------------------------------
 967
 968 getProgramName :: IO String
 969 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
 970    where str `withoutSuffix` suff
 971             | suff `isSuffixOf` str = take (length str - length suff) str
 972             | otherwise             = str
 973
 974 bye :: String -> IO a
 975 bye s = putStr s >> exitWith ExitSuccess
 976
 977 die :: String -> IO a
 978 die s = do
 979   hFlush stdout
 980   prog <- getProgramName
 981   hPutStrLn stderr (prog ++ ": " ++ s)
 982   exitWith (ExitFailure 1)
 983
 984 dieOrForceAll :: Force -> String -> IO ()
 985 dieOrForceAll ForceAll s = ignoreError s
 986 dieOrForceAll _other s   = dieForcible s
 987
 988 dieOrForceFile :: Force -> String -> IO ()
 989 dieOrForceFile ForceAll   s = ignoreError s
 990 dieOrForceFile ForceFiles s = ignoreError s
 991 dieOrForceFile _other     s = dieForcible s
 992
 993 ignoreError :: String -> IO ()
 994 ignoreError s = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
 995
 996 dieForcible :: String -> IO ()
 997 dieForcible s = die (s ++ " (use --force to override)")
 998
 999 -----------------------------------------
1000 --      Cut and pasted from ghc/compiler/SysTools
1001
1002 #if defined(mingw32_HOST_OS)
1003 subst a b ls = map (\ x -> if x == a then b else x) ls
1004 unDosifyPath xs = subst '\\' '/' xs
1005
1006 getExecDir :: String -> IO (Maybe String)
1007 -- (getExecDir cmd) returns the directory in which the current
1008 --                  executable, which should be called 'cmd', is running
1009 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
1010 -- you'll get "/a/b/c" back as the result
1011 getExecDir cmd
1012   = allocaArray len $ \buf -> do
1013         ret <- getModuleFileName nullPtr buf len
1014         if ret == 0 then return Nothing
1015                     else do s <- peekCString buf
1016                             return (Just (reverse (drop (length cmd)
1017                                                         (reverse (unDosifyPath s)))))
1018   where
1019     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
1020
1021 foreign import stdcall unsafe  "GetModuleFileNameA"
1022   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
1023 #else
1024 getExecDir :: String -> IO (Maybe String)
1025 getExecDir _ = return Nothing
1026 #endif
1027
1028 -- -----------------------------------------------------------------------------
1029 -- FilePath utils
1030
1031 -- | The 'joinFileName' function is the opposite of 'splitFileName'.
1032 -- It joins directory and file names to form a complete file path.
1033 --
1034 -- The general rule is:
1035 --
1036 -- > dir `joinFileName` basename == path
1037 -- >   where
1038 -- >     (dir,basename) = splitFileName path
1039 --
1040 -- There might be an exceptions to the rule but in any case the
1041 -- reconstructed path will refer to the same object (file or directory).
1042 -- An example exception is that on Windows some slashes might be converted
1043 -- to backslashes.
1044 joinFileName :: String -> String -> FilePath
1045 joinFileName ""  fname = fname
1046 joinFileName "." fname = fname
1047 joinFileName dir ""    = dir
1048 joinFileName dir fname
1049   | isPathSeparator (last dir) = dir++fname
1050   | otherwise                  = dir++pathSeparator:fname
1051
1052 -- | Checks whether the character is a valid path separator for the host
1053 -- platform. The valid character is a 'pathSeparator' but since the Windows
1054 -- operating system also accepts a slash (\"\/\") since DOS 2, the function
1055 -- checks for it on this platform, too.
1056 isPathSeparator :: Char -> Bool
1057 isPathSeparator ch = ch == pathSeparator || ch == '/'
1058
1059 -- | Provides a platform-specific character used to separate directory levels in
1060 -- a path string that reflects a hierarchical file system organization. The
1061 -- separator is a slash (@\"\/\"@) on Unix and Macintosh, and a backslash
1062 -- (@\"\\\"@) on the Windows operating system.
1063 pathSeparator :: Char
1064 #ifdef mingw32_HOST_OS
1065 pathSeparator = '\\'
1066 #else
1067 pathSeparator = '/'
1068 #endif
1069
1070 getFilenameDir :: FilePath -> FilePath
1071 getFilenameDir fn = case break isPathSeparator (reverse fn) of
1072                         (xs, "") -> "."
1073                         (_, sep:ys) -> reverse ys
1074
1075 -- | The function splits the given string to substrings
1076 -- using the 'searchPathSeparator'.
1077 parseSearchPath :: String -> [FilePath]
1078 parseSearchPath path = split path
1079   where
1080     split :: String -> [String]
1081     split s =
1082       case rest' of
1083         []     -> [chunk]
1084         _:rest -> chunk : split rest
1085       where
1086         chunk =
1087           case chunk' of
1088 #ifdef mingw32_HOST_OS
1089             ('\"':xs@(_:_)) | last xs == '\"' -> init xs
1090 #endif
1091             _                                 -> chunk'
1092
1093         (chunk', rest') = break (==searchPathSeparator) s
1094
1095 -- | A platform-specific character used to separate search path strings in
1096 -- environment variables. The separator is a colon (\":\") on Unix and Macintosh,
1097 -- and a semicolon (\";\") on the Windows operating system.
1098 searchPathSeparator :: Char
1099 #if mingw32_HOST_OS || mingw32_TARGET_OS
1100 searchPathSeparator = ';'
1101 #else
1102 searchPathSeparator = ':'
1103 #endif
1104