[project @ 2003-08-21 20:08:43 by panne]

Added a new test FP_HTML_COMMENT (better name?) and use it in configure.ac.

As an additional bonus, autoreconf doesn't call aclocal anymore
because we have an aclocal.m4 now and it obviously doesn't require
automake stuff. This fixes problems with older (< 1.4-p6) automakes,
which insist on "configure.in".

diff --git a/ghc/aclocal.m4 b/ghc/aclocal.m4
new file mode 100644 (file)
index 0000000..e22229b
--- /dev/null
+++ b/ghc/aclocal.m4
@@ -0,0 +1,9 @@
+# FP_HTML_COMMENT(VARIABLE, PREFIX)
+# ---------------------------------
+AC_DEFUN([FP_HTML_COMMENT],
+[AS_IF([$1],
+       [$2HTMLStart="";     $2HTMLEnd=""],
+       [$2HTMLStart="<!--"; $2HTMLEnd="-->"])[]dnl
+AC_SUBST([$2HTMLStart])[]dnl
+AC_SUBST([$2HTMLEnd])[]dnl
+])# FP_HTML_COMMENT

diff --git a/ghc/configure.ac b/ghc/configure.ac
index e87bae7..338678c 100644 (file)
--- a/ghc/configure.ac
+++ b/ghc/configure.ac
@@ -1,80 +1,37 @@
-dnl GHC-only part of fptools configuration
-dnl 
-dnl Copyright (c) 1999 Manuel M. T. Chakravarty <chak@acm.org>
-dnl 
-dnl This file is subject to the same free software license as GHC.
-
-dnl ######################################################################
-dnl Process this file with autoconf to produce a configure script.
-dnl ######################################################################
-
-
-dnl * Initialise and check sanity.
+# Initialise and check sanity.
 AC_INIT(ghc.spec.in)
 
-dnl * Compute the version number.
+# Compute the version number.
 version=`sed -e 's/.*\([[0-9]]\)\.\([[0-9]]*\).*/\1.\2/' VERSION`
 patchlevel=1
 
-dnl These are needed by the .spec file.
+# These are needed by the .spec file.
 AC_SUBST(version)
 AC_SUBST(patchlevel)
 
-dnl Uncomment links to unix docs if necessary dnl NOTE: This is a slight
-dnl hack: It needs to be synchronized with fptools/configure.ac and
-dnl fptools/libraries/Makefile and should probably use target features
-dnl instead of host.
+# Uncomment links to unix docs if necessary.
+# NOTE: This is a slight hack: It needs to be synchronized with
+# fptools/configure.ac and fptools/libraries/Makefile and should probably use
+# target features instead of host.
 AC_CANONICAL_HOST
 
 case $host in
-i[3456]86-*-mingw32*)
-       unixHTMLStart="<!--"
-       unixHTMLEnd="-->"
-       ;;
-*)
-       unixHTMLStart=""
-       unixHTMLEnd=""
-       ;;
+i[[3456]]86-*-mingw32*) fp_supports_unix=no  ;;
+*)                      fp_supports_unix=yes ;;
 esac
+FP_HTML_COMMENT([test x"$fp_supports_unix" = xyes], [unix])
 
-AC_SUBST(unixHTMLStart)
-AC_SUBST(unixHTMLEnd)
-
-dnl Uncomment links to ObjectIO docs if necessary
-AC_ARG_ENABLE(objectio,
-[  --enable-objectio
-        Build ObjectIO, a portable GUI library for Haskell.
-],
-[
-ObjectIOHTMLStart=""
-ObjectIOHTMLEnd=""
-],
-[
-ObjectIOHTMLStart="<!--"
-ObjectIOHTMLEnd="-->"
-]
-)
-
-AC_SUBST(ObjectIOHTMLStart)
-AC_SUBST(ObjectIOHTMLEnd)
-
-dnl Uncomment links to HOpenGL docs if necessary
-AC_ARG_ENABLE(hopengl,
-[  --enable-hopengl
-        Build HOpenGL, a Haskell binding for OpenGL/GLUT.
-],
-[
-HOpenGLHTMLStart=""
-HOpenGLHTMLEnd=""
-],
-[
-HOpenGLHTMLStart="<!--"
-HOpenGLHTMLEnd="-->"
-]
-)
+# Uncomment links to ObjectIO docs if necessary.
+AC_ARG_ENABLE([objectio],
+  AC_HELP_STRING([--enable-objectio],
+                 [Build ObjectIO, a portable GUI library for Haskell.]))
+FP_HTML_COMMENT([test x"$enable_objectio" = xyes], [ObjectIO])
 
-AC_SUBST(HOpenGLHTMLStart)
-AC_SUBST(HOpenGLHTMLEnd)
+# Uncomment links to HOpenGL docs if necessary
+AC_ARG_ENABLE([hopengl],
+  AC_HELP_STRING([--enable-hopengl],
+                 [Build HOpenGL, a Haskell binding for OpenGL/GLUT.]))
+FP_HTML_COMMENT([{ test x"$enable_hopengl" = xyes || test x"$enable_hopengl" = xx11; }], [HOpenGL])
 
-dnl * Write the results...
+# Write the results...
 AC_OUTPUT(ghc.spec docs/libraries.html)