utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts -cpp #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 -- * validate modules
  12 -- * expanding of variables in new-style package conf
  13 -- * version manipulation (checking whether old version exists,
  14 --   hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo hiding (depends)
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils
  22 import Distribution.Package
  23 import Distribution.Text
  24 import Distribution.Version
  25 import System.FilePath
  26 import System.Cmd       ( rawSystem )
  27 import System.Directory ( getAppUserDataDirectory, createDirectoryIfMissing )
  28
  29 import Prelude
  30
  31 #include "../../includes/ghcconfig.h"
  32
  33 import System.Console.GetOpt
  34 import Text.PrettyPrint
  35 import qualified Control.Exception as Exception
  36 import Data.Maybe
  37
  38 import Data.Char ( isSpace, toLower )
  39 import Control.Monad
  40 import System.Directory ( doesDirectoryExist, getDirectoryContents,
  41                           doesFileExist, renameFile, removeFile )
  42 import System.Exit ( exitWith, ExitCode(..) )
  43 import System.Environment ( getArgs, getProgName, getEnv )
  44 import System.IO
  45 import System.IO.Error (try)
  46 import Data.List ( isPrefixOf, isSuffixOf, intersperse, sortBy, nub,
  47                    unfoldr, break )
  48 #if __GLASGOW_HASKELL__ > 604
  49 import Data.List ( isInfixOf )
  50 #else
  51 import Data.List ( tails )
  52 #endif
  53 import Control.Concurrent
  54
  55 #ifdef mingw32_HOST_OS
  56 import Foreign
  57 import Foreign.C.String
  58 import GHC.ConsoleHandler
  59 #else
  60 import System.Posix
  61 #endif
  62
  63 import IO ( isPermissionError, isDoesNotExistError )
  64
  65 #if defined(GLOB)
  66 import System.Process(runInteractiveCommand)
  67 import qualified System.Info(os)
  68 #endif
  69
  70 -- -----------------------------------------------------------------------------
  71 -- Entry point
  72
  73 main :: IO ()
  74 main = do
  75   args <- getArgs
  76
  77   case getOpt Permute (flags ++ deprecFlags) args of
  78         (cli,_,[]) | FlagHelp `elem` cli -> do
  79            prog <- getProgramName
  80            bye (usageInfo (usageHeader prog) flags)
  81         (cli,_,[]) | FlagVersion `elem` cli ->
  82            bye ourCopyright
  83         (cli,nonopts,[]) ->
  84            runit cli nonopts
  85         (_,_,errors) -> do
  86            prog <- getProgramName
  87            die (concat errors ++ usageInfo (usageHeader prog) flags)
  88
  89 -- -----------------------------------------------------------------------------
  90 -- Command-line syntax
  91
  92 data Flag
  93   = FlagUser
  94   | FlagGlobal
  95   | FlagHelp
  96   | FlagVersion
  97   | FlagConfig FilePath
  98   | FlagGlobalConfig FilePath
  99   | FlagForce
 100   | FlagForceFiles
 101   | FlagAutoGHCiLibs
 102   | FlagSimpleOutput
 103   | FlagNamesOnly
 104   | FlagIgnoreCase
 105   deriving Eq
 106
 107 flags :: [OptDescr Flag]
 108 flags = [
 109   Option [] ["user"] (NoArg FlagUser)
 110         "use the current user's package database",
 111   Option [] ["global"] (NoArg FlagGlobal)
 112         "use the global package database",
 113   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 114         "use the specified package config file",
 115   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 116         "location of the global package config",
 117   Option [] ["force"] (NoArg FlagForce)
 118          "ignore missing dependencies, directories, and libraries",
 119   Option [] ["force-files"] (NoArg FlagForceFiles)
 120          "ignore missing directories and libraries only",
 121   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 122         "automatically build libs for GHCi (with register)",
 123   Option ['?'] ["help"] (NoArg FlagHelp)
 124         "display this help and exit",
 125   Option ['V'] ["version"] (NoArg FlagVersion)
 126         "output version information and exit",
 127   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 128         "print output in easy-to-parse format for some commands",
 129   Option [] ["names-only"] (NoArg FlagNamesOnly)
 130         "only print package names, not versions; can only be used with list --simple-output",
 131   Option [] ["ignore-case"] (NoArg FlagIgnoreCase)
 132         "ignore case for substring matching"
 133   ]
 134
 135 deprecFlags :: [OptDescr Flag]
 136 deprecFlags = [
 137         -- put deprecated flags here
 138   ]
 139
 140 ourCopyright :: String
 141 ourCopyright = "GHC package manager version " ++ Version.version ++ "\n"
 142
 143 usageHeader :: String -> String
 144 usageHeader prog = substProg prog $
 145   "Usage:\n" ++
 146   "  $p register {filename | -}\n" ++
 147   "    Register the package using the specified installed package\n" ++
 148   "    description. The syntax for the latter is given in the $p\n" ++
 149   "    documentation.\n" ++
 150   "\n" ++
 151   "  $p update {filename | -}\n" ++
 152   "    Register the package, overwriting any other package with the\n" ++
 153   "    same name.\n" ++
 154   "\n" ++
 155   "  $p unregister {pkg-id}\n" ++
 156   "    Unregister the specified package.\n" ++
 157   "\n" ++
 158   "  $p expose {pkg-id}\n" ++
 159   "    Expose the specified package.\n" ++
 160   "\n" ++
 161   "  $p hide {pkg-id}\n" ++
 162   "    Hide the specified package.\n" ++
 163   "\n" ++
 164   "  $p list [pkg]\n" ++
 165   "    List registered packages in the global database, and also the\n" ++
 166   "    user database if --user is given. If a package name is given\n" ++
 167   "    all the registered versions will be listed in ascending order.\n" ++
 168   "    Accepts the --simple-output flag.\n" ++
 169   "\n" ++
 170   "  $p find-module {module}\n" ++
 171   "    List registered packages exposing module {module} in the global\n" ++
 172   "    database, and also the user database if --user is given.\n" ++
 173   "    All the registered versions will be listed in ascending order.\n" ++
 174   "    Accepts the --simple-output flag.\n" ++
 175   "\n" ++
 176   "  $p latest {pkg-id}\n" ++
 177   "    Prints the highest registered version of a package.\n" ++
 178   "\n" ++
 179   "  $p check\n" ++
 180   "    Check the consistency of package depenencies and list broken packages.\n" ++
 181   "    Accepts the --simple-output flag.\n" ++
 182   "\n" ++
 183   "  $p describe {pkg}\n" ++
 184   "    Give the registered description for the specified package. The\n" ++
 185   "    description is returned in precisely the syntax required by $p\n" ++
 186   "    register.\n" ++
 187   "\n" ++
 188   "  $p field {pkg} {field}\n" ++
 189   "    Extract the specified field of the package description for the\n" ++
 190   "    specified package. Accepts comma-separated multiple fields.\n" ++
 191   "\n" ++
 192   " Substring matching is supported for {module} in find-module and\n" ++
 193   " for {pkg} in list, describe, and field, where a '*' indicates\n" ++
 194   " open substring ends (prefix*, *suffix, *infix*).\n" ++
 195   "\n" ++
 196   "  When asked to modify a database (register, unregister, update,\n"++
 197   "  hide, expose, and also check), ghc-pkg modifies the global database by\n"++
 198   "  default.  Specifying --user causes it to act on the user database,\n"++
 199   "  or --package-conf can be used to act on another database\n"++
 200   "  entirely. When multiple of these options are given, the rightmost\n"++
 201   "  one is used as the database to act upon.\n"++
 202   "\n"++
 203   "  Commands that query the package database (list, latest, describe,\n"++
 204   "  field) operate on the list of databases specified by the flags\n"++
 205   "  --user, --global, and --package-conf.  If none of these flags are\n"++
 206   "  given, the default is --global --user.\n"++
 207   "\n" ++
 208   " The following optional flags are also accepted:\n"
 209
 210 substProg :: String -> String -> String
 211 substProg _ [] = []
 212 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 213 substProg prog (c:xs) = c : substProg prog xs
 214
 215 -- -----------------------------------------------------------------------------
 216 -- Do the business
 217
 218 data Force = ForceAll | ForceFiles | NoForce
 219
 220 data PackageArg = Id PackageIdentifier | Substring String (String->Bool)
 221
 222 runit :: [Flag] -> [String] -> IO ()
 223 runit cli nonopts = do
 224   installSignalHandlers -- catch ^C and clean up
 225   prog <- getProgramName
 226   let
 227         force
 228           | FlagForce `elem` cli        = ForceAll
 229           | FlagForceFiles `elem` cli   = ForceFiles
 230           | otherwise                   = NoForce
 231         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 232         splitFields fields = unfoldr splitComma (',':fields)
 233           where splitComma "" = Nothing
 234                 splitComma fs = Just $ break (==',') (tail fs)
 235
 236         substringCheck :: String -> Maybe (String -> Bool)
 237         substringCheck ""    = Nothing
 238         substringCheck "*"   = Just (const True)
 239         substringCheck [_]   = Nothing
 240         substringCheck (h:t) =
 241           case (h, init t, last t) of
 242             ('*',s,'*') -> Just (isInfixOf (f s) . f)
 243             ('*',_, _ ) -> Just (isSuffixOf (f t) . f)
 244             ( _ ,s,'*') -> Just (isPrefixOf (f (h:s)) . f)
 245             _           -> Nothing
 246           where f | FlagIgnoreCase `elem` cli = map toLower
 247                   | otherwise                 = id
 248 #if defined(GLOB)
 249         glob x | System.Info.os=="mingw32" = do
 250           -- glob echoes its argument, after win32 filename globbing
 251           (_,o,_,_) <- runInteractiveCommand ("glob "++x)
 252           txt <- hGetContents o
 253           return (read txt)
 254         glob x | otherwise = return [x]
 255 #endif
 256   --
 257   -- first, parse the command
 258   case nonopts of
 259 #if defined(GLOB)
 260     -- dummy command to demonstrate usage and permit testing
 261     -- without messing things up; use glob to selectively enable
 262     -- windows filename globbing for file parameters
 263     -- register, update, FlagGlobalConfig, FlagConfig; others?
 264     ["glob", filename] -> do
 265         print filename
 266         glob filename >>= print
 267 #endif
 268     ["register", filename] ->
 269         registerPackage filename cli auto_ghci_libs False force
 270     ["update", filename] ->
 271         registerPackage filename cli auto_ghci_libs True force
 272     ["unregister", pkgid_str] -> do
 273         pkgid <- readGlobPkgId pkgid_str
 274         unregisterPackage pkgid cli
 275     ["expose", pkgid_str] -> do
 276         pkgid <- readGlobPkgId pkgid_str
 277         exposePackage pkgid cli
 278     ["hide",   pkgid_str] -> do
 279         pkgid <- readGlobPkgId pkgid_str
 280         hidePackage pkgid cli
 281     ["list"] -> do
 282         listPackages cli Nothing Nothing
 283     ["list", pkgid_str] ->
 284         case substringCheck pkgid_str of
 285           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 286                         listPackages cli (Just (Id pkgid)) Nothing
 287           Just m -> listPackages cli (Just (Substring pkgid_str m)) Nothing
 288     ["find-module", moduleName] -> do
 289         let match = maybe (==moduleName) id (substringCheck moduleName)
 290         listPackages cli Nothing (Just match)
 291     ["latest", pkgid_str] -> do
 292         pkgid <- readGlobPkgId pkgid_str
 293         latestPackage cli pkgid
 294     ["describe", pkgid_str] ->
 295         case substringCheck pkgid_str of
 296           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 297                         describePackage cli (Id pkgid)
 298           Just m -> describePackage cli (Substring pkgid_str m)
 299     ["field", pkgid_str, fields] ->
 300         case substringCheck pkgid_str of
 301           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 302                         describeField cli (Id pkgid) (splitFields fields)
 303           Just m -> describeField cli (Substring pkgid_str m)
 304                                       (splitFields fields)
 305     ["check"] -> do
 306         checkConsistency cli
 307     [] -> do
 308         die ("missing command\n" ++
 309                 usageInfo (usageHeader prog) flags)
 310     (_cmd:_) -> do
 311         die ("command-line syntax error\n" ++
 312                 usageInfo (usageHeader prog) flags)
 313
 314 parseCheck :: ReadP a a -> String -> String -> IO a
 315 parseCheck parser str what =
 316   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 317     [x] -> return x
 318     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 319
 320 readGlobPkgId :: String -> IO PackageIdentifier
 321 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 322
 323 parseGlobPackageId :: ReadP r PackageIdentifier
 324 parseGlobPackageId =
 325   parse
 326      +++
 327   (do n <- parsePackageName; string "-*"
 328       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 329
 330 -- globVersion means "all versions"
 331 globVersion :: Version
 332 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 333
 334 -- -----------------------------------------------------------------------------
 335 -- Package databases
 336
 337 -- Some commands operate on a single database:
 338 --      register, unregister, expose, hide
 339 -- however these commands also check the union of the available databases
 340 -- in order to check consistency.  For example, register will check that
 341 -- dependencies exist before registering a package.
 342 --
 343 -- Some commands operate  on multiple databases, with overlapping semantics:
 344 --      list, describe, field
 345
 346 type PackageDBName  = FilePath
 347 type PackageDB      = [InstalledPackageInfo]
 348
 349 type PackageDBStack = [(PackageDBName,PackageDB)]
 350         -- A stack of package databases.  Convention: head is the topmost
 351         -- in the stack.  Earlier entries override later one.
 352
 353 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 354 getPkgDatabases modify flags = do
 355   -- first we determine the location of the global package config.  On Windows,
 356   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 357   -- location is passed to the binary using the --global-config flag by the
 358   -- wrapper script.
 359   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 360   global_conf <-
 361      case [ f | FlagGlobalConfig f <- flags ] of
 362         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 363                  case mb_dir of
 364                         Nothing  -> die err_msg
 365                         Just dir -> return (dir </> "package.conf")
 366         fs -> return (last fs)
 367
 368   let global_conf_dir = global_conf ++ ".d"
 369   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 370   global_confs <-
 371     if global_conf_dir_exists
 372       then do files <- getDirectoryContents global_conf_dir
 373               return [ global_conf_dir ++ '/' : file
 374                      | file <- files
 375                      , isSuffixOf ".conf" file]
 376       else return []
 377
 378   -- get the location of the user package database, and create it if necessary
 379   appdir <- getAppUserDataDirectory "ghc"
 380
 381   let
 382         subdir = targetARCH ++ '-':targetOS ++ '-':Version.version
 383         archdir   = appdir </> subdir
 384         user_conf = archdir </> "package.conf"
 385   user_exists <- doesFileExist user_conf
 386
 387   -- If the user database doesn't exist, and this command isn't a
 388   -- "modify" command, then we won't attempt to create or use it.
 389   let sys_databases
 390         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 391         | otherwise             = global_confs ++ [global_conf]
 392
 393   e_pkg_path <- try (System.Environment.getEnv "GHC_PACKAGE_PATH")
 394   let env_stack =
 395         case e_pkg_path of
 396                 Left  _ -> sys_databases
 397                 Right path
 398                   | last cs == ""  -> init cs ++ sys_databases
 399                   | otherwise      -> cs
 400                   where cs = splitSearchPath path
 401
 402         -- The "global" database is always the one at the bottom of the stack.
 403         -- This is the database we modify by default.
 404       virt_global_conf = last env_stack
 405
 406   let db_flags = [ f | Just f <- map is_db_flag flags ]
 407          where is_db_flag FlagUser       = Just user_conf
 408                is_db_flag FlagGlobal     = Just virt_global_conf
 409                is_db_flag (FlagConfig f) = Just f
 410                is_db_flag _              = Nothing
 411
 412   final_stack <-
 413      if not modify
 414         then    -- For a "read" command, we use all the databases
 415                 -- specified on the command line.  If there are no
 416                 -- command-line flags specifying databases, the default
 417                 -- is to use all the ones we know about.
 418              if null db_flags then return env_stack
 419                               else return (reverse (nub db_flags))
 420         else let
 421                 -- For a "modify" command, treat all the databases as
 422                 -- a stack, where we are modifying the top one, but it
 423                 -- can refer to packages in databases further down the
 424                 -- stack.
 425
 426                 -- -f flags on the command line add to the database
 427                 -- stack, unless any of them are present in the stack
 428                 -- already.
 429                 flag_stack = filter (`notElem` env_stack)
 430                                 [ f | FlagConfig f <- reverse flags ]
 431                                 ++ env_stack
 432
 433                 modifying f
 434                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 435                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 436              in
 437                 if null db_flags
 438                    then modifying virt_global_conf
 439                    else modifying (head db_flags)
 440
 441   db_stack <- mapM readParseDatabase final_stack
 442   return db_stack
 443
 444 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 445 readParseDatabase filename = do
 446   str <- readFile filename `Exception.catch` \_ -> return emptyPackageConfig
 447   let packages = read str
 448   Exception.evaluate packages
 449     `Exception.catch` \e->
 450         die ("error while parsing " ++ filename ++ ": " ++ show e)
 451   return (filename,packages)
 452
 453 emptyPackageConfig :: String
 454 emptyPackageConfig = "[]"
 455
 456 -- -----------------------------------------------------------------------------
 457 -- Registering
 458
 459 registerPackage :: FilePath
 460                 -> [Flag]
 461                 -> Bool              -- auto_ghci_libs
 462                 -> Bool              -- update
 463                 -> Force
 464                 -> IO ()
 465 registerPackage input flags auto_ghci_libs update force = do
 466   db_stack <- getPkgDatabases True flags
 467   let
 468         db_to_operate_on = my_head "db" db_stack
 469         db_filename      = fst db_to_operate_on
 470   --
 471
 472   s <-
 473     case input of
 474       "-" -> do
 475         putStr "Reading package info from stdin ... "
 476         getContents
 477       f   -> do
 478         putStr ("Reading package info from " ++ show f ++ " ... ")
 479         readFile f
 480
 481   expanded <- expandEnvVars s force
 482
 483   pkg <- parsePackageInfo expanded
 484   putStrLn "done."
 485
 486   validatePackageConfig pkg db_stack auto_ghci_libs update force
 487   let new_details = filter not_this (snd db_to_operate_on) ++ [pkg]
 488       not_this p = package p /= package pkg
 489   savingOldConfig db_filename $
 490     writeNewConfig db_filename new_details
 491
 492 parsePackageInfo
 493         :: String
 494         -> IO InstalledPackageInfo
 495 parsePackageInfo str =
 496   case parseInstalledPackageInfo str of
 497     ParseOk _warns ok -> return ok
 498     ParseFailed err -> case locatedErrorMsg err of
 499                            (Nothing, s) -> die s
 500                            (Just l, s) -> die (show l ++ ": " ++ s)
 501
 502 -- -----------------------------------------------------------------------------
 503 -- Exposing, Hiding, Unregistering are all similar
 504
 505 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 506 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 507
 508 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 509 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 510
 511 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 512 unregisterPackage = modifyPackage (\p -> [])
 513
 514 modifyPackage
 515   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 516   -> PackageIdentifier
 517   -> [Flag]
 518   -> IO ()
 519 modifyPackage fn pkgid flags  = do
 520   db_stack <- getPkgDatabases True{-modify-} flags
 521   let ((db_name, pkgs) : _) = db_stack
 522   ps <- findPackages [(db_name,pkgs)] (Id pkgid)
 523   let pids = map package ps
 524   let new_config = concat (map modify pkgs)
 525       modify pkg
 526           | package pkg `elem` pids = fn pkg
 527           | otherwise               = [pkg]
 528   savingOldConfig db_name $
 529       writeNewConfig db_name new_config
 530
 531 -- -----------------------------------------------------------------------------
 532 -- Listing packages
 533
 534 listPackages ::  [Flag] -> Maybe PackageArg -> Maybe (String->Bool) -> IO ()
 535 listPackages flags mPackageName mModuleName = do
 536   let simple_output = FlagSimpleOutput `elem` flags
 537   db_stack <- getPkgDatabases False flags
 538   let db_stack_filtered -- if a package is given, filter out all other packages
 539         | Just this <- mPackageName =
 540             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 541                 db_stack
 542         | Just match <- mModuleName = -- packages which expose mModuleName
 543             map (\(conf,pkgs) -> (conf, filter (match `exposedInPkg`) pkgs))
 544                 db_stack
 545         | otherwise = db_stack
 546
 547       db_stack_sorted
 548           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 549           where sort_pkgs = sortBy cmpPkgIds
 550                 cmpPkgIds pkg1 pkg2 =
 551                    case pkgName p1 `compare` pkgName p2 of
 552                         LT -> LT
 553                         GT -> GT
 554                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 555                    where (p1,p2) = (package pkg1, package pkg2)
 556
 557       match `exposedInPkg` pkg = any match (exposedModules pkg)
 558
 559       pkg_map = map (\p -> (package p, p)) $ concatMap snd db_stack
 560       show_func = if simple_output then show_simple else mapM_ (show_normal pkg_map)
 561
 562   show_func (reverse db_stack_sorted)
 563
 564   where show_normal pkg_map (db_name,pkg_confs) =
 565           hPutStrLn stdout (render $
 566                 text db_name <> colon $$ nest 4 packages
 567                 )
 568            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 569                  pp_pkg p
 570                    | isBrokenPackage p pkg_map = braces doc
 571                    | exposed p = doc
 572                    | otherwise = parens doc
 573                    where doc = text (display (package p))
 574
 575         show_simple db_stack = do
 576           let showPkg = if FlagNamesOnly `elem` flags then pkgName
 577                                                       else display
 578               pkgs = map showPkg $ sortBy compPkgIdVer $
 579                           map package (concatMap snd db_stack)
 580           when (not (null pkgs)) $
 581              hPutStrLn stdout $ concat $ intersperse " " pkgs
 582
 583 -- -----------------------------------------------------------------------------
 584 -- Prints the highest (hidden or exposed) version of a package
 585
 586 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 587 latestPackage flags pkgid = do
 588   db_stack <- getPkgDatabases False flags
 589   ps <- findPackages db_stack (Id pkgid)
 590   show_pkg (sortBy compPkgIdVer (map package ps))
 591   where
 592     show_pkg [] = die "no matches"
 593     show_pkg pids = hPutStrLn stdout (display (last pids))
 594
 595 -- -----------------------------------------------------------------------------
 596 -- Describe
 597
 598 describePackage :: [Flag] -> PackageArg -> IO ()
 599 describePackage flags pkgarg = do
 600   db_stack <- getPkgDatabases False flags
 601   ps <- findPackages db_stack pkgarg
 602   mapM_ (putStrLn . showInstalledPackageInfo) ps
 603
 604 -- PackageId is can have globVersion for the version
 605 findPackages :: PackageDBStack -> PackageArg -> IO [InstalledPackageInfo]
 606 findPackages db_stack pkgarg
 607   = case [ p | p <- all_pkgs, pkgarg `matchesPkg` p ] of
 608         []  -> die ("cannot find package " ++ pkg_msg pkgarg)
 609         ps -> return ps
 610   where
 611         all_pkgs = concat (map snd db_stack)
 612         pkg_msg (Id pkgid)           = display pkgid
 613         pkg_msg (Substring pkgpat _) = "matching "++pkgpat
 614
 615 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 616 pid `matches` pid'
 617   = (pkgName pid == pkgName pid')
 618     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 619
 620 matchesPkg :: PackageArg -> InstalledPackageInfo -> Bool
 621 (Id pid)        `matchesPkg` pkg = pid `matches` package pkg
 622 (Substring _ m) `matchesPkg` pkg = m (display (package pkg))
 623
 624 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 625 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 626
 627 -- -----------------------------------------------------------------------------
 628 -- Field
 629
 630 describeField :: [Flag] -> PackageArg -> [String] -> IO ()
 631 describeField flags pkgarg fields = do
 632   db_stack <- getPkgDatabases False flags
 633   fns <- toFields fields
 634   ps <- findPackages db_stack pkgarg
 635   let top_dir = takeDirectory (fst (last db_stack))
 636   mapM_ (selectFields fns) (mungePackagePaths top_dir ps)
 637   where toFields [] = return []
 638         toFields (f:fs) = case toField f of
 639             Nothing -> die ("unknown field: " ++ f)
 640             Just fn -> do fns <- toFields fs
 641                           return (fn:fns)
 642         selectFields fns info = mapM_ (\fn->putStrLn (fn info)) fns
 643
 644 mungePackagePaths :: String -> [InstalledPackageInfo] -> [InstalledPackageInfo]
 645 -- Replace the strings "$topdir" and "$httptopdir" at the beginning of a path
 646 -- with the current topdir (obtained from the -B option).
 647 mungePackagePaths top_dir ps = map munge_pkg ps
 648   where
 649   munge_pkg p = p{ importDirs        = munge_paths (importDirs p),
 650                    includeDirs       = munge_paths (includeDirs p),
 651                    libraryDirs       = munge_paths (libraryDirs p),
 652                    frameworkDirs     = munge_paths (frameworkDirs p),
 653                    haddockInterfaces = munge_paths (haddockInterfaces p),
 654                    haddockHTMLs      = munge_paths (haddockHTMLs p)
 655                  }
 656
 657   munge_paths = map munge_path
 658
 659   munge_path p
 660    | Just p' <- maybePrefixMatch "$topdir"     p =            top_dir ++ p'
 661    | Just p' <- maybePrefixMatch "$httptopdir" p = toHttpPath top_dir ++ p'
 662    | otherwise                               = p
 663
 664   toHttpPath p = "file:///" ++ p
 665
 666 maybePrefixMatch :: String -> String -> Maybe String
 667 maybePrefixMatch []    rest = Just rest
 668 maybePrefixMatch (_:_) []   = Nothing
 669 maybePrefixMatch (p:pat) (r:rest)
 670   | p == r    = maybePrefixMatch pat rest
 671   | otherwise = Nothing
 672
 673 toField :: String -> Maybe (InstalledPackageInfo -> String)
 674 -- backwards compatibility:
 675 toField "import_dirs"     = Just $ strList . importDirs
 676 toField "source_dirs"     = Just $ strList . importDirs
 677 toField "library_dirs"    = Just $ strList . libraryDirs
 678 toField "hs_libraries"    = Just $ strList . hsLibraries
 679 toField "extra_libraries" = Just $ strList . extraLibraries
 680 toField "include_dirs"    = Just $ strList . includeDirs
 681 toField "c_includes"      = Just $ strList . includes
 682 toField "package_deps"    = Just $ strList . map display. depends
 683 toField "extra_cc_opts"   = Just $ strList . ccOptions
 684 toField "extra_ld_opts"   = Just $ strList . ldOptions
 685 toField "framework_dirs"  = Just $ strList . frameworkDirs
 686 toField "extra_frameworks"= Just $ strList . frameworks
 687 toField s                 = showInstalledPackageInfoField s
 688
 689 strList :: [String] -> String
 690 strList = show
 691
 692
 693 -- -----------------------------------------------------------------------------
 694 -- Check: Check consistency of installed packages
 695
 696 checkConsistency :: [Flag] -> IO ()
 697 checkConsistency flags = do
 698   db_stack <- getPkgDatabases True flags
 699          -- check behaves like modify for the purposes of deciding which
 700          -- databases to use, because ordering is important.
 701   let pkgs = map (\p -> (package p, p)) $ concatMap snd db_stack
 702       broken_pkgs = do
 703         (pid, p) <- pkgs
 704         let broken_deps = missingPackageDeps p pkgs
 705         guard (not . null $ broken_deps)
 706         return (pid, broken_deps)
 707   mapM_ (putStrLn . render . show_func) broken_pkgs
 708   where
 709   show_func | FlagSimpleOutput `elem` flags = show_simple
 710             | otherwise = show_normal
 711   show_simple (pid,deps) =
 712     text (display pid) <> colon
 713       <+> fsep (punctuate comma (map (text . display) deps))
 714   show_normal (pid,deps) =
 715     text "package" <+> text (display pid) <+> text "has missing dependencies:"
 716       $$ nest 4 (fsep (punctuate comma (map (text . display) deps)))
 717
 718 missingPackageDeps :: InstalledPackageInfo
 719                    -> [(PackageIdentifier, InstalledPackageInfo)]
 720                    -> [PackageIdentifier]
 721 missingPackageDeps pkg pkg_map =
 722   [ d | d <- depends pkg, isNothing (lookup d pkg_map)] ++
 723   [ d | d <- depends pkg, Just p <- return (lookup d pkg_map),
 724                           isBrokenPackage p pkg_map]
 725
 726 isBrokenPackage :: InstalledPackageInfo -> [(PackageIdentifier, InstalledPackageInfo)] -> Bool
 727 isBrokenPackage pkg pkg_map
 728    = not . null $ missingPackageDeps pkg (filter notme pkg_map)
 729    where notme (p,ipi) = package pkg /= p
 730         -- remove p from the database when we invoke missingPackageDeps,
 731         -- because we want mutually recursive groups of package to show up
 732         -- as broken. (#1750)
 733
 734 -- -----------------------------------------------------------------------------
 735 -- Manipulating package.conf files
 736
 737 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 738 writeNewConfig filename packages = do
 739   hPutStr stdout "Writing new package config file... "
 740   createDirectoryIfMissing True $ takeDirectory filename
 741   h <- openFile filename WriteMode `catch` \e ->
 742       if isPermissionError e
 743       then die (filename ++ ": you don't have permission to modify this file")
 744       else ioError e
 745   let shown = concat $ intersperse ",\n " $ map show packages
 746       fileContents = "[" ++ shown ++ "\n]"
 747   hPutStrLn h fileContents
 748   hClose h
 749   hPutStrLn stdout "done."
 750
 751 savingOldConfig :: FilePath -> IO () -> IO ()
 752 savingOldConfig filename io = Exception.block $ do
 753   hPutStr stdout "Saving old package config file... "
 754     -- mv rather than cp because we've already done an hGetContents
 755     -- on this file so we won't be able to open it for writing
 756     -- unless we move the old one out of the way...
 757   let oldFile = filename ++ ".old"
 758   restore_on_error <- catch (renameFile filename oldFile >> return True) $
 759       \err -> do
 760           unless (isDoesNotExistError err) $ do
 761               hPutStrLn stderr (unwords ["Unable to rename", show filename,
 762                                          "to", show oldFile])
 763               ioError err
 764           return False
 765   (do hPutStrLn stdout "done."; io)
 766     `Exception.catch` \e -> do
 767       hPutStr stdout ("WARNING: an error was encountered while writing "
 768                    ++ "the new configuration.\n")
 769         -- remove any partially complete new version:
 770       try (removeFile filename)
 771         -- and attempt to restore the old one, if we had one:
 772       when restore_on_error $ do
 773            hPutStr stdout "Attempting to restore the old configuration... "
 774            do renameFile oldFile filename
 775               hPutStrLn stdout "done."
 776             `catch` \err -> hPutStrLn stdout ("Failed: " ++ show err)
 777         -- Note the above renameFile sometimes fails on Windows with
 778         -- "permission denied", I have no idea why --SDM.
 779       Exception.throwIO e
 780
 781 -----------------------------------------------------------------------------
 782 -- Sanity-check a new package config, and automatically build GHCi libs
 783 -- if requested.
 784
 785 validatePackageConfig :: InstalledPackageInfo
 786                       -> PackageDBStack
 787                       -> Bool   -- auto-ghc-libs
 788                       -> Bool   -- update
 789                       -> Force
 790                       -> IO ()
 791 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 792   checkPackageId pkg
 793   checkDuplicates db_stack pkg update force
 794   mapM_ (checkDep db_stack force) (depends pkg)
 795   mapM_ (checkDir force) (importDirs pkg)
 796   mapM_ (checkDir force) (libraryDirs pkg)
 797   mapM_ (checkDir force) (includeDirs pkg)
 798   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 799   -- ToDo: check these somehow?
 800   --    extra_libraries :: [String],
 801   --    c_includes      :: [String],
 802
 803 -- When the package name and version are put together, sometimes we can
 804 -- end up with a package id that cannot be parsed.  This will lead to
 805 -- difficulties when the user wants to refer to the package later, so
 806 -- we check that the package id can be parsed properly here.
 807 checkPackageId :: InstalledPackageInfo -> IO ()
 808 checkPackageId ipi =
 809   let str = display (package ipi) in
 810   case [ x :: PackageIdentifier | (x,ys) <- readP_to_S parse str, all isSpace ys ] of
 811     [_] -> return ()
 812     []  -> die ("invalid package identifier: " ++ str)
 813     _   -> die ("ambiguous package identifier: " ++ str)
 814
 815 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> Force -> IO ()
 816 checkDuplicates db_stack pkg update force = do
 817   let
 818         pkgid = package pkg
 819         (_top_db_name, pkgs) : _  = db_stack
 820   --
 821   -- Check whether this package id already exists in this DB
 822   --
 823   when (not update && (pkgid `elem` map package pkgs)) $
 824        die ("package " ++ display pkgid ++ " is already installed")
 825
 826   let
 827         uncasep = map toLower . display
 828         dups = filter ((== uncasep pkgid) . uncasep) (map package pkgs)
 829
 830   when (not update && not (null dups)) $ dieOrForceAll force $
 831         "Package names may be treated case-insensitively in the future.\n"++
 832         "Package " ++ display pkgid ++
 833         " overlaps with: " ++ unwords (map display dups)
 834
 835
 836 checkDir :: Force -> String -> IO ()
 837 checkDir force d
 838  | "$topdir"     `isPrefixOf` d = return ()
 839  | "$httptopdir" `isPrefixOf` d = return ()
 840         -- can't check these, because we don't know what $(http)topdir is
 841  | otherwise = do
 842    there <- doesDirectoryExist d
 843    when (not there)
 844        (dieOrForceFile force (d ++ " doesn't exist or isn't a directory"))
 845
 846 checkDep :: PackageDBStack -> Force -> PackageIdentifier -> IO ()
 847 checkDep db_stack force pkgid
 848   | pkgid `elem` pkgids || (not real_version && name_exists) = return ()
 849   | otherwise = dieOrForceAll force ("dependency " ++ display pkgid
 850                                         ++ " doesn't exist")
 851   where
 852         -- for backwards compat, we treat 0.0 as a special version,
 853         -- and don't check that it actually exists.
 854         real_version = realVersion pkgid
 855
 856         name_exists = any (\p -> pkgName (package p) == name) all_pkgs
 857         name = pkgName pkgid
 858
 859         all_pkgs = concat (map snd db_stack)
 860         pkgids = map package all_pkgs
 861
 862 realVersion :: PackageIdentifier -> Bool
 863 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 864
 865 checkHSLib :: [String] -> Bool -> Force -> String -> IO ()
 866 checkHSLib dirs auto_ghci_libs force lib = do
 867   let batch_lib_file = "lib" ++ lib ++ ".a"
 868   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 869   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 870         [] -> dieOrForceFile force ("cannot find " ++ batch_lib_file ++
 871                                     " on library path")
 872         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 873
 874 doesLibExistIn :: String -> String -> IO Bool
 875 doesLibExistIn lib d
 876  | "$topdir"     `isPrefixOf` d = return True
 877  | "$httptopdir" `isPrefixOf` d = return True
 878  | otherwise                = doesFileExist (d ++ '/':lib)
 879
 880 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 881 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 882   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 883   | otherwise  = do
 884       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 885       case [dir | (exists,dir) <- zip bs dirs, exists] of
 886         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 887         (_:_) -> return ()
 888   where
 889     ghci_lib_file = lib ++ ".o"
 890
 891 -- automatically build the GHCi version of a batch lib,
 892 -- using ld --whole-archive.
 893
 894 autoBuildGHCiLib :: String -> String -> String -> IO ()
 895 autoBuildGHCiLib dir batch_file ghci_file = do
 896   let ghci_lib_file  = dir ++ '/':ghci_file
 897       batch_lib_file = dir ++ '/':batch_file
 898   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 899 #if defined(darwin_HOST_OS)
 900   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 901 #elif defined(mingw32_HOST_OS)
 902   execDir <- getExecDir "/bin/ghc-pkg.exe"
 903   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 904 #else
 905   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 906 #endif
 907   when (r /= ExitSuccess) $ exitWith r
 908   hPutStrLn stderr (" done.")
 909
 910 -- -----------------------------------------------------------------------------
 911 -- Searching for modules
 912
 913 #if not_yet
 914
 915 findModules :: [FilePath] -> IO [String]
 916 findModules paths =
 917   mms <- mapM searchDir paths
 918   return (concat mms)
 919
 920 searchDir path prefix = do
 921   fs <- getDirectoryEntries path `catch` \_ -> return []
 922   searchEntries path prefix fs
 923
 924 searchEntries path prefix [] = return []
 925 searchEntries path prefix (f:fs)
 926   | looks_like_a_module  =  do
 927         ms <- searchEntries path prefix fs
 928         return (prefix `joinModule` f : ms)
 929   | looks_like_a_component  =  do
 930         ms <- searchDir (path </> f) (prefix `joinModule` f)
 931         ms' <- searchEntries path prefix fs
 932         return (ms ++ ms')
 933   | otherwise
 934         searchEntries path prefix fs
 935
 936   where
 937         (base,suffix) = splitFileExt f
 938         looks_like_a_module =
 939                 suffix `elem` haskell_suffixes &&
 940                 all okInModuleName base
 941         looks_like_a_component =
 942                 null suffix && all okInModuleName base
 943
 944 okInModuleName c
 945
 946 #endif
 947
 948 -- ---------------------------------------------------------------------------
 949 -- expanding environment variables in the package configuration
 950
 951 expandEnvVars :: String -> Force -> IO String
 952 expandEnvVars str force = go str ""
 953  where
 954    go "" acc = return $! reverse acc
 955    go ('$':'{':str) acc | (var, '}':rest) <- break close str
 956         = do value <- lookupEnvVar var
 957              go rest (reverse value ++ acc)
 958         where close c = c == '}' || c == '\n' -- don't span newlines
 959    go (c:str) acc
 960         = go str (c:acc)
 961
 962    lookupEnvVar :: String -> IO String
 963    lookupEnvVar nm =
 964         catch (System.Environment.getEnv nm)
 965            (\ _ -> do dieOrForceAll force ("Unable to expand variable " ++
 966                                         show nm)
 967                       return "")
 968
 969 -----------------------------------------------------------------------------
 970
 971 getProgramName :: IO String
 972 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
 973    where str `withoutSuffix` suff
 974             | suff `isSuffixOf` str = take (length str - length suff) str
 975             | otherwise             = str
 976
 977 bye :: String -> IO a
 978 bye s = putStr s >> exitWith ExitSuccess
 979
 980 die :: String -> IO a
 981 die s = do
 982   hFlush stdout
 983   prog <- getProgramName
 984   hPutStrLn stderr (prog ++ ": " ++ s)
 985   exitWith (ExitFailure 1)
 986
 987 dieOrForceAll :: Force -> String -> IO ()
 988 dieOrForceAll ForceAll s = ignoreError s
 989 dieOrForceAll _other s   = dieForcible s
 990
 991 dieOrForceFile :: Force -> String -> IO ()
 992 dieOrForceFile ForceAll   s = ignoreError s
 993 dieOrForceFile ForceFiles s = ignoreError s
 994 dieOrForceFile _other     s = dieForcible s
 995
 996 ignoreError :: String -> IO ()
 997 ignoreError s = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
 998
 999 dieForcible :: String -> IO ()
1000 dieForcible s = die (s ++ " (use --force to override)")
1001
1002 my_head :: String -> [a] -> a
1003 my_head s [] = error s
1004 my_head s (x:xs) = x
1005
1006 -----------------------------------------
1007 -- Cut and pasted from ghc/compiler/main/SysTools
1008
1009 #if defined(mingw32_HOST_OS)
1010 subst :: Char -> Char -> String -> String
1011 subst a b ls = map (\ x -> if x == a then b else x) ls
1012
1013 unDosifyPath :: FilePath -> FilePath
1014 unDosifyPath xs = subst '\\' '/' xs
1015
1016 getExecDir :: String -> IO (Maybe String)
1017 -- (getExecDir cmd) returns the directory in which the current
1018 --                  executable, which should be called 'cmd', is running
1019 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
1020 -- you'll get "/a/b/c" back as the result
1021 getExecDir cmd
1022   = allocaArray len $ \buf -> do
1023         ret <- getModuleFileName nullPtr buf len
1024         if ret == 0 then return Nothing
1025                     else do s <- peekCString buf
1026                             return (Just (reverse (drop (length cmd)
1027                                                         (reverse (unDosifyPath s)))))
1028   where
1029     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
1030
1031 foreign import stdcall unsafe  "GetModuleFileNameA"
1032   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
1033 #else
1034 getExecDir :: String -> IO (Maybe String)
1035 getExecDir _ = return Nothing
1036 #endif
1037
1038 -----------------------------------------
1039 -- Adapted from ghc/compiler/utils/Panic
1040
1041 installSignalHandlers :: IO ()
1042 installSignalHandlers = do
1043   threadid <- myThreadId
1044   let
1045       interrupt = throwTo threadid (Exception.ErrorCall "interrupted")
1046   --
1047 #if !defined(mingw32_HOST_OS)
1048   installHandler sigQUIT (Catch interrupt) Nothing
1049   installHandler sigINT  (Catch interrupt) Nothing
1050   return ()
1051 #elif __GLASGOW_HASKELL__ >= 603
1052   -- GHC 6.3+ has support for console events on Windows
1053   -- NOTE: running GHCi under a bash shell for some reason requires
1054   -- you to press Ctrl-Break rather than Ctrl-C to provoke
1055   -- an interrupt.  Ctrl-C is getting blocked somewhere, I don't know
1056   -- why --SDM 17/12/2004
1057   let sig_handler ControlC = interrupt
1058       sig_handler Break    = interrupt
1059       sig_handler _        = return ()
1060
1061   installHandler (Catch sig_handler)
1062   return ()
1063 #else
1064   return () -- nothing
1065 #endif
1066
1067 #if __GLASGOW_HASKELL__ <= 604
1068 isInfixOf               :: (Eq a) => [a] -> [a] -> Bool
1069 isInfixOf needle haystack = any (isPrefixOf needle) (tails haystack)
1070 #endif