tests/meta.g

   1 s         ::=  Grammar ws                  => "gram"
   2 ws       !::=  w** | w** "//" (~[\n]*) "\n" ws
   3 wp       !::=  w++
   4 Grammar   ::=  r +/ ws                        => "grammar"
   5
   6 r         ::=  word  ^"::=" alternatives /ws
   7             |  word ^"!::=" alternatives /ws
   8
   9 alternatives  ::=  (Conjuncts +/ (ws "|" ws)) +/ (ws ">" ws)
  10
  11 Conjuncts     ::=  Sequence
  12                 |  Sequence ^"&"  e*/ws   /ws
  13                 |  Sequence ^"&~" e*/ws   /ws
  14
  15 ps         ::= e*/ws                              => "ps"
  16              | (e+/ws ws)? "^" Quoted (ws e+/ws)? => "ps2"
  17 psy        ::= ps
  18              | ps wp ^"/" ws e
  19 psx        ::= psy                   => "psy"
  20              | e "<-" psy        /ws => "psyl"
  21              |        psy "->" e /ws => "psyr"
  22              | e "<-" psy "->" e /ws => "psylr"
  23 Sequence   ::= Quoted => "qprod"
  24              > psx
  25              | psx  "=>" ^"[]"         /ws
  26              | psx ^"=>" (word|Quoted) /ws
  27
  28 ec       ::= ~[\-\]\\]
  29            | escaped
  30
  31 Range    ::= ec          => "range"
  32            | ec ^"-" ec
  33
  34 e        ::=  word                          => "nonTerminal"
  35            |  Quoted                        => "literal"
  36            |    ^"()"
  37            |    ^"{" Sequence "}"       /ws
  38            |    ^"["  Range* "]"
  39
  40            |  (e ^"++"    /ws > e ^"+"    /ws)
  41            |  (e ^"++/" e /ws > e ^"+/" e /ws)
  42            |  (e ^"**"    /ws > e ^"*"    /ws)
  43            |  (e ^"**/" e /ws > e ^"*/" e /ws)
  44            |  e ^"?"                    /ws
  45
  46            |     "(" word         ^")"  /ws
  47            >    ^"(" alternatives  ")"  /ws
  48            |    ^"~" e
  49
  50 w       !::= " "
  51            | "\n"
  52            | "\r"
  53 word     ::= [a-zA-Z0-9_]++
  54 Quoted   ::= "\"" ((~[\"\\] | escaped)+) "\""
  55            | "\"\"" => ""
  56 escaped  ::= "\\n" => "\n"
  57            | "\\r" => "\r"
  58            | "\\" ~[nr]
  59
  60