utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts -cpp #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 -- * validate modules
  12 -- * expanding of variables in new-style package conf
  13 -- * version manipulation (checking whether old version exists,
  14 --   hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo hiding (depends)
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils
  22 import Distribution.Package
  23 import Distribution.Text
  24 import Distribution.Version
  25 import System.FilePath
  26 import System.Cmd       ( rawSystem )
  27 import System.Directory ( getAppUserDataDirectory, createDirectoryIfMissing )
  28
  29 import Prelude
  30
  31 #include "../../includes/ghcconfig.h"
  32
  33 import System.Console.GetOpt
  34 import Text.PrettyPrint
  35 import qualified Control.Exception as Exception
  36 import Data.Maybe
  37
  38 import Data.Char ( isSpace, toLower )
  39 import Control.Monad
  40 import System.Directory ( doesDirectoryExist, getDirectoryContents,
  41                           doesFileExist, renameFile, removeFile )
  42 import System.Exit ( exitWith, ExitCode(..) )
  43 import System.Environment ( getArgs, getProgName, getEnv )
  44 import System.IO
  45 import System.IO.Error (try)
  46 import Data.List ( isPrefixOf, isSuffixOf, intersperse, sortBy, nub,
  47                    unfoldr, break )
  48 #if __GLASGOW_HASKELL__ > 604
  49 import Data.List ( isInfixOf )
  50 #else
  51 import Data.List ( tails )
  52 #endif
  53 import Control.Concurrent
  54
  55 #ifdef mingw32_HOST_OS
  56 import Foreign
  57 import Foreign.C.String
  58 import GHC.ConsoleHandler
  59 #else
  60 import System.Posix
  61 #endif
  62
  63 import IO ( isPermissionError, isDoesNotExistError )
  64
  65 #if defined(GLOB)
  66 import System.Process(runInteractiveCommand)
  67 import qualified System.Info(os)
  68 #endif
  69
  70 -- -----------------------------------------------------------------------------
  71 -- Entry point
  72
  73 main :: IO ()
  74 main = do
  75   args <- getArgs
  76
  77   case getOpt Permute (flags ++ deprecFlags) args of
  78         (cli,_,[]) | FlagHelp `elem` cli -> do
  79            prog <- getProgramName
  80            bye (usageInfo (usageHeader prog) flags)
  81         (cli,_,[]) | FlagVersion `elem` cli ->
  82            bye ourCopyright
  83         (cli,nonopts,[]) ->
  84            runit cli nonopts
  85         (_,_,errors) -> do
  86            prog <- getProgramName
  87            die (concat errors ++ usageInfo (usageHeader prog) flags)
  88
  89 -- -----------------------------------------------------------------------------
  90 -- Command-line syntax
  91
  92 data Flag
  93   = FlagUser
  94   | FlagGlobal
  95   | FlagHelp
  96   | FlagVersion
  97   | FlagConfig FilePath
  98   | FlagGlobalConfig FilePath
  99   | FlagForce
 100   | FlagForceFiles
 101   | FlagAutoGHCiLibs
 102   | FlagSimpleOutput
 103   | FlagNamesOnly
 104   | FlagIgnoreCase
 105   deriving Eq
 106
 107 flags :: [OptDescr Flag]
 108 flags = [
 109   Option [] ["user"] (NoArg FlagUser)
 110         "use the current user's package database",
 111   Option [] ["global"] (NoArg FlagGlobal)
 112         "use the global package database",
 113   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 114         "use the specified package config file",
 115   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 116         "location of the global package config",
 117   Option [] ["force"] (NoArg FlagForce)
 118          "ignore missing dependencies, directories, and libraries",
 119   Option [] ["force-files"] (NoArg FlagForceFiles)
 120          "ignore missing directories and libraries only",
 121   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 122         "automatically build libs for GHCi (with register)",
 123   Option ['?'] ["help"] (NoArg FlagHelp)
 124         "display this help and exit",
 125   Option ['V'] ["version"] (NoArg FlagVersion)
 126         "output version information and exit",
 127   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 128         "print output in easy-to-parse format for some commands",
 129   Option [] ["names-only"] (NoArg FlagNamesOnly)
 130         "only print package names, not versions; can only be used with list --simple-output",
 131   Option [] ["ignore-case"] (NoArg FlagIgnoreCase)
 132         "ignore case for substring matching"
 133   ]
 134
 135 deprecFlags :: [OptDescr Flag]
 136 deprecFlags = [
 137         -- put deprecated flags here
 138   ]
 139
 140 ourCopyright :: String
 141 ourCopyright = "GHC package manager version " ++ Version.version ++ "\n"
 142
 143 usageHeader :: String -> String
 144 usageHeader prog = substProg prog $
 145   "Usage:\n" ++
 146   "  $p register {filename | -}\n" ++
 147   "    Register the package using the specified installed package\n" ++
 148   "    description. The syntax for the latter is given in the $p\n" ++
 149   "    documentation.\n" ++
 150   "\n" ++
 151   "  $p update {filename | -}\n" ++
 152   "    Register the package, overwriting any other package with the\n" ++
 153   "    same name.\n" ++
 154   "\n" ++
 155   "  $p unregister {pkg-id}\n" ++
 156   "    Unregister the specified package.\n" ++
 157   "\n" ++
 158   "  $p expose {pkg-id}\n" ++
 159   "    Expose the specified package.\n" ++
 160   "\n" ++
 161   "  $p hide {pkg-id}\n" ++
 162   "    Hide the specified package.\n" ++
 163   "\n" ++
 164   "  $p list [pkg]\n" ++
 165   "    List registered packages in the global database, and also the\n" ++
 166   "    user database if --user is given. If a package name is given\n" ++
 167   "    all the registered versions will be listed in ascending order.\n" ++
 168   "    Accepts the --simple-output flag.\n" ++
 169   "\n" ++
 170   "  $p find-module {module}\n" ++
 171   "    List registered packages exposing module {module} in the global\n" ++
 172   "    database, and also the user database if --user is given.\n" ++
 173   "    All the registered versions will be listed in ascending order.\n" ++
 174   "    Accepts the --simple-output flag.\n" ++
 175   "\n" ++
 176   "  $p latest {pkg-id}\n" ++
 177   "    Prints the highest registered version of a package.\n" ++
 178   "\n" ++
 179   "  $p check\n" ++
 180   "    Check the consistency of package depenencies and list broken packages.\n" ++
 181   "    Accepts the --simple-output flag.\n" ++
 182   "\n" ++
 183   "  $p describe {pkg}\n" ++
 184   "    Give the registered description for the specified package. The\n" ++
 185   "    description is returned in precisely the syntax required by $p\n" ++
 186   "    register.\n" ++
 187   "\n" ++
 188   "  $p field {pkg} {field}\n" ++
 189   "    Extract the specified field of the package description for the\n" ++
 190   "    specified package. Accepts comma-separated multiple fields.\n" ++
 191   "\n" ++
 192   "  $p dump\n" ++
 193   "    Dump the registered description for every package.  This is like\n" ++
 194   "    \"ghc-pkg describe '*'\", except that it is intended to be used\n" ++
 195   "    by tools that parse the results, rather than humans.\n" ++
 196   "\n" ++
 197   " Substring matching is supported for {module} in find-module and\n" ++
 198   " for {pkg} in list, describe, and field, where a '*' indicates\n" ++
 199   " open substring ends (prefix*, *suffix, *infix*).\n" ++
 200   "\n" ++
 201   "  When asked to modify a database (register, unregister, update,\n"++
 202   "  hide, expose, and also check), ghc-pkg modifies the global database by\n"++
 203   "  default.  Specifying --user causes it to act on the user database,\n"++
 204   "  or --package-conf can be used to act on another database\n"++
 205   "  entirely. When multiple of these options are given, the rightmost\n"++
 206   "  one is used as the database to act upon.\n"++
 207   "\n"++
 208   "  Commands that query the package database (list, latest, describe,\n"++
 209   "  field) operate on the list of databases specified by the flags\n"++
 210   "  --user, --global, and --package-conf.  If none of these flags are\n"++
 211   "  given, the default is --global --user.\n"++
 212   "\n" ++
 213   " The following optional flags are also accepted:\n"
 214
 215 substProg :: String -> String -> String
 216 substProg _ [] = []
 217 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 218 substProg prog (c:xs) = c : substProg prog xs
 219
 220 -- -----------------------------------------------------------------------------
 221 -- Do the business
 222
 223 data Force = ForceAll | ForceFiles | NoForce
 224
 225 data PackageArg = Id PackageIdentifier | Substring String (String->Bool)
 226
 227 runit :: [Flag] -> [String] -> IO ()
 228 runit cli nonopts = do
 229   installSignalHandlers -- catch ^C and clean up
 230   prog <- getProgramName
 231   let
 232         force
 233           | FlagForce `elem` cli        = ForceAll
 234           | FlagForceFiles `elem` cli   = ForceFiles
 235           | otherwise                   = NoForce
 236         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 237         splitFields fields = unfoldr splitComma (',':fields)
 238           where splitComma "" = Nothing
 239                 splitComma fs = Just $ break (==',') (tail fs)
 240
 241         substringCheck :: String -> Maybe (String -> Bool)
 242         substringCheck ""    = Nothing
 243         substringCheck "*"   = Just (const True)
 244         substringCheck [_]   = Nothing
 245         substringCheck (h:t) =
 246           case (h, init t, last t) of
 247             ('*',s,'*') -> Just (isInfixOf (f s) . f)
 248             ('*',_, _ ) -> Just (isSuffixOf (f t) . f)
 249             ( _ ,s,'*') -> Just (isPrefixOf (f (h:s)) . f)
 250             _           -> Nothing
 251           where f | FlagIgnoreCase `elem` cli = map toLower
 252                   | otherwise                 = id
 253 #if defined(GLOB)
 254         glob x | System.Info.os=="mingw32" = do
 255           -- glob echoes its argument, after win32 filename globbing
 256           (_,o,_,_) <- runInteractiveCommand ("glob "++x)
 257           txt <- hGetContents o
 258           return (read txt)
 259         glob x | otherwise = return [x]
 260 #endif
 261   --
 262   -- first, parse the command
 263   case nonopts of
 264 #if defined(GLOB)
 265     -- dummy command to demonstrate usage and permit testing
 266     -- without messing things up; use glob to selectively enable
 267     -- windows filename globbing for file parameters
 268     -- register, update, FlagGlobalConfig, FlagConfig; others?
 269     ["glob", filename] -> do
 270         print filename
 271         glob filename >>= print
 272 #endif
 273     ["register", filename] ->
 274         registerPackage filename cli auto_ghci_libs False force
 275     ["update", filename] ->
 276         registerPackage filename cli auto_ghci_libs True force
 277     ["unregister", pkgid_str] -> do
 278         pkgid <- readGlobPkgId pkgid_str
 279         unregisterPackage pkgid cli
 280     ["expose", pkgid_str] -> do
 281         pkgid <- readGlobPkgId pkgid_str
 282         exposePackage pkgid cli
 283     ["hide",   pkgid_str] -> do
 284         pkgid <- readGlobPkgId pkgid_str
 285         hidePackage pkgid cli
 286     ["list"] -> do
 287         listPackages cli Nothing Nothing
 288     ["list", pkgid_str] ->
 289         case substringCheck pkgid_str of
 290           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 291                         listPackages cli (Just (Id pkgid)) Nothing
 292           Just m -> listPackages cli (Just (Substring pkgid_str m)) Nothing
 293     ["find-module", moduleName] -> do
 294         let match = maybe (==moduleName) id (substringCheck moduleName)
 295         listPackages cli Nothing (Just match)
 296     ["latest", pkgid_str] -> do
 297         pkgid <- readGlobPkgId pkgid_str
 298         latestPackage cli pkgid
 299     ["describe", pkgid_str] ->
 300         case substringCheck pkgid_str of
 301           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 302                         describePackage cli (Id pkgid)
 303           Just m -> describePackage cli (Substring pkgid_str m)
 304     ["field", pkgid_str, fields] ->
 305         case substringCheck pkgid_str of
 306           Nothing -> do pkgid <- readGlobPkgId pkgid_str
 307                         describeField cli (Id pkgid) (splitFields fields)
 308           Just m -> describeField cli (Substring pkgid_str m)
 309                                       (splitFields fields)
 310     ["check"] -> do
 311         checkConsistency cli
 312
 313     ["dump"] -> do
 314         dumpPackages cli
 315
 316     [] -> do
 317         die ("missing command\n" ++
 318                 usageInfo (usageHeader prog) flags)
 319     (_cmd:_) -> do
 320         die ("command-line syntax error\n" ++
 321                 usageInfo (usageHeader prog) flags)
 322
 323 parseCheck :: ReadP a a -> String -> String -> IO a
 324 parseCheck parser str what =
 325   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 326     [x] -> return x
 327     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 328
 329 readGlobPkgId :: String -> IO PackageIdentifier
 330 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 331
 332 parseGlobPackageId :: ReadP r PackageIdentifier
 333 parseGlobPackageId =
 334   parse
 335      +++
 336   (do n <- parse
 337       string "-*"
 338       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 339
 340 -- globVersion means "all versions"
 341 globVersion :: Version
 342 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 343
 344 -- -----------------------------------------------------------------------------
 345 -- Package databases
 346
 347 -- Some commands operate on a single database:
 348 --      register, unregister, expose, hide
 349 -- however these commands also check the union of the available databases
 350 -- in order to check consistency.  For example, register will check that
 351 -- dependencies exist before registering a package.
 352 --
 353 -- Some commands operate  on multiple databases, with overlapping semantics:
 354 --      list, describe, field
 355
 356 type PackageDBName  = FilePath
 357 type PackageDB      = [InstalledPackageInfo]
 358
 359 type PackageDBStack = [(PackageDBName,PackageDB)]
 360         -- A stack of package databases.  Convention: head is the topmost
 361         -- in the stack.  Earlier entries override later one.
 362
 363 allPackagesInStack :: PackageDBStack -> [InstalledPackageInfo]
 364 allPackagesInStack = concatMap snd
 365
 366 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 367 getPkgDatabases modify my_flags = do
 368   -- first we determine the location of the global package config.  On Windows,
 369   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 370   -- location is passed to the binary using the --global-config flag by the
 371   -- wrapper script.
 372   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 373   global_conf <-
 374      case [ f | FlagGlobalConfig f <- my_flags ] of
 375         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 376                  case mb_dir of
 377                         Nothing  -> die err_msg
 378                         Just dir ->
 379                             do let path1 = dir </> "package.conf"
 380                                    path2 = dir </> ".." </> ".." </> ".."
 381                                                </> "inplace-datadir"
 382                                                </> "package.conf"
 383                                exists1 <- doesFileExist path1
 384                                exists2 <- doesFileExist path2
 385                                if exists1 then return path1
 386                                    else if exists2 then return path2
 387                                    else die "Can't find package.conf"
 388         fs -> return (last fs)
 389
 390   let global_conf_dir = global_conf ++ ".d"
 391   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 392   global_confs <-
 393     if global_conf_dir_exists
 394       then do files <- getDirectoryContents global_conf_dir
 395               return [ global_conf_dir ++ '/' : file
 396                      | file <- files
 397                      , isSuffixOf ".conf" file]
 398       else return []
 399
 400   -- get the location of the user package database, and create it if necessary
 401   appdir <- getAppUserDataDirectory "ghc"
 402
 403   let
 404         subdir = targetARCH ++ '-':targetOS ++ '-':Version.version
 405         archdir   = appdir </> subdir
 406         user_conf = archdir </> "package.conf"
 407   user_exists <- doesFileExist user_conf
 408
 409   -- If the user database doesn't exist, and this command isn't a
 410   -- "modify" command, then we won't attempt to create or use it.
 411   let sys_databases
 412         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 413         | otherwise             = global_confs ++ [global_conf]
 414
 415   e_pkg_path <- try (System.Environment.getEnv "GHC_PACKAGE_PATH")
 416   let env_stack =
 417         case e_pkg_path of
 418                 Left  _ -> sys_databases
 419                 Right path
 420                   | last cs == ""  -> init cs ++ sys_databases
 421                   | otherwise      -> cs
 422                   where cs = splitSearchPath path
 423
 424         -- The "global" database is always the one at the bottom of the stack.
 425         -- This is the database we modify by default.
 426       virt_global_conf = last env_stack
 427
 428   let db_flags = [ f | Just f <- map is_db_flag my_flags ]
 429          where is_db_flag FlagUser       = Just user_conf
 430                is_db_flag FlagGlobal     = Just virt_global_conf
 431                is_db_flag (FlagConfig f) = Just f
 432                is_db_flag _              = Nothing
 433
 434   final_stack <-
 435      if not modify
 436         then    -- For a "read" command, we use all the databases
 437                 -- specified on the command line.  If there are no
 438                 -- command-line flags specifying databases, the default
 439                 -- is to use all the ones we know about.
 440              if null db_flags then return env_stack
 441                               else return (reverse (nub db_flags))
 442         else let
 443                 -- For a "modify" command, treat all the databases as
 444                 -- a stack, where we are modifying the top one, but it
 445                 -- can refer to packages in databases further down the
 446                 -- stack.
 447
 448                 -- -f flags on the command line add to the database
 449                 -- stack, unless any of them are present in the stack
 450                 -- already.
 451                 flag_stack = filter (`notElem` env_stack)
 452                                 [ f | FlagConfig f <- reverse my_flags ]
 453                                 ++ env_stack
 454
 455                 modifying f
 456                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 457                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 458              in
 459                 if null db_flags
 460                    then modifying virt_global_conf
 461                    else modifying (head db_flags)
 462
 463   db_stack <- mapM readParseDatabase final_stack
 464   return db_stack
 465
 466 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 467 readParseDatabase filename = do
 468   str <- readFile filename `catchIO` \_ -> return emptyPackageConfig
 469   let packages = map convertPackageInfoIn $ read str
 470   Exception.evaluate packages
 471     `catchError` \e->
 472         die ("error while parsing " ++ filename ++ ": " ++ show e)
 473   return (filename,packages)
 474
 475 emptyPackageConfig :: String
 476 emptyPackageConfig = "[]"
 477
 478 -- -----------------------------------------------------------------------------
 479 -- Registering
 480
 481 registerPackage :: FilePath
 482                 -> [Flag]
 483                 -> Bool              -- auto_ghci_libs
 484                 -> Bool              -- update
 485                 -> Force
 486                 -> IO ()
 487 registerPackage input my_flags auto_ghci_libs update force = do
 488   db_stack <- getPkgDatabases True my_flags
 489   let
 490         db_to_operate_on = my_head "db" db_stack
 491         db_filename      = fst db_to_operate_on
 492   --
 493
 494   s <-
 495     case input of
 496       "-" -> do
 497         putStr "Reading package info from stdin ... "
 498         getContents
 499       f   -> do
 500         putStr ("Reading package info from " ++ show f ++ " ... ")
 501         readFile f
 502
 503   expanded <- expandEnvVars s force
 504
 505   pkg <- parsePackageInfo expanded
 506   putStrLn "done."
 507
 508   validatePackageConfig pkg db_stack auto_ghci_libs update force
 509   let new_details = filter not_this (snd db_to_operate_on) ++ [pkg]
 510       not_this p = package p /= package pkg
 511   savingOldConfig db_filename $
 512     writeNewConfig db_filename new_details
 513
 514 parsePackageInfo
 515         :: String
 516         -> IO InstalledPackageInfo
 517 parsePackageInfo str =
 518   case parseInstalledPackageInfo str of
 519     ParseOk _warns ok -> return ok
 520     ParseFailed err -> case locatedErrorMsg err of
 521                            (Nothing, s) -> die s
 522                            (Just l, s) -> die (show l ++ ": " ++ s)
 523
 524 -- -----------------------------------------------------------------------------
 525 -- Exposing, Hiding, Unregistering are all similar
 526
 527 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 528 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 529
 530 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 531 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 532
 533 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 534 unregisterPackage = modifyPackage (\_ -> [])
 535
 536 modifyPackage
 537   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 538   -> PackageIdentifier
 539   -> [Flag]
 540   -> IO ()
 541 modifyPackage fn pkgid my_flags  = do
 542   db_stack <- getPkgDatabases True{-modify-} my_flags
 543   let ((db_name, pkgs) : _) = db_stack
 544   ps <- findPackages [(db_name,pkgs)] (Id pkgid)
 545   let pids = map package ps
 546   let new_config = concat (map modify pkgs)
 547       modify pkg
 548           | package pkg `elem` pids = fn pkg
 549           | otherwise               = [pkg]
 550   savingOldConfig db_name $
 551       writeNewConfig db_name new_config
 552
 553 -- -----------------------------------------------------------------------------
 554 -- Listing packages
 555
 556 listPackages ::  [Flag] -> Maybe PackageArg -> Maybe (String->Bool) -> IO ()
 557 listPackages my_flags mPackageName mModuleName = do
 558   let simple_output = FlagSimpleOutput `elem` my_flags
 559   db_stack <- getPkgDatabases False my_flags
 560   let db_stack_filtered -- if a package is given, filter out all other packages
 561         | Just this <- mPackageName =
 562             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 563                 db_stack
 564         | Just match <- mModuleName = -- packages which expose mModuleName
 565             map (\(conf,pkgs) -> (conf, filter (match `exposedInPkg`) pkgs))
 566                 db_stack
 567         | otherwise = db_stack
 568
 569       db_stack_sorted
 570           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 571           where sort_pkgs = sortBy cmpPkgIds
 572                 cmpPkgIds pkg1 pkg2 =
 573                    case pkgName p1 `compare` pkgName p2 of
 574                         LT -> LT
 575                         GT -> GT
 576                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 577                    where (p1,p2) = (package pkg1, package pkg2)
 578
 579       match `exposedInPkg` pkg = any match (map display $ exposedModules pkg)
 580
 581       pkg_map = map (\p -> (package p, p)) $ allPackagesInStack db_stack
 582       show_func = if simple_output then show_simple else mapM_ (show_normal pkg_map)
 583
 584   show_func (reverse db_stack_sorted)
 585
 586   where show_normal pkg_map (db_name,pkg_confs) =
 587           hPutStrLn stdout (render $
 588                 text db_name <> colon $$ nest 4 packages
 589                 )
 590            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 591                  pp_pkg p
 592                    | isBrokenPackage p pkg_map = braces doc
 593                    | exposed p = doc
 594                    | otherwise = parens doc
 595                    where doc = text (display (package p))
 596
 597         show_simple db_stack = do
 598           let showPkg = if FlagNamesOnly `elem` my_flags then display . pkgName
 599                                                          else display
 600               pkgs = map showPkg $ sortBy compPkgIdVer $
 601                           map package (allPackagesInStack db_stack)
 602           when (not (null pkgs)) $
 603              hPutStrLn stdout $ concat $ intersperse " " pkgs
 604
 605 -- -----------------------------------------------------------------------------
 606 -- Prints the highest (hidden or exposed) version of a package
 607
 608 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 609 latestPackage my_flags pkgid = do
 610   db_stack <- getPkgDatabases False my_flags
 611   ps <- findPackages db_stack (Id pkgid)
 612   show_pkg (sortBy compPkgIdVer (map package ps))
 613   where
 614     show_pkg [] = die "no matches"
 615     show_pkg pids = hPutStrLn stdout (display (last pids))
 616
 617 -- -----------------------------------------------------------------------------
 618 -- Describe
 619
 620 describePackage :: [Flag] -> PackageArg -> IO ()
 621 describePackage my_flags pkgarg = do
 622   db_stack <- getPkgDatabases False my_flags
 623   ps <- findPackages db_stack pkgarg
 624   doDump ps
 625
 626 dumpPackages :: [Flag] -> IO ()
 627 dumpPackages my_flags = do
 628   db_stack <- getPkgDatabases False my_flags
 629   doDump (allPackagesInStack db_stack)
 630
 631 doDump :: [InstalledPackageInfo] -> IO ()
 632 doDump = mapM_ putStrLn . intersperse "---" . map showInstalledPackageInfo
 633
 634 -- PackageId is can have globVersion for the version
 635 findPackages :: PackageDBStack -> PackageArg -> IO [InstalledPackageInfo]
 636 findPackages db_stack pkgarg
 637   = case [ p | p <- all_pkgs, pkgarg `matchesPkg` p ] of
 638         []  -> dieWith 2 ("cannot find package " ++ pkg_msg pkgarg)
 639         ps -> return ps
 640   where
 641         all_pkgs = allPackagesInStack db_stack
 642         pkg_msg (Id pkgid)           = display pkgid
 643         pkg_msg (Substring pkgpat _) = "matching "++pkgpat
 644
 645 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 646 pid `matches` pid'
 647   = (pkgName pid == pkgName pid')
 648     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 649
 650 matchesPkg :: PackageArg -> InstalledPackageInfo -> Bool
 651 (Id pid)        `matchesPkg` pkg = pid `matches` package pkg
 652 (Substring _ m) `matchesPkg` pkg = m (display (package pkg))
 653
 654 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 655 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 656
 657 -- -----------------------------------------------------------------------------
 658 -- Field
 659
 660 describeField :: [Flag] -> PackageArg -> [String] -> IO ()
 661 describeField my_flags pkgarg fields = do
 662   db_stack <- getPkgDatabases False my_flags
 663   fns <- toFields fields
 664   ps <- findPackages db_stack pkgarg
 665   let top_dir = takeDirectory (fst (last db_stack))
 666   mapM_ (selectFields fns) (mungePackagePaths top_dir ps)
 667   where toFields [] = return []
 668         toFields (f:fs) = case toField f of
 669             Nothing -> die ("unknown field: " ++ f)
 670             Just fn -> do fns <- toFields fs
 671                           return (fn:fns)
 672         selectFields fns info = mapM_ (\fn->putStrLn (fn info)) fns
 673
 674 mungePackagePaths :: String -> [InstalledPackageInfo] -> [InstalledPackageInfo]
 675 -- Replace the strings "$topdir" and "$httptopdir" at the beginning of a path
 676 -- with the current topdir (obtained from the -B option).
 677 mungePackagePaths top_dir ps = map munge_pkg ps
 678   where
 679   munge_pkg p = p{ importDirs        = munge_paths (importDirs p),
 680                    includeDirs       = munge_paths (includeDirs p),
 681                    libraryDirs       = munge_paths (libraryDirs p),
 682                    frameworkDirs     = munge_paths (frameworkDirs p),
 683                    haddockInterfaces = munge_paths (haddockInterfaces p),
 684                    haddockHTMLs      = munge_paths (haddockHTMLs p)
 685                  }
 686
 687   munge_paths = map munge_path
 688
 689   munge_path p
 690    | Just p' <- maybePrefixMatch "$topdir"     p =            top_dir ++ p'
 691    | Just p' <- maybePrefixMatch "$httptopdir" p = toHttpPath top_dir ++ p'
 692    | otherwise                               = p
 693
 694   toHttpPath p = "file:///" ++ p
 695
 696 maybePrefixMatch :: String -> String -> Maybe String
 697 maybePrefixMatch []    rest = Just rest
 698 maybePrefixMatch (_:_) []   = Nothing
 699 maybePrefixMatch (p:pat) (r:rest)
 700   | p == r    = maybePrefixMatch pat rest
 701   | otherwise = Nothing
 702
 703 toField :: String -> Maybe (InstalledPackageInfo -> String)
 704 -- backwards compatibility:
 705 toField "import_dirs"     = Just $ strList . importDirs
 706 toField "source_dirs"     = Just $ strList . importDirs
 707 toField "library_dirs"    = Just $ strList . libraryDirs
 708 toField "hs_libraries"    = Just $ strList . hsLibraries
 709 toField "extra_libraries" = Just $ strList . extraLibraries
 710 toField "include_dirs"    = Just $ strList . includeDirs
 711 toField "c_includes"      = Just $ strList . includes
 712 toField "package_deps"    = Just $ strList . map display. depends
 713 toField "extra_cc_opts"   = Just $ strList . ccOptions
 714 toField "extra_ld_opts"   = Just $ strList . ldOptions
 715 toField "framework_dirs"  = Just $ strList . frameworkDirs
 716 toField "extra_frameworks"= Just $ strList . frameworks
 717 toField s                 = showInstalledPackageInfoField s
 718
 719 strList :: [String] -> String
 720 strList = show
 721
 722
 723 -- -----------------------------------------------------------------------------
 724 -- Check: Check consistency of installed packages
 725
 726 checkConsistency :: [Flag] -> IO ()
 727 checkConsistency my_flags = do
 728   db_stack <- getPkgDatabases True my_flags
 729          -- check behaves like modify for the purposes of deciding which
 730          -- databases to use, because ordering is important.
 731   let pkgs = map (\p -> (package p, p)) $ allPackagesInStack db_stack
 732       broken_pkgs = do
 733         (pid, p) <- pkgs
 734         let broken_deps = missingPackageDeps p pkgs
 735         guard (not . null $ broken_deps)
 736         return (pid, broken_deps)
 737   mapM_ (putStrLn . render . show_func) broken_pkgs
 738   where
 739   show_func | FlagSimpleOutput `elem` my_flags = show_simple
 740             | otherwise = show_normal
 741   show_simple (pid,deps) =
 742     text (display pid) <> colon
 743       <+> fsep (punctuate comma (map (text . display) deps))
 744   show_normal (pid,deps) =
 745     text "package" <+> text (display pid) <+> text "has missing dependencies:"
 746       $$ nest 4 (fsep (punctuate comma (map (text . display) deps)))
 747
 748 missingPackageDeps :: InstalledPackageInfo
 749                    -> [(PackageIdentifier, InstalledPackageInfo)]
 750                    -> [PackageIdentifier]
 751 missingPackageDeps pkg pkg_map =
 752   [ d | d <- depends pkg, isNothing (lookup d pkg_map)] ++
 753   [ d | d <- depends pkg, Just p <- return (lookup d pkg_map),
 754                           isBrokenPackage p pkg_map]
 755
 756 isBrokenPackage :: InstalledPackageInfo -> [(PackageIdentifier, InstalledPackageInfo)] -> Bool
 757 isBrokenPackage pkg pkg_map
 758    = not . null $ missingPackageDeps pkg (filter notme pkg_map)
 759    where notme (p, _ipi) = package pkg /= p
 760         -- remove p from the database when we invoke missingPackageDeps,
 761         -- because we want mutually recursive groups of package to show up
 762         -- as broken. (#1750)
 763
 764 -- -----------------------------------------------------------------------------
 765 -- Manipulating package.conf files
 766
 767 type InstalledPackageInfoString = InstalledPackageInfo_ String
 768
 769 convertPackageInfoOut :: InstalledPackageInfo -> InstalledPackageInfoString
 770 convertPackageInfoOut
 771     (pkgconf@(InstalledPackageInfo { exposedModules = e,
 772                                      hiddenModules = h })) =
 773         pkgconf{ exposedModules = map display e,
 774                  hiddenModules  = map display h }
 775
 776 convertPackageInfoIn :: InstalledPackageInfoString -> InstalledPackageInfo
 777 convertPackageInfoIn
 778     (pkgconf@(InstalledPackageInfo { exposedModules = e,
 779                                      hiddenModules = h })) =
 780         pkgconf{ exposedModules = map convert e,
 781                  hiddenModules  = map convert h }
 782     where convert = fromJust . simpleParse
 783
 784 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 785 writeNewConfig filename packages = do
 786   hPutStr stdout "Writing new package config file... "
 787   createDirectoryIfMissing True $ takeDirectory filename
 788   h <- openFile filename WriteMode `catch` \e ->
 789       if isPermissionError e
 790       then die (filename ++ ": you don't have permission to modify this file")
 791       else ioError e
 792   let shown = concat $ intersperse ",\n "
 793                      $ map (show . convertPackageInfoOut) packages
 794       fileContents = "[" ++ shown ++ "\n]"
 795   hPutStrLn h fileContents
 796   hClose h
 797   hPutStrLn stdout "done."
 798
 799 savingOldConfig :: FilePath -> IO () -> IO ()
 800 savingOldConfig filename io = Exception.block $ do
 801   hPutStr stdout "Saving old package config file... "
 802     -- mv rather than cp because we've already done an hGetContents
 803     -- on this file so we won't be able to open it for writing
 804     -- unless we move the old one out of the way...
 805   let oldFile = filename ++ ".old"
 806   restore_on_error <- catch (renameFile filename oldFile >> return True) $
 807       \err -> do
 808           unless (isDoesNotExistError err) $ do
 809               hPutStrLn stderr (unwords ["Unable to rename", show filename,
 810                                          "to", show oldFile])
 811               ioError err
 812           return False
 813   (do hPutStrLn stdout "done."; io)
 814     `onException` do
 815       hPutStr stdout ("WARNING: an error was encountered while writing "
 816                    ++ "the new configuration.\n")
 817         -- remove any partially complete new version:
 818       removeFile filename `catchIO` \_ -> return ()
 819         -- and attempt to restore the old one, if we had one:
 820       when restore_on_error $ do
 821            hPutStr stdout "Attempting to restore the old configuration... "
 822            do renameFile oldFile filename
 823               hPutStrLn stdout "done."
 824             `catchIO` \err -> hPutStrLn stdout ("Failed: " ++ show err)
 825         -- Note the above renameFile sometimes fails on Windows with
 826         -- "permission denied", I have no idea why --SDM.
 827
 828 -----------------------------------------------------------------------------
 829 -- Sanity-check a new package config, and automatically build GHCi libs
 830 -- if requested.
 831
 832 validatePackageConfig :: InstalledPackageInfo
 833                       -> PackageDBStack
 834                       -> Bool   -- auto-ghc-libs
 835                       -> Bool   -- update
 836                       -> Force
 837                       -> IO ()
 838 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 839   checkPackageId pkg
 840   checkDuplicates db_stack pkg update force
 841   mapM_ (checkDep db_stack force) (depends pkg)
 842   mapM_ (checkDir force) (importDirs pkg)
 843   mapM_ (checkDir force) (libraryDirs pkg)
 844   mapM_ (checkDir force) (includeDirs pkg)
 845   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 846   -- ToDo: check these somehow?
 847   --    extra_libraries :: [String],
 848   --    c_includes      :: [String],
 849
 850 -- When the package name and version are put together, sometimes we can
 851 -- end up with a package id that cannot be parsed.  This will lead to
 852 -- difficulties when the user wants to refer to the package later, so
 853 -- we check that the package id can be parsed properly here.
 854 checkPackageId :: InstalledPackageInfo -> IO ()
 855 checkPackageId ipi =
 856   let str = display (package ipi) in
 857   case [ x :: PackageIdentifier | (x,ys) <- readP_to_S parse str, all isSpace ys ] of
 858     [_] -> return ()
 859     []  -> die ("invalid package identifier: " ++ str)
 860     _   -> die ("ambiguous package identifier: " ++ str)
 861
 862 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> Force -> IO ()
 863 checkDuplicates db_stack pkg update force = do
 864   let
 865         pkgid = package pkg
 866         (_top_db_name, pkgs) : _  = db_stack
 867   --
 868   -- Check whether this package id already exists in this DB
 869   --
 870   when (not update && (pkgid `elem` map package pkgs)) $
 871        die ("package " ++ display pkgid ++ " is already installed")
 872
 873   let
 874         uncasep = map toLower . display
 875         dups = filter ((== uncasep pkgid) . uncasep) (map package pkgs)
 876
 877   when (not update && not (null dups)) $ dieOrForceAll force $
 878         "Package names may be treated case-insensitively in the future.\n"++
 879         "Package " ++ display pkgid ++
 880         " overlaps with: " ++ unwords (map display dups)
 881
 882
 883 checkDir :: Force -> String -> IO ()
 884 checkDir force d
 885  | "$topdir"     `isPrefixOf` d = return ()
 886  | "$httptopdir" `isPrefixOf` d = return ()
 887         -- can't check these, because we don't know what $(http)topdir is
 888  | otherwise = do
 889    there <- doesDirectoryExist d
 890    when (not there)
 891        (dieOrForceFile force (d ++ " doesn't exist or isn't a directory"))
 892
 893 checkDep :: PackageDBStack -> Force -> PackageIdentifier -> IO ()
 894 checkDep db_stack force pkgid
 895   | pkgid `elem` pkgids || (not real_version && name_exists) = return ()
 896   | otherwise = dieOrForceAll force ("dependency " ++ display pkgid
 897                                         ++ " doesn't exist")
 898   where
 899         -- for backwards compat, we treat 0.0 as a special version,
 900         -- and don't check that it actually exists.
 901         real_version = realVersion pkgid
 902
 903         name_exists = any (\p -> pkgName (package p) == name) all_pkgs
 904         name = pkgName pkgid
 905
 906         all_pkgs = allPackagesInStack db_stack
 907         pkgids = map package all_pkgs
 908
 909 realVersion :: PackageIdentifier -> Bool
 910 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 911
 912 checkHSLib :: [String] -> Bool -> Force -> String -> IO ()
 913 checkHSLib dirs auto_ghci_libs force lib = do
 914   let batch_lib_file = "lib" ++ lib ++ ".a"
 915   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 916   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 917         [] -> dieOrForceFile force ("cannot find " ++ batch_lib_file ++
 918                                     " on library path")
 919         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 920
 921 doesLibExistIn :: String -> String -> IO Bool
 922 doesLibExistIn lib d
 923  | "$topdir"     `isPrefixOf` d = return True
 924  | "$httptopdir" `isPrefixOf` d = return True
 925  | otherwise                = doesFileExist (d ++ '/':lib)
 926
 927 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 928 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 929   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 930   | otherwise  = do
 931       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 932       case [dir | (exists,dir) <- zip bs dirs, exists] of
 933         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 934         (_:_) -> return ()
 935   where
 936     ghci_lib_file = lib ++ ".o"
 937
 938 -- automatically build the GHCi version of a batch lib,
 939 -- using ld --whole-archive.
 940
 941 autoBuildGHCiLib :: String -> String -> String -> IO ()
 942 autoBuildGHCiLib dir batch_file ghci_file = do
 943   let ghci_lib_file  = dir ++ '/':ghci_file
 944       batch_lib_file = dir ++ '/':batch_file
 945   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 946 #if defined(darwin_HOST_OS)
 947   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 948 #elif defined(mingw32_HOST_OS)
 949   execDir <- getExecDir "/bin/ghc-pkg.exe"
 950   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 951 #else
 952   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 953 #endif
 954   when (r /= ExitSuccess) $ exitWith r
 955   hPutStrLn stderr (" done.")
 956
 957 -- -----------------------------------------------------------------------------
 958 -- Searching for modules
 959
 960 #if not_yet
 961
 962 findModules :: [FilePath] -> IO [String]
 963 findModules paths =
 964   mms <- mapM searchDir paths
 965   return (concat mms)
 966
 967 searchDir path prefix = do
 968   fs <- getDirectoryEntries path `catch` \_ -> return []
 969   searchEntries path prefix fs
 970
 971 searchEntries path prefix [] = return []
 972 searchEntries path prefix (f:fs)
 973   | looks_like_a_module  =  do
 974         ms <- searchEntries path prefix fs
 975         return (prefix `joinModule` f : ms)
 976   | looks_like_a_component  =  do
 977         ms <- searchDir (path </> f) (prefix `joinModule` f)
 978         ms' <- searchEntries path prefix fs
 979         return (ms ++ ms')
 980   | otherwise
 981         searchEntries path prefix fs
 982
 983   where
 984         (base,suffix) = splitFileExt f
 985         looks_like_a_module =
 986                 suffix `elem` haskell_suffixes &&
 987                 all okInModuleName base
 988         looks_like_a_component =
 989                 null suffix && all okInModuleName base
 990
 991 okInModuleName c
 992
 993 #endif
 994
 995 -- ---------------------------------------------------------------------------
 996 -- expanding environment variables in the package configuration
 997
 998 expandEnvVars :: String -> Force -> IO String
 999 expandEnvVars str0 force = go str0 ""
1000  where
1001    go "" acc = return $! reverse acc
1002    go ('$':'{':str) acc | (var, '}':rest) <- break close str
1003         = do value <- lookupEnvVar var
1004              go rest (reverse value ++ acc)
1005         where close c = c == '}' || c == '\n' -- don't span newlines
1006    go (c:str) acc
1007         = go str (c:acc)
1008
1009    lookupEnvVar :: String -> IO String
1010    lookupEnvVar nm =
1011         catch (System.Environment.getEnv nm)
1012            (\ _ -> do dieOrForceAll force ("Unable to expand variable " ++
1013                                         show nm)
1014                       return "")
1015
1016 -----------------------------------------------------------------------------
1017
1018 getProgramName :: IO String
1019 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
1020    where str `withoutSuffix` suff
1021             | suff `isSuffixOf` str = take (length str - length suff) str
1022             | otherwise             = str
1023
1024 bye :: String -> IO a
1025 bye s = putStr s >> exitWith ExitSuccess
1026
1027 die :: String -> IO a
1028 die = dieWith 1
1029
1030 dieWith :: Int -> String -> IO a
1031 dieWith ec s = do
1032   hFlush stdout
1033   prog <- getProgramName
1034   hPutStrLn stderr (prog ++ ": " ++ s)
1035   exitWith (ExitFailure ec)
1036
1037 dieOrForceAll :: Force -> String -> IO ()
1038 dieOrForceAll ForceAll s = ignoreError s
1039 dieOrForceAll _other s   = dieForcible s
1040
1041 dieOrForceFile :: Force -> String -> IO ()
1042 dieOrForceFile ForceAll   s = ignoreError s
1043 dieOrForceFile ForceFiles s = ignoreError s
1044 dieOrForceFile _other     s = dieForcible s
1045
1046 ignoreError :: String -> IO ()
1047 ignoreError s = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
1048
1049 dieForcible :: String -> IO ()
1050 dieForcible s = die (s ++ " (use --force to override)")
1051
1052 my_head :: String -> [a] -> a
1053 my_head s []      = error s
1054 my_head _ (x : _) = x
1055
1056 -----------------------------------------
1057 -- Cut and pasted from ghc/compiler/main/SysTools
1058
1059 #if defined(mingw32_HOST_OS)
1060 subst :: Char -> Char -> String -> String
1061 subst a b ls = map (\ x -> if x == a then b else x) ls
1062
1063 unDosifyPath :: FilePath -> FilePath
1064 unDosifyPath xs = subst '\\' '/' xs
1065
1066 getExecDir :: String -> IO (Maybe String)
1067 -- (getExecDir cmd) returns the directory in which the current
1068 --                  executable, which should be called 'cmd', is running
1069 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
1070 -- you'll get "/a/b/c" back as the result
1071 getExecDir cmd
1072   = allocaArray len $ \buf -> do
1073         ret <- getModuleFileName nullPtr buf len
1074         if ret == 0 then return Nothing
1075                     else do s <- peekCString buf
1076                             return (Just (reverse (drop (length cmd)
1077                                                         (reverse (unDosifyPath s)))))
1078   where
1079     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
1080
1081 foreign import stdcall unsafe  "GetModuleFileNameA"
1082   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
1083 #else
1084 getExecDir :: String -> IO (Maybe String)
1085 getExecDir _ = return Nothing
1086 #endif
1087
1088 -----------------------------------------
1089 -- Adapted from ghc/compiler/utils/Panic
1090
1091 installSignalHandlers :: IO ()
1092 installSignalHandlers = do
1093   threadid <- myThreadId
1094   let
1095       interrupt = throwTo threadid (Exception.ErrorCall "interrupted")
1096   --
1097 #if !defined(mingw32_HOST_OS)
1098   installHandler sigQUIT (Catch interrupt) Nothing
1099   installHandler sigINT  (Catch interrupt) Nothing
1100   return ()
1101 #elif __GLASGOW_HASKELL__ >= 603
1102   -- GHC 6.3+ has support for console events on Windows
1103   -- NOTE: running GHCi under a bash shell for some reason requires
1104   -- you to press Ctrl-Break rather than Ctrl-C to provoke
1105   -- an interrupt.  Ctrl-C is getting blocked somewhere, I don't know
1106   -- why --SDM 17/12/2004
1107   let sig_handler ControlC = interrupt
1108       sig_handler Break    = interrupt
1109       sig_handler _        = return ()
1110
1111   installHandler (Catch sig_handler)
1112   return ()
1113 #else
1114   return () -- nothing
1115 #endif
1116
1117 #if __GLASGOW_HASKELL__ <= 604
1118 isInfixOf               :: (Eq a) => [a] -> [a] -> Bool
1119 isInfixOf needle haystack = any (isPrefixOf needle) (tails haystack)
1120 #endif
1121
1122 catchIO :: IO a -> (Exception.IOException -> IO a) -> IO a
1123 #if __GLASGOW_HASKELL__ >= 609
1124 catchIO = Exception.catch
1125 #else
1126 catchIO io handler = io `Exception.catch` handler'
1127     where handler' (Exception.IOException ioe) = handler ioe
1128           handler' e                           = Exception.throw e
1129 #endif
1130
1131 catchError :: IO a -> (String -> IO a) -> IO a
1132 #if __GLASGOW_HASKELL__ >= 609
1133 catchError io handler = io `Exception.catch` handler'
1134     where handler' (Exception.ErrorCall err) = handler err
1135 #else
1136 catchError io handler = io `Exception.catch` handler'
1137     where handler' (Exception.ErrorCall err) = handler err
1138           handler' e                         = Exception.throw e
1139 #endif
1140
1141 onException :: IO a -> IO () -> IO a
1142 #if __GLASGOW_HASKELL__ >= 609
1143 onException = Exception.onException
1144 #else
1145 onException io what = io `Exception.catch` \e -> do what
1146                                                     Exception.throw e
1147 #endif
1148