tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r +/ ws                        => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 alternatives  ::=  equiAlt   +/ (ws ">" ws)
   8 equiAlt       ::=  conjuncts +/ (ws "|" ws)
   9
  10 conjuncts   ::=  rewrite
  11               |  rewrite ^"&"  e*/ws   /ws
  12               |  rewrite ^"&~" e*/ws   /ws
  13
  14 sequence    ::= e*/ws
  15                 (ws "/" e)?
  16                 (ws "=>" ws (word|quoted))?              => "seq"
  17
  18 rewrite  ::=  sequence
  19
  20 ec       ::= [~\-\]\\\~]
  21            | escaped
  22
  23 range    ::= ec          => "range"
  24            | ec ^"-" ec
  25
  26 e        ::= word                             => "nonTerminal"
  27            |    [(][)]                        => "epsilon"
  28            |    ^"{" alternatives "}"   /ws
  29            |    ^"["  (range*) "]"
  30            |    ^"[~" (range*) "]"
  31            |    ^"^" quoted             /ws
  32            |    ^"!" e                  /ws
  33
  34            |  (e ws ^"**" > e ws ^"*")
  35            |  e ^"*/" e                 /ws
  36            |  (e ws ^"++" > e ws ^"+")
  37            |  e ^"+/" e                 /ws
  38            |  e ^"?"                    /ws
  39
  40            |  quoted                        => "literal"
  41
  42            |     "(" word ^")"          /ws
  43            >    ^"(" alternatives ")"   /ws
  44
  45 w       !::= " "
  46            | "//" ([~\n]*) "\n"
  47            | "\n"
  48            | "\r"
  49 word     ::= [a-zA-Z0-9_]++
  50 quoted   ::= "\"" (([~\"\\] | escaped)+) "\""
  51            | "\"\"" => ""
  52 escaped  ::= "\\n" => "\n"
  53            | "\\r" => "\r"
  54            | "\\" [~nr]
  55
  56