utils/ghc-pkg/Main.hs

   1 {-# OPTIONS -fglasgow-exts #-}
   2 -----------------------------------------------------------------------------
   3 --
   4 -- (c) The University of Glasgow 2004.
   5 --
   6 -- Package management tool
   7 --
   8 -----------------------------------------------------------------------------
   9
  10 -- TODO:
  11 --      - validate modules
  12 --      - expanding of variables in new-style package conf
  13 --      - version manipulation (checking whether old version exists,
  14 --        hiding old version?)
  15
  16 module Main (main) where
  17
  18 import Version  ( version, targetOS, targetARCH )
  19 import Distribution.InstalledPackageInfo
  20 import Distribution.Compat.ReadP
  21 import Distribution.ParseUtils  ( showError )
  22 import Distribution.Package
  23 import Distribution.Version
  24 import Compat.Directory         ( getAppUserDataDirectory, createDirectoryIfMissing )
  25 import Compat.RawSystem         ( rawSystem )
  26
  27 import Prelude
  28
  29 #include "../../includes/ghcconfig.h"
  30
  31 #if __GLASGOW_HASKELL__ >= 504
  32 import System.Console.GetOpt
  33 import Text.PrettyPrint
  34 import qualified Control.Exception as Exception
  35 import Data.Maybe
  36 #else
  37 import GetOpt
  38 import Pretty
  39 import qualified Exception
  40 import Maybe
  41 #endif
  42
  43 import Data.Char        ( isSpace )
  44 import Monad
  45 import Directory
  46 import System   ( getArgs, getProgName, getEnv,
  47                   exitWith, ExitCode(..)
  48                 )
  49 import System.IO
  50 #if __GLASGOW_HASKELL__ >= 600
  51 import System.IO.Error (try)
  52 #else
  53 import System.IO (try)
  54 #endif
  55 import Data.List ( isPrefixOf, isSuffixOf, intersperse, sortBy )
  56
  57 #ifdef mingw32_HOST_OS
  58 import Foreign
  59
  60 #if __GLASGOW_HASKELL__ >= 504
  61 import Foreign.C.String
  62 #else
  63 import CString
  64 #endif
  65 #endif
  66
  67 -- -----------------------------------------------------------------------------
  68 -- Entry point
  69
  70 main :: IO ()
  71 main = do
  72   args <- getArgs
  73
  74   case getOpt Permute flags args of
  75         (cli,_,[]) | FlagHelp `elem` cli -> do
  76            prog <- getProgramName
  77            bye (usageInfo (usageHeader prog) flags)
  78         (cli,_,[]) | FlagVersion `elem` cli ->
  79            bye ourCopyright
  80         (cli,nonopts,[]) ->
  81            runit cli nonopts
  82         (_,_,errors) -> tryOldCmdLine errors args
  83
  84 -- If the new command-line syntax fails, then we try the old.  If that
  85 -- fails too, then we output the original errors and the new syntax
  86 -- (so the old syntax is still available, but hidden).
  87 tryOldCmdLine :: [String] -> [String] -> IO ()
  88 tryOldCmdLine errors args = do
  89   case getOpt Permute oldFlags args of
  90         (cli@(_:_),[],[]) ->
  91            oldRunit cli
  92         _failed -> do
  93            prog <- getProgramName
  94            die (concat errors ++ usageInfo (usageHeader prog) flags)
  95
  96 -- -----------------------------------------------------------------------------
  97 -- Command-line syntax
  98
  99 data Flag
 100   = FlagUser
 101   | FlagGlobal
 102   | FlagHelp
 103   | FlagVersion
 104   | FlagConfig  FilePath
 105   | FlagGlobalConfig FilePath
 106   | FlagForce
 107   | FlagAutoGHCiLibs
 108   | FlagDefinedName String String
 109   | FlagSimpleOutput
 110   deriving Eq
 111
 112 flags :: [OptDescr Flag]
 113 flags = [
 114   Option [] ["user"] (NoArg FlagUser)
 115         "use the current user's package database",
 116   Option [] ["global"] (NoArg FlagGlobal)
 117         "(default) use the global package database",
 118   Option ['f'] ["package-conf"] (ReqArg FlagConfig "FILE")
 119         "act upon specified package config file (only)",
 120   Option [] ["global-conf"] (ReqArg FlagGlobalConfig "FILE")
 121         "location of the global package config",
 122   Option [] ["force"] (NoArg FlagForce)
 123         "ignore missing dependencies, directories, and libraries",
 124   Option ['g'] ["auto-ghci-libs"] (NoArg FlagAutoGHCiLibs)
 125         "automatically build libs for GHCi (with register)",
 126   Option ['?'] ["help"] (NoArg FlagHelp)
 127         "display this help and exit",
 128   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 129         "define NAME as VALUE",
 130   Option ['V'] ["version"] (NoArg FlagVersion)
 131         "output version information and exit",
 132   Option [] ["simple-output"] (NoArg FlagSimpleOutput)
 133         "print output in easy-to-parse format when running command 'list'"
 134   ]
 135  where
 136   toDefined str =
 137     case break (=='=') str of
 138       (nm,[])    -> FlagDefinedName nm []
 139       (nm,_:val) -> FlagDefinedName nm val
 140
 141 ourCopyright :: String
 142 ourCopyright = "GHC package manager version " ++ version ++ "\n"
 143
 144 usageHeader :: String -> String
 145 usageHeader prog = substProg prog $
 146   "Usage:\n" ++
 147   "  $p register {filename | -}\n" ++
 148   "    Register the package using the specified installed package\n" ++
 149   "    description. The syntax for the latter is given in the $p\n" ++
 150   "    documentation.\n" ++
 151   "\n" ++
 152   "  $p update {filename | -}\n" ++
 153   "    Register the package, overwriting any other package with the\n" ++
 154   "    same name.\n" ++
 155   "\n" ++
 156   "  $p unregister {pkg-id}\n" ++
 157   "    Unregister the specified package.\n" ++
 158   "\n" ++
 159   "  $p expose {pkg-id}\n" ++
 160   "    Expose the specified package.\n" ++
 161   "\n" ++
 162   "  $p hide {pkg-id}\n" ++
 163   "    Hide the specified package.\n" ++
 164   "\n" ++
 165   "  $p list [pkg]\n" ++
 166   "    List registered packages in the global database, and also the\n" ++
 167   "    user database if --user is given. If a package name is given\n" ++
 168   "    all the registered versions will be listed in ascending order.\n" ++
 169   "\n" ++
 170   "  $p latest pkg\n" ++
 171   "    Prints the highest registered version of a package.\n" ++
 172   "\n" ++
 173   "  $p describe {pkg-id}\n" ++
 174   "    Give the registered description for the specified package. The\n" ++
 175   "    description is returned in precisely the syntax required by $p\n" ++
 176   "    register.\n" ++
 177   "\n" ++
 178   "  $p field {pkg-id} {field}\n" ++
 179   "    Extract the specified field of the package description for the\n" ++
 180   "    specified package.\n" ++
 181   "\n" ++
 182   " The following optional flags are also accepted:\n"
 183
 184 substProg :: String -> String -> String
 185 substProg _ [] = []
 186 substProg prog ('$':'p':xs) = prog ++ substProg prog xs
 187 substProg prog (c:xs) = c : substProg prog xs
 188
 189 -- -----------------------------------------------------------------------------
 190 -- Do the business
 191
 192 runit :: [Flag] -> [String] -> IO ()
 193 runit cli nonopts = do
 194   prog <- getProgramName
 195   let
 196         force = FlagForce `elem` cli
 197         auto_ghci_libs = FlagAutoGHCiLibs `elem` cli
 198         defines = [ (nm,val) | FlagDefinedName nm val <- cli ]
 199   --
 200   -- first, parse the command
 201   case nonopts of
 202     ["register", filename] ->
 203         registerPackage filename defines cli auto_ghci_libs False force
 204     ["update", filename] ->
 205         registerPackage filename defines cli auto_ghci_libs True force
 206     ["unregister", pkgid_str] -> do
 207         pkgid <- readGlobPkgId pkgid_str
 208         unregisterPackage pkgid cli
 209     ["expose", pkgid_str] -> do
 210         pkgid <- readGlobPkgId pkgid_str
 211         exposePackage pkgid cli
 212     ["hide",   pkgid_str] -> do
 213         pkgid <- readGlobPkgId pkgid_str
 214         hidePackage pkgid cli
 215     ["list"] -> do
 216         listPackages cli Nothing
 217     ["list", pkgid_str] -> do
 218         pkgid <- readGlobPkgId pkgid_str
 219         listPackages cli (Just pkgid)
 220     ["latest", pkgid_str] -> do
 221         pkgid <- readGlobPkgId pkgid_str
 222         latestPackage cli pkgid
 223     ["describe", pkgid_str] -> do
 224         pkgid <- readGlobPkgId pkgid_str
 225         describePackage cli pkgid
 226     ["field", pkgid_str, field] -> do
 227         pkgid <- readGlobPkgId pkgid_str
 228         describeField cli pkgid field
 229     [] -> do
 230         die ("missing command\n" ++
 231                 usageInfo (usageHeader prog) flags)
 232     (_cmd:_) -> do
 233         die ("command-line syntax error\n" ++
 234                 usageInfo (usageHeader prog) flags)
 235
 236 parseCheck :: ReadP a a -> String -> String -> IO a
 237 parseCheck parser str what =
 238   case [ x | (x,ys) <- readP_to_S parser str, all isSpace ys ] of
 239     [x] -> return x
 240     _ -> die ("cannot parse \'" ++ str ++ "\' as a " ++ what)
 241
 242 readPkgId :: String -> IO PackageIdentifier
 243 readPkgId str = parseCheck parsePackageId str "package identifier"
 244
 245 readGlobPkgId :: String -> IO PackageIdentifier
 246 readGlobPkgId str = parseCheck parseGlobPackageId str "package identifier"
 247
 248 parseGlobPackageId :: ReadP r PackageIdentifier
 249 parseGlobPackageId =
 250   parsePackageId
 251      +++
 252   (do n <- parsePackageName; string "-*"
 253       return (PackageIdentifier{ pkgName = n, pkgVersion = globVersion }))
 254
 255 -- globVersion means "all versions"
 256 globVersion :: Version
 257 globVersion = Version{ versionBranch=[], versionTags=["*"] }
 258
 259 -- -----------------------------------------------------------------------------
 260 -- Package databases
 261
 262 -- Some commands operate on a single database:
 263 --      register, unregister, expose, hide
 264 -- however these commands also check the union of the available databases
 265 -- in order to check consistency.  For example, register will check that
 266 -- dependencies exist before registering a package.
 267 --
 268 -- Some commands operate  on multiple databases, with overlapping semantics:
 269 --      list, describe, field
 270
 271 type PackageDBName  = FilePath
 272 type PackageDB      = [InstalledPackageInfo]
 273
 274 type PackageDBStack = [(PackageDBName,PackageDB)]
 275         -- A stack of package databases.  Convention: head is the topmost
 276         -- in the stack.  Earlier entries override later one.
 277
 278 getPkgDatabases :: Bool -> [Flag] -> IO PackageDBStack
 279 getPkgDatabases modify flags = do
 280   -- first we determine the location of the global package config.  On Windows,
 281   -- this is found relative to the ghc-pkg.exe binary, whereas on Unix the
 282   -- location is passed to the binary using the --global-config flag by the
 283   -- wrapper script.
 284   let err_msg = "missing --global-conf option, location of global package.conf unknown\n"
 285   global_conf <-
 286      case [ f | FlagGlobalConfig f <- flags ] of
 287         [] -> do mb_dir <- getExecDir "/bin/ghc-pkg.exe"
 288                  case mb_dir of
 289                         Nothing  -> die err_msg
 290                         Just dir -> return (dir `joinFileName` "package.conf")
 291         fs -> return (last fs)
 292
 293   let global_conf_dir = global_conf ++ ".d"
 294   global_conf_dir_exists <- doesDirectoryExist global_conf_dir
 295   global_confs <-
 296     if global_conf_dir_exists
 297       then do files <- getDirectoryContents global_conf_dir
 298               return [ global_conf_dir ++ '/' : file
 299                      | file <- files
 300                      , isSuffixOf ".conf" file]
 301       else return []
 302
 303   -- get the location of the user package database, and create it if necessary
 304   appdir <- getAppUserDataDirectory "ghc"
 305
 306   let
 307         subdir = targetARCH ++ '-':targetOS ++ '-':version
 308         archdir   = appdir `joinFileName` subdir
 309         user_conf = archdir `joinFileName` "package.conf"
 310   user_exists <- doesFileExist user_conf
 311
 312   -- If the user database doesn't exist, and this command isn't a
 313   -- "modify" command, then we won't attempt to create or use it.
 314   let sys_databases
 315         | modify || user_exists = user_conf : global_confs ++ [global_conf]
 316         | otherwise             = global_confs ++ [global_conf]
 317
 318   e_pkg_path <- try (getEnv "GHC_PACKAGE_PATH")
 319   let env_stack =
 320         case e_pkg_path of
 321                 Left  _ -> sys_databases
 322                 Right path
 323                   | last cs == ""  -> init cs ++ sys_databases
 324                   | otherwise      -> cs
 325                   where cs = parseSearchPath path
 326
 327         -- The "global" database is always the one at the bottom of the stack.
 328         -- This is the database we modify by default.
 329       virt_global_conf = last env_stack
 330
 331   -- -f flags on the command line add to the database stack, unless any
 332   -- of them are present in the stack already.
 333   let flag_stack = filter (`notElem` env_stack)
 334                         [ f | FlagConfig f <- reverse flags ] ++ env_stack
 335
 336   -- Now we have the full stack of databases.  Next, if the current
 337   -- command is a "modify" type command, then we truncate the stack
 338   -- so that the topmost element is the database being modified.
 339   final_stack <-
 340      if not modify
 341         then return flag_stack
 342         else let
 343                 go (FlagUser : fs)     = modifying user_conf
 344                 go (FlagGlobal : fs)   = modifying virt_global_conf
 345                 go (FlagConfig f : fs) = modifying f
 346                 go (_ : fs)            = go fs
 347                 go []                  = modifying virt_global_conf
 348
 349                 modifying f
 350                   | f `elem` flag_stack = return (dropWhile (/= f) flag_stack)
 351                   | otherwise           = die ("requesting modification of database:\n\t" ++ f ++ "\n\twhich is not in the database stack.")
 352              in
 353                 go flags
 354
 355   db_stack <- mapM readParseDatabase final_stack
 356   return db_stack
 357
 358 readParseDatabase :: PackageDBName -> IO (PackageDBName,PackageDB)
 359 readParseDatabase filename = do
 360   str <- readFile filename `Exception.catch` \_ -> return emptyPackageConfig
 361   let packages = read str
 362   Exception.evaluate packages
 363     `Exception.catch` \_ ->
 364         die (filename ++ ": parse error in package config file")
 365   return (filename,packages)
 366
 367 emptyPackageConfig :: String
 368 emptyPackageConfig = "[]"
 369
 370 -- -----------------------------------------------------------------------------
 371 -- Registering
 372
 373 registerPackage :: FilePath
 374                 -> [(String,String)] -- defines
 375                 -> [Flag]
 376                 -> Bool         -- auto_ghci_libs
 377                 -> Bool         -- update
 378                 -> Bool         -- force
 379                 -> IO ()
 380 registerPackage input defines flags auto_ghci_libs update force = do
 381   db_stack <- getPkgDatabases True flags
 382   let
 383         db_to_operate_on = my_head "db" db_stack
 384         db_filename      = fst db_to_operate_on
 385   --
 386   checkConfigAccess db_filename
 387
 388   s <-
 389     case input of
 390       "-" -> do
 391         putStr "Reading package info from stdin ... "
 392         getContents
 393       f   -> do
 394         putStr ("Reading package info from " ++ show f ++ " ... ")
 395         readFile f
 396
 397   expanded <- expandEnvVars s defines force
 398
 399   pkg0 <- parsePackageInfo expanded defines force
 400   putStrLn "done."
 401
 402   let pkg = resolveDeps db_stack pkg0
 403   validatePackageConfig pkg db_stack auto_ghci_libs update force
 404   let new_details = snd db_to_operate_on ++ [pkg]
 405   savePackageConfig db_filename
 406   maybeRestoreOldConfig db_filename $
 407     writeNewConfig db_filename new_details
 408
 409 parsePackageInfo
 410         :: String
 411         -> [(String,String)]
 412         -> Bool
 413         -> IO InstalledPackageInfo
 414 parsePackageInfo str defines force =
 415   case parseInstalledPackageInfo str of
 416     ParseOk _warns ok -> return ok
 417     ParseFailed err -> die (showError err)
 418
 419 -- -----------------------------------------------------------------------------
 420 -- Exposing, Hiding, Unregistering are all similar
 421
 422 exposePackage :: PackageIdentifier ->  [Flag] -> IO ()
 423 exposePackage = modifyPackage (\p -> [p{exposed=True}])
 424
 425 hidePackage :: PackageIdentifier ->  [Flag] -> IO ()
 426 hidePackage = modifyPackage (\p -> [p{exposed=False}])
 427
 428 unregisterPackage :: PackageIdentifier ->  [Flag] -> IO ()
 429 unregisterPackage = modifyPackage (\p -> [])
 430
 431 modifyPackage
 432   :: (InstalledPackageInfo -> [InstalledPackageInfo])
 433   -> PackageIdentifier
 434   -> [Flag]
 435   -> IO ()
 436 modifyPackage fn pkgid flags  = do
 437   db_stack <- getPkgDatabases True{-modify-} flags
 438   let ((db_name, pkgs) : _) = db_stack
 439   checkConfigAccess db_name
 440   ps <- findPackages [(db_name,pkgs)] pkgid
 441   let pids = map package ps
 442   savePackageConfig db_name
 443   let new_config = concat (map modify pkgs)
 444       modify pkg
 445           | package pkg `elem` pids = fn pkg
 446           | otherwise               = [pkg]
 447   maybeRestoreOldConfig db_name $
 448       writeNewConfig db_name new_config
 449
 450 -- -----------------------------------------------------------------------------
 451 -- Listing packages
 452
 453 listPackages ::  [Flag] -> Maybe PackageIdentifier -> IO ()
 454 listPackages flags mPackageName = do
 455   let simple_output = FlagSimpleOutput `elem` flags
 456   db_stack <- getPkgDatabases False flags
 457   let db_stack_filtered -- if a package is given, filter out all other packages
 458         | Just this <- mPackageName =
 459             map (\(conf,pkgs) -> (conf, filter (this `matchesPkg`) pkgs))
 460                 db_stack
 461         | otherwise = db_stack
 462
 463       db_stack_sorted
 464           = [ (db, sort_pkgs pkgs) | (db,pkgs) <- db_stack_filtered ]
 465           where sort_pkgs = sortBy cmpPkgIds
 466                 cmpPkgIds pkg1 pkg2 =
 467                    case pkgName p1 `compare` pkgName p2 of
 468                         LT -> LT
 469                         GT -> GT
 470                         EQ -> pkgVersion p1 `compare` pkgVersion p2
 471                    where (p1,p2) = (package pkg1, package pkg2)
 472
 473       show_func = if simple_output then show_easy else mapM_ show_regular
 474
 475   show_func (reverse db_stack_sorted)
 476
 477   where show_regular (db_name,pkg_confs) =
 478           hPutStrLn stdout (render $
 479                 text (db_name ++ ":") $$ nest 4 packages
 480                 )
 481            where packages = fsep (punctuate comma (map pp_pkg pkg_confs))
 482                  pp_pkg p
 483                    | exposed p = doc
 484                    | otherwise = parens doc
 485                    where doc = text (showPackageId (package p))
 486
 487         show_easy db_stack = do
 488           let pkgs = map showPackageId $ sortBy compPkgIdVer $
 489                           map package (concatMap snd db_stack)
 490           when (null pkgs) $ die "no matches"
 491           hPutStrLn stdout $ concat $ intersperse " " pkgs
 492
 493 -- -----------------------------------------------------------------------------
 494 -- Prints the highest (hidden or exposed) version of a package
 495
 496 latestPackage ::  [Flag] -> PackageIdentifier -> IO ()
 497 latestPackage flags pkgid = do
 498   db_stack <- getPkgDatabases False flags
 499   ps <- findPackages db_stack pkgid
 500   show_pkg (sortBy compPkgIdVer (map package ps))
 501   where
 502     show_pkg [] = die "no matches"
 503     show_pkg pids = hPutStrLn stdout (showPackageId (last pids))
 504
 505 -- -----------------------------------------------------------------------------
 506 -- Describe
 507
 508 describePackage :: [Flag] -> PackageIdentifier -> IO ()
 509 describePackage flags pkgid = do
 510   db_stack <- getPkgDatabases False flags
 511   ps <- findPackages db_stack pkgid
 512   mapM_ (putStrLn . showInstalledPackageInfo) ps
 513
 514 -- PackageId is can have globVersion for the version
 515 findPackages :: PackageDBStack -> PackageIdentifier -> IO [InstalledPackageInfo]
 516 findPackages db_stack pkgid
 517   = case [ p | p <- all_pkgs, pkgid `matchesPkg` p ] of
 518         []  -> die ("cannot find package " ++ showPackageId pkgid)
 519         ps -> return ps
 520   where
 521         all_pkgs = concat (map snd db_stack)
 522
 523 matches :: PackageIdentifier -> PackageIdentifier -> Bool
 524 pid `matches` pid'
 525   = (pkgName pid == pkgName pid')
 526     && (pkgVersion pid == pkgVersion pid' || not (realVersion pid))
 527
 528 matchesPkg :: PackageIdentifier -> InstalledPackageInfo -> Bool
 529 pid `matchesPkg` pkg = pid `matches` package pkg
 530
 531 compPkgIdVer :: PackageIdentifier -> PackageIdentifier -> Ordering
 532 compPkgIdVer p1 p2 = pkgVersion p1 `compare` pkgVersion p2
 533
 534 -- -----------------------------------------------------------------------------
 535 -- Field
 536
 537 describeField :: [Flag] -> PackageIdentifier -> String -> IO ()
 538 describeField flags pkgid field = do
 539   db_stack <- getPkgDatabases False flags
 540   case toField field of
 541     Nothing -> die ("unknown field: " ++ field)
 542     Just fn -> do
 543         ps <- findPackages db_stack pkgid
 544         mapM_ (putStrLn.fn) ps
 545
 546 toField :: String -> Maybe (InstalledPackageInfo -> String)
 547 -- backwards compatibility:
 548 toField "import_dirs"     = Just $ strList . importDirs
 549 toField "source_dirs"     = Just $ strList . importDirs
 550 toField "library_dirs"    = Just $ strList . libraryDirs
 551 toField "hs_libraries"    = Just $ strList . hsLibraries
 552 toField "extra_libraries" = Just $ strList . extraLibraries
 553 toField "include_dirs"    = Just $ strList . includeDirs
 554 toField "c_includes"      = Just $ strList . includes
 555 toField "package_deps"    = Just $ strList . map showPackageId. depends
 556 toField "extra_cc_opts"   = Just $ strList . ccOptions
 557 toField "extra_ld_opts"   = Just $ strList . ldOptions
 558 toField "framework_dirs"  = Just $ strList . frameworkDirs
 559 toField "extra_frameworks"= Just $ strList . frameworks
 560 toField s                 = showInstalledPackageInfoField s
 561
 562 strList :: [String] -> String
 563 strList = show
 564
 565 -- -----------------------------------------------------------------------------
 566 -- Manipulating package.conf files
 567
 568 checkConfigAccess :: FilePath -> IO ()
 569 checkConfigAccess filename = do
 570   access <- getPermissions filename
 571   when (not (writable access))
 572       (die (filename ++ ": you don't have permission to modify this file"))
 573
 574 maybeRestoreOldConfig :: FilePath -> IO () -> IO ()
 575 maybeRestoreOldConfig filename io
 576   = io `catch` \e -> do
 577         hPutStrLn stderr (show e)
 578         hPutStr stdout ("\nWARNING: an error was encountered while the new \n"++
 579                           "configuration was being written.  Attempting to \n"++
 580                           "restore the old configuration... ")
 581         renameFile (filename ++ ".old")  filename
 582         hPutStrLn stdout "done."
 583         ioError e
 584
 585 writeNewConfig :: FilePath -> [InstalledPackageInfo] -> IO ()
 586 writeNewConfig filename packages = do
 587   hPutStr stdout "Writing new package config file... "
 588   h <- openFile filename WriteMode
 589   hPutStrLn h (show packages)
 590   hClose h
 591   hPutStrLn stdout "done."
 592
 593 savePackageConfig :: FilePath -> IO ()
 594 savePackageConfig filename = do
 595   hPutStr stdout "Saving old package config file... "
 596     -- mv rather than cp because we've already done an hGetContents
 597     -- on this file so we won't be able to open it for writing
 598     -- unless we move the old one out of the way...
 599   let oldFile = filename ++ ".old"
 600   doesExist <- doesFileExist oldFile  `catch` (\ _ -> return False)
 601   when doesExist (removeFile oldFile `catch` (const $ return ()))
 602   catch (renameFile filename oldFile)
 603         (\ err -> do
 604                 hPutStrLn stderr (unwords [ "Unable to rename "
 605                                           , show filename
 606                                           , " to "
 607                                           , show oldFile
 608                                           ])
 609                 ioError err)
 610   hPutStrLn stdout "done."
 611
 612 -----------------------------------------------------------------------------
 613 -- Sanity-check a new package config, and automatically build GHCi libs
 614 -- if requested.
 615
 616 validatePackageConfig :: InstalledPackageInfo
 617                       -> PackageDBStack
 618                       -> Bool   -- auto-ghc-libs
 619                       -> Bool   -- update
 620                       -> Bool   -- force
 621                       -> IO ()
 622 validatePackageConfig pkg db_stack auto_ghci_libs update force = do
 623   checkPackageId pkg
 624   checkDuplicates db_stack pkg update force
 625   mapM_ (checkDep db_stack force) (depends pkg)
 626   mapM_ (checkDir force) (importDirs pkg)
 627   mapM_ (checkDir force) (libraryDirs pkg)
 628   mapM_ (checkDir force) (includeDirs pkg)
 629   mapM_ (checkHSLib (libraryDirs pkg) auto_ghci_libs force) (hsLibraries pkg)
 630   -- ToDo: check these somehow?
 631   --    extra_libraries :: [String],
 632   --    c_includes      :: [String],
 633
 634 -- When the package name and version are put together, sometimes we can
 635 -- end up with a package id that cannot be parsed.  This will lead to
 636 -- difficulties when the user wants to refer to the package later, so
 637 -- we check that the package id can be parsed properly here.
 638 checkPackageId :: InstalledPackageInfo -> IO ()
 639 checkPackageId ipi =
 640   let str = showPackageId (package ipi) in
 641   case [ x | (x,ys) <- readP_to_S parsePackageId str, all isSpace ys ] of
 642     [_] -> return ()
 643     []  -> die ("invalid package identifier: " ++ str)
 644     _   -> die ("ambiguous package identifier: " ++ str)
 645
 646 resolveDeps :: PackageDBStack -> InstalledPackageInfo -> InstalledPackageInfo
 647 resolveDeps db_stack p = updateDeps p
 648   where
 649         -- The input package spec is allowed to give a package dependency
 650         -- without a version number; e.g.
 651         --      depends: base
 652         -- Here, we update these dependencies without version numbers to
 653         -- match the actual versions of the relevant packages installed.
 654         updateDeps p = p{depends = map resolveDep (depends p)}
 655
 656         resolveDep dep_pkgid
 657            | realVersion dep_pkgid  = dep_pkgid
 658            | otherwise              = lookupDep dep_pkgid
 659
 660         lookupDep dep_pkgid
 661            = let
 662                 name = pkgName dep_pkgid
 663              in
 664              case [ pid | p <- concat (map snd db_stack),
 665                           let pid = package p,
 666                           pkgName pid == name ] of
 667                 (pid:_) -> pid          -- Found installed package,
 668                                         -- replete with its version
 669                 []      -> dep_pkgid    -- No installed package; use
 670                                         -- the version-less one
 671
 672 checkDuplicates :: PackageDBStack -> InstalledPackageInfo -> Bool -> Bool
 673          -> IO ()
 674 checkDuplicates db_stack pkg update force = do
 675   let
 676         pkgid = package pkg
 677         (_top_db_name, pkgs) : _  = db_stack
 678   --
 679   -- Check whether this package id already exists in this DB
 680   --
 681   when (not update && (pkgid `elem` map package pkgs)) $
 682        die ("package " ++ showPackageId pkgid ++ " is already installed")
 683
 684
 685
 686 checkDir :: Bool -> String -> IO ()
 687 checkDir force d
 688  | "$topdir" `isPrefixOf` d = return ()
 689         -- can't check this, because we don't know what $topdir is
 690  | otherwise = do
 691    there <- doesDirectoryExist d
 692    when (not there)
 693        (dieOrForce force (d ++ " doesn't exist or isn't a directory"))
 694
 695 checkDep :: PackageDBStack -> Bool -> PackageIdentifier -> IO ()
 696 checkDep db_stack force pkgid
 697   | not real_version || pkgid `elem` pkgids = return ()
 698   | otherwise = dieOrForce force ("dependency " ++ showPackageId pkgid
 699                                         ++ " doesn't exist")
 700   where
 701         -- for backwards compat, we treat 0.0 as a special version,
 702         -- and don't check that it actually exists.
 703         real_version = realVersion pkgid
 704
 705         all_pkgs = concat (map snd db_stack)
 706         pkgids = map package all_pkgs
 707
 708 realVersion :: PackageIdentifier -> Bool
 709 realVersion pkgid = versionBranch (pkgVersion pkgid) /= []
 710
 711 checkHSLib :: [String] -> Bool -> Bool -> String -> IO ()
 712 checkHSLib dirs auto_ghci_libs force lib = do
 713   let batch_lib_file = "lib" ++ lib ++ ".a"
 714   bs <- mapM (doesLibExistIn batch_lib_file) dirs
 715   case [ dir | (exists,dir) <- zip bs dirs, exists ] of
 716         [] -> dieOrForce force ("cannot find " ++ batch_lib_file ++
 717                                  " on library path")
 718         (dir:_) -> checkGHCiLib dirs dir batch_lib_file lib auto_ghci_libs
 719
 720 doesLibExistIn :: String -> String -> IO Bool
 721 doesLibExistIn lib d
 722  | "$topdir" `isPrefixOf` d = return True
 723  | otherwise                = doesFileExist (d ++ '/':lib)
 724
 725 checkGHCiLib :: [String] -> String -> String -> String -> Bool -> IO ()
 726 checkGHCiLib dirs batch_lib_dir batch_lib_file lib auto_build
 727   | auto_build = autoBuildGHCiLib batch_lib_dir batch_lib_file ghci_lib_file
 728   | otherwise  = do
 729       bs <- mapM (doesLibExistIn ghci_lib_file) dirs
 730       case [dir | (exists,dir) <- zip bs dirs, exists] of
 731         []    -> hPutStrLn stderr ("warning: can't find GHCi lib " ++ ghci_lib_file)
 732         (_:_) -> return ()
 733   where
 734     ghci_lib_file = lib ++ ".o"
 735
 736 -- automatically build the GHCi version of a batch lib,
 737 -- using ld --whole-archive.
 738
 739 autoBuildGHCiLib :: String -> String -> String -> IO ()
 740 autoBuildGHCiLib dir batch_file ghci_file = do
 741   let ghci_lib_file  = dir ++ '/':ghci_file
 742       batch_lib_file = dir ++ '/':batch_file
 743   hPutStr stderr ("building GHCi library " ++ ghci_lib_file ++ "...")
 744 #if defined(darwin_HOST_OS)
 745   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"-all_load",batch_lib_file]
 746 #elif defined(mingw32_HOST_OS)
 747   execDir <- getExecDir "/bin/ghc-pkg.exe"
 748   r <- rawSystem (maybe "" (++"/gcc-lib/") execDir++"ld") ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 749 #else
 750   r <- rawSystem "ld" ["-r","-x","-o",ghci_lib_file,"--whole-archive",batch_lib_file]
 751 #endif
 752   when (r /= ExitSuccess) $ exitWith r
 753   hPutStrLn stderr (" done.")
 754
 755 -- -----------------------------------------------------------------------------
 756 -- Searching for modules
 757
 758 #if not_yet
 759
 760 findModules :: [FilePath] -> IO [String]
 761 findModules paths =
 762   mms <- mapM searchDir paths
 763   return (concat mms)
 764
 765 searchDir path prefix = do
 766   fs <- getDirectoryEntries path `catch` \_ -> return []
 767   searchEntries path prefix fs
 768
 769 searchEntries path prefix [] = return []
 770 searchEntries path prefix (f:fs)
 771   | looks_like_a_module  =  do
 772         ms <- searchEntries path prefix fs
 773         return (prefix `joinModule` f : ms)
 774   | looks_like_a_component  =  do
 775         ms <- searchDir (path `joinFilename` f) (prefix `joinModule` f)
 776         ms' <- searchEntries path prefix fs
 777         return (ms ++ ms')
 778   | otherwise
 779         searchEntries path prefix fs
 780
 781   where
 782         (base,suffix) = splitFileExt f
 783         looks_like_a_module =
 784                 suffix `elem` haskell_suffixes &&
 785                 all okInModuleName base
 786         looks_like_a_component =
 787                 null suffix && all okInModuleName base
 788
 789 okInModuleName c
 790
 791 #endif
 792
 793 -- -----------------------------------------------------------------------------
 794 -- The old command-line syntax, supported for backwards compatibility
 795
 796 data OldFlag
 797   = OF_Config FilePath
 798   | OF_Input FilePath
 799   | OF_List
 800   | OF_ListLocal
 801   | OF_Add Bool {- True => replace existing info -}
 802   | OF_Remove String | OF_Show String
 803   | OF_Field String | OF_AutoGHCiLibs | OF_Force
 804   | OF_DefinedName String String
 805   | OF_GlobalConfig FilePath
 806   deriving (Eq)
 807
 808 isAction :: OldFlag -> Bool
 809 isAction OF_Config{}        = False
 810 isAction OF_Field{}         = False
 811 isAction OF_Input{}         = False
 812 isAction OF_AutoGHCiLibs{}  = False
 813 isAction OF_Force{}         = False
 814 isAction OF_DefinedName{}   = False
 815 isAction OF_GlobalConfig{}  = False
 816 isAction _                  = True
 817
 818 oldFlags :: [OptDescr OldFlag]
 819 oldFlags = [
 820   Option ['f'] ["config-file"] (ReqArg OF_Config "FILE")
 821         "use the specified package config file",
 822   Option ['l'] ["list-packages"] (NoArg OF_List)
 823         "list packages in all config files",
 824   Option ['L'] ["list-local-packages"] (NoArg OF_ListLocal)
 825         "list packages in the specified config file",
 826   Option ['a'] ["add-package"] (NoArg (OF_Add False))
 827         "add a new package",
 828   Option ['u'] ["update-package"] (NoArg (OF_Add True))
 829         "update package with new configuration",
 830   Option ['i'] ["input-file"] (ReqArg OF_Input "FILE")
 831         "read new package info from specified file",
 832   Option ['s'] ["show-package"] (ReqArg OF_Show "NAME")
 833         "show the configuration for package NAME",
 834   Option [] ["field"] (ReqArg OF_Field "FIELD")
 835         "(with --show-package) Show field FIELD only",
 836   Option [] ["force"] (NoArg OF_Force)
 837         "ignore missing directories/libraries",
 838   Option ['r'] ["remove-package"] (ReqArg OF_Remove "NAME")
 839         "remove an installed package",
 840   Option ['g'] ["auto-ghci-libs"] (NoArg OF_AutoGHCiLibs)
 841         "automatically build libs for GHCi (with -a)",
 842   Option ['D'] ["define-name"] (ReqArg toDefined "NAME=VALUE")
 843         "define NAME as VALUE",
 844   Option [] ["global-conf"] (ReqArg OF_GlobalConfig "FILE")
 845         "location of the global package config"
 846   ]
 847  where
 848   toDefined str =
 849     case break (=='=') str of
 850       (nm,[]) -> OF_DefinedName nm []
 851       (nm,_:val) -> OF_DefinedName nm val
 852
 853 oldRunit :: [OldFlag] -> IO ()
 854 oldRunit clis = do
 855   let new_flags = [ f | Just f <- map conv clis ]
 856
 857       conv (OF_GlobalConfig f) = Just (FlagGlobalConfig f)
 858       conv (OF_Config f)       = Just (FlagConfig f)
 859       conv _                   = Nothing
 860
 861
 862
 863   let fields = [ f | OF_Field f <- clis ]
 864
 865   let auto_ghci_libs = any isAuto clis
 866          where isAuto OF_AutoGHCiLibs = True; isAuto _ = False
 867       input_file = my_head "inp" ([ f | (OF_Input f) <- clis] ++ ["-"])
 868
 869       force = OF_Force `elem` clis
 870
 871       defines = [ (nm,val) | OF_DefinedName nm val <- clis ]
 872
 873   case [ c | c <- clis, isAction c ] of
 874     [ OF_List ]      -> listPackages new_flags Nothing
 875     [ OF_ListLocal ] -> listPackages new_flags Nothing
 876     [ OF_Add upd ]   ->
 877         registerPackage input_file defines new_flags auto_ghci_libs upd force
 878     [ OF_Remove pkgid_str ]  -> do
 879         pkgid <- readPkgId pkgid_str
 880         unregisterPackage pkgid new_flags
 881     [ OF_Show pkgid_str ]
 882         | null fields -> do
 883                 pkgid <- readPkgId pkgid_str
 884                 describePackage new_flags pkgid
 885         | otherwise   -> do
 886                 pkgid <- readPkgId pkgid_str
 887                 mapM_ (describeField new_flags pkgid) fields
 888     _ -> do
 889         prog <- getProgramName
 890         die (usageInfo (usageHeader prog) flags)
 891
 892 my_head :: String -> [a] -> a
 893 my_head s [] = error s
 894 my_head s (x:xs) = x
 895
 896 -- ---------------------------------------------------------------------------
 897 -- expanding environment variables in the package configuration
 898
 899 expandEnvVars :: String -> [(String, String)] -> Bool -> IO String
 900 expandEnvVars str defines force = go str ""
 901  where
 902    go "" acc = return $! reverse acc
 903    go ('$':'{':str) acc | (var, '}':rest) <- break close str
 904         = do value <- lookupEnvVar var
 905              go rest (reverse value ++ acc)
 906         where close c = c == '}' || c == '\n' -- don't span newlines
 907    go (c:str) acc
 908         = go str (c:acc)
 909
 910    lookupEnvVar :: String -> IO String
 911    lookupEnvVar nm =
 912      case lookup nm defines of
 913        Just x | not (null x) -> return x
 914        _      ->
 915         catch (System.getEnv nm)
 916            (\ _ -> do dieOrForce force ("Unable to expand variable " ++
 917                                         show nm)
 918                       return "")
 919
 920 -----------------------------------------------------------------------------
 921
 922 getProgramName :: IO String
 923 getProgramName = liftM (`withoutSuffix` ".bin") getProgName
 924    where str `withoutSuffix` suff
 925             | suff `isSuffixOf` str = take (length str - length suff) str
 926             | otherwise             = str
 927
 928 bye :: String -> IO a
 929 bye s = putStr s >> exitWith ExitSuccess
 930
 931 die :: String -> IO a
 932 die s = do
 933   hFlush stdout
 934   prog <- getProgramName
 935   hPutStrLn stderr (prog ++ ": " ++ s)
 936   exitWith (ExitFailure 1)
 937
 938 dieOrForce :: Bool -> String -> IO ()
 939 dieOrForce force s
 940   | force     = do hFlush stdout; hPutStrLn stderr (s ++ " (ignoring)")
 941   | otherwise = die (s ++ " (use --force to override)")
 942
 943 -----------------------------------------
 944 --      Cut and pasted from ghc/compiler/SysTools
 945
 946 #if defined(mingw32_HOST_OS)
 947 subst a b ls = map (\ x -> if x == a then b else x) ls
 948 unDosifyPath xs = subst '\\' '/' xs
 949
 950 getExecDir :: String -> IO (Maybe String)
 951 -- (getExecDir cmd) returns the directory in which the current
 952 --                  executable, which should be called 'cmd', is running
 953 -- So if the full path is /a/b/c/d/e, and you pass "d/e" as cmd,
 954 -- you'll get "/a/b/c" back as the result
 955 getExecDir cmd
 956   = allocaArray len $ \buf -> do
 957         ret <- getModuleFileName nullPtr buf len
 958         if ret == 0 then return Nothing
 959                     else do s <- peekCString buf
 960                             return (Just (reverse (drop (length cmd)
 961                                                         (reverse (unDosifyPath s)))))
 962   where
 963     len = 2048::Int -- Plenty, PATH_MAX is 512 under Win32.
 964
 965 foreign import stdcall unsafe  "GetModuleFileNameA"
 966   getModuleFileName :: Ptr () -> CString -> Int -> IO Int32
 967 #else
 968 getExecDir :: String -> IO (Maybe String)
 969 getExecDir _ = return Nothing
 970 #endif
 971
 972 -- -----------------------------------------------------------------------------
 973 -- FilePath utils
 974
 975 -- | The 'joinFileName' function is the opposite of 'splitFileName'.
 976 -- It joins directory and file names to form a complete file path.
 977 --
 978 -- The general rule is:
 979 --
 980 -- > dir `joinFileName` basename == path
 981 -- >   where
 982 -- >     (dir,basename) = splitFileName path
 983 --
 984 -- There might be an exceptions to the rule but in any case the
 985 -- reconstructed path will refer to the same object (file or directory).
 986 -- An example exception is that on Windows some slashes might be converted
 987 -- to backslashes.
 988 joinFileName :: String -> String -> FilePath
 989 joinFileName ""  fname = fname
 990 joinFileName "." fname = fname
 991 joinFileName dir ""    = dir
 992 joinFileName dir fname
 993   | isPathSeparator (last dir) = dir++fname
 994   | otherwise                  = dir++pathSeparator:fname
 995
 996 -- | Checks whether the character is a valid path separator for the host
 997 -- platform. The valid character is a 'pathSeparator' but since the Windows
 998 -- operating system also accepts a slash (\"\/\") since DOS 2, the function
 999 -- checks for it on this platform, too.
1000 isPathSeparator :: Char -> Bool
1001 isPathSeparator ch = ch == pathSeparator || ch == '/'
1002
1003 -- | Provides a platform-specific character used to separate directory levels in
1004 -- a path string that reflects a hierarchical file system organization. The
1005 -- separator is a slash (@\"\/\"@) on Unix and Macintosh, and a backslash
1006 -- (@\"\\\"@) on the Windows operating system.
1007 pathSeparator :: Char
1008 #ifdef mingw32_HOST_OS
1009 pathSeparator = '\\'
1010 #else
1011 pathSeparator = '/'
1012 #endif
1013
1014 -- | The function splits the given string to substrings
1015 -- using the 'searchPathSeparator'.
1016 parseSearchPath :: String -> [FilePath]
1017 parseSearchPath path = split path
1018   where
1019     split :: String -> [String]
1020     split s =
1021       case rest' of
1022         []     -> [chunk]
1023         _:rest -> chunk : split rest
1024       where
1025         chunk =
1026           case chunk' of
1027 #ifdef mingw32_HOST_OS
1028             ('\"':xs@(_:_)) | last xs == '\"' -> init xs
1029 #endif
1030             _                                 -> chunk'
1031
1032         (chunk', rest') = break (==searchPathSeparator) s
1033
1034 -- | A platform-specific character used to separate search path strings in
1035 -- environment variables. The separator is a colon (\":\") on Unix and Macintosh,
1036 -- and a semicolon (\";\") on the Windows operating system.
1037 searchPathSeparator :: Char
1038 #if mingw32_HOST_OS || mingw32_TARGET_OS
1039 searchPathSeparator = ';'
1040 #else
1041 searchPathSeparator = ':'
1042 #endif
1043