tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r +/ ws                        => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 alternatives  ::=  equiAlt   +/ (ws ">" ws)
   8 equiAlt       ::=  conjuncts +/ (ws "|" ws)
   9
  10 sequence    ::= es
  11               > es ws ^"/" e
  12 es          ::= e */ (w**)
  13
  14 ss ::= es => "seq" | es ^"/" e /ws
  15
  16 conjuncts   ::=  rewrite
  17               |  rewrite ^"&"  e*/ws   /ws
  18               |  rewrite ^"&~" e*/ws   /ws
  19
  20 rewrite  ::=  sequence                  /ws        => "rewrite"
  21            |  sequence ^"=>" word       /ws
  22            |  sequence ^"=>" quoted     /ws
  23
  24 ec       ::= [~\-\]\\\~]
  25            | escaped
  26
  27 range    ::= ec          => "range"
  28            | ec ^"-" ec
  29
  30 e        ::= word                             => "nonTerminal"
  31            |    [(][)]                        => "epsilon"
  32            |    ^"{" alternatives "}"   /ws
  33            |    ^"["  (range*) "]"
  34            |    ^"[~" (range*) "]"
  35            |    ^"^" quoted             /ws
  36            |    ^"!" e                  /ws
  37
  38            |  (e ws ^"**" > e ws ^"*")
  39            |  e ^"*/" e                 /ws
  40            |  (e ws ^"++" > e ws ^"+")
  41            |  e ^"+/" e                 /ws
  42            |  e ^"?"                    /ws
  43
  44            |  quoted                        => "literal"
  45
  46            |     "(" word ^")"          /ws
  47            >    ^"(" alternatives ")"   /ws
  48
  49 w       !::= " "
  50            | "//" ([~\n]*) "\n"
  51            | "\n"
  52            | "\r"
  53 an       ::= [a-zA-Z0-9_]
  54 word     ::= an++
  55 quoted   ::= "\"" (([~\"\\] | escaped)+) "\""
  56            | "\"\"" => ""
  57 escaped  ::= "\\n" => "\n"
  58            | "\\r" => "\r"
  59            | "\\" [~nr]
  60
  61