utils/genprimopcode/Main.hs

   1 {-# OPTIONS -cpp #-}
   2 ------------------------------------------------------------------
   3 -- A primop-table mangling program                              --
   4 ------------------------------------------------------------------
   5
   6 module Main where
   7
   8 import Parser
   9 import Syntax
  10
  11 import Monad
  12 import Char
  13 import List
  14 import System ( getArgs )
  15 import Maybe ( catMaybes )
  16
  17 main :: IO ()
  18 main = getArgs >>= \args ->
  19        if length args /= 1 || head args `notElem` known_args
  20        then error ("usage: genprimopcode command < primops.txt > ...\n"
  21                    ++ "   where command is one of\n"
  22                    ++ unlines (map ("            "++) known_args)
  23                   )
  24        else
  25        do s <- getContents
  26           case parse s of
  27              Left err -> error ("parse error at " ++ (show err))
  28              Right p_o_specs@(Info _ entries)
  29                 -> seq (sanityTop p_o_specs) (
  30                    case head args of
  31
  32                       "--data-decl"
  33                          -> putStr (gen_data_decl p_o_specs)
  34
  35                       "--has-side-effects"
  36                          -> putStr (gen_switch_from_attribs
  37                                        "has_side_effects"
  38                                        "primOpHasSideEffects" p_o_specs)
  39
  40                       "--out-of-line"
  41                          -> putStr (gen_switch_from_attribs
  42                                        "out_of_line"
  43                                        "primOpOutOfLine" p_o_specs)
  44
  45                       "--commutable"
  46                          -> putStr (gen_switch_from_attribs
  47                                        "commutable"
  48                                        "commutableOp" p_o_specs)
  49
  50                       "--needs-wrapper"
  51                          -> putStr (gen_switch_from_attribs
  52                                        "needs_wrapper"
  53                                        "primOpNeedsWrapper" p_o_specs)
  54
  55                       "--can-fail"
  56                          -> putStr (gen_switch_from_attribs
  57                                        "can_fail"
  58                                        "primOpCanFail" p_o_specs)
  59
  60                       "--strictness"
  61                          -> putStr (gen_switch_from_attribs
  62                                        "strictness"
  63                                        "primOpStrictness" p_o_specs)
  64
  65                       "--primop-primop-info"
  66                          -> putStr (gen_primop_info p_o_specs)
  67
  68                       "--primop-tag"
  69                          -> putStr (gen_primop_tag p_o_specs)
  70
  71                       "--primop-list"
  72                          -> putStr (gen_primop_list p_o_specs)
  73
  74                       "--make-haskell-wrappers"
  75                          -> putStr (gen_wrappers p_o_specs)
  76
  77                       "--make-haskell-source"
  78                          -> putStr (gen_hs_source p_o_specs)
  79
  80                       "--make-ext-core-source"
  81                          -> putStr (gen_ext_core_source entries)
  82
  83                       "--make-latex-doc"
  84                          -> putStr (gen_latex_doc p_o_specs)
  85
  86                       _ -> error "Should not happen, known_args out of sync?"
  87                    )
  88
  89 known_args :: [String]
  90 known_args
  91    = [ "--data-decl",
  92        "--has-side-effects",
  93        "--out-of-line",
  94        "--commutable",
  95        "--needs-wrapper",
  96        "--can-fail",
  97        "--strictness",
  98        "--primop-primop-info",
  99        "--primop-tag",
 100        "--primop-list",
 101        "--make-haskell-wrappers",
 102        "--make-haskell-source",
 103        "--make-ext-core-source",
 104        "--make-latex-doc"
 105      ]
 106
 107 ------------------------------------------------------------------
 108 -- Code generators -----------------------------------------------
 109 ------------------------------------------------------------------
 110
 111 gen_hs_source :: Info -> String
 112 gen_hs_source (Info defaults entries) =
 113            "-----------------------------------------------------------------------------\n"
 114         ++ "-- |\n"
 115         ++ "-- Module      :  GHC.Prim\n"
 116         ++ "-- \n"
 117         ++ "-- Maintainer  :  cvs-ghc@haskell.org\n"
 118         ++ "-- Stability   :  internal\n"
 119         ++ "-- Portability :  non-portable (GHC extensions)\n"
 120         ++ "--\n"
 121         ++ "-- GHC\'s primitive types and operations.\n"
 122         ++ "--\n"
 123         ++ "-----------------------------------------------------------------------------\n"
 124         ++ "module GHC.Prim (\n"
 125         ++ unlines (map (("\t" ++) . hdr) entries)
 126         ++ ") where\n\n{-\n"
 127         ++ unlines (map opt defaults) ++ "-}\n"
 128         ++ unlines (map ent entries) ++ "\n\n\n"
 129      where opt (OptionFalse n)    = n ++ " = False"
 130            opt (OptionTrue n)     = n ++ " = True"
 131            opt (OptionString n v) = n ++ " = { " ++ v ++ "}"
 132
 133            hdr s@(Section {})                    = sec s
 134            hdr (PrimOpSpec { name = n })         = wrapOp n ++ ","
 135            hdr (PseudoOpSpec { name = n })       = wrapOp n ++ ","
 136            hdr (PrimTypeSpec { ty = TyApp n _ }) = wrapTy n ++ ","
 137            hdr (PrimTypeSpec {})                 = error "Illegal type spec"
 138
 139            ent   (Section {})      = ""
 140            ent o@(PrimOpSpec {})   = spec o
 141            ent o@(PrimTypeSpec {}) = spec o
 142            ent o@(PseudoOpSpec {}) = spec o
 143
 144            sec s = "\n-- * " ++ escape (title s) ++ "\n"
 145                         ++ (unlines $ map ("-- " ++ ) $ lines $ unlatex $ escape $ "|" ++ desc s) ++ "\n"
 146
 147            spec o = comm ++ decl
 148              where decl = case o of
 149                         PrimOpSpec { name = n, ty = t }   -> wrapOp n ++ " :: " ++ pty t
 150                         PseudoOpSpec { name = n, ty = t } -> wrapOp n ++ " :: " ++ pty t
 151                         PrimTypeSpec { ty = t }   -> "data " ++ pty t
 152                         Section { } -> ""
 153
 154                    comm = case (desc o) of
 155                         [] -> ""
 156                         d -> "\n" ++ (unlines $ map ("-- " ++ ) $ lines $ unlatex $ escape $ "|" ++ d)
 157
 158                    pty (TyF t1 t2) = pbty t1 ++ " -> " ++ pty t2
 159                    pty t           = pbty t
 160
 161                    pbty (TyApp tc ts) = tc ++ (concat (map (' ':) (map paty ts)))
 162                    pbty (TyUTup ts)   = "(# " ++ (concat (intersperse "," (map pty ts))) ++ " #)"
 163                    pbty t             = paty t
 164
 165                    paty (TyVar tv)      = tv
 166                    paty t               = "(" ++ pty t ++ ")"
 167
 168            wrapOp nm | isAlpha (head nm) = nm
 169                      | otherwise         = "(" ++ nm ++ ")"
 170            wrapTy nm | isAlpha (head nm) = nm
 171                      | otherwise         = "(" ++ nm ++ ")"
 172            unlatex s = case s of
 173                 '\\':'t':'e':'x':'t':'t':'t':'{':cs -> markup "@" "@" cs
 174                 '{':'\\':'t':'t':cs -> markup "@" "@" cs
 175                 '{':'\\':'i':'t':cs -> markup "/" "/" cs
 176                 c : cs -> c : unlatex cs
 177                 [] -> []
 178            markup s t xs = s ++ mk (dropWhile isSpace xs)
 179                 where mk ""        = t
 180                       mk ('\n':cs) = ' ' : mk cs
 181                       mk ('}':cs)  = t ++ unlatex cs
 182                       mk (c:cs)    = c : mk cs
 183            escape = concatMap (\c -> if c `elem` special then '\\':c:[] else c:[])
 184                 where special = "/'`\"@<"
 185
 186 -- Generates the type environment that the stand-alone External Core tools use.
 187 gen_ext_core_source :: [Entry] -> String
 188 gen_ext_core_source entries =
 189       "-----------------------------------------------------------------------\n"
 190    ++ "-- This module is automatically generated by the GHC utility\n"
 191    ++ "-- \"genprimopcode\". Do not edit!\n"
 192    ++ "-----------------------------------------------------------------------\n"
 193    ++ "module Language.Core.PrimEnv(primTcs, primVals, intLitTypes, ratLitTypes,"
 194    ++ "\n charLitTypes, stringLitTypes) where\nimport Language.Core.Core"
 195    ++ "\nimport Language.Core.Encoding\n\n"
 196    ++ "primTcs :: [(Tcon, Kind)]\n"
 197    ++ "primTcs = [\n"
 198    ++ printList tcEnt entries
 199    ++ "   ]\n"
 200    ++ "primVals :: [(Var, Ty)]\n"
 201    ++ "primVals = [\n"
 202    ++ printList valEnt entries
 203    ++ "]\n"
 204    ++ "intLitTypes :: [Ty]\n"
 205    ++ "intLitTypes = [\n"
 206    ++ printList tyEnt (intLitTys entries)
 207    ++ "]\n"
 208    ++ "ratLitTypes :: [Ty]\n"
 209    ++ "ratLitTypes = [\n"
 210    ++ printList tyEnt (ratLitTys entries)
 211    ++ "]\n"
 212    ++ "charLitTypes :: [Ty]\n"
 213    ++ "charLitTypes = [\n"
 214    ++ printList tyEnt (charLitTys entries)
 215    ++ "]\n"
 216    ++ "stringLitTypes :: [Ty]\n"
 217    ++ "stringLitTypes = [\n"
 218    ++ printList tyEnt (stringLitTys entries)
 219    ++ "]\n\n"
 220
 221   where printList f = concat . intersperse ",\n" . filter (not . null) . map f
 222         tcEnt  (PrimTypeSpec {ty=t}) =
 223            case t of
 224             TyApp tc args -> parens tc (tcKind tc args)
 225             _             -> error ("tcEnt: type in PrimTypeSpec is not a type"
 226                               ++ " constructor: " ++ show t)
 227         tcEnt  _                = ""
 228         -- hack alert!
 229         -- The primops.txt.pp format doesn't have enough information in it to
 230         -- print out some of the information that ext-core needs (like kinds,
 231         -- and later on in this code, module names) so we special-case. An
 232         -- alternative would be to refer to things indirectly and hard-wire
 233         -- certain things (e.g., the kind of the Any constructor, here) into
 234         -- ext-core's Prims module again.
 235         tcKind "Any" _                = "Klifted"
 236         tcKind tc [] | last tc == '#' = "Kunlifted"
 237         tcKind tc [] | otherwise      = "Klifted"
 238         -- assumes that all type arguments are lifted (are they?)
 239         tcKind tc (v:as)              = "(Karrow Klifted " ++ tcKind tc as
 240                                         ++ ")"
 241         valEnt (PseudoOpSpec {name=n, ty=t}) = valEntry n t
 242         valEnt (PrimOpSpec {name=n, ty=t})   = valEntry n t
 243         valEnt _                             = ""
 244         valEntry name ty = parens name (mkForallTy (freeTvars ty) (pty ty))
 245             where pty (TyF t1 t2) = mkFunTy (pty t1) (pty t2)
 246                   pty (TyApp tc ts) = mkTconApp (mkTcon tc) (map pty ts)
 247                   pty (TyUTup ts)   = mkUtupleTy (map pty ts)
 248                   pty (TyVar tv)    = paren $ "Tvar \"" ++ tv ++ "\""
 249
 250                   mkFunTy s1 s2 = "Tapp " ++ (paren ("Tapp (Tcon tcArrow)"
 251                                                ++ " " ++ paren s1))
 252                                           ++ " " ++ paren s2
 253                   mkTconApp tc args = foldl tapp tc args
 254                   mkTcon tc = paren $ "Tcon " ++ paren (qualify True tc)
 255                   mkUtupleTy args = foldl tapp (tcUTuple (length args)) args
 256                   mkForallTy [] t = t
 257                   mkForallTy vs t = foldr
 258                      (\ v s -> "Tforall " ++
 259                                (paren (quot v ++ ", " ++ vKind v)) ++ " "
 260                                ++ paren s) t vs
 261
 262                   -- hack alert!
 263                   vKind "o" = "Kopen"
 264                   vKind _   = "Klifted"
 265
 266                   freeTvars (TyF t1 t2)   = freeTvars t1 `union` freeTvars t2
 267                   freeTvars (TyApp _ tys) = freeTvarss tys
 268                   freeTvars (TyVar v)     = [v]
 269                   freeTvars (TyUTup tys)  = freeTvarss tys
 270                   freeTvarss = nub . concatMap freeTvars
 271
 272                   tapp s nextArg = paren $ "Tapp " ++ s ++ " " ++ paren nextArg
 273                   tcUTuple n = paren $ "Tcon " ++ paren (qualify False $ "Z"
 274                                                           ++ show n ++ "H")
 275
 276         tyEnt (PrimTypeSpec {ty=(TyApp tc args)}) = "   " ++ paren ("Tcon " ++
 277                                                        (paren (qualify True tc)))
 278         tyEnt _ = ""
 279
 280         -- more hacks. might be better to do this on the ext-core side,
 281         -- as per earlier comment
 282         qualify _ tc | tc == "Bool" = "Just boolMname" ++ ", "
 283                                                 ++ ze True tc
 284         qualify _ tc | tc == "()"  = "Just baseMname" ++ ", "
 285                                                 ++ ze True tc
 286         qualify enc tc = "Just primMname" ++ ", " ++ (ze enc tc)
 287         ze enc tc      = (if enc then "zEncodeString " else "")
 288                                       ++ "\"" ++ tc ++ "\""
 289
 290         intLitTys = prefixes ["Int", "Word", "Addr", "Char"]
 291         ratLitTys = prefixes ["Float", "Double"]
 292         charLitTys = prefixes ["Char"]
 293         stringLitTys = prefixes ["Addr"]
 294         prefixes ps = filter (\ t ->
 295                         case t of
 296                           (PrimTypeSpec {ty=(TyApp tc args)}) ->
 297                             any (\ p -> p `isPrefixOf` tc) ps
 298                           _ -> False)
 299
 300         parens n ty = "      (zEncodeString \"" ++ n ++ "\", " ++ ty ++ ")"
 301         paren s = "(" ++ s ++ ")"
 302         quot s = "\"" ++ s ++ "\""
 303
 304 gen_latex_doc :: Info -> String
 305 gen_latex_doc (Info defaults entries)
 306    = "\\primopdefaults{"
 307          ++ mk_options defaults
 308          ++ "}\n"
 309      ++ (concat (map mk_entry entries))
 310      where mk_entry (PrimOpSpec {cons=constr,name=n,ty=t,cat=c,desc=d,opts=o}) =
 311                  "\\primopdesc{"
 312                  ++ latex_encode constr ++ "}{"
 313                  ++ latex_encode n ++ "}{"
 314                  ++ latex_encode (zencode n) ++ "}{"
 315                  ++ latex_encode (show c) ++ "}{"
 316                  ++ latex_encode (mk_source_ty t) ++ "}{"
 317                  ++ latex_encode (mk_core_ty t) ++ "}{"
 318                  ++ d ++ "}{"
 319                  ++ mk_options o
 320                  ++ "}\n"
 321            mk_entry (Section {title=ti,desc=d}) =
 322                  "\\primopsection{"
 323                  ++ latex_encode ti ++ "}{"
 324                  ++ d ++ "}\n"
 325            mk_entry (PrimTypeSpec {ty=t,desc=d,opts=o}) =
 326                  "\\primtypespec{"
 327                  ++ latex_encode (mk_source_ty t) ++ "}{"
 328                  ++ latex_encode (mk_core_ty t) ++ "}{"
 329                  ++ d ++ "}{"
 330                  ++ mk_options o
 331                  ++ "}\n"
 332            mk_entry (PseudoOpSpec {name=n,ty=t,desc=d,opts=o}) =
 333                  "\\pseudoopspec{"
 334                  ++ latex_encode (zencode n) ++ "}{"
 335                  ++ latex_encode (mk_source_ty t) ++ "}{"
 336                  ++ latex_encode (mk_core_ty t) ++ "}{"
 337                  ++ d ++ "}{"
 338                  ++ mk_options o
 339                  ++ "}\n"
 340            mk_source_ty typ = pty typ
 341              where pty (TyF t1 t2) = pbty t1 ++ " -> " ++ pty t2
 342                    pty t = pbty t
 343                    pbty (TyApp tc ts) = tc ++ (concat (map (' ':) (map paty ts)))
 344                    pbty (TyUTup ts) = "(# " ++ (concat (intersperse "," (map pty ts))) ++ " #)"
 345                    pbty t = paty t
 346                    paty (TyVar tv) = tv
 347                    paty t = "(" ++ pty t ++ ")"
 348
 349            mk_core_ty typ = foralls ++ (pty typ)
 350              where pty (TyF t1 t2) = pbty t1 ++ " -> " ++ pty t2
 351                    pty t = pbty t
 352                    pbty (TyApp tc ts) = (zencode tc) ++ (concat (map (' ':) (map paty ts)))
 353                    pbty (TyUTup ts) = (zencode (utuplenm (length ts))) ++ (concat ((map (' ':) (map paty ts))))
 354                    pbty t = paty t
 355                    paty (TyVar tv) = zencode tv
 356                    paty (TyApp tc []) = zencode tc
 357                    paty t = "(" ++ pty t ++ ")"
 358                    utuplenm 1 = "(# #)"
 359                    utuplenm n = "(#" ++ (replicate (n-1) ',') ++ "#)"
 360                    foralls = if tvars == [] then "" else "%forall " ++ (tbinds tvars)
 361                    tvars = tvars_of typ
 362                    tbinds [] = ". "
 363                    tbinds ("o":tbs) = "(o::?) " ++ (tbinds tbs)
 364                    tbinds (tv:tbs) = tv ++ " " ++ (tbinds tbs)
 365            tvars_of (TyF t1 t2) = tvars_of t1 `union` tvars_of t2
 366            tvars_of (TyApp _ ts) = foldl union [] (map tvars_of ts)
 367            tvars_of (TyUTup ts) = foldr union [] (map tvars_of ts)
 368            tvars_of (TyVar tv) = [tv]
 369
 370            mk_options o =
 371              "\\primoptions{"
 372               ++ mk_has_side_effects o ++ "}{"
 373               ++ mk_out_of_line o ++ "}{"
 374               ++ mk_commutable o ++ "}{"
 375               ++ mk_needs_wrapper o ++ "}{"
 376               ++ mk_can_fail o ++ "}{"
 377               ++ latex_encode (mk_strictness o) ++ "}{"
 378               ++ "}"
 379
 380            mk_has_side_effects o = mk_bool_opt o "has_side_effects" "Has side effects." "Has no side effects."
 381            mk_out_of_line o = mk_bool_opt o "out_of_line" "Implemented out of line." "Implemented in line."
 382            mk_commutable o = mk_bool_opt o "commutable" "Commutable." "Not commutable."
 383            mk_needs_wrapper o = mk_bool_opt o "needs_wrapper" "Needs wrapper." "Needs no wrapper."
 384            mk_can_fail o = mk_bool_opt o "can_fail" "Can fail." "Cannot fail."
 385
 386            mk_bool_opt o opt_name if_true if_false =
 387              case lookup_attrib opt_name o of
 388                Just (OptionTrue _) -> if_true
 389                Just (OptionFalse _) -> if_false
 390                Just (OptionString _ _) -> error "String value for boolean option"
 391                Nothing -> ""
 392
 393            mk_strictness o =
 394              case lookup_attrib "strictness" o of
 395                Just (OptionString _ s) -> s  -- for now
 396                Just _ -> error "Boolean value for strictness"
 397                Nothing -> ""
 398
 399            zencode xs =
 400              case maybe_tuple xs of
 401                 Just n  -> n            -- Tuples go to Z2T etc
 402                 Nothing -> concat (map encode_ch xs)
 403              where
 404                maybe_tuple "(# #)" = Just("Z1H")
 405                maybe_tuple ('(' : '#' : cs) = case count_commas (0::Int) cs of
 406                                                 (n, '#' : ')' : _) -> Just ('Z' : shows (n+1) "H")
 407                                                 _                  -> Nothing
 408                maybe_tuple "()" = Just("Z0T")
 409                maybe_tuple ('(' : cs)       = case count_commas (0::Int) cs of
 410                                                 (n, ')' : _) -> Just ('Z' : shows (n+1) "T")
 411                                                 _            -> Nothing
 412                maybe_tuple _                 = Nothing
 413
 414                count_commas :: Int -> String -> (Int, String)
 415                count_commas n (',' : cs) = count_commas (n+1) cs
 416                count_commas n cs          = (n,cs)
 417
 418                unencodedChar :: Char -> Bool    -- True for chars that don't need encoding
 419                unencodedChar 'Z' = False
 420                unencodedChar 'z' = False
 421                unencodedChar c   = isAlphaNum c
 422
 423                encode_ch :: Char -> String
 424                encode_ch c | unencodedChar c = [c]      -- Common case first
 425
 426                -- Constructors
 427                encode_ch '('  = "ZL"    -- Needed for things like (,), and (->)
 428                encode_ch ')'  = "ZR"    -- For symmetry with (
 429                encode_ch '['  = "ZM"
 430                encode_ch ']'  = "ZN"
 431                encode_ch ':'  = "ZC"
 432                encode_ch 'Z'  = "ZZ"
 433
 434                -- Variables
 435                encode_ch 'z'  = "zz"
 436                encode_ch '&'  = "za"
 437                encode_ch '|'  = "zb"
 438                encode_ch '^'  = "zc"
 439                encode_ch '$'  = "zd"
 440                encode_ch '='  = "ze"
 441                encode_ch '>'  = "zg"
 442                encode_ch '#'  = "zh"
 443                encode_ch '.'  = "zi"
 444                encode_ch '<'  = "zl"
 445                encode_ch '-'  = "zm"
 446                encode_ch '!'  = "zn"
 447                encode_ch '+'  = "zp"
 448                encode_ch '\'' = "zq"
 449                encode_ch '\\' = "zr"
 450                encode_ch '/'  = "zs"
 451                encode_ch '*'  = "zt"
 452                encode_ch '_'  = "zu"
 453                encode_ch '%'  = "zv"
 454                encode_ch c    = 'z' : shows (ord c) "U"
 455
 456            latex_encode [] = []
 457            latex_encode (c:cs) | c `elem` "#$%&_^{}" = "\\" ++ c:(latex_encode cs)
 458            latex_encode ('~':cs) = "\\verb!~!" ++ (latex_encode cs)
 459            latex_encode ('\\':cs) = "$\\backslash$" ++ (latex_encode cs)
 460            latex_encode (c:cs) = c:(latex_encode cs)
 461
 462 gen_wrappers :: Info -> String
 463 gen_wrappers (Info _ entries)
 464    = "{-# LANGUAGE NoImplicitPrelude #-}\n"
 465         -- Dependencies on Prelude must be explicit in libraries/base, but we
 466         -- don't need the Prelude here so we add NoImplicitPrelude.
 467      ++ "module GHC.PrimopWrappers where\n"
 468      ++ "import qualified GHC.Prim\n"
 469      ++ unlines (map f (filter (not.dodgy) (filter is_primop entries)))
 470      where
 471         f spec = let args = map (\n -> "a" ++ show n) [1 .. arity (ty spec)]
 472                      src_name = wrap (name spec)
 473                  in "{-# NOINLINE " ++ src_name ++ " #-}\n" ++
 474                     src_name ++ " " ++ unwords args
 475                      ++ " = (GHC.Prim." ++ name spec ++ ") " ++ unwords args
 476         wrap nm | isLower (head nm) = nm
 477                 | otherwise = "(" ++ nm ++ ")"
 478
 479         dodgy spec
 480            = name spec `elem`
 481              [-- C code generator can't handle these
 482               "seq#",
 483               "tagToEnum#",
 484               -- not interested in parallel support
 485               "par#", "parGlobal#", "parLocal#", "parAt#",
 486               "parAtAbs#", "parAtRel#", "parAtForNow#"
 487              ]
 488
 489 gen_primop_list :: Info -> String
 490 gen_primop_list (Info _ entries)
 491    = unlines (
 492         [      "   [" ++ cons first       ]
 493         ++
 494         map (\p -> "   , " ++ cons p) rest
 495         ++
 496         [     "   ]"     ]
 497      ) where (first:rest) = filter is_primop entries
 498
 499 gen_primop_tag :: Info -> String
 500 gen_primop_tag (Info _ entries)
 501    = unlines (max_def_type : max_def :
 502               tagOf_type : zipWith f primop_entries [1 :: Int ..])
 503      where
 504         primop_entries = filter is_primop entries
 505         tagOf_type = "tagOf_PrimOp :: PrimOp -> FastInt"
 506         f i n = "tagOf_PrimOp " ++ cons i ++ " = _ILIT(" ++ show n ++ ")"
 507         max_def_type = "maxPrimOpTag :: Int"
 508         max_def      = "maxPrimOpTag = " ++ show (length primop_entries)
 509
 510 gen_data_decl :: Info -> String
 511 gen_data_decl (Info _ entries)
 512    = let conss = map cons (filter is_primop entries)
 513      in  "data PrimOp\n   = " ++ head conss ++ "\n"
 514          ++ unlines (map ("   | "++) (tail conss))
 515
 516 gen_switch_from_attribs :: String -> String -> Info -> String
 517 gen_switch_from_attribs attrib_name fn_name (Info defaults entries)
 518    = let defv = lookup_attrib attrib_name defaults
 519          alternatives = catMaybes (map mkAlt (filter is_primop entries))
 520
 521          getAltRhs (OptionFalse _)    = "False"
 522          getAltRhs (OptionTrue _)     = "True"
 523          getAltRhs (OptionString _ s) = s
 524
 525          mkAlt po
 526             = case lookup_attrib attrib_name (opts po) of
 527                  Nothing -> Nothing
 528                  Just xx -> Just (fn_name ++ " " ++ cons po ++ " = " ++ getAltRhs xx)
 529
 530      in
 531          case defv of
 532             Nothing -> error ("gen_switch_from: " ++ attrib_name)
 533             Just xx
 534                -> unlines alternatives
 535                   ++ fn_name ++ " _ = " ++ getAltRhs xx ++ "\n"
 536
 537 ------------------------------------------------------------------
 538 -- Create PrimOpInfo text from PrimOpSpecs -----------------------
 539 ------------------------------------------------------------------
 540
 541 gen_primop_info :: Info -> String
 542 gen_primop_info (Info _ entries)
 543    = unlines (map mkPOItext (filter is_primop entries))
 544
 545 mkPOItext :: Entry -> String
 546 mkPOItext i = mkPOI_LHS_text i ++ mkPOI_RHS_text i
 547
 548 mkPOI_LHS_text :: Entry -> String
 549 mkPOI_LHS_text i
 550    = "primOpInfo " ++ cons i ++ " = "
 551
 552 mkPOI_RHS_text :: Entry -> String
 553 mkPOI_RHS_text i
 554    = case cat i of
 555         Compare
 556            -> case ty i of
 557                  TyF t1 (TyF _ _)
 558                     -> "mkCompare " ++ sl_name i ++ ppType t1
 559                  _ -> error "Type error in comparison op"
 560         Monadic
 561            -> case ty i of
 562                  TyF t1 _
 563                     -> "mkMonadic " ++ sl_name i ++ ppType t1
 564                  _ -> error "Type error in monadic op"
 565         Dyadic
 566            -> case ty i of
 567                  TyF t1 (TyF _ _)
 568                     -> "mkDyadic " ++ sl_name i ++ ppType t1
 569                  _ -> error "Type error in dyadic op"
 570         GenPrimOp
 571            -> let (argTys, resTy) = flatTys (ty i)
 572                   tvs = nub (tvsIn (ty i))
 573               in
 574                   "mkGenPrimOp " ++ sl_name i ++ " "
 575                       ++ listify (map ppTyVar tvs) ++ " "
 576                       ++ listify (map ppType argTys) ++ " "
 577                       ++ "(" ++ ppType resTy ++ ")"
 578
 579 sl_name :: Entry -> String
 580 sl_name i = "(fsLit \"" ++ name i ++ "\") "
 581
 582 ppTyVar :: String -> String
 583 ppTyVar "a" = "alphaTyVar"
 584 ppTyVar "b" = "betaTyVar"
 585 ppTyVar "c" = "gammaTyVar"
 586 ppTyVar "s" = "deltaTyVar"
 587 ppTyVar "o" = "openAlphaTyVar"
 588 ppTyVar _   = error "Unknown type var"
 589
 590 ppType :: Ty -> String
 591 ppType (TyApp "Bool"        []) = "boolTy"
 592
 593 ppType (TyApp "Int#"        []) = "intPrimTy"
 594 ppType (TyApp "Int32#"      []) = "int32PrimTy"
 595 ppType (TyApp "Int64#"      []) = "int64PrimTy"
 596 ppType (TyApp "Char#"       []) = "charPrimTy"
 597 ppType (TyApp "Word#"       []) = "wordPrimTy"
 598 ppType (TyApp "Word32#"     []) = "word32PrimTy"
 599 ppType (TyApp "Word64#"     []) = "word64PrimTy"
 600 ppType (TyApp "Addr#"       []) = "addrPrimTy"
 601 ppType (TyApp "Float#"      []) = "floatPrimTy"
 602 ppType (TyApp "Double#"     []) = "doublePrimTy"
 603 ppType (TyApp "ByteArray#"  []) = "byteArrayPrimTy"
 604 ppType (TyApp "RealWorld"   []) = "realWorldTy"
 605 ppType (TyApp "ThreadId#"   []) = "threadIdPrimTy"
 606 ppType (TyApp "ForeignObj#" []) = "foreignObjPrimTy"
 607 ppType (TyApp "BCO#"        []) = "bcoPrimTy"
 608 ppType (TyApp "()"          []) = "unitTy"      -- unitTy is TysWiredIn's name for ()
 609
 610 ppType (TyVar "a")               = "alphaTy"
 611 ppType (TyVar "b")               = "betaTy"
 612 ppType (TyVar "c")               = "gammaTy"
 613 ppType (TyVar "s")               = "deltaTy"
 614 ppType (TyVar "o")               = "openAlphaTy"
 615 ppType (TyApp "State#" [x])      = "mkStatePrimTy " ++ ppType x
 616 ppType (TyApp "MutVar#" [x,y])   = "mkMutVarPrimTy " ++ ppType x
 617                                    ++ " " ++ ppType y
 618 ppType (TyApp "MutableArray#" [x,y]) = "mkMutableArrayPrimTy " ++ ppType x
 619                                     ++ " " ++ ppType y
 620
 621 ppType (TyApp "MutableByteArray#" [x]) = "mkMutableByteArrayPrimTy "
 622                                    ++ ppType x
 623
 624 ppType (TyApp "Array#" [x])      = "mkArrayPrimTy " ++ ppType x
 625
 626
 627 ppType (TyApp "Weak#"  [x])      = "mkWeakPrimTy " ++ ppType x
 628 ppType (TyApp "StablePtr#"  [x])      = "mkStablePtrPrimTy " ++ ppType x
 629 ppType (TyApp "StableName#"  [x])      = "mkStableNamePrimTy " ++ ppType x
 630
 631 ppType (TyApp "MVar#" [x,y])     = "mkMVarPrimTy " ++ ppType x
 632                                    ++ " " ++ ppType y
 633 ppType (TyApp "TVar#" [x,y])     = "mkTVarPrimTy " ++ ppType x
 634                                    ++ " " ++ ppType y
 635 ppType (TyUTup ts)               = "(mkTupleTy Unboxed " ++ show (length ts)
 636                                    ++ " "
 637                                    ++ listify (map ppType ts) ++ ")"
 638
 639 ppType (TyF s d) = "(mkFunTy (" ++ ppType s ++ ") (" ++ ppType d ++ "))"
 640
 641 ppType other
 642    = error ("ppType: can't handle: " ++ show other ++ "\n")
 643
 644 listify :: [String] -> String
 645 listify ss = "[" ++ concat (intersperse ", " ss) ++ "]"
 646
 647 flatTys :: Ty -> ([Ty],Ty)
 648 flatTys (TyF t1 t2) = case flatTys t2 of (ts,t) -> (t1:ts,t)
 649 flatTys other       = ([],other)
 650
 651 tvsIn :: Ty -> [TyVar]
 652 tvsIn (TyF t1 t2)    = tvsIn t1 ++ tvsIn t2
 653 tvsIn (TyApp _ tys)  = concatMap tvsIn tys
 654 tvsIn (TyVar tv)     = [tv]
 655 tvsIn (TyUTup tys)   = concatMap tvsIn tys
 656
 657 arity :: Ty -> Int
 658 arity = length . fst . flatTys
 659