Control/Concurrent/MVar.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Control.Concurrent.MVar
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable (concurrency)
  10 --
  11 -- Synchronising variables
  12 --
  13 -----------------------------------------------------------------------------
  14
  15 module Control.Concurrent.MVar
  16         (
  17           -- * @MVar@s
  18           MVar          -- abstract
  19         , newEmptyMVar  -- :: IO (MVar a)
  20         , newMVar       -- :: a -> IO (MVar a)
  21         , takeMVar      -- :: MVar a -> IO a
  22         , putMVar       -- :: MVar a -> a -> IO ()
  23         , readMVar      -- :: MVar a -> IO a
  24         , swapMVar      -- :: MVar a -> a -> IO a
  25         , tryTakeMVar   -- :: MVar a -> IO (Maybe a)
  26         , tryPutMVar    -- :: MVar a -> a -> IO Bool
  27         , isEmptyMVar   -- :: MVar a -> IO Bool
  28         , withMVar      -- :: MVar a -> (a -> IO b) -> IO b
  29         , modifyMVar_   -- :: MVar a -> (a -> IO a) -> IO ()
  30         , modifyMVar    -- :: MVar a -> (a -> IO (a,b)) -> IO b
  31 #ifndef __HUGS__
  32         , addMVarFinalizer -- :: MVar a -> IO () -> IO ()
  33 #endif
  34     ) where
  35
  36 #ifdef __HUGS__
  37 import Hugs.ConcBase ( MVar, newEmptyMVar, newMVar, takeMVar, putMVar,
  38                   tryTakeMVar, tryPutMVar, isEmptyMVar,
  39                 )
  40 #endif
  41
  42 #ifdef __GLASGOW_HASKELL__
  43 import GHC.Conc ( MVar, newEmptyMVar, newMVar, takeMVar, putMVar,
  44                   tryTakeMVar, tryPutMVar, isEmptyMVar, addMVarFinalizer
  45                 )
  46 #endif
  47
  48 import Prelude
  49 import Control.Exception as Exception
  50
  51 {-|
  52   This is a combination of 'takeMVar' and 'putMVar'; ie. it takes the value
  53   from the 'MVar', puts it back, and also returns it.
  54 -}
  55 readMVar :: MVar a -> IO a
  56 readMVar m =
  57   block $ do
  58     a <- takeMVar m
  59     putMVar m a
  60     return a
  61
  62 -- |Swap the contents of an 'MVar' for a new value.
  63 swapMVar :: MVar a -> a -> IO a
  64 swapMVar mvar new =
  65   block $ do
  66     old <- takeMVar mvar
  67     putMVar mvar new
  68     return old
  69
  70 {-|
  71   'withMVar' is a safe wrapper for operating on the contents of an
  72   'MVar'.  This operation is exception-safe: it will replace the
  73   original contents of the 'MVar' if an exception is raised (see
  74   "Control.Exception").
  75 -}
  76 {-# INLINE withMVar #-}
  77 -- inlining has been reported to have dramatic effects; see
  78 -- http://www.haskell.org//pipermail/haskell/2006-May/017907.html
  79 withMVar :: MVar a -> (a -> IO b) -> IO b
  80 withMVar m io =
  81   block $ do
  82     a <- takeMVar m
  83     b <- Exception.catch (unblock (io a))
  84             (\e -> do putMVar m a; throw e)
  85     putMVar m a
  86     return b
  87
  88 {-|
  89   A safe wrapper for modifying the contents of an 'MVar'.  Like 'withMVar',
  90   'modifyMVar' will replace the original contents of the 'MVar' if an
  91   exception is raised during the operation.
  92 -}
  93 {-# INLINE modifyMVar_ #-}
  94 modifyMVar_ :: MVar a -> (a -> IO a) -> IO ()
  95 modifyMVar_ m io =
  96   block $ do
  97     a  <- takeMVar m
  98     a' <- Exception.catch (unblock (io a))
  99             (\e -> do putMVar m a; throw e)
 100     putMVar m a'
 101
 102 {-|
 103   A slight variation on 'modifyMVar_' that allows a value to be
 104   returned (@b@) in addition to the modified value of the 'MVar'.
 105 -}
 106 {-# INLINE modifyMVar #-}
 107 modifyMVar :: MVar a -> (a -> IO (a,b)) -> IO b
 108 modifyMVar m io =
 109   block $ do
 110     a      <- takeMVar m
 111     (a',b) <- Exception.catch (unblock (io a))
 112                 (\e -> do putMVar m a; throw e)
 113     putMVar m a'
 114     return b