tests/meta.g

   1 s         ::=  ws grammar ws                  => "gram"
   2 ws       !::=  w**
   3 grammar   ::=  r+/ws => "grammar"
   4 r         ::=  word  ^"::=" alternatives /ws
   5             |  word ^"!::=" alternatives /ws
   6
   7 ec        ::=  [~\]\\\-\~] | escaped
   8
   9 alternatives  ::=  equiAlt   +/ (ws ">" ws)
  10 equiAlt       ::=  conjuncts +/ (ws "|" ws)          => "alternatives"
  11
  12 sequence    ::= Es
  13               > Es ^"/" e  /ws
  14 Es          ::= e+
  15 es          ::= e+/ws
  16
  17 conjuncts   ::=  rewrite
  18               |  rewrite ^"&"  sequence   /ws
  19               |  rewrite ^"&~" sequence   /ws
  20
  21 rewrite  ::=  sequence                  /ws        => "rewrite"
  22            |  sequence ^"=>" word       /ws
  23            |  sequence ^"=>" quoted     /ws
  24            |  sequence  "=>" "()"       /ws        => "wrap"
  25
  26 range    ::= ec          => "range0"
  27            | ec ^"-" ec  => "range0"
  28
  29 e        ::= word                             => "nonTerminalY"
  30            |    [(][)] => "epsilon"
  31            |    ^"{" alternatives "}"   /ws
  32            |     "[" [\~]?  range* "]"        => "range"
  33            |  e ^"*/" e                 /ws
  34            |  e ^"+/" e                 /ws
  35            |  e ^"?"                    /ws
  36            |  e ^"~/~"                  /ws
  37
  38            |  e ^"-"  e                 /ws
  39
  40            |    ^"!" e                  /ws
  41            |     "^" quoted             /ws => "care"
  42            |    ^"`" e                  /ws
  43            |  e ^"#"                    /ws
  44            |  quoted                        => "literal"
  45
  46            |  (e ws ^"**" > e ws ^"*")
  47            |  (e ws ^"++" > e ws ^"+")
  48
  49            |     "(" word ^")"          /ws
  50            >    ^"(" alternatives ")"   /ws
  51
  52 w       !::= " "
  53            | "//" [~\n]* "\n"
  54            | "\n"
  55            | "\r"
  56 an       ::= [a-zA-Z0-9_]
  57 word     ::= an++                           => "sify"
  58 quoted   ::= "\"" ([~\"\\] | escaped)* "\"" => "sify"
  59 escaped  ::= "\\n" => "\n"
  60            | "\\r" => "\r"
  61            | "\\" [~nr]
  62
  63