tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r $$ ws => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 alternatives  ::=  equiAlt   $$ (ws ">" ws)
   8 equiAlt       ::=  conjuncts $$ (ws "|" ws)          => "alternatives"
   9
  10 sequence    ::= Es
  11               > Es ^"/" e  /ws
  12 Es          ::= e+
  13 es          ::= e %% ws
  14
  15
  16 conjuncts   ::=  rewrite
  17               |  rewrite ^"&"  sequence   /ws
  18               |  rewrite ^"&~" sequence   /ws
  19
  20 rewrite  ::=  sequence                  /ws        => "rewrite"
  21            |  sequence ^"=>" word       /ws
  22            |  sequence ^"=>" quoted     /ws
  23            |  sequence  "=>" "()"       /ws        => "wrap"
  24
  25 ec       ::= [~\-\]\\\~]
  26            | escaped
  27
  28 range    ::= ec          => "range0"
  29            | ec ^"-" ec  => "range1"
  30
  31 e        ::= word                             => "nonTerminalY"
  32            |    [(][)] => "epsilon"
  33            |    ^"{" alternatives "}"   /ws
  34            |     "["  ranges "]"        => "range"
  35            |     "[~" ranges "]"        => "rangex"
  36            |  e ^"%%" e                 /ws
  37            |  e ^"$$" e                 /ws
  38            |  e ^"?"                    /ws
  39            |  e ^"~/~"                  /ws
  40
  41            |  e ^"-"  e                 /ws
  42
  43            |    ^"!" e                  /ws
  44            |     "^" quoted             /ws => "care"
  45            |    ^"`" e                  /ws
  46            |  e ^"#"                    /ws
  47            |  quoted                        => "literal"
  48
  49            |  (e ws ^"**" > e ws ^"*")
  50            |  (e ws ^"++" > e ws ^"+")
  51
  52            |     "(" word ^")"          /ws
  53            >    ^"(" alternatives ")"   /ws
  54
  55 ranges ::= range*
  56
  57 w       !::= " "
  58            | "//" [~\n]* "\n"
  59            | "\n"
  60            | "\r"
  61 an       ::= [a-zA-Z0-9_]
  62 word     ::= an++                           => "sify"
  63 quoted   ::= "\"" ([~\"\\] | escaped)* "\"" => "sify"
  64 escaped  ::= "\\n" => "\n"
  65            | "\\r" => "\r"
  66            | "\\" [~nr]
  67
  68