tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r+/ws => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 ec        ::=  [~\]\\\-\~] | escaped
   8
   9 alternatives  ::=  equiAlt   +/ (ws ">" ws)
  10 equiAlt       ::=  conjuncts +/ (ws "|" ws)          => "alternatives"
  11
  12 sequence    ::= Es
  13               > Es ^"/" e  /ws
  14 Es          ::= e+
  15 //es          ::= E+/ws
  16
  17 conjuncts   ::=  rewrite
  18               |  rewrite ^"&"  sequence   /ws
  19               |  rewrite ^"&~" sequence   /ws
  20
  21 rewrite  ::=  sequence                  /ws        => "rewrite"
  22            |  sequence ^"=>" word       /ws
  23            |  sequence ^"=>" quoted     /ws
  24            |  sequence  "=>" "()"       /ws        => "wrap"
  25
  26 range    ::= ec => "range0" | ec ^"-" ec      => "range0"
  27 e        ::= word                             => "nonTerminalY"
  28            |    [(][)] => "epsilon"
  29            |    ^"{" alternatives "}"   /ws
  30            |     "[" [\~]?  range* "]"        => "range"
  31            |  e ^"*/" e                 /ws
  32            |  e ^"+/" e                 /ws
  33            |  e ^"?"                    /ws
  34            |  e ^"~/~"                  /ws
  35
  36            |  e ^"-"  e                 /ws
  37
  38            |    ^"!" e                  /ws
  39            |     "^" quoted             /ws => "care"
  40            |    ^"`" e                  /ws
  41            |  e ^"#"                    /ws
  42            |  quoted                        => "literal"
  43
  44            |  (e ws ^"**" > e ws ^"*")
  45            |  (e ws ^"++" > e ws ^"+")
  46
  47            |     "(" word ^")"          /ws
  48            >    ^"(" alternatives ")"   /ws
  49
  50 w       !::= " "
  51            | "//" [~\n]* "\n"
  52            | "\n"
  53            | "\r"
  54 an       ::= [a-zA-Z0-9_]
  55 word     ::= an++                           => "sify"
  56 quoted   ::= "\"" ([~\"\\] | escaped)* "\"" => "sify"
  57 escaped  ::= "\\n" => "\n"
  58            | "\\r" => "\r"
  59            | "\\" [~nr]